libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_INIT(package-unused, version-unused,, libgo)
  10 AC_CONFIG_SRCDIR(Makefile.am)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 libtool_VERSION=14:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 AM_ENABLE_MULTILIB(, ..)
  17
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$host_alias}
  20
  21 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist subdir-objects -Wall -Wno-portability -Wno-override])
  22 AH_TEMPLATE(PACKAGE, [Name of package])
  23 AH_TEMPLATE(VERSION, [Version number of package])
  24
  25 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  26 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  27 AC_PROG_CC
  28 AC_PROG_GO
  29 AM_PROG_AS
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39     ;;
  40 esac
  41
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_LD
  45 AC_PROG_RANLIB
  46 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  47
  48 AC_LIBTOOL_DLOPEN
  49 AM_PROG_LIBTOOL
  50 AC_SUBST(enable_shared)
  51 AC_SUBST(enable_static)
  52
  53 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  54 AC_SUBST(CC_FOR_BUILD)
  55
  56 AC_PROG_AWK
  57
  58 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  59 AC_SUBST(WARN_FLAGS)
  60
  61 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  62                                       [turns on -Werror @<:@default=yes@:>@])])
  63 if test "x$enable_werror" != "xno"; then
  64   WERROR="-Werror"
  65 fi
  66 AC_SUBST(WERROR)
  67
  68 glibgo_toolexecdir=no
  69 glibgo_toolexeclibdir=no
  70
  71 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  72 AC_ARG_ENABLE([version-specific-runtime-libs],
  73   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  74                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  75   [case "$enableval" in
  76     yes) version_specific_libs=yes ;;
  77     no)  version_specific_libs=no ;;
  78     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  79    esac],
  80   [version_specific_libs=no])
  81 AC_MSG_RESULT($version_specific_libs)
  82
  83 # Version-specific runtime libs processing.
  84 if test $version_specific_libs = yes; then
  85   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  86   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  87 fi
  88
  89 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  90 # Install a library built with a cross compiler in tooldir, not libdir.
  91 if test -n "$with_cross_host" &&
  92    test x"$with_cross_host" != x"no"; then
  93   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  94   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  95 else
  96   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  97   nover_glibgo_toolexeclibdir='${libdir}'
  98 fi
  99 multi_os_directory=`$GOC -print-multi-os-directory`
 100 case $multi_os_directory in
 101   .) ;; # Avoid trailing /.
 102   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 103 esac
 104
 105 if test x"$glibgo_toolexecdir" = x"no"; then
 106   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 107   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 108 fi
 109
 110 AC_SUBST(glibgo_toolexecdir)
 111 AC_SUBST(glibgo_toolexeclibdir)
 112 AC_SUBST(nover_glibgo_toolexeclibdir)
 113
 114 # See if the user wants to configure without libffi.  Some
 115 # architectures don't support it.  FIXME: We should set a default
 116 # based on the host.
 117 AC_ARG_WITH(libffi,
 118   AS_HELP_STRING([--without-libffi],
 119                  [don't use libffi]),
 120   [:],
 121   [with_libffi=${with_libffi_default-yes}])
 122
 123 LIBFFI=
 124 LIBFFIINCS=
 125 if test "$with_libffi" != no; then
 126    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 127    LIBFFI=../libffi/libffi_convenience.la
 128    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 129 fi
 130 AC_SUBST(LIBFFI)
 131 AC_SUBST(LIBFFIINCS)
 132 AM_CONDITIONAL(USE_LIBFFI, test "$with_libffi" != "no")
 133
 134 # See if the user wants to configure without libatomic. This is useful if we are
 135 # on an architecture for which libgo does not need an atomic support library and
 136 # libatomic does not support our C compiler.
 137 AC_ARG_WITH(libatomic,
 138   AS_HELP_STRING([--without-libatomic],
 139                  [don't use libatomic]),
 140   [:],
 141   [with_libatomic=${with_libatomic_default-yes}])
 142
 143 LIBATOMIC=
 144 if test "$with_libatomic" != no; then
 145    LIBATOMIC=../libatomic/libatomic_convenience.la
 146 fi
 147 AC_SUBST(LIBATOMIC)
 148
 149 # Used to tell GNU make to include a file without telling automake to
 150 # include it.
 151 go_include="-include"
 152 AC_SUBST(go_include)
 153
 154 # All known GOOS values.  This is the union of all operating systems
 155 # supported by the gofrontend and all operating systems supported by
 156 # the gc toolchain.
 157 ALLGOOS="aix android darwin dragonfly freebsd hurd irix js linux netbsd openbsd plan9 rtems solaris windows"
 158
 159 is_darwin=no
 160 is_freebsd=no
 161 is_irix=no
 162 is_linux=no
 163 is_netbsd=no
 164 is_openbsd=no
 165 is_dragonfly=no
 166 is_rtems=no
 167 is_solaris=no
 168 is_aix=no
 169 is_hurd=no
 170 GOOS=unknown
 171 case ${host} in
 172   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 173   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 174   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 175   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 176   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 177   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 178   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 179   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 180   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 181   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 182   *-*-gnu*)      is_hurd=yes;    GOOS=hurd ;;
 183 esac
 184 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 185 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 186 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 187 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 188 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 189 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 190 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 191 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 192 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 193 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 194 AM_CONDITIONAL(LIBGO_IS_HURD, test $is_hurd = yes)
 195 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 196 AC_SUBST(GOOS)
 197 AC_SUBST(ALLGOOS)
 198
 199 dnl Test whether we need to use DejaGNU or whether we can use the
 200 dnl simpler gotest approach.  We can only use gotest for a native
 201 dnl build.
 202 USE_DEJAGNU=no
 203 case ${host} in
 204   *-*-rtems*) USE_DEJAGNU=yes ;;
 205   ${build}) ;;
 206   *) USE_DEJAGNU=yes ;;
 207 esac
 208 AC_SUBST(USE_DEJAGNU)
 209
 210 # All known GOARCH values.  This is the union of all architectures
 211 # supported by the gofrontend and all architectures supported by the
 212 # gc toolchain.
 213 # To add a new architecture:
 214 # - add it to this list
 215 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 216 # - add an entry to the case on ${host} below to set GOARCH
 217 # - update goarchList in libgo/go/go/build/syslist.go
 218 # - update goarch.sh to report the values for this architecture
 219 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 220 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 221 # - update arch lists in libgo/match.sh
 222 # - update arch lists in libgo/testsuite/gotest
 223 # - update +build lines in several places
 224 #   - libgo/go/runtime/lfstack_NNbit.go
 225 #   - libgo/go/runtime/hashNN.go
 226 #   - libgo/go/runtime/unalignedN.go
 227 #   - libgo/go/syscall/endian_XX.go
 228 #   - possibly others
 229 # - possibly update files in libgo/go/internal/syscall/unix
 230 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le nios2 ppc ppc64 ppc64le riscv riscv64 s390 s390x sh shbe sparc sparc64 wasm"
 231
 232 # All known GOARCH family values.
 233 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 NIOS2 PPC PPC64 RISCV RISCV64 S390 S390X SH SPARC SPARC64 WASM"
 234
 235 GOARCH=unknown
 236 case ${host} in
 237   alpha*-*-*)
 238     GOARCH=alpha
 239     ;;
 240   aarch64-*-*)
 241     GOARCH=arm64
 242     ;;
 243   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 244     GOARCH=arm
 245     case ${host} in
 246       arm*b*-*-*)
 247         GOARCH=armbe
 248         ;;
 249     esac
 250     ;;
 251 changequote(,)dnl
 252   i[34567]86-*-* | x86_64-*-*)
 253 changequote([,])dnl
 254     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 255 #ifdef __x86_64__
 256 #error 64-bit
 257 #endif
 258 ])],
 259         [GOARCH=386],
 260         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 261 #ifdef __ILP32__
 262 #error x32
 263 #endif
 264 ])],
 265         [GOARCH=amd64],
 266         [GOARCH=amd64p32]))
 267     ;;
 268   ia64-*-*)
 269     GOARCH=ia64
 270     ;;
 271   m68k*-*-*)
 272     GOARCH=m68k
 273     ;;
 274   mips*-*-*)
 275     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 276 #if _MIPS_SIM != _ABIO32
 277 #error not o32
 278 #endif
 279 ])],
 280 [mips_abi="o32"],
 281         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 282 #if _MIPS_SIM != _ABIN32
 283 #error not n32
 284 #endif
 285 ])],
 286 [mips_abi="n32"],
 287         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 288 #if _MIPS_SIM != _ABI64
 289 #error not n64
 290 #endif
 291 ])],
 292 [mips_abi="n64"],
 293         [AC_MSG_ERROR([unknown MIPS ABI])
 294 [mips_abi="n32"]])])])
 295     case "$mips_abi" in
 296     "o32") GOARCH=mips ;;
 297     "n32") GOARCH=mips64p32 ;;
 298     "n64") GOARCH=mips64 ;;
 299     esac
 300     case "${host}" in
 301     mips*el-*-*)
 302         GOARCH="${GOARCH}le"
 303         ;;
 304     esac
 305     ;;
 306   nios2-*-*)
 307     GOARCH=nios2
 308     ;;
 309   rs6000*-*-* | powerpc*-*-*)
 310     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 311 #ifdef _ARCH_PPC64
 312 #error 64-bit
 313 #endif
 314 ])],
 315 [GOARCH=ppc],
 316     [
 317 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 318 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 319 #error 64be
 320 #endif
 321 ])],
 322 [GOARCH=ppc64le],
 323 [GOARCH=ppc64])])
 324     ;;
 325   riscv64-*-*)
 326     GOARCH=riscv64
 327     ;;
 328   s390*-*-*)
 329     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 330 #if defined(__s390x__)
 331 #error 64-bit
 332 #endif
 333 ])],
 334 [GOARCH=s390],
 335 [GOARCH=s390x])
 336     ;;
 337   sh3eb*-*-* | sh4eb*-*-*)
 338     GOARCH=shbe
 339     ;;
 340   sh3*-*-* | sh4*-*-*)
 341     GOARCH=sh
 342     ;;
 343   sparc*-*-*)
 344     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 345 #if defined(__sparcv9) || defined(__arch64__)
 346 #error 64-bit
 347 #endif
 348 ])],
 349 [GOARCH=sparc],
 350 [GOARCH=sparc64])
 351     ;;
 352 esac
 353 AC_SUBST(GOARCH)
 354 AC_SUBST(ALLGOARCH)
 355 AC_SUBST(ALLGOARCHFAMILY)
 356
 357 FUNCTION_DESCRIPTORS=false
 358 case ${host} in
 359   rs6000*-*-* | powerpc*-*-*)
 360     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 361 #if _CALL_ELF == 1
 362 #error descriptors
 363 #endif
 364 ])],
 365         [FUNCTION_DESCRIPTORS=false],
 366         [FUNCTION_DESCRIPTORS=true])
 367     ;;
 368 esac
 369 AC_SUBST(FUNCTION_DESCRIPTORS)
 370
 371 dnl Some files are only present when needed for specific architectures.
 372 GO_LIBCALL_OS_FILE=
 373 GO_LIBCALL_OS_ARCH_FILE=
 374 GO_SYSCALL_OS_FILE=
 375 GO_SYSCALL_OS_ARCH_FILE=
 376 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 377   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 378 fi
 379 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 380   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 381 fi
 382 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 383   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 384 fi
 385 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 386   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 387 fi
 388 AC_SUBST(GO_LIBCALL_OS_FILE)
 389 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 390 AC_SUBST(GO_SYSCALL_OS_FILE)
 391 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 392
 393 dnl Special flags used to generate sysinfo.go.
 394 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 395 case "$target" in
 396     mips-sgi-irix6.5*)
 397         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 398         # msghdr in <sys/socket.h>.
 399         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 400         ;;
 401     *-*-solaris2.*)
 402         # Solaris 10+ needs this so struct msghdr gets the msg_control
 403         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 404         # above doesn't work with C99.
 405         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 406         ;;
 407 esac
 408 AC_SUBST(OSCFLAGS)
 409
 410 dnl Check if assembler supports disabling hardware capability support.
 411 GCC_CHECK_ASSEMBLER_HWCAP
 412
 413 dnl Use -fsplit-stack when compiling C code if available.
 414 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 415 [libgo_cv_c_split_stack_supported],
 416 [CFLAGS_hold=$CFLAGS
 417 CFLAGS="$CFLAGS -fsplit-stack"
 418 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 419 [libgo_cv_c_split_stack_supported=yes],
 420 [libgo_cv_c_split_stack_supported=no])
 421 CFLAGS=$CFLAGS_hold])
 422
 423 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 424 dnl reject split-stack code calling non-split-stack code on targets
 425 dnl they don't support.
 426 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 427 [libgo_cv_c_linker_split_non_split],
 428 [cat > conftest1.c << EOF
 429 extern void f();
 430 int main() { f(); return 0; }
 431 EOF
 432 cat > conftest2.c << EOF
 433 void f() {}
 434 EOF
 435 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 436 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 437 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 438   libgo_cv_c_linker_split_non_split=yes
 439 else
 440   libgo_cv_c_linker_split_non_split=no
 441 fi
 442 rm -f conftest1.* conftest2.* conftest])
 443
 444 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 445   SPLIT_STACK=-fsplit-stack
 446   AC_DEFINE(USING_SPLIT_STACK, 1,
 447                 [Define if the compiler supports -fsplit-stack])
 448 else
 449   SPLIT_STACK=
 450 fi
 451 AC_SUBST(SPLIT_STACK)
 452 AM_CONDITIONAL(USING_SPLIT_STACK,
 453         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 454
 455 dnl If the compiler supports split-stack but the linker does not, then
 456 dnl we need to explicitly disable split-stack for Go.
 457 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 458   GO_SPLIT_STACK=-fno-split-stack
 459 else
 460   GO_SPLIT_STACK=
 461 fi
 462 AC_SUBST(GO_SPLIT_STACK)
 463
 464 dnl Check whether the linker does stack munging when calling from
 465 dnl split-stack into non-split-stack code.  We check this by looking
 466 dnl at the --help output.  FIXME: This is only half right: it's
 467 dnl possible for the linker to support this for some targets but not
 468 dnl others.
 469 dnl This is slightly different from the above check, which is whether
 470 dnl the linker permits the call at all.
 471 AC_CACHE_CHECK([whether linker supports split stack],
 472 [libgo_cv_c_linker_supports_split_stack],
 473 [libgo_cv_c_linker_supports_split_stack=no
 474 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 475   libgo_cv_c_linker_supports_split_stack=yes
 476 fi])
 477 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 478   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 479             [Define if the linker support split stack adjustments])
 480 fi
 481
 482 AC_CACHE_CHECK([whether compiler is llgo],
 483 [libgo_cv_c_goc_is_llgo],
 484 [libgo_cv_c_goc_is_llgo=no
 485 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 486   libgo_cv_c_goc_is_llgo=yes
 487 fi])
 488 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 489
 490 dnl Test for the -lm library.
 491 MATH_LIBS=
 492 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 493 AC_SUBST(MATH_LIBS)
 494
 495 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 496 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 497   [libgo_cv_lib_sockets=
 498    libgo_check_both=no
 499    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 500    if test "$libgo_check_socket" = "yes"; then
 501      unset ac_cv_func_connect
 502      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 503                   libgo_check_both=yes)
 504    fi
 505    if test "$libgo_check_both" = "yes"; then
 506      libgo_old_libs=$LIBS
 507      LIBS="$LIBS -lsocket -lnsl"
 508      unset ac_cv_func_accept
 509      AC_CHECK_FUNC(accept,
 510                    [libgo_check_nsl=no
 511                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 512      unset ac_cv_func_accept
 513      LIBS=$libgo_old_libs
 514    fi
 515    unset ac_cv_func_gethostbyname
 516    libgo_old_libs="$LIBS"
 517    AC_CHECK_FUNC(gethostbyname, ,
 518                  [AC_CHECK_LIB(nsl, main,
 519                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 520    unset ac_cv_func_gethostbyname
 521    AC_CHECK_FUNC(sendfile, ,
 522                  [AC_CHECK_LIB(sendfile, main,
 523                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 524    LIBS=$libgo_old_libs
 525 ])
 526 NET_LIBS="$libgo_cv_lib_sockets"
 527 AC_SUBST(NET_LIBS)
 528
 529 dnl Test whether the compiler supports the -pthread option.
 530 AC_CACHE_CHECK([whether -pthread is supported],
 531 [libgo_cv_lib_pthread],
 532 [CFLAGS_hold=$CFLAGS
 533 CFLAGS="$CFLAGS -pthread -L../libatomic/.libs"
 534 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 535 [libgo_cv_lib_pthread=yes],
 536 [libgo_cv_lib_pthread=no])
 537 CFLAGS=$CFLAGS_hold])
 538 PTHREAD_CFLAGS=
 539 if test "$libgo_cv_lib_pthread" = yes; then
 540   # RISC-V apparently adds -latomic when using -pthread.
 541   PTHREAD_CFLAGS="-pthread -L../libatomic/.libs"
 542 fi
 543 AC_SUBST(PTHREAD_CFLAGS)
 544
 545 dnl Test for the -lpthread library.
 546 PTHREAD_LIBS=
 547 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 548 AC_SUBST(PTHREAD_LIBS)
 549
 550 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 551 AC_SEARCH_LIBS([sched_yield], [rt])
 552 AC_SEARCH_LIBS([nanosleep], [rt])
 553 AC_SEARCH_LIBS([clock_gettime], [rt])
 554
 555 AC_C_BIGENDIAN
 556
 557 GCC_CHECK_UNWIND_GETIPINFO
 558
 559 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 560
 561 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 562 [#include <netinet/in.h>
 563 ])
 564
 565 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 566 [#ifdef HAVE_SYS_SOCKET_H
 567 #include <sys/socket.h>
 568 #endif
 569 ])
 570
 571 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 572
 573 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr memmem)
 574 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 575 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 576
 577 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 578 AC_TYPE_OFF_T
 579 AC_CHECK_TYPES([loff_t])
 580
 581 LIBS_hold="$LIBS"
 582 LIBS="$LIBS -lm"
 583 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 584 LIBS="$LIBS_hold"
 585
 586 CFLAGS_hold="$CFLAGS"
 587 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 588 LIBS_hold="$LIBS"
 589 LIBS="$LIBS $PTHREAD_LIBS"
 590 AC_CHECK_FUNCS(sem_timedwait)
 591 CFLAGS="$CFLAGS_hold"
 592 LIBS="$LIBS_hold"
 593
 594 LIBS_hold="$LIBS"
 595 LIBS="$LIBS $MATH_LIBS"
 596 AC_CHECK_FUNCS(matherr)
 597 LIBS="$LIBS_hold"
 598
 599 dnl For x86 we want to use the -minline-all-stringops option to avoid
 600 dnl forcing a stack split when calling memcpy and friends.
 601 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 602 [libgo_cv_c_stringops],
 603 [CFLAGS_hold=$CFLAGS
 604 CFLAGS="$CFLAGS -minline-all-stringops"
 605 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 606 [libgo_cv_c_stringops=yes],
 607 [libgo_cv_c_stringops=no])
 608 CFLAGS=$CFLAGS_hold])
 609 STRINGOPS_FLAG=
 610 if test "$libgo_cv_c_stringops" = yes; then
 611   STRINGOPS_FLAG=-minline-all-stringops
 612 fi
 613 AC_SUBST(STRINGOPS_FLAG)
 614
 615 dnl For x86 we want to compile the math library with -mfancy-math-387
 616 dnl so that we can use the builtin instructions directly.
 617 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 618 [libgo_cv_c_fancymath],
 619 [CFLAGS_hold=$CFLAGS
 620 CFLAGS="$CFLAGS -mfancy-math-387"
 621 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 622 [libgo_cv_c_fancymath=yes],
 623 [libgo_cv_c_fancymath=no])
 624 CFLAGS=$CFLAGS_hold])
 625 MATH_FLAG=
 626 if test "$libgo_cv_c_fancymath" = yes; then
 627   MATH_FLAG="-mfancy-math-387"
 628 fi
 629 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 630 AC_SUBST(MATH_FLAG)
 631
 632 CFLAGS_hold=$CFLAGS
 633 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 634 AC_CHECK_TYPES([off64_t])
 635 CFLAGS=$CFLAGS_hold
 636
 637 dnl Work out the size of the epoll_events struct on GNU/Linux.
 638 AC_CACHE_CHECK([epoll_event size],
 639 [libgo_cv_c_epoll_event_size],
 640 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 641 [sizeof (struct epoll_event)],
 642 [#include <sys/epoll.h>],
 643 [libgo_cv_c_epoll_event_size=0])])
 644 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 645 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 646
 647 dnl Work out the offset of the fd field in the epoll_events struct on
 648 dnl GNU/Linux.
 649 AC_CACHE_CHECK([epoll_event data.fd offset],
 650 [libgo_cv_c_epoll_event_fd_offset],
 651 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 652 [offsetof (struct epoll_event, data.fd)],
 653 [#include <stddef.h>
 654 #include <sys/epoll.h>],
 655 [libgo_cv_c_epoll_event_fd_offset=0])])
 656 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 657 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 658
 659 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 660 dnl in Solaris 11.4 for XPG7 compatibility.
 661 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 662                 [have_stat_timespec=yes], [have_stat_timespec=no])
 663 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 664
 665 dnl See if struct exception is defined in <math.h>.
 666 AC_CHECK_TYPE([struct exception],
 667 [libgo_has_struct_exception=yes],
 668 [libgo_has_struct_exception=no],
 669 [#include <math.h>])
 670 if test "$libgo_has_struct_exception" = "yes"; then
 671   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 672             [Define to 1 if <math.h> defines struct exception])
 673 fi
 674
 675 dnl See whether setcontext changes the value of TLS variables.
 676 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 677 [libgo_cv_lib_setcontext_clobbers_tls],
 678 [CFLAGS_hold="$CFLAGS"
 679 CFLAGS="$PTHREAD_CFLAGS"
 680 LIBS_hold="$LIBS"
 681 LIBS="$LIBS $PTHREAD_LIBS"
 682 AC_CHECK_SIZEOF([void *])
 683 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 684 AC_RUN_IFELSE(
 685   [AC_LANG_SOURCE([
 686 #include <pthread.h>
 687 #include <stdlib.h>
 688 #include <ucontext.h>
 689 #include <unistd.h>
 690
 691 __thread int tls;
 692
 693 static char stack[[10 * 1024 * 1024]];
 694 static ucontext_t c;
 695
 696 /* Called via makecontext/setcontext.  */
 697
 698 static void
 699 cfn (void)
 700 {
 701   exit (tls);
 702 }
 703
 704 /* Called via pthread_create.  */
 705
 706 static void *
 707 tfn (void *dummy)
 708 {
 709   /* The thread should still see this value after calling
 710      setcontext.  */
 711   tls = 0;
 712
 713   setcontext (&c);
 714
 715   /* The call to setcontext should not return.  */
 716   abort ();
 717 }
 718
 719 int
 720 main ()
 721 {
 722   pthread_t tid;
 723
 724   /* The thread should not see this value.  */
 725   tls = 1;
 726
 727   if (getcontext (&c) < 0)
 728     abort ();
 729
 730   c.uc_stack.ss_sp = stack;
 731 #ifdef MAKECONTEXT_STACK_TOP
 732   c.uc_stack.ss_sp += sizeof stack;
 733 #endif
 734   c.uc_stack.ss_flags = 0;
 735   c.uc_stack.ss_size = sizeof stack;
 736   c.uc_link = NULL;
 737   makecontext (&c, cfn, 0);
 738
 739   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 740     abort ();
 741
 742   if (pthread_join (tid, NULL) != 0)
 743     abort ();
 744
 745   /* The thread should have called exit.  */
 746   abort ();
 747 }
 748 ])],
 749 [libgo_cv_lib_setcontext_clobbers_tls=no],
 750 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 751 [case "$target:$ptr_type_size" in
 752   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 753     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 754   *)
 755     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 756  esac
 757 ])
 758 CFLAGS="$CFLAGS_hold"
 759 LIBS="$LIBS_hold"
 760 ])
 761 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 762   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 763             [Define if setcontext clobbers TLS variables])
 764 fi
 765
 766 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 767 libgo_cv_ro_eh_frame, [
 768 libgo_cv_ro_eh_frame=no
 769 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 770 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 771   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 772     libgo_cv_ro_eh_frame=yes
 773   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 774        | grep -v '#write' > /dev/null; then
 775     libgo_cv_ro_eh_frame=yes
 776   fi
 777 fi
 778 rm -f conftest.*
 779 ])
 780 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 781   AC_DEFINE(EH_FRAME_FLAGS, "a",
 782             [Define to the flags needed for the .section .eh_frame directive.])
 783 else
 784   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 785             [Define to the flags needed for the .section .eh_frame directive.])
 786 fi
 787
 788 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 789 [libgo_cv_c_unused_arguments],
 790 [CFLAGS_hold=$CFLAGS
 791 CFLAGS="$CFLAGS -Qunused-arguments"
 792 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 793 [libgo_cv_c_unused_arguments=yes],
 794 [libgo_cv_c_unused_arguments=no])
 795 CFLAGS=$CFLAGS_hold])
 796
 797 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 798 libgo_cv_as_comdat_gnu, [
 799 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 800 CFLAGS_hold=$CFLAGS
 801 if test "$libgo_cv_c_unused_arguments" = yes; then
 802   CFLAGS="$CFLAGS -Qunused-arguments"
 803 fi
 804 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 805   libgo_cv_as_comdat_gnu=yes
 806 else
 807   libgo_cv_as_comdat_gnu=no
 808 fi
 809 CFLAGS=$CFLAGS_hold
 810 ])
 811 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 812   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 813             [Define if your assembler supports GNU comdat group syntax.])
 814 fi
 815
 816 AC_CACHE_CHECK([assembler supports pc related relocs],
 817 libgo_cv_as_x86_pcrel, [
 818 libgo_cv_as_x86_pcrel=yes
 819 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 820 CFLAGS_hold=$CFLAGS
 821 if test "$libgo_cv_c_unused_arguments" = yes; then
 822   CFLAGS="$CFLAGS -Qunused-arguments"
 823 fi
 824 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 825     libgo_cv_as_x86_pcrel=no
 826 fi
 827 CFLAGS=$CFLAGS_hold
 828 ])
 829 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 830   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 831             [Define if your assembler supports PC relative relocs.])
 832 fi
 833
 834 AC_CACHE_CHECK([assembler supports unwind section type],
 835 libgo_cv_as_x86_64_unwind_section_type, [
 836 libgo_cv_as_x86_64_unwind_section_type=yes
 837 echo '.section .eh_frame,"a",@unwind' > conftest.s
 838 CFLAGS_hold=$CFLAGS
 839 if test "$libgo_cv_c_unused_arguments" = yes; then
 840   CFLAGS="$CFLAGS -Qunused-arguments"
 841 fi
 842 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 843     libgo_cv_as_x86_64_unwind_section_type=no
 844 fi
 845 CFLAGS=$CFLAGS_hold
 846 ])
 847 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 848   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 849             [Define if your assembler supports unwind section type.])
 850 fi
 851
 852 AC_CACHE_CHECK([assembler supports AES instructions],
 853 libgo_cv_as_x86_aes, [
 854 libgo_cv_as_x86_aes=yes
 855 echo 'aesenc %xmm0, %xmm1' > conftest.s
 856 CFLAGS_hold=$CFLAGS
 857 if test "$libgo_cv_c_unused_arguments" = yes; then
 858   CFLAGS="$CFLAGS -Qunused-arguments"
 859 fi
 860 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 861     libgo_cv_as_x86_aes=no
 862 fi
 863 CFLAGS=$CFLAGS_hold
 864 ])
 865 if test "x$libgo_cv_as_x86_aes" = xyes; then
 866   AC_DEFINE(HAVE_AS_X86_AES, 1,
 867             [Define if your assembler supports AES instructions.])
 868 fi
 869
 870 AC_CACHE_SAVE
 871
 872 if test ${multilib} = yes; then
 873   multilib_arg="--enable-multilib"
 874 else
 875   multilib_arg=
 876 fi
 877
 878 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 879
 880 AC_CONFIG_COMMANDS([default],
 881 [if test -n "$CONFIG_FILES"; then
 882    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 883    # that multilib installs will end up installed in the correct place.
 884    # The testsuite needs it for multilib-aware ABI baseline files.
 885    # To work around this not being passed down from config-ml.in ->
 886    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 887    # append it here.  Only modify Makefiles that have just been created.
 888    #
 889    # Also, get rid of this simulated-VPATH thing that automake does.
 890    cat > vpsed << \_EOF
 891 s!`test -f '$<' || echo '$(srcdir)/'`!!
 892 _EOF
 893    for i in $SUBDIRS; do
 894     case $CONFIG_FILES in
 895      *${i}/Makefile*)
 896        #echo "Adding MULTISUBDIR to $i/Makefile"
 897        sed -f vpsed $i/Makefile > tmp
 898        grep '^MULTISUBDIR =' Makefile >> tmp
 899        mv tmp $i/Makefile
 900        ;;
 901     esac
 902    done
 903    rm vpsed
 904  fi
 905 ],
 906 [
 907 # Variables needed in config.status (file generation) which aren't already
 908 # passed by autoconf.
 909 SUBDIRS="$SUBDIRS"
 910 ])
 911
 912 AC_OUTPUT