libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14
  15 AC_PREREQ(2.64)
  16 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  17 AC_CONFIG_SRCDIR([static-object.mk])
  18
  19 # The libgcc should not depend on any header files
  20 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  21   [m4_divert_text([DEFAULTS],
  22     [ac_includes_default='/* none */'])])
  23
  24 AC_ARG_WITH(target-subdir,
  25 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  26 AC_ARG_WITH(cross-host,
  27 [  --with-cross-host=HOST           Configuring with a cross compiler])
  28 AC_ARG_WITH(ld,
  29 [  --with-ld               arrange to use the specified ld (full pathname)])
  30
  31 if test "${srcdir}" = "."; then
  32   if test -n "${with_build_subdir}"; then
  33     libgcc_topdir="${srcdir}/../.."
  34     with_target_subdir=
  35   elif test -z "${with_target_subdir}"; then
  36     libgcc_topdir="${srcdir}/.."
  37   else
  38     if test "${with_target_subdir}" != "."; then
  39       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  40     else
  41       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  42     fi
  43   fi
  44 else
  45   libgcc_topdir="${srcdir}/.."
  46 fi
  47 AC_SUBST(libgcc_topdir)
  48 AC_CONFIG_AUX_DIR($libgcc_topdir)
  49 AC_CONFIG_HEADER(auto-target.h:config.in)
  50
  51 AC_ARG_ENABLE(shared,
  52 [  --disable-shared        don't provide a shared libgcc],
  53 [
  54   case $enable_shared in
  55   yes | no) ;;
  56   *)
  57     enable_shared=no
  58     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  59     for pkg in $enableval; do
  60       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  61         enable_shared=yes
  62       fi
  63     done
  64     IFS="$ac_save_ifs"
  65     ;;
  66   esac
  67 ], [enable_shared=yes])
  68 AC_SUBST(enable_shared)
  69
  70 AC_ARG_ENABLE(vtable-verify,
  71 [  --enable-vtable-verify    Enable vtable verification feature ],
  72 [case "$enableval" in
  73  yes) enable_vtable_verify=yes ;;
  74  no)  enable_vtable_verify=no ;;
  75  *)   enable_vtable_verify=no;;
  76  esac],
  77 [enable_vtable_verify=no])
  78 AC_SUBST(enable_vtable_verify)
  79
  80 AC_ARG_WITH(aix-soname,
  81 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  82     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  83 [case "${host}:${enable_shared}" in
  84  power*-*-aix[[5-9]]*:yes)
  85    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  86    case ${withval} in
  87      aix|svr4|both) ;;
  88      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  89    esac
  90    AC_MSG_RESULT($withval)
  91    ;;
  92  *) with_aix_soname=aix ;;
  93  esac
  94 ], [with_aix_soname=aix])
  95 AC_SUBST(with_aix_soname)
  96
  97 GCC_PICFLAG
  98 AC_SUBST(PICFLAG)
  99
 100 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 101 AC_ARG_ENABLE(version-specific-runtime-libs,
 102 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 103 [case "$enableval" in
 104  yes) version_specific_libs=yes ;;
 105  no)  version_specific_libs=no ;;
 106  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 107  esac],
 108 [version_specific_libs=no])
 109 AC_MSG_RESULT($version_specific_libs)
 110
 111 AC_ARG_WITH(slibdir,
 112 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 113 slibdir="$with_slibdir",
 114 if test "${version_specific_libs}" = yes; then
 115   slibdir='$(libsubdir)'
 116 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 117   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 118 else
 119   slibdir='$(libdir)'
 120 fi)
 121 AC_SUBST(slibdir)
 122
 123 # Command-line options.
 124 # Very limited version of AC_MAINTAINER_MODE.
 125 AC_ARG_ENABLE([maintainer-mode],
 126   [AC_HELP_STRING([--enable-maintainer-mode],
 127                  [enable make rules and dependencies not useful (and
 128                   sometimes confusing) to the casual installer])],
 129   [case ${enable_maintainer_mode} in
 130      yes) MAINT='' ;;
 131      no) MAINT='#' ;;
 132      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 133    esac
 134    maintainer_mode=${enableval}],
 135   [MAINT='#'])
 136 AC_SUBST([MAINT])dnl
 137
 138 AC_PROG_INSTALL
 139
 140 AC_PROG_AWK
 141 # We need awk; bail out if it's missing.
 142 case ${AWK} in
 143   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 144 esac
 145
 146 AC_CANONICAL_HOST
 147 ACX_NONCANONICAL_HOST
 148 ACX_NONCANONICAL_TARGET
 149 GCC_TOPLEV_SUBDIRS
 150
 151 # Calculate toolexeclibdir
 152 # Also toolexecdir, though it's only used in toolexeclibdir
 153 case ${version_specific_libs} in
 154   yes)
 155     # Need the gcc compiler version to know where to install libraries
 156     # and header files if --enable-version-specific-runtime-libs option
 157     # is selected.
 158     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 159     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 160     ;;
 161   no)
 162     if test -n "$with_cross_host" &&
 163        test x"$with_cross_host" != x"no"; then
 164       # Install a library built with a cross compiler in tooldir, not libdir.
 165       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 166       toolexeclibdir='$(toolexecdir)/lib'
 167     else
 168       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 169       toolexeclibdir='$(libdir)'
 170     fi
 171     multi_os_directory=`$CC -print-multi-os-directory`
 172     case $multi_os_directory in
 173       .) ;; # Avoid trailing /.
 174       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 175     esac
 176     ;;
 177 esac
 178 AC_SUBST(toolexecdir)
 179 AC_SUBST(toolexeclibdir)
 180
 181 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 182 dnl to call AC_CHECK_PROG.
 183 AC_CHECK_TOOL(AR, ar)
 184 AC_CHECK_TOOL(LIPO, lipo, :)
 185 AC_CHECK_TOOL(NM, nm)
 186 AC_CHECK_TOOL(RANLIB, ranlib, :)
 187 AC_CHECK_TOOL(STRIP, strip, :)
 188 AC_PROG_LN_S
 189
 190 GCC_NO_EXECUTABLES
 191 AC_PROG_CC
 192 AC_PROG_CPP_WERROR
 193
 194 AC_SYS_LARGEFILE
 195
 196 AC_CHECK_SIZEOF([double])
 197 AC_CHECK_SIZEOF([long double])
 198 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 199 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 200 AC_SUBST(double_type_size)
 201 AC_SUBST(long_double_type_size)
 202
 203 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 204         unistd.h sys/stat.h sys/types.h \
 205         string.h strings.h memory.h)
 206 AC_HEADER_STDC
 207
 208 # Check for decimal float support.
 209 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 210                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 211 #include <fenv.h>
 212 ]], [[
 213 _Decimal32 x;
 214 int fe_except =
 215   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 216 ]])],
 217                                   [libgcc_cv_dfp=yes],
 218                                   [libgcc_cv_dfp=no])])
 219 decimal_float=$libgcc_cv_dfp
 220 AC_SUBST(decimal_float)
 221
 222 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 223
 224 # Check for fixed-point support.
 225 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 226                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 227                                   [libgcc_cv_fixed_point=no])])
 228 fixed_point=$libgcc_cv_fixed_point
 229 AC_SUBST(fixed_point)
 230
 231 # For platforms with the unwind ABI which includes an unwind library,
 232 # libunwind, we can choose to use the system libunwind.
 233 # config.gcc also contains tests of with_system_libunwind.
 234 GCC_CHECK_UNWIND_GETIPINFO
 235
 236 # Check if the compiler is configured for setjmp/longjmp exceptions.
 237 GCC_CHECK_SJLJ_EXCEPTIONS
 238
 239 AC_ARG_ENABLE([explicit-exception-frame-registration],
 240   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 241      [register exception tables explicitly at module start, for use
 242       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 243 [
 244 force_explicit_eh_registry=
 245 if test "$enable_explicit_exception_frame_registration" = yes; then
 246   if test $ac_cv_sjlj_exceptions = yes; then
 247     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 248                   with setjmp/longjmp exceptions])
 249   fi
 250   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 251 fi
 252 ])
 253 AC_SUBST([force_explicit_eh_registry])
 254
 255 AC_LIB_PROG_LD_GNU
 256
 257 AC_MSG_CHECKING([for thread model used by GCC])
 258 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 259 AC_MSG_RESULT([$target_thread_file])
 260
 261 # Check for assembler CFI support.
 262 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 263                [AC_COMPILE_IFELSE(
 264 [asm("\n\
 265         .text\n\
 266         .cfi_startproc\n\
 267         .cfi_personality 0, symbol\n\
 268         .cfi_endproc");],
 269   [libgcc_cv_cfi=yes],
 270   [libgcc_cv_cfi=no])])
 271
 272 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 273 # word size rather than the address size.
 274 cat > conftest.c <<EOF
 275 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 276     || defined(__mips64)
 277 host_address=64
 278 #else
 279 host_address=32
 280 #endif
 281 EOF
 282 eval `${CC-cc} -E conftest.c | grep host_address=`
 283 rm -f conftest.c
 284
 285 case ${host} in
 286 mips*-*-*)
 287   AC_CACHE_CHECK([whether the target is hard-float],
 288                  [libgcc_cv_mips_hard_float],
 289                  [AC_COMPILE_IFELSE(
 290     [#ifndef __mips_hard_float
 291      #error FOO
 292      #endif],
 293     [libgcc_cv_mips_hard_float=yes],
 294     [libgcc_cv_mips_hard_float=no])])
 295 esac
 296
 297 case ${host} in
 298 *-*-solaris2*)
 299   # Check for system-provided CRTs on Solaris 11.x and Solaris 12.
 300   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 301                  [libgcc_cv_solaris_crts],
 302     [libgcc_cv_solaris_crts=no
 303      libgcc_sysroot="`${CC} -print-sysroot`"
 304      libgcc_libdir="$libgcc_sysroot/usr/lib"
 305      # At the time they were added, gcrt1.o became a symlink for backwards
 306      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 307      case ${host} in
 308        i?86-*-solaris2* | x86_64-*-solaris2*)
 309          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 310          ;;
 311        sparc*-*-solaris2*)
 312          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 313          ;;
 314      esac])
 315   if test $libgcc_cv_solaris_crts = yes; then
 316     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 317       [Define if the system-provided CRTs are present on Solaris.])
 318   fi
 319   ;;
 320 esac
 321
 322 # Determine the version of glibc, if any, used on the target.
 323 AC_MSG_CHECKING([for target glibc version])
 324 AC_ARG_WITH([glibc-version],
 325   [AS_HELP_STRING([--with-glibc-version=M.N],
 326     [assume GCC used with glibc version M.N or later])], [
 327 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 328   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 329   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 330 else
 331   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 332 fi], [
 333 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 334                                       [#include <features.h>],
 335                                       [glibc_version_major=0])
 336 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 337                                       [#include <features.h>],
 338                                       [glibc_version_minor=0])])
 339 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 340
 341 # Determine floating-point type for powerpc*-*-linux*.
 342 # Single-precision-only FPRs are not a supported configuration for
 343 # this target, so are not allowed for in this test.
 344 case ${host} in
 345 powerpc*-*-linux*)
 346   cat > conftest.c <<EOF
 347 #ifdef __powerpc64__
 348 ppc_fp_type=64
 349 #elif defined _SOFT_FLOAT
 350 ppc_fp_type=soft
 351 #elif defined _SOFT_DOUBLE
 352 ppc_fp_type=e500v1
 353 #elif defined __NO_FPRS__
 354 ppc_fp_type=e500v2
 355 #else
 356 ppc_fp_type=hard
 357 #endif
 358 EOF
 359 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 360 rm -f conftest.c
 361 # glibc 2.19 and later provide all the soft-fp functions, with proper
 362 # interactions with <fenv.h> exception and rounding mode handling, so
 363 # make libgcc's versions into compat symbols if a recent enough glibc
 364 # version is being used.
 365 ppc_fp_compat=
 366 case ${ppc_fp_type} in
 367 soft|e500v1|e500v2)
 368   if test $glibc_version_major -gt 2 \
 369     || ( test $glibc_version_major -eq 2 \
 370         && test $glibc_version_minor -ge 19 ); then
 371     ppc_fp_compat="t-softfp-compat"
 372   fi
 373   ;;
 374 esac
 375 ;;
 376 esac
 377
 378 case ${host} in
 379 # At present, we cannot turn -mfloat128 on via #pragma GCC target,
 380 # so just check if we have VSX (ISA 2.06) support to build the
 381 # software libraries, and whether the assembler can handle xsaddqp
 382 # for hardware support.
 383 powerpc*-*-linux*)
 384   saved_CFLAGS="$CFLAGS"
 385   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 386   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 387                  [libgcc_cv_powerpc_float128],
 388                  [AC_COMPILE_IFELSE(
 389     [vector double dadd (vector double a, vector double b) { return a + b; }],
 390     [libgcc_cv_powerpc_float128=yes],
 391     [libgcc_cv_powerpc_float128=no])])
 392
 393   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 394   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 395                  [libgcc_cv_powerpc_float128_hw],
 396                  [AC_COMPILE_IFELSE(
 397     [#include <sys/auxv.h>
 398      #ifndef AT_PLATFORM
 399      #error "AT_PLATFORM is not defined"
 400      #endif
 401      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 402      {
 403        vector unsigned char ret;
 404        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 405        return ret;
 406      }
 407      void *add_resolver (void) { return (void *) add; }
 408      __float128 add_ifunc (__float128, __float128)
 409         __attribute__ ((__ifunc__ ("add_resolver")));],
 410     [libgcc_cv_powerpc_float128_hw=yes],
 411     [libgcc_cv_powerpc_float128_hw=no])])
 412   CFLAGS="$saved_CFLAGS"
 413 esac
 414
 415 # Collect host-machine-specific information.
 416 . ${srcdir}/config.host
 417
 418 # Used for constructing correct paths for offload compilers.
 419 accel_dir_suffix=
 420 real_host_noncanonical=${host_noncanonical}
 421 if test x"$enable_as_accelerator_for" != x; then
 422   accel_dir_suffix=/accel/${target_noncanonical}
 423   real_host_noncanonical=${enable_as_accelerator_for}
 424 fi
 425 AC_SUBST(accel_dir_suffix)
 426 AC_SUBST(real_host_noncanonical)
 427
 428 if test x"$enable_offload_targets" != x; then
 429   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 430 fi
 431
 432 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 433 # This is after config.host so we can augment tmake_file.
 434 # Link with -nostartfiles -nodefaultlibs since neither are present while
 435 # building libgcc.
 436 case ${host} in
 437 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 438   cat > conftest.s <<EOF
 439         .section        .eh_frame,"a",@unwind
 440         .zero   4
 441         .section        .jcr,"aw",@progbits
 442         .zero   8
 443 EOF
 444   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 445       tmake_file="${tmake_file} i386/t-crtstuff"
 446   fi
 447   ;;
 448 esac
 449
 450 # Check if xtensa target is configured for windowed ABI and thus needs to use
 451 # custom unwind code.
 452 # This is after config.host so we can augment tmake_file.
 453 case ${host} in
 454 xtensa*-*)
 455   cat > conftest.c <<EOF
 456         #ifdef __XTENSA_CALL0_ABI__
 457         #error
 458         #endif
 459 EOF
 460   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 461       tmake_file="${tmake_file} xtensa/t-windowed"
 462   fi
 463   ;;
 464 esac
 465
 466 # Check for visibility support.  This is after config.host so that
 467 # we can check for asm_hidden_op.
 468 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 469     libgcc_cv_hidden_visibility_attribute, [
 470         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 471         libgcc_cv_hidden_visibility_attribute=no
 472         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 473             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 474                 libgcc_cv_hidden_visibility_attribute=yes
 475             fi
 476         fi
 477         rm -f conftest.*
 478     ])
 479
 480 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 481     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 482 else
 483     vis_hide=
 484 fi
 485 AC_SUBST(vis_hide)
 486
 487 # See if we have thread-local storage.  We can only test assembler
 488 # since link-time and run-time tests require the newly built
 489 # gcc, which can't be used to build executable due to that libgcc
 490 # is yet to be built here.
 491 GCC_CHECK_CC_TLS
 492 set_have_cc_tls=
 493 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 494   set_have_cc_tls="-DHAVE_CC_TLS"
 495 fi
 496 AC_SUBST(set_have_cc_tls)
 497
 498 # See if we have emulated thread-local storage.
 499 GCC_CHECK_EMUTLS
 500 set_use_emutls=
 501 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 502   set_use_emutls="-DUSE_EMUTLS"
 503 fi
 504 AC_SUBST(set_use_emutls)
 505
 506 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 507 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 508   [[void ip (void) __attribute__ ((constructor (1)));]])],
 509   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 510 if test $libgcc_cv_init_priority = yes; then
 511   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 512   [Define if the compiler supports init priority.])
 513 fi
 514
 515 # Conditionalize the sfp-machine.h header for this target machine.
 516 if test -z "${sfp_machine_header}"; then
 517         sfp_machine_header=$cpu_type/sfp-machine.h
 518         if test -f ${srcdir}/config/${sfp_machine_header}; then
 519                 :
 520         else
 521                 sfp_machine_header=no-sfp-machine.h
 522         fi
 523 fi
 524 AC_SUBST(sfp_machine_header)
 525
 526 # Conditionalize the makefile for this target machine.
 527 tmake_file_=
 528 for f in ${tmake_file}
 529 do
 530         if test -f ${srcdir}/config/$f
 531         then
 532                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 533         fi
 534 done
 535 tmake_file="${tmake_file_}"
 536 AC_SUBST(tmake_file)
 537
 538 # Likewise export definitions for libgcc_tm.h
 539 tm_file_=
 540 for f in ${tm_file}
 541 do
 542         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 543 done
 544 tm_file="${tm_file_}"
 545 AC_SUBST(tm_file)
 546 AC_SUBST(tm_defines)
 547
 548 # Map from thread model to thread header.
 549 GCC_AC_THREAD_HEADER([$target_thread_file])
 550
 551 # Determine what GCC version number to use in filesystem paths.
 552 GCC_BASE_VER
 553
 554 # Substitute configuration variables
 555 AC_SUBST(cpu_type)
 556 AC_SUBST(extra_parts)
 557 AC_SUBST(asm_hidden_op)
 558 AC_SUBST(enable_execute_stack)
 559 AC_SUBST(unwind_header)
 560 AC_SUBST(md_unwind_header)
 561 AC_SUBST(sfp_machine_header)
 562 AC_SUBST(thread_header)
 563
 564 # We need multilib support.
 565 AC_CONFIG_FILES([Makefile])
 566 AC_CONFIG_COMMANDS([default],
 567   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 568 if test -n "$CONFIG_FILES"; then
 569   # FIXME: We shouldn't need to set ac_file
 570   ac_file=Makefile
 571   . ${libgcc_topdir}/config-ml.in
 572 fi]],
 573 [[srcdir=${srcdir}
 574 host=${host}
 575 with_target_subdir=${with_target_subdir}
 576 with_multisubdir=${with_multisubdir}
 577 ac_configure_args="--enable-multilib ${ac_configure_args}"
 578 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 579 libgcc_topdir=${libgcc_topdir}
 580 CC="${CC}"
 581 ]])
 582 AC_OUTPUT