gcc/ada/scn.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  S C N                                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Hostparm; use Hostparm;
  29 with Namet;    use Namet;
  30 with Opt;      use Opt;
  31 with Output;   use Output;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Scans;    use Scans;
  35 with Sinfo;    use Sinfo;
  36 with Sinput;   use Sinput;
  37 with Uintp;    use Uintp;
  38
  39 with GNAT.Byte_Order_Mark; use GNAT.Byte_Order_Mark;
  40
  41 with System.WCh_Con; use System.WCh_Con;
  42
  43 package body Scn is
  44
  45    use ASCII;
  46
  47    Obsolescent_Check_Flag : Boolean := True;
  48    --  Obsolescent check activation. Set to False during integrated
  49    --  preprocessing.
  50
  51    Used_As_Identifier : array (Token_Type) of Boolean;
  52    --  Flags set True if a given keyword is used as an identifier (used to
  53    --  make sure that we only post an error message for incorrect use of a
  54    --  keyword as an identifier once for a given keyword).
  55
  56    procedure Check_End_Of_Line;
  57    --  Called when end of line encountered. Checks that line is not too long,
  58    --  and that other style checks for the end of line are met.
  59
  60    function Determine_License return License_Type;
  61    --  Scan header of file and check that it has an appropriate GNAT-style
  62    --  header with a proper license statement. Returns GPL, Unrestricted,
  63    --  or Modified_GPL depending on header. If none of these, returns Unknown.
  64
  65    procedure Error_Long_Line;
  66    --  Signal error of excessively long line
  67
  68    -----------------------
  69    -- Check_End_Of_Line --
  70    -----------------------
  71
  72    procedure Check_End_Of_Line is
  73       Len : constant Int := Int (Scan_Ptr) - Int (Current_Line_Start);
  74    begin
  75       if Style_Check then
  76          Style.Check_Line_Terminator (Len);
  77       elsif Len > Max_Line_Length then
  78          Error_Long_Line;
  79       end if;
  80    end Check_End_Of_Line;
  81
  82    -----------------------
  83    -- Determine_License --
  84    -----------------------
  85
  86    function Determine_License return License_Type is
  87       GPL_Found : Boolean := False;
  88       Result    : License_Type;
  89
  90       function Contains (S : String) return Boolean;
  91       --  See if current comment contains successive non-blank characters
  92       --  matching the contents of S. If so leave Scan_Ptr unchanged and
  93       --  return True, otherwise leave Scan_Ptr unchanged and return False.
  94
  95       procedure Skip_EOL;
  96       --  Skip to line terminator character
  97
  98       --------------
  99       -- Contains --
 100       --------------
 101
 102       function Contains (S : String) return Boolean is
 103          CP : Natural;
 104          SP : Source_Ptr;
 105          SS : Source_Ptr;
 106
 107       begin
 108          --  Loop to check characters. This loop is terminated by end of
 109          --  line, and also we need to check for the EOF case, to take
 110          --  care of files containing only comments.
 111
 112          SP := Scan_Ptr;
 113          while Source (SP) /= CR and then
 114                Source (SP) /= LF and then
 115                Source (SP) /= EOF
 116          loop
 117             if Source (SP) = S (S'First) then
 118                SS := SP;
 119                CP := S'First;
 120
 121                loop
 122                   SS := SS + 1;
 123                   CP := CP + 1;
 124
 125                   if CP > S'Last then
 126                      return True;
 127                   end if;
 128
 129                   while Source (SS) = ' ' loop
 130                      SS := SS + 1;
 131                   end loop;
 132
 133                   exit when Source (SS) /= S (CP);
 134                end loop;
 135             end if;
 136
 137             SP := SP + 1;
 138          end loop;
 139
 140          return False;
 141       end Contains;
 142
 143       --------------
 144       -- Skip_EOL --
 145       --------------
 146
 147       procedure Skip_EOL is
 148       begin
 149          while Source (Scan_Ptr) /= CR
 150            and then Source (Scan_Ptr) /= LF
 151            and then Source (Scan_Ptr) /= EOF
 152          loop
 153             Scan_Ptr := Scan_Ptr + 1;
 154          end loop;
 155       end Skip_EOL;
 156
 157    --  Start of processing for Determine_License
 158
 159    begin
 160       loop
 161          if Source (Scan_Ptr) /= '-'
 162            or else Source (Scan_Ptr + 1) /= '-'
 163          then
 164             if GPL_Found then
 165                Result := GPL;
 166                exit;
 167             else
 168                Result := Unknown;
 169                exit;
 170             end if;
 171
 172          elsif Contains ("Asaspecialexception") then
 173             if GPL_Found then
 174                Result := Modified_GPL;
 175                exit;
 176             end if;
 177
 178          elsif Contains ("GNUGeneralPublicLicense") then
 179             GPL_Found := True;
 180
 181          elsif
 182              Contains
 183                ("ThisspecificationisadaptedfromtheAdaSemanticInterface")
 184            or else
 185              Contains
 186               ("ThisspecificationisderivedfromtheAdaReferenceManual")
 187          then
 188             Result := Unrestricted;
 189             exit;
 190          end if;
 191
 192          Skip_EOL;
 193
 194          Check_End_Of_Line;
 195
 196          if Source (Scan_Ptr) /= EOF then
 197
 198             --  We have to take into account a degenerate case when the source
 199             --  file contains only comments and no Ada code.
 200
 201             declare
 202                Physical : Boolean;
 203
 204             begin
 205                Skip_Line_Terminators (Scan_Ptr, Physical);
 206
 207                --  If we are at start of physical line, update scan pointers
 208                --  to reflect the start of the new line.
 209
 210                if Physical then
 211                   Current_Line_Start       := Scan_Ptr;
 212                   Start_Column             := Scanner.Set_Start_Column;
 213                   First_Non_Blank_Location := Scan_Ptr;
 214                end if;
 215             end;
 216          end if;
 217       end loop;
 218
 219       return Result;
 220    end Determine_License;
 221
 222    ----------------------------
 223    -- Determine_Token_Casing --
 224    ----------------------------
 225
 226    function Determine_Token_Casing return Casing_Type is
 227    begin
 228       return Scanner.Determine_Token_Casing;
 229    end Determine_Token_Casing;
 230
 231    ---------------------
 232    -- Error_Long_Line --
 233    ---------------------
 234
 235    procedure Error_Long_Line is
 236    begin
 237       Error_Msg
 238         ("this line is too long",
 239          Current_Line_Start + Source_Ptr (Max_Line_Length));
 240    end Error_Long_Line;
 241
 242    ------------------------
 243    -- Initialize_Scanner --
 244    ------------------------
 245
 246    procedure Initialize_Scanner
 247      (Unit  : Unit_Number_Type;
 248       Index : Source_File_Index)
 249    is
 250       GNAT_Hedr : constant Text_Buffer (1 .. 78) := (others => '-');
 251
 252    begin
 253       Scanner.Initialize_Scanner (Index);
 254
 255       if Index /= Internal_Source_File then
 256          Set_Unit (Index, Unit);
 257       end if;
 258
 259       Current_Source_Unit := Unit;
 260
 261       --  Set default for Comes_From_Source (except if we are going to process
 262       --  an artificial string internally created within the compiler and
 263       --  placed into internal source duffer). All nodes built now until we
 264       --  reenter the analyzer will have Comes_From_Source set to True
 265
 266       if Index /= Internal_Source_File then
 267          Set_Comes_From_Source_Default (True);
 268       end if;
 269
 270       --  Check license if GNAT type header possibly present
 271
 272       if Source_Last (Index) - Scan_Ptr > 80
 273         and then Source (Scan_Ptr .. Scan_Ptr + 77) = GNAT_Hedr
 274       then
 275          Set_License (Current_Source_File, Determine_License);
 276       end if;
 277
 278       --  Check for BOM
 279
 280       declare
 281          BOM : BOM_Kind;
 282          Len : Natural;
 283          Tst : String (1 .. 5);
 284
 285       begin
 286          for J in 1 .. 5 loop
 287             Tst (J) := Source (Scan_Ptr + Source_Ptr (J) - 1);
 288          end loop;
 289
 290          Read_BOM (Tst, Len, BOM, False);
 291
 292          case BOM is
 293             when UTF8_All =>
 294                Scan_Ptr := Scan_Ptr + Source_Ptr (Len);
 295                Wide_Character_Encoding_Method := WCEM_UTF8;
 296                Upper_Half_Encoding := True;
 297
 298             when UTF16_LE | UTF16_BE =>
 299                Set_Standard_Error;
 300                Write_Line ("UTF-16 encoding format not recognized");
 301                Set_Standard_Output;
 302                raise Unrecoverable_Error;
 303
 304             when UTF32_LE | UTF32_BE =>
 305                Set_Standard_Error;
 306                Write_Line ("UTF-32 encoding format not recognized");
 307                Set_Standard_Output;
 308                raise Unrecoverable_Error;
 309
 310             when Unknown =>
 311                null;
 312
 313             when others =>
 314                raise Program_Error;
 315          end case;
 316       end;
 317
 318       --  Because of the License stuff above, Scng.Initialize_Scanner cannot
 319       --  call Scan. Scan initial token (note this initializes Prev_Token,
 320       --  Prev_Token_Ptr).
 321
 322       --  There are two reasons not to do the Scan step in case if we
 323       --  initialize the scanner for the internal source buffer:
 324
 325       --  - The artificial string may not be created by the compiler in this
 326       --    buffer when we call Initialize_Scanner
 327
 328       --  - For these artificial strings a special way of scanning is used, so
 329       --    the standard step of the scanner may just break the algorithm of
 330       --    processing these strings.
 331
 332       if Index /= Internal_Source_File then
 333          Scan;
 334       end if;
 335
 336       --  Clear flags for reserved words used as identifiers
 337
 338       for J in Token_Type loop
 339          Used_As_Identifier (J) := False;
 340       end loop;
 341    end Initialize_Scanner;
 342
 343    -----------------------
 344    -- Obsolescent_Check --
 345    -----------------------
 346
 347    procedure Obsolescent_Check (S : Source_Ptr) is
 348    begin
 349       if Obsolescent_Check_Flag then
 350          --  This is a pain in the neck case, since we normally need a node to
 351          --  call Check_Restrictions, and all we have is a source pointer. The
 352          --  easiest thing is to construct a dummy node. A bit kludgy, but this
 353          --  is a marginal case. It's not worth trying to do things more
 354          --  cleanly.
 355
 356          Check_Restriction (No_Obsolescent_Features, New_Node (N_Empty, S));
 357       end if;
 358    end Obsolescent_Check;
 359
 360    ---------------
 361    -- Post_Scan --
 362    ---------------
 363
 364    procedure Post_Scan is
 365    begin
 366       case Token is
 367          when Tok_Char_Literal =>
 368             Token_Node := New_Node (N_Character_Literal, Token_Ptr);
 369             Set_Char_Literal_Value (Token_Node, UI_From_CC (Character_Code));
 370             Set_Chars (Token_Node, Token_Name);
 371
 372          when Tok_Identifier =>
 373             Token_Node := New_Node (N_Identifier, Token_Ptr);
 374             Set_Chars (Token_Node, Token_Name);
 375
 376          when Tok_Real_Literal =>
 377             Token_Node := New_Node (N_Real_Literal, Token_Ptr);
 378             Set_Realval (Token_Node, Real_Literal_Value);
 379
 380          when Tok_Integer_Literal =>
 381             Token_Node := New_Node (N_Integer_Literal, Token_Ptr);
 382             Set_Intval (Token_Node, Int_Literal_Value);
 383
 384          when Tok_String_Literal =>
 385             Token_Node := New_Node (N_String_Literal, Token_Ptr);
 386             Set_Has_Wide_Character (Token_Node, Wide_Character_Found);
 387             Set_Strval (Token_Node, String_Literal_Id);
 388
 389          when Tok_Operator_Symbol =>
 390             Token_Node := New_Node (N_Operator_Symbol, Token_Ptr);
 391             Set_Chars (Token_Node, Token_Name);
 392             Set_Strval (Token_Node, String_Literal_Id);
 393
 394          when others =>
 395             null;
 396       end case;
 397    end Post_Scan;
 398
 399    ------------------------------
 400    -- Scan_Reserved_Identifier --
 401    ------------------------------
 402
 403    procedure Scan_Reserved_Identifier (Force_Msg : Boolean) is
 404       Token_Chars : constant String := Token_Type'Image (Token);
 405
 406    begin
 407       --  We have in Token_Chars the image of the Token name, i.e. Tok_xxx.
 408       --  This code extracts the xxx and makes an identifier out of it.
 409
 410       Name_Len := 0;
 411
 412       for J in 5 .. Token_Chars'Length loop
 413          Name_Len := Name_Len + 1;
 414          Name_Buffer (Name_Len) := Fold_Lower (Token_Chars (J));
 415       end loop;
 416
 417       Token_Name := Name_Find;
 418
 419       if not Used_As_Identifier (Token) or else Force_Msg then
 420          Error_Msg_Name_1 := Token_Name;
 421          Error_Msg_SC ("reserved word* cannot be used as identifier!");
 422          Used_As_Identifier (Token) := True;
 423       end if;
 424
 425       Token := Tok_Identifier;
 426       Token_Node := New_Node (N_Identifier, Token_Ptr);
 427       Set_Chars (Token_Node, Token_Name);
 428    end Scan_Reserved_Identifier;
 429
 430    ---------------------------
 431    -- Set_Obsolescent_Check --
 432    ---------------------------
 433
 434    procedure Set_Obsolescent_Check (Value : Boolean) is
 435    begin
 436       Obsolescent_Check_Flag := Value;
 437    end Set_Obsolescent_Check;
 438
 439 end Scn;