libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_INIT(package-unused, version-unused,, libgo)
  10 AC_CONFIG_SRCDIR(Makefile.am)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 libtool_VERSION=17:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 AM_ENABLE_MULTILIB(, ..)
  17
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$host_alias}
  20
  21 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist subdir-objects -Wall -Wno-portability -Wno-override])
  22 AH_TEMPLATE(PACKAGE, [Name of package])
  23 AH_TEMPLATE(VERSION, [Version number of package])
  24
  25 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  26 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  27 AC_PROG_CC
  28 AC_PROG_GO
  29 AM_PROG_AS
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39
  40     # Check default architecture for FAT library creation
  41     if test -z "`$CC -x c -E /dev/null -g3 -o - | grep 64BIT`" ; then
  42         AIX_EXTRA_ARCH='64'
  43     else
  44         AIX_EXTRA_ARCH='32'
  45     fi
  46     AC_SUBST(AIX_EXTRA_ARCH)
  47     ;;
  48 esac
  49
  50 AM_MAINTAINER_MODE
  51
  52 AC_PROG_LD
  53 AC_PROG_RANLIB
  54 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  55
  56 AC_LIBTOOL_DLOPEN
  57 AM_PROG_LIBTOOL
  58 AC_SUBST(enable_shared)
  59 AC_SUBST(enable_static)
  60
  61 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  62 AC_SUBST(CC_FOR_BUILD)
  63
  64 AC_PROG_AWK
  65
  66 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  67 AC_SUBST(WARN_FLAGS)
  68
  69 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  70                                       [turns on -Werror @<:@default=yes@:>@])])
  71 if test "x$enable_werror" != "xno"; then
  72   WERROR="-Werror"
  73 fi
  74 AC_SUBST(WERROR)
  75
  76 glibgo_toolexecdir=no
  77 glibgo_toolexeclibdir=no
  78
  79 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  80 AC_ARG_ENABLE([version-specific-runtime-libs],
  81   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  82                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  83   [case "$enableval" in
  84     yes) version_specific_libs=yes ;;
  85     no)  version_specific_libs=no ;;
  86     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  87    esac],
  88   [version_specific_libs=no])
  89 AC_MSG_RESULT($version_specific_libs)
  90
  91 GCC_WITH_TOOLEXECLIBDIR
  92
  93 # Version-specific runtime libs processing.
  94 if test $version_specific_libs = yes; then
  95   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  96   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  97 fi
  98
  99 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
 100 # Install a library built with a cross compiler in tooldir, not libdir.
 101 if test -n "$with_cross_host" &&
 102    test x"$with_cross_host" != x"no"; then
 103   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
 104   case ${with_toolexeclibdir} in
 105     no)
 106       nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
 107       ;;
 108     *)
 109       nover_glibgo_toolexeclibdir=${with_toolexeclibdir}
 110       ;;
 111   esac
 112 else
 113   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
 114   nover_glibgo_toolexeclibdir='${libdir}'
 115 fi
 116 multi_os_directory=`$GOC -print-multi-os-directory`
 117 case $multi_os_directory in
 118   .) ;; # Avoid trailing /.
 119   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 120 esac
 121
 122 if test x"$glibgo_toolexecdir" = x"no"; then
 123   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 124   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 125 fi
 126
 127 AC_SUBST(glibgo_toolexecdir)
 128 AC_SUBST(glibgo_toolexeclibdir)
 129 AC_SUBST(nover_glibgo_toolexeclibdir)
 130
 131 # See if the user wants to configure without libffi.  Some
 132 # architectures don't support it.  FIXME: We should set a default
 133 # based on the host.
 134 AC_ARG_WITH(libffi,
 135   AS_HELP_STRING([--without-libffi],
 136                  [don't use libffi]),
 137   [:],
 138   [with_libffi=${with_libffi_default-yes}])
 139
 140 LIBFFI=
 141 LIBFFIINCS=
 142 if test "$with_libffi" != no; then
 143    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 144    LIBFFI=../libffi/libffi_convenience.la
 145    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 146 fi
 147 AC_SUBST(LIBFFI)
 148 AC_SUBST(LIBFFIINCS)
 149 AM_CONDITIONAL(USE_LIBFFI, test "$with_libffi" != "no")
 150
 151 # See if the user wants to configure without libatomic. This is useful if we are
 152 # on an architecture for which libgo does not need an atomic support library and
 153 # libatomic does not support our C compiler.
 154 AC_ARG_WITH(libatomic,
 155   AS_HELP_STRING([--without-libatomic],
 156                  [don't use libatomic]),
 157   [:],
 158   [with_libatomic=${with_libatomic_default-yes}])
 159
 160 LIBATOMIC=
 161 if test "$with_libatomic" != no; then
 162    LIBATOMIC=../libatomic/libatomic_convenience.la
 163 fi
 164 AC_SUBST(LIBATOMIC)
 165
 166 # Used to tell GNU make to include a file without telling automake to
 167 # include it.
 168 go_include="-include"
 169 AC_SUBST(go_include)
 170
 171 # All known GOOS values.  This is the union of all operating systems
 172 # supported by the gofrontend and all operating systems supported by
 173 # the gc toolchain.
 174 ALLGOOS="aix android darwin dragonfly freebsd hurd illumos irix js linux netbsd openbsd plan9 rtems solaris windows"
 175
 176 is_darwin=no
 177 is_freebsd=no
 178 is_irix=no
 179 is_linux=no
 180 is_netbsd=no
 181 is_openbsd=no
 182 is_dragonfly=no
 183 is_rtems=no
 184 is_solaris=no
 185 is_aix=no
 186 is_hurd=no
 187 GOOS=unknown
 188 case ${host} in
 189   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 190   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 191   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 192   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 193   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 194   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 195   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 196   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 197   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 198   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 199   *-*-gnu*)      is_hurd=yes;    GOOS=hurd ;;
 200 esac
 201 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 202 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 203 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 204 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 205 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 206 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 207 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 208 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 209 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 210 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 211 AM_CONDITIONAL(LIBGO_IS_HURD, test $is_hurd = yes)
 212 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 213 AC_SUBST(GOOS)
 214 AC_SUBST(ALLGOOS)
 215
 216 dnl Test whether we need to use DejaGNU or whether we can use the
 217 dnl simpler gotest approach.  We can only use gotest for a native
 218 dnl build.
 219 USE_DEJAGNU=no
 220 case ${host} in
 221   *-*-rtems*) USE_DEJAGNU=yes ;;
 222   ${build}) ;;
 223   *) USE_DEJAGNU=yes ;;
 224 esac
 225 AC_SUBST(USE_DEJAGNU)
 226
 227 # All known GOARCH values.  This is the union of all architectures
 228 # supported by the gofrontend and all architectures supported by the
 229 # gc toolchain.
 230 # To add a new architecture:
 231 # - add it to this list
 232 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 233 # - add an entry to the case on ${host} below to set GOARCH
 234 # - update goarchList in libgo/go/go/build/syslist.go
 235 # - update goarch.sh to report the values for this architecture
 236 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 237 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 238 # - update arch lists in libgo/match.sh
 239 # - update arch lists in libgo/testsuite/gotest
 240 # - update +build lines in several places
 241 #   - libgo/go/runtime/lfstack_NNbit.go
 242 #   - libgo/go/runtime/hashNN.go
 243 #   - libgo/go/runtime/unalignedN.go
 244 #   - libgo/go/syscall/endian_XX.go
 245 #   - possibly others
 246 # - possibly update files in libgo/go/internal/syscall/unix
 247 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le nios2 ppc ppc64 ppc64le riscv riscv64 s390 s390x sh shbe sparc sparc64 wasm"
 248
 249 # All known GOARCH family values.
 250 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 NIOS2 PPC PPC64 RISCV RISCV64 S390 S390X SH SPARC SPARC64 WASM"
 251
 252 GOARCH=unknown
 253 case ${host} in
 254   alpha*-*-*)
 255     GOARCH=alpha
 256     ;;
 257   aarch64-*-*)
 258     GOARCH=arm64
 259     ;;
 260   aarch64_be-*-*)
 261     GOARCH=arm64be
 262     ;;
 263   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 264     GOARCH=arm
 265     case ${host} in
 266       arm*b*-*-*)
 267         GOARCH=armbe
 268         ;;
 269     esac
 270     ;;
 271 changequote(,)dnl
 272   i[34567]86-*-* | x86_64-*-*)
 273 changequote([,])dnl
 274     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 275 #ifdef __x86_64__
 276 #error 64-bit
 277 #endif
 278 ])],
 279         [GOARCH=386],
 280         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 281 #ifdef __ILP32__
 282 #error x32
 283 #endif
 284 ])],
 285         [GOARCH=amd64],
 286         [GOARCH=amd64p32]))
 287     ;;
 288   ia64-*-*)
 289     GOARCH=ia64
 290     ;;
 291   m68k*-*-*)
 292     GOARCH=m68k
 293     ;;
 294   mips*-*-*)
 295     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 296 #if _MIPS_SIM != _ABIO32
 297 #error not o32
 298 #endif
 299 ])],
 300 [mips_abi="o32"],
 301         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 302 #if _MIPS_SIM != _ABIN32
 303 #error not n32
 304 #endif
 305 ])],
 306 [mips_abi="n32"],
 307         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 308 #if _MIPS_SIM != _ABI64
 309 #error not n64
 310 #endif
 311 ])],
 312 [mips_abi="n64"],
 313         [AC_MSG_ERROR([unknown MIPS ABI])
 314 [mips_abi="n32"]])])])
 315     case "$mips_abi" in
 316     "o32") GOARCH=mips ;;
 317     "n32") GOARCH=mips64p32 ;;
 318     "n64") GOARCH=mips64 ;;
 319     esac
 320     case "${host}" in
 321     mips*el-*-*)
 322         GOARCH="${GOARCH}le"
 323         ;;
 324     esac
 325     ;;
 326   nios2-*-*)
 327     GOARCH=nios2
 328     ;;
 329   rs6000*-*-* | powerpc*-*-*)
 330     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 331 #ifdef _ARCH_PPC64
 332 #error 64-bit
 333 #endif
 334 ])],
 335 [GOARCH=ppc],
 336     [
 337 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 338 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 339 #error 64be
 340 #endif
 341 ])],
 342 [GOARCH=ppc64le],
 343 [GOARCH=ppc64])])
 344     ;;
 345   riscv*-*-*)
 346     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 347 #if __riscv_xlen == 64
 348 #error 64-bit
 349 #endif
 350 ])],
 351 [GOARCH=riscv],
 352 [GOARCH=riscv64])
 353     ;;
 354   s390*-*-*)
 355     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 356 #if defined(__s390x__)
 357 #error 64-bit
 358 #endif
 359 ])],
 360 [GOARCH=s390],
 361 [GOARCH=s390x])
 362     ;;
 363   sh3eb*-*-* | sh4eb*-*-*)
 364     GOARCH=shbe
 365     ;;
 366   sh3*-*-* | sh4*-*-*)
 367     GOARCH=sh
 368     ;;
 369   sparc*-*-*)
 370     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 371 #if defined(__sparcv9) || defined(__arch64__)
 372 #error 64-bit
 373 #endif
 374 ])],
 375 [GOARCH=sparc],
 376 [GOARCH=sparc64])
 377     ;;
 378 esac
 379 AC_SUBST(GOARCH)
 380 AC_SUBST(ALLGOARCH)
 381 AC_SUBST(ALLGOARCHFAMILY)
 382
 383 AM_CONDITIONAL(LIBGO_IS_X86, test "$GOARCH" = "386" -o "$GOARCH" = "amd64" -o "$GOARCH" = "amd64p32")
 384
 385 FUNCTION_DESCRIPTORS=false
 386 case ${host} in
 387   rs6000*-*-* | powerpc*-*-*)
 388     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 389 #if _CALL_ELF == 1
 390 #error descriptors
 391 #endif
 392 ])],
 393         [FUNCTION_DESCRIPTORS=false],
 394         [FUNCTION_DESCRIPTORS=true])
 395     ;;
 396 esac
 397 AC_SUBST(FUNCTION_DESCRIPTORS)
 398
 399 dnl Some files are only present when needed for specific architectures.
 400 GO_LIBCALL_OS_FILE=
 401 GO_LIBCALL_OS_ARCH_FILE=
 402 GO_SYSCALL_OS_FILE=
 403 GO_SYSCALL_OS_ARCH_FILE=
 404 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 405   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 406 fi
 407 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 408   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 409 fi
 410 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 411   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 412 fi
 413 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 414   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 415 fi
 416 AC_SUBST(GO_LIBCALL_OS_FILE)
 417 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 418 AC_SUBST(GO_SYSCALL_OS_FILE)
 419 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 420
 421 dnl Special flags used to generate sysinfo.go.
 422 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 423 case "$target" in
 424     mips-sgi-irix6.5*)
 425         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 426         # msghdr in <sys/socket.h>.
 427         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 428         ;;
 429     *-*-solaris2.*)
 430         # Solaris 10+ needs this so struct msghdr gets the msg_control
 431         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 432         # above doesn't work with C99.
 433         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 434         ;;
 435 esac
 436 AC_SUBST(OSCFLAGS)
 437
 438 dnl Check if assembler supports disabling hardware capability support.
 439 GCC_CHECK_ASSEMBLER_HWCAP
 440
 441 dnl Use -fsplit-stack when compiling C code if available.
 442 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 443 [libgo_cv_c_split_stack_supported],
 444 [CFLAGS_hold=$CFLAGS
 445 CFLAGS="$CFLAGS -fsplit-stack"
 446 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 447 [libgo_cv_c_split_stack_supported=yes],
 448 [libgo_cv_c_split_stack_supported=no])
 449 CFLAGS=$CFLAGS_hold])
 450
 451 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 452 dnl reject split-stack code calling non-split-stack code on targets
 453 dnl they don't support.
 454 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 455 [libgo_cv_c_linker_split_non_split],
 456 [cat > conftest1.c << EOF
 457 extern void f();
 458 int main() { f(); return 0; }
 459 EOF
 460 cat > conftest2.c << EOF
 461 void f() {}
 462 EOF
 463 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 464 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 465 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 466   libgo_cv_c_linker_split_non_split=yes
 467 else
 468   libgo_cv_c_linker_split_non_split=no
 469 fi
 470 rm -f conftest1.* conftest2.* conftest])
 471
 472 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 473   SPLIT_STACK=-fsplit-stack
 474   AC_DEFINE(USING_SPLIT_STACK, 1,
 475                 [Define if the compiler supports -fsplit-stack])
 476 else
 477   SPLIT_STACK=
 478 fi
 479 AC_SUBST(SPLIT_STACK)
 480 AM_CONDITIONAL(USING_SPLIT_STACK,
 481         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 482
 483 dnl If the compiler supports split-stack but the linker does not, then
 484 dnl we need to explicitly disable split-stack for Go.
 485 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 486   GO_SPLIT_STACK=-fno-split-stack
 487 else
 488   GO_SPLIT_STACK=
 489 fi
 490 AC_SUBST(GO_SPLIT_STACK)
 491
 492 dnl Check whether the linker does stack munging when calling from
 493 dnl split-stack into non-split-stack code.  We check this by looking
 494 dnl at the --help output.  FIXME: This is only half right: it's
 495 dnl possible for the linker to support this for some targets but not
 496 dnl others.
 497 dnl This is slightly different from the above check, which is whether
 498 dnl the linker permits the call at all.
 499 AC_CACHE_CHECK([whether linker supports split stack],
 500 [libgo_cv_c_linker_supports_split_stack],
 501 [libgo_cv_c_linker_supports_split_stack=no
 502 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 503   libgo_cv_c_linker_supports_split_stack=yes
 504 fi])
 505 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 506   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 507             [Define if the linker support split stack adjustments])
 508 fi
 509
 510 AC_CACHE_CHECK([whether compiler is llgo],
 511 [libgo_cv_c_goc_is_llgo],
 512 [libgo_cv_c_goc_is_llgo=no
 513 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 514   libgo_cv_c_goc_is_llgo=yes
 515 fi])
 516 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 517
 518 dnl Test for the -lm library.
 519 MATH_LIBS=
 520 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 521 AC_SUBST(MATH_LIBS)
 522
 523 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 524 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 525   [libgo_cv_lib_sockets=
 526    libgo_check_both=no
 527    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 528    if test "$libgo_check_socket" = "yes"; then
 529      unset ac_cv_func_connect
 530      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 531                   libgo_check_both=yes)
 532    fi
 533    if test "$libgo_check_both" = "yes"; then
 534      libgo_old_libs=$LIBS
 535      LIBS="$LIBS -lsocket -lnsl"
 536      unset ac_cv_func_accept
 537      AC_CHECK_FUNC(accept,
 538                    [libgo_check_nsl=no
 539                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 540      unset ac_cv_func_accept
 541      LIBS=$libgo_old_libs
 542    fi
 543    unset ac_cv_func_gethostbyname
 544    libgo_old_libs="$LIBS"
 545    AC_CHECK_FUNC(gethostbyname, ,
 546                  [AC_CHECK_LIB(nsl, main,
 547                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 548    unset ac_cv_func_gethostbyname
 549    AC_CHECK_FUNC(sendfile, ,
 550                  [AC_CHECK_LIB(sendfile, main,
 551                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 552    LIBS=$libgo_old_libs
 553 ])
 554 NET_LIBS="$libgo_cv_lib_sockets"
 555 AC_SUBST(NET_LIBS)
 556
 557 dnl Test whether the compiler supports the -pthread option.
 558 AC_CACHE_CHECK([whether -pthread is supported],
 559 [libgo_cv_lib_pthread],
 560 [CFLAGS_hold=$CFLAGS
 561 CFLAGS="$CFLAGS -pthread -L../libatomic/.libs"
 562 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 563 [libgo_cv_lib_pthread=yes],
 564 [libgo_cv_lib_pthread=no])
 565 CFLAGS=$CFLAGS_hold])
 566 PTHREAD_CFLAGS=
 567 if test "$libgo_cv_lib_pthread" = yes; then
 568   # RISC-V apparently adds -latomic when using -pthread.
 569   PTHREAD_CFLAGS="-pthread -L../libatomic/.libs"
 570 fi
 571 AC_SUBST(PTHREAD_CFLAGS)
 572
 573 dnl Test for the -lpthread library.
 574 PTHREAD_LIBS=
 575 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 576 AC_SUBST(PTHREAD_LIBS)
 577
 578 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 579 AC_SEARCH_LIBS([sched_yield], [rt])
 580 AC_SEARCH_LIBS([nanosleep], [rt])
 581 AC_SEARCH_LIBS([clock_gettime], [rt])
 582
 583 AC_C_BIGENDIAN
 584
 585 GCC_CHECK_UNWIND_GETIPINFO
 586
 587 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 588
 589 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 590 [#include <netinet/in.h>
 591 ])
 592
 593 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 594 [#ifdef HAVE_SYS_SOCKET_H
 595 #include <sys/socket.h>
 596 #endif
 597 ])
 598
 599 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 600
 601 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr memmem)
 602 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 603 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 604
 605 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 606 AC_TYPE_OFF_T
 607 AC_CHECK_TYPES([loff_t])
 608
 609 LIBS_hold="$LIBS"
 610 LIBS="$LIBS -lm"
 611 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 612 LIBS="$LIBS_hold"
 613
 614 CFLAGS_hold="$CFLAGS"
 615 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 616 LIBS_hold="$LIBS"
 617 LIBS="$LIBS $PTHREAD_LIBS"
 618 AC_CHECK_FUNCS(sem_timedwait)
 619 CFLAGS="$CFLAGS_hold"
 620 LIBS="$LIBS_hold"
 621
 622 LIBS_hold="$LIBS"
 623 LIBS="$LIBS $MATH_LIBS"
 624 AC_CHECK_FUNCS(matherr)
 625 LIBS="$LIBS_hold"
 626
 627 dnl For x86 we want to use the -minline-all-stringops option to avoid
 628 dnl forcing a stack split when calling memcpy and friends.
 629 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 630 [libgo_cv_c_stringops],
 631 [CFLAGS_hold=$CFLAGS
 632 CFLAGS="$CFLAGS -minline-all-stringops"
 633 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 634 [libgo_cv_c_stringops=yes],
 635 [libgo_cv_c_stringops=no])
 636 CFLAGS=$CFLAGS_hold])
 637 STRINGOPS_FLAG=
 638 if test "$libgo_cv_c_stringops" = yes; then
 639   STRINGOPS_FLAG=-minline-all-stringops
 640 fi
 641 AC_SUBST(STRINGOPS_FLAG)
 642
 643 dnl For x86 we want to compile the math library with -mfancy-math-387
 644 dnl so that we can use the builtin instructions directly.
 645 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 646 [libgo_cv_c_fancymath],
 647 [CFLAGS_hold=$CFLAGS
 648 CFLAGS="$CFLAGS -mfancy-math-387"
 649 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 650 [libgo_cv_c_fancymath=yes],
 651 [libgo_cv_c_fancymath=no])
 652 CFLAGS=$CFLAGS_hold])
 653 MATH_FLAG=
 654 if test "$libgo_cv_c_fancymath" = yes; then
 655   MATH_FLAG="-mfancy-math-387"
 656 fi
 657 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 658 AC_SUBST(MATH_FLAG)
 659
 660 CFLAGS_hold=$CFLAGS
 661 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 662 AC_CHECK_TYPES([off64_t])
 663 CFLAGS=$CFLAGS_hold
 664
 665 dnl Work out the size of the epoll_events struct on GNU/Linux.
 666 AC_CACHE_CHECK([epoll_event size],
 667 [libgo_cv_c_epoll_event_size],
 668 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 669 [sizeof (struct epoll_event)],
 670 [#include <sys/epoll.h>],
 671 [libgo_cv_c_epoll_event_size=0])])
 672 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 673 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 674
 675 dnl Work out the offset of the fd field in the epoll_events struct on
 676 dnl GNU/Linux.
 677 AC_CACHE_CHECK([epoll_event data.fd offset],
 678 [libgo_cv_c_epoll_event_fd_offset],
 679 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 680 [offsetof (struct epoll_event, data.fd)],
 681 [#include <stddef.h>
 682 #include <sys/epoll.h>],
 683 [libgo_cv_c_epoll_event_fd_offset=0])])
 684 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 685 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 686
 687 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 688 dnl in Solaris 11.4 for XPG7 compatibility.
 689 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 690                 [have_stat_timespec=yes], [have_stat_timespec=no])
 691 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 692
 693 dnl See if struct exception is defined in <math.h>.
 694 AC_CHECK_TYPE([struct exception],
 695 [libgo_has_struct_exception=yes],
 696 [libgo_has_struct_exception=no],
 697 [#include <math.h>])
 698 if test "$libgo_has_struct_exception" = "yes"; then
 699   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 700             [Define to 1 if <math.h> defines struct exception])
 701 fi
 702
 703 dnl See whether setcontext changes the value of TLS variables.
 704 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 705 [libgo_cv_lib_setcontext_clobbers_tls],
 706 [CFLAGS_hold="$CFLAGS"
 707 CFLAGS="$PTHREAD_CFLAGS"
 708 LIBS_hold="$LIBS"
 709 LIBS="$LIBS $PTHREAD_LIBS"
 710 AC_CHECK_SIZEOF([void *])
 711 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 712 AC_RUN_IFELSE(
 713   [AC_LANG_SOURCE([
 714 #include <pthread.h>
 715 #include <stdlib.h>
 716 #include <ucontext.h>
 717 #include <unistd.h>
 718
 719 __thread int tls;
 720
 721 static char stack[[10 * 1024 * 1024]];
 722 static ucontext_t c;
 723
 724 /* Called via makecontext/setcontext.  */
 725
 726 static void
 727 cfn (void)
 728 {
 729   exit (tls);
 730 }
 731
 732 /* Called via pthread_create.  */
 733
 734 static void *
 735 tfn (void *dummy)
 736 {
 737   /* The thread should still see this value after calling
 738      setcontext.  */
 739   tls = 0;
 740
 741   setcontext (&c);
 742
 743   /* The call to setcontext should not return.  */
 744   abort ();
 745 }
 746
 747 int
 748 main ()
 749 {
 750   pthread_t tid;
 751
 752   /* The thread should not see this value.  */
 753   tls = 1;
 754
 755   if (getcontext (&c) < 0)
 756     abort ();
 757
 758   c.uc_stack.ss_sp = stack;
 759 #ifdef MAKECONTEXT_STACK_TOP
 760   c.uc_stack.ss_sp += sizeof stack;
 761 #endif
 762   c.uc_stack.ss_flags = 0;
 763   c.uc_stack.ss_size = sizeof stack;
 764   c.uc_link = NULL;
 765   makecontext (&c, cfn, 0);
 766
 767   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 768     abort ();
 769
 770   if (pthread_join (tid, NULL) != 0)
 771     abort ();
 772
 773   /* The thread should have called exit.  */
 774   abort ();
 775 }
 776 ])],
 777 [libgo_cv_lib_setcontext_clobbers_tls=no],
 778 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 779 [case "$target:$ptr_type_size" in
 780   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 781     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 782   *)
 783     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 784  esac
 785 ])
 786 CFLAGS="$CFLAGS_hold"
 787 LIBS="$LIBS_hold"
 788 ])
 789 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 790   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 791             [Define if setcontext clobbers TLS variables])
 792 fi
 793
 794 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 795 libgo_cv_ro_eh_frame, [
 796 libgo_cv_ro_eh_frame=no
 797 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 798 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 799   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 800     libgo_cv_ro_eh_frame=yes
 801   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 802        | grep -v '#write' > /dev/null; then
 803     libgo_cv_ro_eh_frame=yes
 804   fi
 805 fi
 806 rm -f conftest.*
 807 ])
 808 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 809   AC_DEFINE(EH_FRAME_FLAGS, "a",
 810             [Define to the flags needed for the .section .eh_frame directive.])
 811 else
 812   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 813             [Define to the flags needed for the .section .eh_frame directive.])
 814 fi
 815
 816 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 817 [libgo_cv_c_unused_arguments],
 818 [CFLAGS_hold=$CFLAGS
 819 CFLAGS="$CFLAGS -Qunused-arguments"
 820 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 821 [libgo_cv_c_unused_arguments=yes],
 822 [libgo_cv_c_unused_arguments=no])
 823 CFLAGS=$CFLAGS_hold])
 824
 825 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 826 libgo_cv_as_comdat_gnu, [
 827 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 828 CFLAGS_hold=$CFLAGS
 829 if test "$libgo_cv_c_unused_arguments" = yes; then
 830   CFLAGS="$CFLAGS -Qunused-arguments"
 831 fi
 832 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 833   libgo_cv_as_comdat_gnu=yes
 834 else
 835   libgo_cv_as_comdat_gnu=no
 836 fi
 837 CFLAGS=$CFLAGS_hold
 838 ])
 839 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 840   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 841             [Define if your assembler supports GNU comdat group syntax.])
 842 fi
 843
 844 AC_CACHE_CHECK([assembler supports pc related relocs],
 845 libgo_cv_as_x86_pcrel, [
 846 libgo_cv_as_x86_pcrel=yes
 847 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 848 CFLAGS_hold=$CFLAGS
 849 if test "$libgo_cv_c_unused_arguments" = yes; then
 850   CFLAGS="$CFLAGS -Qunused-arguments"
 851 fi
 852 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 853     libgo_cv_as_x86_pcrel=no
 854 fi
 855 CFLAGS=$CFLAGS_hold
 856 ])
 857 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 858   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 859             [Define if your assembler supports PC relative relocs.])
 860 fi
 861
 862 AC_CACHE_CHECK([assembler supports unwind section type],
 863 libgo_cv_as_x86_64_unwind_section_type, [
 864 libgo_cv_as_x86_64_unwind_section_type=yes
 865 echo '.section .eh_frame,"a",@unwind' > conftest.s
 866 CFLAGS_hold=$CFLAGS
 867 if test "$libgo_cv_c_unused_arguments" = yes; then
 868   CFLAGS="$CFLAGS -Qunused-arguments"
 869 fi
 870 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 871     libgo_cv_as_x86_64_unwind_section_type=no
 872 fi
 873 CFLAGS=$CFLAGS_hold
 874 ])
 875 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 876   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 877             [Define if your assembler supports unwind section type.])
 878 fi
 879
 880 AC_CACHE_CHECK([assembler supports AES instructions],
 881 libgo_cv_as_x86_aes, [
 882 libgo_cv_as_x86_aes=yes
 883 echo 'aesenc %xmm0, %xmm1' > conftest.s
 884 CFLAGS_hold=$CFLAGS
 885 if test "$libgo_cv_c_unused_arguments" = yes; then
 886   CFLAGS="$CFLAGS -Qunused-arguments"
 887 fi
 888 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 889     libgo_cv_as_x86_aes=no
 890 fi
 891 CFLAGS=$CFLAGS_hold
 892 ])
 893 if test "x$libgo_cv_as_x86_aes" = xyes; then
 894   AC_DEFINE(HAVE_AS_X86_AES, 1,
 895             [Define if your assembler supports AES instructions.])
 896 fi
 897
 898 dnl Test whether the linker supports the -static option.
 899 AC_CACHE_CHECK([whether -static is supported],
 900 [libgo_cv_ld_static],
 901 [LDFLAGS_hold=$LDFLAGS
 902 LDFLAGS="$LDFLAGS -static"
 903 AC_LINK_IFELSE([AC_LANG_PROGRAM(,)],
 904 [libgo_cv_ld_static=yes],
 905 [libgo_cv_ld_static=no])
 906 LDFLAGS=$LDFLAGS_hold])
 907 AM_CONDITIONAL(HAVE_STATIC_LINK, test "$libgo_cv_ld_static" = yes)
 908
 909 AC_CACHE_SAVE
 910
 911 if test ${multilib} = yes; then
 912   multilib_arg="--enable-multilib"
 913 else
 914   multilib_arg=
 915 fi
 916
 917 AC_CONFIG_FILES(Makefile testsuite/Makefile testsuite/libgo-test-support.exp)
 918
 919 AC_CONFIG_COMMANDS([default],
 920 [if test -n "$CONFIG_FILES"; then
 921    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 922    # that multilib installs will end up installed in the correct place.
 923    # The testsuite needs it for multilib-aware ABI baseline files.
 924    # To work around this not being passed down from config-ml.in ->
 925    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 926    # append it here.  Only modify Makefiles that have just been created.
 927    #
 928    # Also, get rid of this simulated-VPATH thing that automake does.
 929    cat > vpsed << \_EOF
 930 s!`test -f '$<' || echo '$(srcdir)/'`!!
 931 _EOF
 932    for i in $SUBDIRS; do
 933     case $CONFIG_FILES in
 934      *${i}/Makefile*)
 935        #echo "Adding MULTISUBDIR to $i/Makefile"
 936        sed -f vpsed $i/Makefile > tmp
 937        grep '^MULTISUBDIR =' Makefile >> tmp
 938        mv tmp $i/Makefile
 939        ;;
 940     esac
 941    done
 942    rm vpsed
 943  fi
 944 ],
 945 [
 946 # Variables needed in config.status (file generation) which aren't already
 947 # passed by autoconf.
 948 SUBDIRS="$SUBDIRS"
 949 ])
 950
 951 AC_OUTPUT