libitm/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2 #   Copyright (C) 2011-2023 Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 AC_INIT([GNU TM Runtime Library], 1.0,,[libitm])
  19 AC_CONFIG_HEADER(config.h)
  20
  21 # -------
  22 # Options
  23 # -------
  24
  25 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  26 LIBITM_ENABLE(version-specific-runtime-libs, no, ,
  27    [Specify that runtime libraries should be installed in a compiler-specific directory],
  28    permit yes|no)
  29 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  30
  31 # We would like our source tree to be readonly. However when releases or
  32 # pre-releases are generated, the flex/bison generated files as well as the
  33 # various formats of manuals need to be included along with the rest of the
  34 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  35 # just that.
  36 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  37 LIBITM_ENABLE(generated-files-in-srcdir, no, ,
  38    [put copies of generated files in source dir intended for creating source
  39     tarballs for users without texinfo bison or flex.],
  40    permit yes|no)
  41 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  42 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  43
  44
  45 # -------
  46 # -------
  47
  48 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  49 #
  50 # You will slowly go insane if you do not grok the following fact:  when
  51 # building this library, the top-level /target/ becomes the library's /host/.
  52 #
  53 # configure then causes --target to default to --host, exactly like any
  54 # other package using autoconf.  Therefore, 'target' and 'host' will
  55 # always be the same.  This makes sense both for native and cross compilers
  56 # just think about it for a little while.  :-)
  57 #
  58 # Also, if this library is being configured as part of a cross compiler, the
  59 # top-level configure script will pass the "real" host as $with_cross_host.
  60 #
  61 # Do not delete or change the following two lines.  For why, see
  62 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  63 AC_CANONICAL_SYSTEM
  64 target_alias=${target_alias-$host_alias}
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.9.0:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  no-dist:  we don't want 'dist' and related rules.
  73 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  74 #            file in the top srcdir, etc, etc), so stop complaining.
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is required.
  77 #  -Wno-override: ... and this one, since we do want this in testsuite.
  78 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  79 AM_ENABLE_MULTILIB(, ..)
  80
  81 GCC_WITH_TOOLEXECLIBDIR
  82
  83 # Calculate toolexeclibdir
  84 # Also toolexecdir, though it's only used in toolexeclibdir
  85 case ${enable_version_specific_runtime_libs} in
  86   yes)
  87     # Need the gcc compiler version to know where to install libraries
  88     # and header files if --enable-version-specific-runtime-libs option
  89     # is selected.
  90     toolexecdir='$(libdir)/gcc/$(target_alias)'
  91     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  92     ;;
  93   no)
  94     if test -n "$with_cross_host" &&
  95        test x"$with_cross_host" != x"no"; then
  96       # Install a library built with a cross compiler in tooldir, not libdir.
  97       toolexecdir='$(exec_prefix)/$(target_alias)'
  98       case ${with_toolexeclibdir} in
  99         no)
 100           toolexeclibdir='$(toolexecdir)/lib'
 101           ;;
 102         *)
 103           toolexeclibdir=${with_toolexeclibdir}
 104           ;;
 105       esac
 106     else
 107       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 108       toolexeclibdir='$(libdir)'
 109     fi
 110     multi_os_directory=`$CC -print-multi-os-directory`
 111     case $multi_os_directory in
 112       .) ;; # Avoid trailing /.
 113       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 114     esac
 115     ;;
 116 esac
 117 AC_SUBST(toolexecdir)
 118 AC_SUBST(toolexeclibdir)
 119
 120 # Check the compiler.
 121 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 122 # We must force CC to /not/ be precious variables; otherwise
 123 # the wrong, non-multilib-adjusted value will be used in multilibs.
 124 # As a side effect, we have to subst CFLAGS ourselves.
 125
 126 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 127 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 128 AC_PROG_CC
 129 AC_PROG_CXX
 130 AM_PROG_AS
 131 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 132
 133 AC_SUBST(CFLAGS)
 134
 135 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 136 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 137 # in both places for now and restore CFLAGS at the end of config.
 138 save_CFLAGS="$CFLAGS"
 139
 140 # Find other programs we need.
 141 AC_CHECK_TOOL(AR, ar)
 142 AC_CHECK_TOOL(NM, nm)
 143 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 144 AC_PROG_MAKE_SET
 145 AC_PROG_INSTALL
 146
 147 # See if makeinfo has been installed and is modern enough
 148 # that we can use it.
 149 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 150                    [GNU texinfo.* \([0-9][0-9.]*\)],
 151                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 152 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 153
 154
 155 # Configure libtool
 156 AM_PROG_LIBTOOL
 157 AC_SUBST(enable_shared)
 158 AC_SUBST(enable_static)
 159
 160 AM_MAINTAINER_MODE
 161
 162 # For libtool versioning info, format is CURRENT:REVISION:AGE
 163 libtool_VERSION=1:0:0
 164 AC_SUBST(libtool_VERSION)
 165
 166 # Check header files.
 167 AC_STDC_HEADERS
 168 AC_HEADER_TIME
 169 ACX_HEADER_STRING
 170 AC_CHECK_HEADERS(unistd.h semaphore.h sys/time.h sys/auxv.h malloc.h)
 171
 172 GCC_HEADER_STDINT(gstdint.h)
 173
 174 GCC_AC_FUNC_MMAP_BLACKLIST
 175
 176 AC_C_BIGENDIAN
 177 # I don't like the default behaviour of WORDS_BIGENDIAN undefined for LE.
 178 AH_BOTTOM(
 179 [#ifndef WORDS_BIGENDIAN
 180 #define WORDS_BIGENDIAN 0
 181 #endif])
 182
 183 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 184 # In case the pthread.h system header is not found, this test will fail.
 185 XPCFLAGS=""
 186 CFLAGS="$CFLAGS -pthread"
 187 AC_LINK_IFELSE(
 188  [AC_LANG_PROGRAM(
 189   [#include <pthread.h>
 190    void *g(void *d) { return NULL; }],
 191   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 192  [XPCFLAGS=" -Wc,-pthread"],
 193  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 194   AC_LINK_IFELSE(
 195    [AC_LANG_PROGRAM(
 196     [#include <pthread.h>
 197      void *g(void *d) { return NULL; }],
 198     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 199    [],
 200    [AC_MSG_ERROR([Pthreads are required to build libitm])])])
 201
 202 # Check for functions needed.
 203 AC_CHECK_FUNCS(strtoull memalign posix_memalign getauxval)
 204
 205 # Check for broken semaphore implementation on darwin.
 206 # sem_init returns: sem_init error: Function not implemented.
 207 case "$host" in
 208   *-darwin*)
 209     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 210         Define if the POSIX Semaphores do not work on your system.)
 211     ;;
 212 esac
 213
 214 GCC_LINUX_FUTEX(:)
 215
 216 # See if we support thread-local storage.
 217 GCC_CHECK_TLS
 218
 219 # See what sort of export controls are available.
 220 LIBITM_CHECK_ATTRIBUTE_VISIBILITY
 221 LIBITM_CHECK_ATTRIBUTE_DLLEXPORT
 222 LIBITM_CHECK_ATTRIBUTE_ALIAS
 223
 224 # Check linker hardware capability support.
 225 GCC_CHECK_LINKER_HWCAP
 226 # If defaulting to -mavx, don't clear hwcaps.
 227 AC_CHECK_DECL([__AVX__], [HWCAP_LDFLAGS=''])
 228
 229 LIBITM_ENABLE_SYMVERS
 230 if test $enable_symvers = gnu; then
 231   AC_DEFINE(LIBITM_GNU_SYMBOL_VERSIONING, 1,
 232             [Define to 1 if GNU symbol versioning is used for libitm.])
 233 fi
 234
 235 # See if we can emit unwind info in the sjlj stub.
 236 GCC_AS_CFI_PSEUDO_OP
 237
 238 # Determine the proper ABI type for size_t.
 239 LIBITM_CHECK_SIZE_T_MANGLING
 240
 241 # Get target configury.
 242 . ${srcdir}/configure.tgt
 243 if test -n "$UNSUPPORTED"; then
 244   AC_MSG_ERROR([Configuration ${target} is unsupported.])
 245 fi
 246
 247 CFLAGS="$save_CFLAGS $XCFLAGS"
 248
 249 # Check for __sync_val_compare_and_swap, but only after the target has
 250 # had a chance to set XCFLAGS.
 251 LIBITM_CHECK_SYNC_BUILTINS
 252 LIBITM_CHECK_64BIT_SYNC_BUILTINS
 253 LIBITM_CHECK_AS_AVX
 254 LIBITM_CHECK_AS_RTM
 255 LIBITM_CHECK_AS_HTM
 256
 257 GCC_CHECK_ELF_STYLE_WEAKREF
 258
 259 # Cleanup and exit.
 260 CFLAGS="$save_CFLAGS"
 261 AC_CACHE_SAVE
 262
 263 AC_ARG_ENABLE([werror],
 264   [AS_HELP_STRING([--disable-werror], [disable building with -Werror])])
 265 # Add -Wall -Werror if we are using GCC.
 266 AS_IF([test "x$GCC" = "xyes"],
 267   [XCFLAGS="$XCFLAGS -Wall"])
 268 AS_IF([test "x$enable_werror" != "xno" && test "x$GCC" = "xyes"],
 269   [XCFLAGS="$XCFLAGS -Werror"])
 270
 271 XCFLAGS="$XCFLAGS $XPCFLAGS"
 272
 273 # Add CET specific flags if CET is enabled
 274 GCC_CET_FLAGS(CET_FLAGS)
 275 XCFLAGS="$XCFLAGS $CET_FLAGS"
 276
 277 AC_SUBST(config_path)
 278 AC_SUBST(XCFLAGS)
 279 AC_SUBST(XLDFLAGS)
 280
 281 if test ${multilib} = yes; then
 282   multilib_arg="--enable-multilib"
 283 else
 284   multilib_arg=
 285 fi
 286
 287 # Set up the set of libraries that we need to link against for libitm.
 288 # Note that the GTM_SELF_SPECS in gcc.c will force -pthread for -fgnu-tm,
 289 # which will force linkage against -lpthread (or equivalent for the system).
 290 # That's not 100% ideal, but about the best we can do easily.
 291 if test $enable_shared = yes; then
 292   link_itm="-litm %{static: $LIBS}"
 293 else
 294   link_itm="-litm $LIBS"
 295 fi
 296 AC_SUBST(link_itm)
 297
 298 AM_CONDITIONAL([ARCH_ARM], [test "$ARCH" = arm])
 299 AM_CONDITIONAL([ARCH_X86], [test "$ARCH" = x86])
 300 AM_CONDITIONAL([ARCH_X86_AVX], [test "$libitm_cv_as_avx" = yes])
 301 AM_CONDITIONAL([ARCH_FUTEX], [test $enable_linux_futex = yes])
 302
 303 # Determine what GCC version number to use in filesystem paths.
 304 GCC_BASE_VER
 305
 306 AC_CONFIG_FILES(Makefile testsuite/Makefile libitm.spec)
 307 AC_OUTPUT