libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 GCC_NO_EXECUTABLES
 113 AC_PROG_CC
 114 AC_PROG_CPP_WERROR
 115
 116 # Warn C++ incompatibilities if supported.
 117 AC_CACHE_CHECK(
 118   [whether ${CC} accepts -Wc++-compat],
 119   [ac_cv_prog_cc_w_cxx_compat],
 120   [save_CFLAGS="$CFLAGS"
 121   CFLAGS="-Wc++-compat"
 122   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 123                     [ac_cv_prog_cc_w_cxx_compat=yes],
 124                     [ac_cv_prog_cc_w_cxx_compat=no])
 125   CFLAGS="$save_CFLAGS"
 126   ])
 127
 128
 129 if test x$GCC = xyes; then
 130   ac_libiberty_warn_cflags='-W -Wall -pedantic -Wwrite-strings -Wstrict-prototypes'
 131 fi
 132 if test $ac_cv_prog_cc_w_cxx_compat = yes ; then
 133   ac_libiberty_warn_cflags="${ac_libiberty_warn_cflags} -Wc++-compat"
 134 fi
 135 AC_SUBST(ac_libiberty_warn_cflags)
 136
 137 AC_PROG_CC_C_O
 138 # autoconf is lame and doesn't give us any substitution variable for this.
 139 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 140   NO_MINUS_C_MINUS_O=yes
 141 else
 142   OUTPUT_OPTION='-o $@'
 143 fi
 144 AC_SUBST(NO_MINUS_C_MINUS_O)
 145 AC_SUBST(OUTPUT_OPTION)
 146
 147 AC_C_CONST
 148 AC_C_INLINE
 149 AC_C_BIGENDIAN
 150
 151 dnl When we start using libtool:
 152 dnl Default to a non shared library.  This may be overridden by the
 153 dnl configure option --enable-shared.
 154 dnl AM_DISABLE_SHARED
 155
 156 dnl When we start using libtool:
 157 dnl AM_PROG_LIBTOOL
 158
 159 dnl When we start using automake:
 160 dnl AM_CONFIG_HEADER(config.h:config.in)
 161 AC_CONFIG_HEADER(config.h:config.in)
 162
 163 dnl When we start using automake:
 164 dnl AM_MAINTAINER_MODE
 165 dnl AC_EXEEXT
 166
 167 dnl When we start using automake:
 168 dnl AM_PROG_INSTALL
 169 AC_PROG_INSTALL
 170
 171 # Don't build the shared library for build.
 172 if [[ -n "${with_build_subdir}" ]]; then
 173   enable_shared=no
 174 fi
 175
 176 frag=
 177 case "${host}" in
 178   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 179                         frag=mh-aix ;;
 180   *-*-cxux7*)           frag=mh-cxux7 ;;
 181   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 182   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 183   i370-*-opened*)       frag=mh-openedition ;;
 184   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 185 esac
 186
 187 if [[ -n "${frag}" ]]; then
 188   frags=${libiberty_topdir}/libiberty/config/$frag
 189 else
 190   frags=
 191 fi
 192
 193 # If they didn't specify --enable-shared, don't generate shared libs.
 194 case "${enable_shared}" in
 195   yes) shared=yes ;;
 196   no) shared=no ;;
 197   "") shared=no ;;
 198   *) shared=yes ;;
 199 esac
 200 if [[ "${shared}" = "yes" ]]; then
 201   frag=
 202   case "${host}" in
 203     *-*-cygwin*)        ;;
 204     alpha*-*-linux*)    frag=mh-elfalphapic ;;
 205     arm*-*-*)           frag=mh-armpic ;;
 206     hppa*-*-*)          frag=mh-papic ;;
 207     i[[34567]]86-*-* | x86_64-*-*)
 208                         frag=mh-x86pic ;;
 209     powerpc*-*-aix*)    ;;
 210     powerpc*-*-*)       frag=mh-ppcpic ;;
 211     sparc*-*-*)         frag=mh-sparcpic ;;
 212     s390*-*-*)          frag=mh-s390pic ;;
 213     *)                  frag=mh-${host_cpu}pic ;;
 214   esac
 215   if [[ -n "${frag}" ]]; then
 216     frags="${frags} ${libiberty_topdir}/config/${frag}"
 217   fi
 218 fi
 219
 220 echo "# Warning: this fragment is automatically generated" > temp-frag
 221
 222 for frag in ${frags}; do
 223   if [[ -f ${frag} ]]; then
 224     echo "Appending ${frag} to xhost-mkfrag"
 225     echo "# Following fragment copied from ${frag}" >> temp-frag
 226     cat ${frag} >> temp-frag
 227   fi
 228 done
 229
 230 # record if we want to build shared libs.
 231 if [[ "${shared}" = "yes" ]]; then
 232   echo enable_shared = yes >> temp-frag
 233 else
 234   echo enable_shared = no >> temp-frag
 235 fi
 236
 237 frag=xhost-mkfrag
 238 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 239
 240 host_makefile_frag=${frag}
 241 AC_SUBST_FILE(host_makefile_frag)
 242
 243 # It's OK to check for header files.  Although the compiler may not be
 244 # able to link anything, it had better be able to at least compile
 245 # something.
 246 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h)
 247 AC_HEADER_SYS_WAIT
 248 AC_HEADER_TIME
 249
 250 libiberty_AC_DECLARE_ERRNO
 251
 252 # Determine the size of an int for struct fibnode.
 253 AC_CHECK_SIZEOF([int])
 254
 255 AC_CHECK_TYPE(uintptr_t, unsigned long)
 256
 257 # Look for a 64-bit type.
 258 AC_MSG_CHECKING([for a 64-bit type])
 259 AC_CACHE_VAL(liberty_cv_uint64,
 260 [AC_TRY_COMPILE(
 261 [#ifdef HAVE_STDINT_H
 262 #include <stdint.h>
 263 #endif],
 264 [extern uint64_t foo;],
 265 liberty_cv_uint64=uint64_t,
 266 [AC_TRY_COMPILE(
 267 [#ifdef HAVE_LIMITS_H
 268 #include <limits.h>
 269 #endif
 270 #ifndef CHAR_BIT
 271 #define CHAR_BIT 8
 272 #endif],
 273 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 274 liberty_cv_uint64="unsigned long",
 275 [AC_TRY_COMPILE(
 276 [#ifdef HAVE_LIMITS_H
 277 #include <limits.h>
 278 #endif
 279 #ifndef CHAR_BIT
 280 #define CHAR_BIT 8
 281 #endif],
 282 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 283 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 284 AC_MSG_RESULT($liberty_cv_uint64)
 285 if test "$liberty_cv_uint64" != none; then
 286   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 287                      [Define to an unsigned 64-bit type available in the compiler.])
 288 fi
 289
 290 # Given the above check, we always have uintptr_t or a fallback
 291 # definition.  So define HAVE_UINTPTR_T in case any imported code
 292 # relies on it.
 293 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 294
 295 AC_TYPE_PID_T
 296
 297 # This is the list of functions which libiberty will provide if they
 298 # are not available on the host.
 299
 300 funcs="asprintf"
 301 funcs="$funcs atexit"
 302 funcs="$funcs basename"
 303 funcs="$funcs bcmp"
 304 funcs="$funcs bcopy"
 305 funcs="$funcs bsearch"
 306 funcs="$funcs bzero"
 307 funcs="$funcs calloc"
 308 funcs="$funcs clock"
 309 funcs="$funcs ffs"
 310 funcs="$funcs getcwd"
 311 funcs="$funcs getpagesize"
 312 funcs="$funcs gettimeofday"
 313 funcs="$funcs index"
 314 funcs="$funcs insque"
 315 funcs="$funcs memchr"
 316 funcs="$funcs memcmp"
 317 funcs="$funcs memcpy"
 318 funcs="$funcs memmove"
 319 funcs="$funcs mempcpy"
 320 funcs="$funcs memset"
 321 funcs="$funcs mkstemps"
 322 funcs="$funcs putenv"
 323 funcs="$funcs random"
 324 funcs="$funcs rename"
 325 funcs="$funcs rindex"
 326 funcs="$funcs setenv"
 327 funcs="$funcs snprintf"
 328 funcs="$funcs sigsetmask"
 329 funcs="$funcs stpcpy"
 330 funcs="$funcs stpncpy"
 331 funcs="$funcs strcasecmp"
 332 funcs="$funcs strchr"
 333 funcs="$funcs strdup"
 334 funcs="$funcs strncasecmp"
 335 funcs="$funcs strndup"
 336 funcs="$funcs strrchr"
 337 funcs="$funcs strstr"
 338 funcs="$funcs strtod"
 339 funcs="$funcs strtol"
 340 funcs="$funcs strtoul"
 341 funcs="$funcs strverscmp"
 342 funcs="$funcs tmpnam"
 343 funcs="$funcs vasprintf"
 344 funcs="$funcs vfprintf"
 345 funcs="$funcs vprintf"
 346 funcs="$funcs vsnprintf"
 347 funcs="$funcs vsprintf"
 348 funcs="$funcs waitpid"
 349
 350 # Also in the old function.def file: alloca, vfork, getopt.
 351
 352 vars="sys_errlist sys_nerr sys_siglist"
 353
 354 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 355 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 356 checkfuncs="$checkfuncs getsysinfo table sysctl wait3 wait4 __fsetlocking"
 357
 358 # These are neither executed nor required, but they help keep
 359 # autoheader happy without adding a bunch of text to acconfig.h.
 360 if test "x" = "y"; then
 361   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 362   getcwd getpagesize gettimeofday index insque mkstemps memchr memcmp memcpy \
 363   memmove mempcpy memset putenv random rename rindex sigsetmask \
 364   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strndup strrchr strstr \
 365   strtod strtol strtoul strverscmp tmpnam vasprintf vfprintf vprintf \
 366   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 367   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 368   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl wait3 wait4 \
 369   realpath canonicalize_file_name __fsetlocking)
 370   AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf, snprintf, vsnprintf])
 371   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 372   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 373   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 374 fi
 375
 376 # For each of these functions, if the host does not provide the
 377 # function we want to put FN.o in LIBOBJS, and if the host does
 378 # provide the function, we want to define HAVE_FN in config.h.
 379
 380 setobjs=
 381 CHECK=
 382 target_header_dir=
 383 if test -n "${with_target_subdir}"; then
 384
 385   # We are being configured as a target library.  AC_REPLACE_FUNCS
 386   # may not work correctly, because the compiler may not be able to
 387   # link executables.  Note that we may still be being configured
 388   # native.
 389
 390   # If we are being configured for newlib, we know which functions
 391   # newlib provide and which ones we will be expected to provide.
 392
 393   if test "x${with_newlib}" = "xyes"; then
 394     AC_LIBOBJ([asprintf])
 395     AC_LIBOBJ([basename])
 396     AC_LIBOBJ([insque])
 397     AC_LIBOBJ([random])
 398     AC_LIBOBJ([strdup])
 399     AC_LIBOBJ([vasprintf])
 400
 401     for f in $funcs; do
 402       case "$f" in
 403         asprintf | basename | insque | random | strdup | vasprintf)
 404           ;;
 405         *)
 406           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 407           AC_DEFINE_UNQUOTED($n)
 408           ;;
 409       esac
 410     done
 411
 412     # newlib doesnt provide any of the variables in $vars, so we
 413     # dont have to check them here.
 414
 415     # Of the functions in $checkfuncs, newlib only has strerror.
 416     AC_DEFINE(HAVE_STRERROR)
 417
 418     setobjs=yes
 419
 420   fi
 421
 422   # If we are being configured for Mingw, we know which functions
 423   # Mingw provides and which ones we will be expected to provide.
 424
 425   case "${host}" in
 426   *-*-mingw*)
 427     AC_LIBOBJ([asprintf])
 428     AC_LIBOBJ([basename])
 429     AC_LIBOBJ([bcmp])
 430     AC_LIBOBJ([bcopy])
 431     AC_LIBOBJ([bzero])
 432     AC_LIBOBJ([clock])
 433     AC_LIBOBJ([ffs])
 434     AC_LIBOBJ([getpagesize])
 435     AC_LIBOBJ([index])
 436     AC_LIBOBJ([insque])
 437     AC_LIBOBJ([mempcpy])
 438     AC_LIBOBJ([mkstemps])
 439     AC_LIBOBJ([random])
 440     AC_LIBOBJ([rindex])
 441     AC_LIBOBJ([sigsetmask])
 442     AC_LIBOBJ([stpcpy])
 443     AC_LIBOBJ([stpncpy])
 444     AC_LIBOBJ([strndup])
 445     AC_LIBOBJ([strverscmp])
 446     AC_LIBOBJ([vasprintf])
 447     AC_LIBOBJ([waitpid])
 448
 449     for f in $funcs; do
 450       case "$f" in
 451         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strverscmp | vasprintf | waitpid)
 452           ;;
 453         *)
 454           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 455           AC_DEFINE_UNQUOTED($n)
 456           ;;
 457       esac
 458     done
 459
 460     # Mingw doesnt provide any of the variables in $vars, so we
 461     # dont have to check them here.
 462
 463     # Of the functions in $checkfuncs, Mingw only has strerror.
 464     AC_DEFINE(HAVE_STRERROR)
 465
 466     setobjs=yes
 467     ;;
 468
 469   esac
 470
 471   # We may wish to install the target headers somewhere.
 472   AC_ARG_ENABLE(install-libiberty,
 473   [  --enable-install-libiberty       Install headers for end users],
 474   enable_install_libiberty=$enableval,
 475   enable_install_libiberty=no)dnl
 476
 477   # Option parsed, now set things appropriately.
 478   case x"$enable_install_libiberty" in
 479     xyes|x)
 480       target_header_dir=libiberty
 481       ;;
 482     xno)
 483       target_header_dir=
 484       ;;
 485     *)
 486       # This could be sanity-checked in various ways...
 487       target_header_dir="${enable_install_libiberty}"
 488       ;;
 489   esac
 490
 491
 492 else
 493
 494    # Not a target library, so we set things up to run the test suite.
 495    CHECK=really-check
 496
 497 fi
 498
 499 AC_SUBST(CHECK)
 500 AC_SUBST(target_header_dir)
 501
 502 case "${host}" in
 503   *-*-cygwin* | *-*-mingw*)
 504     AC_DEFINE(HAVE_SYS_ERRLIST)
 505     AC_DEFINE(HAVE_SYS_NERR)
 506     ;;
 507 esac
 508
 509 if test -z "${setobjs}"; then
 510   case "${host}" in
 511
 512   *-*-vxworks*)
 513     # Handle VxWorks configuration specially, since on VxWorks the
 514     # libraries are actually on the target board, not in the file
 515     # system.
 516     AC_LIBOBJ([basename])
 517     AC_LIBOBJ([getpagesize])
 518     AC_LIBOBJ([insque])
 519     AC_LIBOBJ([random])
 520     AC_LIBOBJ([strcasecmp])
 521     AC_LIBOBJ([strncasecmp])
 522     AC_LIBOBJ([strdup])
 523     AC_LIBOBJ([vfork])
 524     AC_LIBOBJ([waitpid])
 525     AC_LIBOBJ([vasprintf])
 526     for f in $funcs; do
 527       case "$f" in
 528         basename | getpagesize | insque | random | strcasecmp)
 529           ;;
 530         strncasecmp | strdup | vfork | waitpid | vasprintf)
 531           ;;
 532         *)
 533           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 534           AC_DEFINE_UNQUOTED($n)
 535           ;;
 536       esac
 537     done
 538
 539     # VxWorks doesn't provide any of the variables in $vars, so we
 540     # don't have to check them here.
 541
 542     # Of the functions in $checkfuncs, VxWorks only has strerror.
 543     AC_DEFINE(HAVE_STRERROR)
 544
 545     setobjs=yes
 546     ;;
 547
 548   esac
 549 fi
 550
 551 if test -z "${setobjs}"; then
 552
 553   case "${host}" in
 554
 555   *-*-cygwin*)
 556     # The Cygwin library actually uses a couple of files from
 557     # libiberty when it is built.  If we are building a native
 558     # Cygwin, and we run the tests, we will appear to have these
 559     # files.  However, when we go on to build winsup, we will wind up
 560     # with a library which does not have the files, since they should
 561     # have come from libiberty.
 562
 563     # We handle this by removing the functions the winsup library
 564     # provides from our shell variables, so that they appear to be
 565     # missing.
 566
 567     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 568
 569     if test -n "${with_target_subdir}"
 570     then
 571       funcs="`echo $funcs | sed -e 's/random//'`"
 572       AC_LIBOBJ([random])
 573       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 574       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 575     fi
 576     ;;
 577
 578   *-*-mingw32*)
 579     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 580     # macros, so the test below won't find them.
 581     libiberty_cv_var_sys_nerr=yes
 582     libiberty_cv_var_sys_errlist=yes
 583     ;;
 584
 585   *-*-msdosdjgpp*)
 586     # vfork and fork are stubs.
 587     ac_cv_func_vfork_works=no
 588     ;;
 589
 590   *-*-uwin*)
 591     # Under some versions of uwin, vfork is notoriously buggy and the test
 592     # can hang configure; on other versions, vfork exists just as a stub.
 593     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 594     ac_cv_func_vfork_works=no
 595     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 596     # macros (actually, these are imported from a DLL, but the end effect
 597     # is the same), so the test below won't find them.
 598     libiberty_cv_var_sys_nerr=yes
 599     libiberty_cv_var_sys_errlist=yes
 600     ;;
 601
 602   *-*-*vms*)
 603     # Under VMS, vfork works very different than on Unix. The standard test
 604     # won't work, and it isn't easily adaptable. It makes more sense to
 605     # just force it.
 606     ac_cv_func_vfork_works=yes
 607     ;;
 608
 609   esac
 610
 611   # We haven't set the list of objects yet.  Use the standard autoconf
 612   # tests.  This will only work if the compiler works.
 613   AC_ISC_POSIX
 614   AC_REPLACE_FUNCS($funcs)
 615   libiberty_AC_FUNC_C_ALLOCA
 616   AC_FUNC_FORK
 617   if test $ac_cv_func_vfork_works = no; then
 618     AC_LIBOBJ([vfork])
 619   fi
 620   # We only need _doprnt if we might use it to implement v*printf.
 621   if test $ac_cv_func_vprintf != yes \
 622      || test $ac_cv_func_vfprintf != yes \
 623      || test $ac_cv_func_vsprintf != yes; then
 624     AC_REPLACE_FUNCS(_doprnt)
 625   else
 626     AC_CHECK_FUNCS(_doprnt)
 627   fi
 628
 629   for v in $vars; do
 630     AC_MSG_CHECKING([for $v])
 631     AC_CACHE_VAL(libiberty_cv_var_$v,
 632       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 633                       [eval "libiberty_cv_var_$v=yes"],
 634                       [eval "libiberty_cv_var_$v=no"])])
 635     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 636       AC_MSG_RESULT(yes)
 637       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 638       AC_DEFINE_UNQUOTED($n)
 639     else
 640       AC_MSG_RESULT(no)
 641     fi
 642   done
 643
 644   # special check for _system_configuration because AIX <4.3.2 do not
 645   # contain the `physmem' member.
 646   AC_MSG_CHECKING([for external symbol _system_configuration])
 647   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 648                         [[double x = _system_configuration.physmem;]])],
 649     [AC_MSG_RESULT([yes])
 650     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 651               [Define if you have the _system_configuration variable.])],
 652     [AC_MSG_RESULT([no])])
 653
 654   AC_CHECK_FUNCS($checkfuncs)
 655   AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf, snprintf, vsnprintf])
 656   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 657   AC_CHECK_DECLS([strverscmp])
 658   libiberty_NEED_DECLARATION(canonicalize_file_name)
 659 fi
 660
 661 # Figure out which version of pexecute to use.
 662 case "${host}" in
 663      *-*-mingw* | *-*-winnt*)   pexecute=./pex-win32.o  ;;
 664      *-*-msdosdjgpp*)           pexecute=./pex-djgpp.o  ;;
 665      *-*-msdos*)                pexecute=./pex-msdos.o  ;;
 666      *)                         pexecute=./pex-unix.o   ;;
 667 esac
 668 AC_SUBST(pexecute)
 669
 670 libiberty_AC_FUNC_STRNCMP
 671
 672 # Install a library built with a cross compiler in $(tooldir) rather
 673 # than $(libdir).
 674 if test -z "${with_cross_host}"; then
 675   INSTALL_DEST=libdir
 676 else
 677   INSTALL_DEST=tooldir
 678 fi
 679 AC_SUBST(INSTALL_DEST)
 680
 681 m4_pattern_allow(LIBOBJS)
 682 L=""
 683 for l in x $LIBOBJS; do
 684   case $l in
 685     x) ;;
 686     *) L="$L ./$l" ;;
 687   esac
 688 done
 689 LIBOBJS="$L"
 690
 691 dnl Required by html and install-html
 692 AC_SUBST(datarootdir)
 693 AC_SUBST(docdir)
 694 AC_SUBST(htmldir)
 695
 696 # We need multilib support, but only if configuring for the target.
 697 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 698 AC_CONFIG_COMMANDS([default],
 699   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 700 if test -n "$CONFIG_FILES"; then
 701   if test -n "${with_target_subdir}"; then
 702     # FIXME: We shouldn't need to set ac_file
 703     ac_file=Makefile
 704     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 705     . ${libiberty_topdir}/config-ml.in
 706   fi
 707 fi]],
 708 [[srcdir=${srcdir}
 709 host=${host}
 710 target=${target}
 711 with_target_subdir=${with_target_subdir}
 712 with_multisubdir=${with_multisubdir}
 713 ac_configure_args="--enable-multilib ${ac_configure_args}"
 714 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 715 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 716 libiberty_topdir=${libiberty_topdir}
 717 ]])
 718 AC_OUTPUT