libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_INIT(package-unused, version-unused,, libgo)
  10 AC_CONFIG_SRCDIR(Makefile.am)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 libtool_VERSION=14:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 AM_ENABLE_MULTILIB(, ..)
  17
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$host_alias}
  20
  21 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist subdir-objects -Wall -Wno-portability -Wno-override])
  22 AH_TEMPLATE(PACKAGE, [Name of package])
  23 AH_TEMPLATE(VERSION, [Version number of package])
  24
  25 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  26 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  27 AC_PROG_CC
  28 AC_PROG_GO
  29 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  30
  31 AC_SUBST(CFLAGS)
  32
  33 case ${host} in
  34   *-*-aix*)
  35     # static hash tables crashes on AIX when libgo is built with O2
  36     CFLAGS="$CFLAGS -fno-section-anchors"
  37     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  38     ;;
  39 esac
  40
  41 AM_MAINTAINER_MODE
  42
  43 AC_PROG_LD
  44 AC_PROG_RANLIB
  45 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  46
  47 AC_LIBTOOL_DLOPEN
  48 AM_PROG_LIBTOOL
  49 AC_SUBST(enable_shared)
  50 AC_SUBST(enable_static)
  51
  52 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  53 AC_SUBST(CC_FOR_BUILD)
  54
  55 AC_PROG_AWK
  56
  57 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  58 AC_SUBST(WARN_FLAGS)
  59
  60 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  61                                       [turns on -Werror @<:@default=yes@:>@])])
  62 if test "x$enable_werror" != "xno"; then
  63   WERROR="-Werror"
  64 fi
  65 AC_SUBST(WERROR)
  66
  67 glibgo_toolexecdir=no
  68 glibgo_toolexeclibdir=no
  69
  70 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  71 AC_ARG_ENABLE([version-specific-runtime-libs],
  72   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  73                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  74   [case "$enableval" in
  75     yes) version_specific_libs=yes ;;
  76     no)  version_specific_libs=no ;;
  77     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  78    esac],
  79   [version_specific_libs=no])
  80 AC_MSG_RESULT($version_specific_libs)
  81
  82 # Version-specific runtime libs processing.
  83 if test $version_specific_libs = yes; then
  84   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  85   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  86 fi
  87
  88 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  89 # Install a library built with a cross compiler in tooldir, not libdir.
  90 if test -n "$with_cross_host" &&
  91    test x"$with_cross_host" != x"no"; then
  92   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  93   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  94 else
  95   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  96   nover_glibgo_toolexeclibdir='${libdir}'
  97 fi
  98 multi_os_directory=`$GOC -print-multi-os-directory`
  99 case $multi_os_directory in
 100   .) ;; # Avoid trailing /.
 101   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 102 esac
 103
 104 if test x"$glibgo_toolexecdir" = x"no"; then
 105   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 106   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 107 fi
 108
 109 AC_SUBST(glibgo_toolexecdir)
 110 AC_SUBST(glibgo_toolexeclibdir)
 111 AC_SUBST(nover_glibgo_toolexeclibdir)
 112
 113 # See if the user wants to configure without libffi.  Some
 114 # architectures don't support it.  FIXME: We should set a default
 115 # based on the host.
 116 AC_ARG_WITH(libffi,
 117   AS_HELP_STRING([--without-libffi],
 118                  [don't use libffi]),
 119   [:],
 120   [with_libffi=${with_libffi_default-yes}])
 121
 122 LIBFFI=
 123 LIBFFIINCS=
 124 if test "$with_libffi" != no; then
 125    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 126    LIBFFI=../libffi/libffi_convenience.la
 127    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 128 fi
 129 AC_SUBST(LIBFFI)
 130 AC_SUBST(LIBFFIINCS)
 131 AM_CONDITIONAL(USE_LIBFFI, test "$with_liffi" != "no")
 132
 133 # See if the user wants to configure without libatomic. This is useful if we are
 134 # on an architecture for which libgo does not need an atomic support library and
 135 # libatomic does not support our C compiler.
 136 AC_ARG_WITH(libatomic,
 137   AS_HELP_STRING([--without-libatomic],
 138                  [don't use libatomic]),
 139   [:],
 140   [with_libatomic=${with_libatomic_default-yes}])
 141
 142 LIBATOMIC=
 143 if test "$with_libatomic" != no; then
 144    LIBATOMIC=../libatomic/libatomic_convenience.la
 145 fi
 146 AC_SUBST(LIBATOMIC)
 147
 148 # Used to tell GNU make to include a file without telling automake to
 149 # include it.
 150 go_include="-include"
 151 AC_SUBST(go_include)
 152
 153 # All known GOOS values.  This is the union of all operating systems
 154 # supported by the gofrontend and all operating systems supported by
 155 # the gc toolchain.
 156 ALLGOOS="aix android darwin dragonfly freebsd hurd irix js linux netbsd openbsd plan9 rtems solaris windows"
 157
 158 is_darwin=no
 159 is_freebsd=no
 160 is_irix=no
 161 is_linux=no
 162 is_netbsd=no
 163 is_openbsd=no
 164 is_dragonfly=no
 165 is_rtems=no
 166 is_solaris=no
 167 is_aix=no
 168 is_hurd=no
 169 GOOS=unknown
 170 case ${host} in
 171   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 172   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 173   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 174   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 175   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 176   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 177   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 178   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 179   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 180   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 181   *-*-gnu*)      is_hurd=yes;    GOOS=hurd ;;
 182 esac
 183 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 184 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 185 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 186 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 187 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 188 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 189 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 190 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 191 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 192 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 193 AM_CONDITIONAL(LIBGO_IS_HURD, test $is_hurd = yes)
 194 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 195 AC_SUBST(GOOS)
 196 AC_SUBST(ALLGOOS)
 197
 198 dnl Test whether we need to use DejaGNU or whether we can use the
 199 dnl simpler gotest approach.  We can only use gotest for a native
 200 dnl build.
 201 USE_DEJAGNU=no
 202 case ${host} in
 203   *-*-rtems*) USE_DEJAGNU=yes ;;
 204   ${build}) ;;
 205   *) USE_DEJAGNU=yes ;;
 206 esac
 207 AC_SUBST(USE_DEJAGNU)
 208
 209 # All known GOARCH values.  This is the union of all architectures
 210 # supported by the gofrontend and all architectures supported by the
 211 # gc toolchain.
 212 # To add a new architecture:
 213 # - add it to this list
 214 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 215 # - add an entry to the case on ${host} below to set GOARCH
 216 # - update goarchList in libgo/go/go/build/syslist.go
 217 # - update goarch.sh to report the values for this architecture
 218 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 219 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 220 # - update arch lists in libgo/match.sh
 221 # - update arch lists in libgo/testsuite/gotest
 222 # - update +build lines in several places
 223 #   - libgo/go/runtime/lfstack_NNbit.go
 224 #   - libgo/go/runtime/hashNN.go
 225 #   - libgo/go/runtime/unalignedN.go
 226 #   - libgo/go/syscall/endian_XX.go
 227 #   - possibly others
 228 # - possibly update files in libgo/go/internal/syscall/unix
 229 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le nios2 ppc ppc64 ppc64le riscv riscv64 s390 s390x sh shbe sparc sparc64 wasm"
 230
 231 # All known GOARCH family values.
 232 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 NIOS2 PPC PPC64 RISCV RISCV64 S390 S390X SH SPARC SPARC64 WASM"
 233
 234 GOARCH=unknown
 235 case ${host} in
 236   alpha*-*-*)
 237     GOARCH=alpha
 238     ;;
 239   aarch64-*-*)
 240     GOARCH=arm64
 241     ;;
 242   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 243     GOARCH=arm
 244     case ${host} in
 245       arm*b*-*-*)
 246         GOARCH=armbe
 247         ;;
 248     esac
 249     ;;
 250 changequote(,)dnl
 251   i[34567]86-*-* | x86_64-*-*)
 252 changequote([,])dnl
 253     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 254 #ifdef __x86_64__
 255 #error 64-bit
 256 #endif
 257 ])],
 258         [GOARCH=386],
 259         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 260 #ifdef __ILP32__
 261 #error x32
 262 #endif
 263 ])],
 264         [GOARCH=amd64],
 265         [GOARCH=amd64p32]))
 266     ;;
 267   ia64-*-*)
 268     GOARCH=ia64
 269     ;;
 270   m68k*-*-*)
 271     GOARCH=m68k
 272     ;;
 273   mips*-*-*)
 274     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 275 #if _MIPS_SIM != _ABIO32
 276 #error not o32
 277 #endif
 278 ])],
 279 [mips_abi="o32"],
 280         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 281 #if _MIPS_SIM != _ABIN32
 282 #error not n32
 283 #endif
 284 ])],
 285 [mips_abi="n32"],
 286         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 287 #if _MIPS_SIM != _ABI64
 288 #error not n64
 289 #endif
 290 ])],
 291 [mips_abi="n64"],
 292         [AC_MSG_ERROR([unknown MIPS ABI])
 293 [mips_abi="n32"]])])])
 294     case "$mips_abi" in
 295     "o32") GOARCH=mips ;;
 296     "n32") GOARCH=mips64p32 ;;
 297     "n64") GOARCH=mips64 ;;
 298     esac
 299     case "${host}" in
 300     mips*el-*-*)
 301         GOARCH="${GOARCH}le"
 302         ;;
 303     esac
 304     ;;
 305   nios2-*-*)
 306     GOARCH=nios2
 307     ;;
 308   rs6000*-*-* | powerpc*-*-*)
 309     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 310 #ifdef _ARCH_PPC64
 311 #error 64-bit
 312 #endif
 313 ])],
 314 [GOARCH=ppc],
 315     [
 316 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 317 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 318 #error 64be
 319 #endif
 320 ])],
 321 [GOARCH=ppc64le],
 322 [GOARCH=ppc64])])
 323     ;;
 324   riscv64-*-*)
 325     GOARCH=riscv64
 326     ;;
 327   s390*-*-*)
 328     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 329 #if defined(__s390x__)
 330 #error 64-bit
 331 #endif
 332 ])],
 333 [GOARCH=s390],
 334 [GOARCH=s390x])
 335     ;;
 336   sh3eb*-*-* | sh4eb*-*-*)
 337     GOARCH=shbe
 338     ;;
 339   sh3*-*-* | sh4*-*-*)
 340     GOARCH=sh
 341     ;;
 342   sparc*-*-*)
 343     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 344 #if defined(__sparcv9) || defined(__arch64__)
 345 #error 64-bit
 346 #endif
 347 ])],
 348 [GOARCH=sparc],
 349 [GOARCH=sparc64])
 350     ;;
 351 esac
 352 AC_SUBST(GOARCH)
 353 AC_SUBST(ALLGOARCH)
 354 AC_SUBST(ALLGOARCHFAMILY)
 355
 356 dnl Some files are only present when needed for specific architectures.
 357 GO_LIBCALL_OS_FILE=
 358 GO_LIBCALL_OS_ARCH_FILE=
 359 GO_SYSCALL_OS_FILE=
 360 GO_SYSCALL_OS_ARCH_FILE=
 361 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 362   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 363 fi
 364 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 365   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 366 fi
 367 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 368   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 369 fi
 370 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 371   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 372 fi
 373 AC_SUBST(GO_LIBCALL_OS_FILE)
 374 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 375 AC_SUBST(GO_SYSCALL_OS_FILE)
 376 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 377
 378 dnl Special flags used to generate sysinfo.go.
 379 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 380 case "$target" in
 381     mips-sgi-irix6.5*)
 382         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 383         # msghdr in <sys/socket.h>.
 384         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 385         ;;
 386     *-*-solaris2.1[[01]])
 387         # Solaris 10+ needs this so struct msghdr gets the msg_control
 388         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 389         # above doesn't work with C99.
 390         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 391         ;;
 392 esac
 393 AC_SUBST(OSCFLAGS)
 394
 395 dnl Check if assembler supports disabling hardware capability support.
 396 GCC_CHECK_ASSEMBLER_HWCAP
 397
 398 dnl Use -fsplit-stack when compiling C code if available.
 399 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 400 [libgo_cv_c_split_stack_supported],
 401 [CFLAGS_hold=$CFLAGS
 402 CFLAGS="$CFLAGS -fsplit-stack"
 403 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 404 [libgo_cv_c_split_stack_supported=yes],
 405 [libgo_cv_c_split_stack_supported=no])
 406 CFLAGS=$CFLAGS_hold])
 407
 408 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 409 dnl reject split-stack code calling non-split-stack code on targets
 410 dnl they don't support.
 411 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 412 [libgo_cv_c_linker_split_non_split],
 413 [cat > conftest1.c << EOF
 414 extern void f();
 415 int main() { f(); return 0; }
 416 EOF
 417 cat > conftest2.c << EOF
 418 void f() {}
 419 EOF
 420 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 421 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 422 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 423   libgo_cv_c_linker_split_non_split=yes
 424 else
 425   libgo_cv_c_linker_split_non_split=no
 426 fi
 427 rm -f conftest1.* conftest2.* conftest])
 428
 429 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 430   SPLIT_STACK=-fsplit-stack
 431   AC_DEFINE(USING_SPLIT_STACK, 1,
 432                 [Define if the compiler supports -fsplit-stack])
 433 else
 434   SPLIT_STACK=
 435 fi
 436 AC_SUBST(SPLIT_STACK)
 437 AM_CONDITIONAL(USING_SPLIT_STACK,
 438         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 439
 440 dnl If the compiler supports split-stack but the linker does not, then
 441 dnl we need to explicitly disable split-stack for Go.
 442 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 443   GO_SPLIT_STACK=-fno-split-stack
 444 else
 445   GO_SPLIT_STACK=
 446 fi
 447 AC_SUBST(GO_SPLIT_STACK)
 448
 449 dnl Check whether the linker does stack munging when calling from
 450 dnl split-stack into non-split-stack code.  We check this by looking
 451 dnl at the --help output.  FIXME: This is only half right: it's
 452 dnl possible for the linker to support this for some targets but not
 453 dnl others.
 454 dnl This is slightly different from the above check, which is whether
 455 dnl the linker permits the call at all.
 456 AC_CACHE_CHECK([whether linker supports split stack],
 457 [libgo_cv_c_linker_supports_split_stack],
 458 [libgo_cv_c_linker_supports_split_stack=no
 459 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 460   libgo_cv_c_linker_supports_split_stack=yes
 461 fi])
 462 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 463   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 464             [Define if the linker support split stack adjustments])
 465 fi
 466
 467 AC_CACHE_CHECK([whether compiler is llgo],
 468 [libgo_cv_c_goc_is_llgo],
 469 [libgo_cv_c_goc_is_llgo=no
 470 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 471   libgo_cv_c_goc_is_llgo=yes
 472 fi])
 473 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 474
 475 dnl Test for the -lm library.
 476 MATH_LIBS=
 477 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 478 AC_SUBST(MATH_LIBS)
 479
 480 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 481 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 482   [libgo_cv_lib_sockets=
 483    libgo_check_both=no
 484    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 485    if test "$libgo_check_socket" = "yes"; then
 486      unset ac_cv_func_connect
 487      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 488                   libgo_check_both=yes)
 489    fi
 490    if test "$libgo_check_both" = "yes"; then
 491      libgo_old_libs=$LIBS
 492      LIBS="$LIBS -lsocket -lnsl"
 493      unset ac_cv_func_accept
 494      AC_CHECK_FUNC(accept,
 495                    [libgo_check_nsl=no
 496                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 497      unset ac_cv_func_accept
 498      LIBS=$libgo_old_libs
 499    fi
 500    unset ac_cv_func_gethostbyname
 501    libgo_old_libs="$LIBS"
 502    AC_CHECK_FUNC(gethostbyname, ,
 503                  [AC_CHECK_LIB(nsl, main,
 504                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 505    unset ac_cv_func_gethostbyname
 506    AC_CHECK_FUNC(sendfile, ,
 507                  [AC_CHECK_LIB(sendfile, main,
 508                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 509    LIBS=$libgo_old_libs
 510 ])
 511 NET_LIBS="$libgo_cv_lib_sockets"
 512 AC_SUBST(NET_LIBS)
 513
 514 dnl Test whether the compiler supports the -pthread option.
 515 AC_CACHE_CHECK([whether -pthread is supported],
 516 [libgo_cv_lib_pthread],
 517 [CFLAGS_hold=$CFLAGS
 518 CFLAGS="$CFLAGS -pthread -L../libatomic/.libs"
 519 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 520 [libgo_cv_lib_pthread=yes],
 521 [libgo_cv_lib_pthread=no])
 522 CFLAGS=$CFLAGS_hold])
 523 PTHREAD_CFLAGS=
 524 if test "$libgo_cv_lib_pthread" = yes; then
 525   # RISC-V apparently adds -latomic when using -pthread.
 526   PTHREAD_CFLAGS="-pthread -L../libatomic/.libs"
 527 fi
 528 AC_SUBST(PTHREAD_CFLAGS)
 529
 530 dnl Test for the -lpthread library.
 531 PTHREAD_LIBS=
 532 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 533 AC_SUBST(PTHREAD_LIBS)
 534
 535 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 536 AC_SEARCH_LIBS([sched_yield], [rt])
 537 AC_SEARCH_LIBS([nanosleep], [rt])
 538 AC_SEARCH_LIBS([clock_gettime], [rt])
 539
 540 AC_C_BIGENDIAN
 541
 542 GCC_CHECK_UNWIND_GETIPINFO
 543
 544 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 545
 546 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 547 [#include <netinet/in.h>
 548 ])
 549
 550 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 551 [#ifdef HAVE_SYS_SOCKET_H
 552 #include <sys/socket.h>
 553 #endif
 554 ])
 555
 556 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 557
 558 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr memmem)
 559 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 560 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 561
 562 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 563 AC_TYPE_OFF_T
 564 AC_CHECK_TYPES([loff_t])
 565
 566 LIBS_hold="$LIBS"
 567 LIBS="$LIBS -lm"
 568 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 569 LIBS="$LIBS_hold"
 570
 571 CFLAGS_hold="$CFLAGS"
 572 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 573 LIBS_hold="$LIBS"
 574 LIBS="$LIBS $PTHREAD_LIBS"
 575 AC_CHECK_FUNCS(sem_timedwait)
 576 CFLAGS="$CFLAGS_hold"
 577 LIBS="$LIBS_hold"
 578
 579 LIBS_hold="$LIBS"
 580 LIBS="$LIBS $MATH_LIBS"
 581 AC_CHECK_FUNCS(matherr)
 582 LIBS="$LIBS_hold"
 583
 584 dnl For x86 we want to use the -minline-all-stringops option to avoid
 585 dnl forcing a stack split when calling memcpy and friends.
 586 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 587 [libgo_cv_c_stringops],
 588 [CFLAGS_hold=$CFLAGS
 589 CFLAGS="$CFLAGS -minline-all-stringops"
 590 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 591 [libgo_cv_c_stringops=yes],
 592 [libgo_cv_c_stringops=no])
 593 CFLAGS=$CFLAGS_hold])
 594 STRINGOPS_FLAG=
 595 if test "$libgo_cv_c_stringops" = yes; then
 596   STRINGOPS_FLAG=-minline-all-stringops
 597 fi
 598 AC_SUBST(STRINGOPS_FLAG)
 599
 600 dnl For x86 we want to compile the math library with -mfancy-math-387
 601 dnl so that we can use the builtin instructions directly.
 602 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 603 [libgo_cv_c_fancymath],
 604 [CFLAGS_hold=$CFLAGS
 605 CFLAGS="$CFLAGS -mfancy-math-387"
 606 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 607 [libgo_cv_c_fancymath=yes],
 608 [libgo_cv_c_fancymath=no])
 609 CFLAGS=$CFLAGS_hold])
 610 MATH_FLAG=
 611 if test "$libgo_cv_c_fancymath" = yes; then
 612   MATH_FLAG="-mfancy-math-387"
 613 fi
 614 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 615 AC_SUBST(MATH_FLAG)
 616
 617 CFLAGS_hold=$CFLAGS
 618 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 619 AC_CHECK_TYPES([off64_t])
 620 CFLAGS=$CFLAGS_hold
 621
 622 dnl Work out the size of the epoll_events struct on GNU/Linux.
 623 AC_CACHE_CHECK([epoll_event size],
 624 [libgo_cv_c_epoll_event_size],
 625 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 626 [sizeof (struct epoll_event)],
 627 [#include <sys/epoll.h>],
 628 [libgo_cv_c_epoll_event_size=0])])
 629 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 630 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 631
 632 dnl Work out the offset of the fd field in the epoll_events struct on
 633 dnl GNU/Linux.
 634 AC_CACHE_CHECK([epoll_event data.fd offset],
 635 [libgo_cv_c_epoll_event_fd_offset],
 636 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 637 [offsetof (struct epoll_event, data.fd)],
 638 [#include <stddef.h>
 639 #include <sys/epoll.h>],
 640 [libgo_cv_c_epoll_event_fd_offset=0])])
 641 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 642 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 643
 644 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 645 dnl in Solaris 11.4 for XPG7 compatibility.
 646 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 647                 [have_stat_timespec=yes], [have_stat_timespec=no])
 648 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 649
 650 dnl See if struct exception is defined in <math.h>.
 651 AC_CHECK_TYPE([struct exception],
 652 [libgo_has_struct_exception=yes],
 653 [libgo_has_struct_exception=no],
 654 [#include <math.h>])
 655 if test "$libgo_has_struct_exception" = "yes"; then
 656   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 657             [Define to 1 if <math.h> defines struct exception])
 658 fi
 659
 660 dnl See whether setcontext changes the value of TLS variables.
 661 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 662 [libgo_cv_lib_setcontext_clobbers_tls],
 663 [CFLAGS_hold="$CFLAGS"
 664 CFLAGS="$PTHREAD_CFLAGS"
 665 LIBS_hold="$LIBS"
 666 LIBS="$LIBS $PTHREAD_LIBS"
 667 AC_CHECK_SIZEOF([void *])
 668 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 669 AC_RUN_IFELSE(
 670   [AC_LANG_SOURCE([
 671 #include <pthread.h>
 672 #include <stdlib.h>
 673 #include <ucontext.h>
 674 #include <unistd.h>
 675
 676 __thread int tls;
 677
 678 static char stack[[10 * 1024 * 1024]];
 679 static ucontext_t c;
 680
 681 /* Called via makecontext/setcontext.  */
 682
 683 static void
 684 cfn (void)
 685 {
 686   exit (tls);
 687 }
 688
 689 /* Called via pthread_create.  */
 690
 691 static void *
 692 tfn (void *dummy)
 693 {
 694   /* The thread should still see this value after calling
 695      setcontext.  */
 696   tls = 0;
 697
 698   setcontext (&c);
 699
 700   /* The call to setcontext should not return.  */
 701   abort ();
 702 }
 703
 704 int
 705 main ()
 706 {
 707   pthread_t tid;
 708
 709   /* The thread should not see this value.  */
 710   tls = 1;
 711
 712   if (getcontext (&c) < 0)
 713     abort ();
 714
 715   c.uc_stack.ss_sp = stack;
 716 #ifdef MAKECONTEXT_STACK_TOP
 717   c.uc_stack.ss_sp += sizeof stack;
 718 #endif
 719   c.uc_stack.ss_flags = 0;
 720   c.uc_stack.ss_size = sizeof stack;
 721   c.uc_link = NULL;
 722   makecontext (&c, cfn, 0);
 723
 724   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 725     abort ();
 726
 727   if (pthread_join (tid, NULL) != 0)
 728     abort ();
 729
 730   /* The thread should have called exit.  */
 731   abort ();
 732 }
 733 ])],
 734 [libgo_cv_lib_setcontext_clobbers_tls=no],
 735 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 736 [case "$target:$ptr_type_size" in
 737   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 738     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 739   *)
 740     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 741  esac
 742 ])
 743 CFLAGS="$CFLAGS_hold"
 744 LIBS="$LIBS_hold"
 745 ])
 746 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 747   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 748             [Define if setcontext clobbers TLS variables])
 749 fi
 750
 751 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 752 libgo_cv_ro_eh_frame, [
 753 libgo_cv_ro_eh_frame=no
 754 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 755 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 756   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 757     libgo_cv_ro_eh_frame=yes
 758   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 759        | grep -v '#write' > /dev/null; then
 760     libgo_cv_ro_eh_frame=yes
 761   fi
 762 fi
 763 rm -f conftest.*
 764 ])
 765 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 766   AC_DEFINE(EH_FRAME_FLAGS, "a",
 767             [Define to the flags needed for the .section .eh_frame directive.])
 768 else
 769   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 770             [Define to the flags needed for the .section .eh_frame directive.])
 771 fi
 772
 773 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 774 [libgo_cv_c_unused_arguments],
 775 [CFLAGS_hold=$CFLAGS
 776 CFLAGS="$CFLAGS -Qunused-arguments"
 777 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 778 [libgo_cv_c_unused_arguments=yes],
 779 [libgo_cv_c_unused_arguments=no])
 780 CFLAGS=$CFLAGS_hold])
 781
 782 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 783 libgo_cv_as_comdat_gnu, [
 784 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 785 CFLAGS_hold=$CFLAGS
 786 if test "$libgo_cv_c_unused_arguments" = yes; then
 787   CFLAGS="$CFLAGS -Qunused-arguments"
 788 fi
 789 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 790   libgo_cv_as_comdat_gnu=yes
 791 else
 792   libgo_cv_as_comdat_gnu=no
 793 fi
 794 CFLAGS=$CFLAGS_hold
 795 ])
 796 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 797   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 798             [Define if your assembler supports GNU comdat group syntax.])
 799 fi
 800
 801 AC_CACHE_CHECK([assembler supports pc related relocs],
 802 libgo_cv_as_x86_pcrel, [
 803 libgo_cv_as_x86_pcrel=yes
 804 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 805 CFLAGS_hold=$CFLAGS
 806 if test "$libgo_cv_c_unused_arguments" = yes; then
 807   CFLAGS="$CFLAGS -Qunused-arguments"
 808 fi
 809 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 810     libgo_cv_as_x86_pcrel=no
 811 fi
 812 CFLAGS=$CFLAGS_hold
 813 ])
 814 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 815   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 816             [Define if your assembler supports PC relative relocs.])
 817 fi
 818
 819 AC_CACHE_CHECK([assembler supports unwind section type],
 820 libgo_cv_as_x86_64_unwind_section_type, [
 821 libgo_cv_as_x86_64_unwind_section_type=yes
 822 echo '.section .eh_frame,"a",@unwind' > conftest.s
 823 CFLAGS_hold=$CFLAGS
 824 if test "$libgo_cv_c_unused_arguments" = yes; then
 825   CFLAGS="$CFLAGS -Qunused-arguments"
 826 fi
 827 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 828     libgo_cv_as_x86_64_unwind_section_type=no
 829 fi
 830 CFLAGS=$CFLAGS_hold
 831 ])
 832 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 833   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 834             [Define if your assembler supports unwind section type.])
 835 fi
 836
 837 AC_CACHE_CHECK([assembler supports AES instructions],
 838 libgo_cv_as_x86_aes, [
 839 libgo_cv_as_x86_aes=yes
 840 echo 'aesenc %xmm0, %xmm1' > conftest.s
 841 CFLAGS_hold=$CFLAGS
 842 if test "$libgo_cv_c_unused_arguments" = yes; then
 843   CFLAGS="$CFLAGS -Qunused-arguments"
 844 fi
 845 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 846     libgo_cv_as_x86_aes=no
 847 fi
 848 CFLAGS=$CFLAGS_hold
 849 ])
 850 if test "x$libgo_cv_as_x86_aes" = xyes; then
 851   AC_DEFINE(HAVE_AS_X86_AES, 1,
 852             [Define if your assembler supports AES instructions.])
 853 fi
 854
 855 AC_CACHE_SAVE
 856
 857 if test ${multilib} = yes; then
 858   multilib_arg="--enable-multilib"
 859 else
 860   multilib_arg=
 861 fi
 862
 863 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 864
 865 AC_CONFIG_COMMANDS([default],
 866 [if test -n "$CONFIG_FILES"; then
 867    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 868    # that multilib installs will end up installed in the correct place.
 869    # The testsuite needs it for multilib-aware ABI baseline files.
 870    # To work around this not being passed down from config-ml.in ->
 871    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 872    # append it here.  Only modify Makefiles that have just been created.
 873    #
 874    # Also, get rid of this simulated-VPATH thing that automake does.
 875    cat > vpsed << \_EOF
 876 s!`test -f '$<' || echo '$(srcdir)/'`!!
 877 _EOF
 878    for i in $SUBDIRS; do
 879     case $CONFIG_FILES in
 880      *${i}/Makefile*)
 881        #echo "Adding MULTISUBDIR to $i/Makefile"
 882        sed -f vpsed $i/Makefile > tmp
 883        grep '^MULTISUBDIR =' Makefile >> tmp
 884        mv tmp $i/Makefile
 885        ;;
 886     esac
 887    done
 888    rm vpsed
 889  fi
 890 ],
 891 [
 892 # Variables needed in config.status (file generation) which aren't already
 893 # passed by autoconf.
 894 SUBDIRS="$SUBDIRS"
 895 ])
 896
 897 AC_OUTPUT