gcc/ada/prj-makr.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             P R J . M A K R                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Csets;
  27 with Opt;
  28 with Output;
  29 with Osint;    use Osint;
  30 with Prj;      use Prj;
  31 with Prj.Com;
  32 with Prj.Part;
  33 with Prj.PP;
  34 with Prj.Tree; use Prj.Tree;
  35 with Prj.Util; use Prj.Util;
  36 with Snames;   use Snames;
  37 with Table;    use Table;
  38
  39 with Ada.Characters.Handling;   use Ada.Characters.Handling;
  40 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  41
  42 with System.Case_Util;          use System.Case_Util;
  43 with System.CRTL;
  44
  45 package body Prj.Makr is
  46
  47    --  Packages of project files where unknown attributes are errors
  48
  49    --  All the following need comments ??? All global variables and
  50    --  subprograms must be fully commented.
  51
  52    Very_Verbose : Boolean := False;
  53    --  Set in call to Initialize to indicate very verbose output
  54
  55    Project_File : Boolean := False;
  56    --  True when gnatname is creating/modifying a project file. False when
  57    --  gnatname is creating a configuration pragmas file.
  58
  59    Tree : constant Project_Node_Tree_Ref := new Project_Node_Tree_Data;
  60    --  The project tree where the project file is parsed
  61
  62    Args : Argument_List_Access;
  63    --  The list of arguments for calls to the compiler to get the unit names
  64    --  and kinds (spec or body) in the Ada sources.
  65
  66    Path_Name : String_Access;
  67
  68    Path_Last : Natural;
  69
  70    Directory_Last    : Natural := 0;
  71
  72    Output_Name      : String_Access;
  73    Output_Name_Last : Natural;
  74    Output_Name_Id   : Name_Id;
  75
  76    Project_Naming_File_Name : String_Access;
  77    --  String (1 .. Output_Name'Length +  Naming_File_Suffix'Length);
  78
  79    Project_Naming_Last : Natural;
  80    Project_Naming_Id   : Name_Id := No_Name;
  81
  82    Source_List_Path : String_Access;
  83    --  (1 .. Output_Name'Length + Source_List_File_Suffix'Length);
  84    Source_List_Last : Natural;
  85
  86    Source_List_FD : File_Descriptor;
  87
  88    Project_Node        : Project_Node_Id := Empty_Node;
  89    Project_Declaration : Project_Node_Id := Empty_Node;
  90    Source_Dirs_List    : Project_Node_Id := Empty_Node;
  91
  92    Project_Naming_Node     : Project_Node_Id := Empty_Node;
  93    Project_Naming_Decl     : Project_Node_Id := Empty_Node;
  94    Naming_Package          : Project_Node_Id := Empty_Node;
  95    Naming_Package_Comments : Project_Node_Id := Empty_Node;
  96
  97    Source_Files_Comments     : Project_Node_Id := Empty_Node;
  98    Source_Dirs_Comments      : Project_Node_Id := Empty_Node;
  99    Source_List_File_Comments : Project_Node_Id := Empty_Node;
 100
 101    Naming_String : aliased String := "naming";
 102
 103    Gnatname_Packages : aliased String_List := (1 => Naming_String'Access);
 104
 105    Packages_To_Check_By_Gnatname : constant String_List_Access :=
 106                                      Gnatname_Packages'Access;
 107
 108    function Dup (Fd : File_Descriptor) return File_Descriptor;
 109
 110    procedure Dup2 (Old_Fd, New_Fd : File_Descriptor);
 111
 112    Gcc      : constant String := "gcc";
 113    Gcc_Path : String_Access := null;
 114
 115    Non_Empty_Node : constant Project_Node_Id := 1;
 116    --  Used for the With_Clause of the naming project
 117
 118    type Matched_Type is (True, False, Excluded);
 119
 120    Naming_File_Suffix      : constant String := "_naming";
 121    Source_List_File_Suffix : constant String := "_source_list.txt";
 122
 123    Output_FD : File_Descriptor;
 124    --  To save the project file and its naming project file
 125
 126    procedure Write_Eol;
 127    --  Output an empty line
 128
 129    procedure Write_A_Char (C : Character);
 130    --  Write one character to Output_FD
 131
 132    procedure Write_A_String (S : String);
 133    --  Write a String to Output_FD
 134
 135    package Processed_Directories is new Table.Table
 136      (Table_Component_Type => String_Access,
 137       Table_Index_Type     => Natural,
 138       Table_Low_Bound      => 0,
 139       Table_Initial        => 10,
 140       Table_Increment      => 100,
 141       Table_Name           => "Prj.Makr.Processed_Directories");
 142    --  The list of already processed directories for each section, to avoid
 143    --  processing several times the same directory in the same section.
 144
 145    package Source_Directories is new Table.Table
 146      (Table_Component_Type => String_Access,
 147       Table_Index_Type     => Natural,
 148       Table_Low_Bound      => 0,
 149       Table_Initial        => 10,
 150       Table_Increment      => 100,
 151       Table_Name           => "Prj.Makr.Source_Directories");
 152    --  The complete list of directories to be put in attribute Source_Dirs in
 153    --  the project file.
 154
 155    type Source is record
 156       File_Name : Name_Id;
 157       Unit_Name : Name_Id;
 158       Index     : Int := 0;
 159       Spec      : Boolean;
 160    end record;
 161
 162    package Sources is new Table.Table
 163      (Table_Component_Type => Source,
 164       Table_Index_Type     => Natural,
 165       Table_Low_Bound      => 0,
 166       Table_Initial        => 10,
 167       Table_Increment      => 100,
 168       Table_Name           => "Prj.Makr.Sources");
 169    --  The list of Ada sources found, with their unit name and kind, to be put
 170    --  in the source attribute and package Naming of the project file, or in
 171    --  the pragmas Source_File_Name in the configuration pragmas file.
 172
 173    ---------
 174    -- Dup --
 175    ---------
 176
 177    function Dup  (Fd : File_Descriptor) return File_Descriptor is
 178    begin
 179       return File_Descriptor (System.CRTL.dup (Integer (Fd)));
 180    end Dup;
 181
 182    ----------
 183    -- Dup2 --
 184    ----------
 185
 186    procedure Dup2 (Old_Fd, New_Fd : File_Descriptor) is
 187       Fd : Integer;
 188       pragma Warnings (Off, Fd);
 189    begin
 190       Fd := System.CRTL.dup2 (Integer (Old_Fd), Integer (New_Fd));
 191    end Dup2;
 192
 193    --------------
 194    -- Finalize --
 195    --------------
 196
 197    procedure Finalize is
 198       Discard : Boolean;
 199       pragma Warnings (Off, Discard);
 200
 201       Current_Source_Dir : Project_Node_Id := Empty_Node;
 202
 203    begin
 204       if Project_File then
 205          --  If there were no already existing project file, or if the parsing
 206          --  was unsuccessful, create an empty project node with the correct
 207          --  name and its project declaration node.
 208
 209          if No (Project_Node) then
 210             Project_Node :=
 211               Default_Project_Node (Of_Kind => N_Project, In_Tree => Tree);
 212             Set_Name_Of (Project_Node, Tree, To => Output_Name_Id);
 213             Set_Project_Declaration_Of
 214               (Project_Node, Tree,
 215                To => Default_Project_Node
 216                  (Of_Kind => N_Project_Declaration, In_Tree => Tree));
 217
 218          end if;
 219
 220       end if;
 221
 222       --  Delete the file if it already exists
 223
 224       Delete_File
 225         (Path_Name (Directory_Last + 1 .. Path_Last),
 226          Success => Discard);
 227
 228       --  Create a new one
 229
 230       if Opt.Verbose_Mode then
 231          Output.Write_Str ("Creating new file """);
 232          Output.Write_Str (Path_Name (Directory_Last + 1 .. Path_Last));
 233          Output.Write_Line ("""");
 234       end if;
 235
 236       Output_FD := Create_New_File
 237         (Path_Name (Directory_Last + 1 .. Path_Last),
 238          Fmode => Text);
 239
 240       --  Fails if project file cannot be created
 241
 242       if Output_FD = Invalid_FD then
 243          Prj.Com.Fail
 244            ("cannot create new """ & Path_Name (1 .. Path_Last) & """");
 245       end if;
 246
 247       if Project_File then
 248
 249          --  Delete the source list file, if it already exists
 250
 251          declare
 252             Discard : Boolean;
 253             pragma Warnings (Off, Discard);
 254          begin
 255             Delete_File
 256               (Source_List_Path (1 .. Source_List_Last),
 257                Success => Discard);
 258          end;
 259
 260          --  And create a new source list file, fail if file cannot be created
 261
 262          Source_List_FD := Create_New_File
 263            (Name  => Source_List_Path (1 .. Source_List_Last),
 264             Fmode => Text);
 265
 266          if Source_List_FD = Invalid_FD then
 267             Prj.Com.Fail
 268               ("cannot create file """
 269                & Source_List_Path (1 .. Source_List_Last)
 270                & """");
 271          end if;
 272
 273          if Opt.Verbose_Mode then
 274             Output.Write_Str ("Naming project file name is """);
 275             Output.Write_Str
 276               (Project_Naming_File_Name (1 .. Project_Naming_Last));
 277             Output.Write_Line ("""");
 278          end if;
 279
 280          --  Create the naming project node
 281
 282          Project_Naming_Node :=
 283            Default_Project_Node (Of_Kind => N_Project, In_Tree => Tree);
 284          Set_Name_Of (Project_Naming_Node, Tree, To => Project_Naming_Id);
 285          Project_Naming_Decl :=
 286            Default_Project_Node
 287              (Of_Kind => N_Project_Declaration, In_Tree => Tree);
 288          Set_Project_Declaration_Of
 289            (Project_Naming_Node, Tree, Project_Naming_Decl);
 290          Naming_Package :=
 291            Default_Project_Node
 292              (Of_Kind => N_Package_Declaration, In_Tree => Tree);
 293          Set_Name_Of (Naming_Package, Tree, To => Name_Naming);
 294
 295          --  Add an attribute declaration for Source_Files as an empty list (to
 296          --  indicate there are no sources in the naming project) and a package
 297          --  Naming (that will be filled later).
 298
 299          declare
 300             Decl_Item : constant Project_Node_Id :=
 301                           Default_Project_Node
 302                             (Of_Kind => N_Declarative_Item, In_Tree => Tree);
 303
 304             Attribute : constant Project_Node_Id :=
 305                           Default_Project_Node
 306                             (Of_Kind       => N_Attribute_Declaration,
 307                              In_Tree       => Tree,
 308                              And_Expr_Kind => List);
 309
 310             Expression : constant Project_Node_Id :=
 311                            Default_Project_Node
 312                              (Of_Kind       => N_Expression,
 313                               In_Tree       => Tree,
 314                               And_Expr_Kind => List);
 315
 316             Term      : constant Project_Node_Id :=
 317                           Default_Project_Node
 318                             (Of_Kind       => N_Term,
 319                              In_Tree       => Tree,
 320                              And_Expr_Kind => List);
 321
 322             Empty_List : constant Project_Node_Id :=
 323                            Default_Project_Node
 324                              (Of_Kind => N_Literal_String_List,
 325                               In_Tree => Tree);
 326
 327          begin
 328             Set_First_Declarative_Item_Of
 329               (Project_Naming_Decl, Tree, To => Decl_Item);
 330             Set_Next_Declarative_Item (Decl_Item, Tree, Naming_Package);
 331             Set_Current_Item_Node (Decl_Item, Tree, To => Attribute);
 332             Set_Name_Of (Attribute, Tree, To => Name_Source_Files);
 333             Set_Expression_Of (Attribute, Tree, To => Expression);
 334             Set_First_Term (Expression, Tree, To => Term);
 335             Set_Current_Term (Term, Tree, To => Empty_List);
 336          end;
 337
 338          --  Add a with clause on the naming project in the main project, if
 339          --  there is not already one.
 340
 341          declare
 342             With_Clause : Project_Node_Id :=
 343                                   First_With_Clause_Of (Project_Node, Tree);
 344
 345          begin
 346             while Present (With_Clause) loop
 347                exit when
 348                  Prj.Tree.Name_Of (With_Clause, Tree) = Project_Naming_Id;
 349                With_Clause := Next_With_Clause_Of (With_Clause, Tree);
 350             end loop;
 351
 352             if No (With_Clause) then
 353                With_Clause := Default_Project_Node
 354                  (Of_Kind => N_With_Clause, In_Tree => Tree);
 355                Set_Next_With_Clause_Of
 356                  (With_Clause, Tree,
 357                   To => First_With_Clause_Of (Project_Node, Tree));
 358                Set_First_With_Clause_Of
 359                  (Project_Node, Tree, To => With_Clause);
 360                Set_Name_Of (With_Clause, Tree, To => Project_Naming_Id);
 361
 362                --  We set the project node to something different than
 363                --  Empty_Node, so that Prj.PP does not generate a limited
 364                --  with clause.
 365
 366                Set_Project_Node_Of (With_Clause, Tree, Non_Empty_Node);
 367
 368                Name_Len := Project_Naming_Last;
 369                Name_Buffer (1 .. Name_Len) :=
 370                  Project_Naming_File_Name (1 .. Project_Naming_Last);
 371                Set_String_Value_Of (With_Clause, Tree, To => Name_Find);
 372             end if;
 373          end;
 374
 375          Project_Declaration := Project_Declaration_Of (Project_Node, Tree);
 376
 377          --  Add a package Naming in the main project, that is a renaming of
 378          --  package Naming in the naming project.
 379
 380          declare
 381             Decl_Item  : constant Project_Node_Id :=
 382                            Default_Project_Node
 383                              (Of_Kind => N_Declarative_Item,
 384                               In_Tree => Tree);
 385
 386             Naming : constant Project_Node_Id :=
 387                            Default_Project_Node
 388                              (Of_Kind => N_Package_Declaration,
 389                               In_Tree => Tree);
 390
 391          begin
 392             Set_Next_Declarative_Item
 393               (Decl_Item, Tree,
 394                To => First_Declarative_Item_Of (Project_Declaration, Tree));
 395             Set_First_Declarative_Item_Of
 396               (Project_Declaration, Tree, To => Decl_Item);
 397             Set_Current_Item_Node (Decl_Item, Tree, To => Naming);
 398             Set_Name_Of (Naming, Tree, To => Name_Naming);
 399             Set_Project_Of_Renamed_Package_Of
 400               (Naming, Tree, To => Project_Naming_Node);
 401
 402             --  Attach the comments, if any, that were saved for package
 403             --  Naming.
 404
 405             Tree.Project_Nodes.Table (Naming).Comments :=
 406               Naming_Package_Comments;
 407          end;
 408
 409          --  Add an attribute declaration for Source_Dirs, initialized as an
 410          --  empty list.
 411
 412          declare
 413             Decl_Item  : constant Project_Node_Id :=
 414                            Default_Project_Node
 415                              (Of_Kind => N_Declarative_Item,
 416                               In_Tree => Tree);
 417
 418             Attribute : constant Project_Node_Id :=
 419                            Default_Project_Node
 420                              (Of_Kind       => N_Attribute_Declaration,
 421                               In_Tree       => Tree,
 422                               And_Expr_Kind => List);
 423
 424             Expression : constant Project_Node_Id :=
 425                            Default_Project_Node
 426                              (Of_Kind       => N_Expression,
 427                               In_Tree       => Tree,
 428                               And_Expr_Kind => List);
 429
 430             Term  : constant Project_Node_Id :=
 431                            Default_Project_Node
 432                              (Of_Kind       => N_Term, In_Tree => Tree,
 433                               And_Expr_Kind => List);
 434
 435          begin
 436             Set_Next_Declarative_Item
 437               (Decl_Item, Tree,
 438                To => First_Declarative_Item_Of (Project_Declaration, Tree));
 439             Set_First_Declarative_Item_Of
 440               (Project_Declaration, Tree, To => Decl_Item);
 441             Set_Current_Item_Node (Decl_Item, Tree, To => Attribute);
 442             Set_Name_Of (Attribute, Tree, To => Name_Source_Dirs);
 443             Set_Expression_Of (Attribute, Tree, To => Expression);
 444             Set_First_Term (Expression, Tree, To => Term);
 445             Source_Dirs_List :=
 446               Default_Project_Node
 447                 (Of_Kind       => N_Literal_String_List,
 448                  In_Tree       => Tree,
 449                  And_Expr_Kind => List);
 450             Set_Current_Term (Term, Tree, To => Source_Dirs_List);
 451
 452             --  Attach the comments, if any, that were saved for attribute
 453             --  Source_Dirs.
 454
 455             Tree.Project_Nodes.Table (Attribute).Comments :=
 456               Source_Dirs_Comments;
 457          end;
 458
 459          --  Put the source directories in attribute Source_Dirs
 460
 461          for Source_Dir_Index in 1 .. Source_Directories.Last loop
 462             declare
 463                Expression : constant Project_Node_Id :=
 464                               Default_Project_Node
 465                                 (Of_Kind       => N_Expression,
 466                                  In_Tree       => Tree,
 467                                  And_Expr_Kind => Single);
 468
 469                Term       : constant Project_Node_Id :=
 470                               Default_Project_Node
 471                                 (Of_Kind       => N_Term,
 472                                  In_Tree       => Tree,
 473                                  And_Expr_Kind => Single);
 474
 475                Value      : constant Project_Node_Id :=
 476                               Default_Project_Node
 477                                 (Of_Kind       => N_Literal_String,
 478                                  In_Tree       => Tree,
 479                                  And_Expr_Kind => Single);
 480
 481             begin
 482                if No (Current_Source_Dir) then
 483                   Set_First_Expression_In_List
 484                     (Source_Dirs_List, Tree, To => Expression);
 485                else
 486                   Set_Next_Expression_In_List
 487                     (Current_Source_Dir, Tree, To => Expression);
 488                end if;
 489
 490                Current_Source_Dir := Expression;
 491                Set_First_Term (Expression, Tree, To => Term);
 492                Set_Current_Term (Term, Tree, To => Value);
 493                Name_Len := 0;
 494                Add_Str_To_Name_Buffer
 495                  (Source_Directories.Table (Source_Dir_Index).all);
 496                Set_String_Value_Of (Value, Tree, To => Name_Find);
 497             end;
 498          end loop;
 499
 500          --  Add an attribute declaration for Source_Files or Source_List_File
 501          --  with the source list file name that will be created.
 502
 503          declare
 504             Decl_Item  : constant Project_Node_Id :=
 505                            Default_Project_Node
 506                              (Of_Kind => N_Declarative_Item,
 507                               In_Tree => Tree);
 508
 509             Attribute  : constant Project_Node_Id :=
 510                             Default_Project_Node
 511                               (Of_Kind       => N_Attribute_Declaration,
 512                                In_Tree       => Tree,
 513                                And_Expr_Kind => Single);
 514
 515             Expression : constant Project_Node_Id :=
 516                            Default_Project_Node
 517                              (Of_Kind       => N_Expression,
 518                               In_Tree       => Tree,
 519                               And_Expr_Kind => Single);
 520
 521             Term       : constant Project_Node_Id :=
 522                            Default_Project_Node
 523                              (Of_Kind       => N_Term,
 524                               In_Tree       => Tree,
 525                               And_Expr_Kind => Single);
 526
 527             Value      : constant Project_Node_Id :=
 528                            Default_Project_Node
 529                              (Of_Kind       => N_Literal_String,
 530                               In_Tree       => Tree,
 531                               And_Expr_Kind => Single);
 532
 533          begin
 534             Set_Next_Declarative_Item
 535               (Decl_Item, Tree,
 536                To => First_Declarative_Item_Of (Project_Declaration, Tree));
 537             Set_First_Declarative_Item_Of
 538               (Project_Declaration, Tree, To => Decl_Item);
 539             Set_Current_Item_Node (Decl_Item, Tree, To => Attribute);
 540
 541             Set_Name_Of (Attribute, Tree, To => Name_Source_List_File);
 542             Set_Expression_Of (Attribute, Tree, To => Expression);
 543             Set_First_Term (Expression, Tree, To => Term);
 544             Set_Current_Term (Term, Tree, To => Value);
 545             Name_Len := Source_List_Last;
 546             Name_Buffer (1 .. Name_Len) :=
 547               Source_List_Path (1 .. Source_List_Last);
 548             Set_String_Value_Of (Value, Tree, To => Name_Find);
 549
 550             --  If there was no comments for attribute Source_List_File, put
 551             --  those for Source_Files, if they exist.
 552
 553             if Present (Source_List_File_Comments) then
 554                Tree.Project_Nodes.Table (Attribute).Comments :=
 555                  Source_List_File_Comments;
 556             else
 557                Tree.Project_Nodes.Table (Attribute).Comments :=
 558                  Source_Files_Comments;
 559             end if;
 560          end;
 561
 562          --  Put the sources in the source list files and in the naming
 563          --  project.
 564
 565          for Source_Index in 1 .. Sources.Last loop
 566
 567             --  Add the corresponding attribute in the
 568             --  Naming package of the naming project.
 569
 570             declare
 571                Current_Source : constant Source :=
 572                                   Sources.Table (Source_Index);
 573
 574                Decl_Item : constant Project_Node_Id :=
 575                              Default_Project_Node
 576                                (Of_Kind =>
 577                                                 N_Declarative_Item,
 578                                 In_Tree => Tree);
 579
 580                Attribute : constant Project_Node_Id :=
 581                              Default_Project_Node
 582                                (Of_Kind =>
 583                                                 N_Attribute_Declaration,
 584                                 In_Tree => Tree);
 585
 586                Expression : constant Project_Node_Id :=
 587                               Default_Project_Node
 588                                 (Of_Kind       => N_Expression,
 589                                  And_Expr_Kind => Single,
 590                                  In_Tree       => Tree);
 591
 592                Term      : constant Project_Node_Id :=
 593                              Default_Project_Node
 594                                (Of_Kind       => N_Term,
 595                                 And_Expr_Kind => Single,
 596                                 In_Tree       => Tree);
 597
 598                Value     : constant Project_Node_Id :=
 599                              Default_Project_Node
 600                                (Of_Kind       => N_Literal_String,
 601                                 And_Expr_Kind => Single,
 602                                 In_Tree       => Tree);
 603
 604             begin
 605                --  Add source file name to the source list file
 606
 607                Get_Name_String (Current_Source.File_Name);
 608                Add_Char_To_Name_Buffer (ASCII.LF);
 609                if Write (Source_List_FD,
 610                          Name_Buffer (1)'Address,
 611                          Name_Len) /= Name_Len
 612                then
 613                   Prj.Com.Fail ("disk full");
 614                end if;
 615
 616                --  For an Ada source, add entry in package Naming
 617
 618                if Current_Source.Unit_Name /= No_Name then
 619                   Set_Next_Declarative_Item
 620                     (Decl_Item,
 621                      To      => First_Declarative_Item_Of
 622                        (Naming_Package, Tree),
 623                      In_Tree => Tree);
 624                   Set_First_Declarative_Item_Of
 625                     (Naming_Package,
 626                      To      => Decl_Item,
 627                      In_Tree => Tree);
 628                   Set_Current_Item_Node
 629                     (Decl_Item,
 630                      To      => Attribute,
 631                      In_Tree => Tree);
 632
 633                   --  Is it a spec or a body?
 634
 635                   if Current_Source.Spec then
 636                      Set_Name_Of
 637                        (Attribute, Tree,
 638                         To => Name_Spec);
 639                   else
 640                      Set_Name_Of
 641                        (Attribute, Tree,
 642                         To => Name_Body);
 643                   end if;
 644
 645                   --  Get the name of the unit
 646
 647                   Get_Name_String (Current_Source.Unit_Name);
 648                   To_Lower (Name_Buffer (1 .. Name_Len));
 649                   Set_Associative_Array_Index_Of
 650                     (Attribute, Tree, To => Name_Find);
 651
 652                   Set_Expression_Of
 653                     (Attribute, Tree, To => Expression);
 654                   Set_First_Term
 655                     (Expression, Tree, To => Term);
 656                   Set_Current_Term
 657                     (Term, Tree, To => Value);
 658
 659                   --  And set the name of the file
 660
 661                   Set_String_Value_Of
 662                     (Value, Tree, To => Current_Source.File_Name);
 663                   Set_Source_Index_Of
 664                     (Value, Tree, To => Current_Source.Index);
 665                end if;
 666             end;
 667          end loop;
 668
 669          --  Close the source list file
 670
 671          Close (Source_List_FD);
 672
 673          --  Output the project file
 674
 675          Prj.PP.Pretty_Print
 676            (Project_Node, Tree,
 677             W_Char                 => Write_A_Char'Access,
 678             W_Eol                  => Write_Eol'Access,
 679             W_Str                  => Write_A_String'Access,
 680             Backward_Compatibility => False);
 681          Close (Output_FD);
 682
 683          --  Delete the naming project file if it already exists
 684
 685          Delete_File
 686            (Project_Naming_File_Name (1 .. Project_Naming_Last),
 687             Success => Discard);
 688
 689          --  Create a new one
 690
 691          if Opt.Verbose_Mode then
 692             Output.Write_Str ("Creating new naming project file """);
 693             Output.Write_Str (Project_Naming_File_Name
 694                               (1 .. Project_Naming_Last));
 695             Output.Write_Line ("""");
 696          end if;
 697
 698          Output_FD := Create_New_File
 699            (Project_Naming_File_Name (1 .. Project_Naming_Last),
 700             Fmode => Text);
 701
 702          --  Fails if naming project file cannot be created
 703
 704          if Output_FD = Invalid_FD then
 705             Prj.Com.Fail
 706               ("cannot create new """
 707                & Project_Naming_File_Name (1 .. Project_Naming_Last)
 708                & """");
 709          end if;
 710
 711          --  Output the naming project file
 712
 713          Prj.PP.Pretty_Print
 714            (Project_Naming_Node, Tree,
 715             W_Char                 => Write_A_Char'Access,
 716             W_Eol                  => Write_Eol'Access,
 717             W_Str                  => Write_A_String'Access,
 718             Backward_Compatibility => False);
 719          Close (Output_FD);
 720
 721       else
 722          --  For each Ada source, write a pragma Source_File_Name to the
 723          --  configuration pragmas file.
 724
 725          for Index in 1 .. Sources.Last loop
 726             if Sources.Table (Index).Unit_Name /= No_Name then
 727                Write_A_String ("pragma Source_File_Name");
 728                Write_Eol;
 729                Write_A_String ("  (");
 730                Write_A_String
 731                  (Get_Name_String (Sources.Table (Index).Unit_Name));
 732                Write_A_String (",");
 733                Write_Eol;
 734
 735                if Sources.Table (Index).Spec then
 736                   Write_A_String ("   Spec_File_Name => """);
 737
 738                else
 739                   Write_A_String ("   Body_File_Name => """);
 740                end if;
 741
 742                Write_A_String
 743                  (Get_Name_String (Sources.Table (Index).File_Name));
 744
 745                Write_A_String ("""");
 746
 747                if Sources.Table (Index).Index /= 0 then
 748                   Write_A_String (", Index =>");
 749                   Write_A_String (Sources.Table (Index).Index'Img);
 750                end if;
 751
 752                Write_A_String (");");
 753                Write_Eol;
 754             end if;
 755          end loop;
 756
 757          Close (Output_FD);
 758       end if;
 759    end Finalize;
 760
 761    ----------------
 762    -- Initialize --
 763    ----------------
 764
 765    procedure Initialize
 766      (File_Path         : String;
 767       Project_File      : Boolean;
 768       Preproc_Switches  : Argument_List;
 769       Very_Verbose      : Boolean)
 770    is
 771    begin
 772       Makr.Very_Verbose := Initialize.Very_Verbose;
 773       Makr.Project_File := Initialize.Project_File;
 774
 775       --  Do some needed initializations
 776
 777       Csets.Initialize;
 778       Namet.Initialize;
 779       Snames.Initialize;
 780       Prj.Initialize (No_Project_Tree);
 781       Prj.Tree.Initialize (Tree);
 782
 783       Sources.Set_Last (0);
 784       Source_Directories.Set_Last (0);
 785
 786       --  Initialize the compiler switches
 787
 788       Args := new Argument_List (1 .. Preproc_Switches'Length + 6);
 789       Args (1) := new String'("-c");
 790       Args (2) := new String'("-gnats");
 791       Args (3) := new String'("-gnatu");
 792       Args (4 .. 3 + Preproc_Switches'Length) := Preproc_Switches;
 793       Args (4 + Preproc_Switches'Length) := new String'("-x");
 794       Args (5 + Preproc_Switches'Length) := new String'("ada");
 795
 796       --  Get the path and file names
 797
 798       Path_Name := new
 799         String (1 .. File_Path'Length + Project_File_Extension'Length);
 800       Path_Last := File_Path'Length;
 801
 802       if File_Names_Case_Sensitive then
 803          Path_Name (1 .. Path_Last) := File_Path;
 804       else
 805          Path_Name (1 .. Path_Last) := To_Lower (File_Path);
 806       end if;
 807
 808       Path_Name (Path_Last + 1 .. Path_Name'Last) :=
 809         Project_File_Extension;
 810
 811       --  Get the end of directory information, if any
 812
 813       for Index in reverse 1 .. Path_Last loop
 814          if Path_Name (Index) = Directory_Separator then
 815             Directory_Last := Index;
 816             exit;
 817          end if;
 818       end loop;
 819
 820       if Project_File then
 821          if Path_Last < Project_File_Extension'Length + 1
 822            or else Path_Name
 823            (Path_Last - Project_File_Extension'Length + 1 .. Path_Last)
 824            /= Project_File_Extension
 825          then
 826             Path_Last := Path_Name'Last;
 827          end if;
 828
 829          Output_Name := new String'(To_Lower (Path_Name (1 .. Path_Last)));
 830          Output_Name_Last := Output_Name'Last - 4;
 831
 832          --  If there is already a project file with the specified name, parse
 833          --  it to get the components that are not automatically generated.
 834
 835          if Is_Regular_File (Output_Name (1 .. Path_Last)) then
 836             if Opt.Verbose_Mode then
 837                Output.Write_Str ("Parsing already existing project file """);
 838                Output.Write_Str (Output_Name.all);
 839                Output.Write_Line ("""");
 840             end if;
 841
 842             Part.Parse
 843               (In_Tree                => Tree,
 844                Project                => Project_Node,
 845                Project_File_Name      => Output_Name.all,
 846                Always_Errout_Finalize => False,
 847                Store_Comments         => True,
 848                Is_Config_File         => False,
 849                Current_Directory      => Get_Current_Dir,
 850                Packages_To_Check      => Packages_To_Check_By_Gnatname);
 851
 852             --  Fail if parsing was not successful
 853
 854             if No (Project_Node) then
 855                Fail ("parsing of existing project file failed");
 856
 857             else
 858                --  If parsing was successful, remove the components that are
 859                --  automatically generated, if any, so that they will be
 860                --  unconditionally added later.
 861
 862                --  Remove the with clause for the naming project file
 863
 864                declare
 865                   With_Clause : Project_Node_Id :=
 866                                   First_With_Clause_Of (Project_Node, Tree);
 867                   Previous    : Project_Node_Id := Empty_Node;
 868
 869                begin
 870                   while Present (With_Clause) loop
 871                      if Prj.Tree.Name_Of (With_Clause, Tree) =
 872                           Project_Naming_Id
 873                      then
 874                         if No (Previous) then
 875                            Set_First_With_Clause_Of
 876                              (Project_Node, Tree,
 877                               To => Next_With_Clause_Of (With_Clause, Tree));
 878                         else
 879                            Set_Next_With_Clause_Of
 880                              (Previous, Tree,
 881                               To => Next_With_Clause_Of (With_Clause, Tree));
 882                         end if;
 883
 884                         exit;
 885                      end if;
 886
 887                      Previous := With_Clause;
 888                      With_Clause := Next_With_Clause_Of (With_Clause, Tree);
 889                   end loop;
 890                end;
 891
 892                --  Remove attribute declarations of Source_Files,
 893                --  Source_List_File, Source_Dirs, and the declaration of
 894                --  package Naming, if they exist, but preserve the comments
 895                --  attached to these nodes.
 896
 897                declare
 898                   Declaration  : Project_Node_Id :=
 899                                    First_Declarative_Item_Of
 900                                      (Project_Declaration_Of
 901                                         (Project_Node, Tree),
 902                                       Tree);
 903                   Previous     : Project_Node_Id := Empty_Node;
 904                   Current_Node : Project_Node_Id := Empty_Node;
 905
 906                   Name         : Name_Id;
 907                   Kind_Of_Node : Project_Node_Kind;
 908                   Comments     : Project_Node_Id;
 909
 910                begin
 911                   while Present (Declaration) loop
 912                      Current_Node := Current_Item_Node (Declaration, Tree);
 913
 914                      Kind_Of_Node := Kind_Of (Current_Node, Tree);
 915
 916                      if Kind_Of_Node = N_Attribute_Declaration or else
 917                        Kind_Of_Node = N_Package_Declaration
 918                      then
 919                         Name := Prj.Tree.Name_Of (Current_Node, Tree);
 920
 921                         if Name = Name_Source_Files     or else
 922                            Name = Name_Source_List_File or else
 923                            Name = Name_Source_Dirs      or else
 924                            Name = Name_Naming
 925                         then
 926                            Comments :=
 927                              Tree.Project_Nodes.Table (Current_Node).Comments;
 928
 929                            if Name = Name_Source_Files then
 930                               Source_Files_Comments := Comments;
 931
 932                            elsif Name = Name_Source_List_File then
 933                               Source_List_File_Comments := Comments;
 934
 935                            elsif Name = Name_Source_Dirs then
 936                               Source_Dirs_Comments := Comments;
 937
 938                            elsif Name = Name_Naming then
 939                               Naming_Package_Comments := Comments;
 940                            end if;
 941
 942                            if No (Previous) then
 943                               Set_First_Declarative_Item_Of
 944                                 (Project_Declaration_Of (Project_Node, Tree),
 945                                  Tree,
 946                                  To => Next_Declarative_Item
 947                                          (Declaration, Tree));
 948
 949                            else
 950                               Set_Next_Declarative_Item
 951                                 (Previous, Tree,
 952                                  To => Next_Declarative_Item
 953                                          (Declaration, Tree));
 954                            end if;
 955
 956                         else
 957                            Previous := Declaration;
 958                         end if;
 959                      end if;
 960
 961                      Declaration := Next_Declarative_Item (Declaration, Tree);
 962                   end loop;
 963                end;
 964             end if;
 965          end if;
 966
 967          if Directory_Last /= 0 then
 968             Output_Name (1 .. Output_Name_Last - Directory_Last) :=
 969               Output_Name (Directory_Last + 1 .. Output_Name_Last);
 970             Output_Name_Last := Output_Name_Last - Directory_Last;
 971          end if;
 972
 973          --  Get the project name id
 974
 975          Name_Len := Output_Name_Last;
 976          Name_Buffer (1 .. Name_Len) := Output_Name (1 .. Name_Len);
 977          Output_Name_Id := Name_Find;
 978
 979          --  Create the project naming file name
 980
 981          Project_Naming_Last := Output_Name_Last;
 982          Project_Naming_File_Name :=
 983            new String'(Output_Name (1 .. Output_Name_Last) &
 984                        Naming_File_Suffix &
 985                        Project_File_Extension);
 986          Project_Naming_Last :=
 987            Project_Naming_Last + Naming_File_Suffix'Length;
 988
 989          --  Get the project naming id
 990
 991          Name_Len := Project_Naming_Last;
 992          Name_Buffer (1 .. Name_Len) :=
 993            Project_Naming_File_Name (1 .. Name_Len);
 994          Project_Naming_Id := Name_Find;
 995
 996          Project_Naming_Last :=
 997            Project_Naming_Last + Project_File_Extension'Length;
 998
 999          --  Create the source list file name
1000
1001          Source_List_Last := Output_Name_Last;
1002          Source_List_Path :=
1003            new String'(Output_Name (1 .. Output_Name_Last) &
1004                        Source_List_File_Suffix);
1005          Source_List_Last :=
1006            Output_Name_Last + Source_List_File_Suffix'Length;
1007
1008          --  Add the project file extension to the project name
1009
1010          Output_Name
1011            (Output_Name_Last + 1 ..
1012               Output_Name_Last + Project_File_Extension'Length) :=
1013            Project_File_Extension;
1014          Output_Name_Last := Output_Name_Last + Project_File_Extension'Length;
1015
1016       end if;
1017
1018       --  Change the current directory to the directory of the project file,
1019       --  if any directory information is specified.
1020
1021       if Directory_Last /= 0 then
1022          begin
1023             Change_Dir (Path_Name (1 .. Directory_Last));
1024          exception
1025             when Directory_Error =>
1026                Prj.Com.Fail
1027                  ("unknown directory """
1028                   & Path_Name (1 .. Directory_Last)
1029                   & """");
1030          end;
1031       end if;
1032    end Initialize;
1033
1034    -------------
1035    -- Process --
1036    -------------
1037
1038    procedure Process
1039      (Directories       : Argument_List;
1040       Name_Patterns     : Regexp_List;
1041       Excluded_Patterns : Regexp_List;
1042       Foreign_Patterns  : Regexp_List)
1043   is
1044       procedure Process_Directory (Dir_Name : String; Recursively : Boolean);
1045       --  Look for Ada and foreign sources in a directory, according to the
1046       --  patterns. When Recursively is True, after looking for sources in
1047       --  Dir_Name, look also in its subdirectories, if any.
1048
1049       -----------------------
1050       -- Process_Directory --
1051       -----------------------
1052
1053       procedure Process_Directory (Dir_Name : String; Recursively : Boolean) is
1054          Matched : Matched_Type := False;
1055          Str     : String (1 .. 2_000);
1056          Canon   : String (1 .. 2_000);
1057          Last    : Natural;
1058          Dir     : Dir_Type;
1059          Do_Process : Boolean := True;
1060
1061          Temp_File_Name         : String_Access := null;
1062          Save_Last_Source_Index : Natural := 0;
1063          File_Name_Id           : Name_Id := No_Name;
1064
1065          Current_Source : Source;
1066
1067       begin
1068          --  Avoid processing the same directory more than once
1069
1070          for Index in 1 .. Processed_Directories.Last loop
1071             if Processed_Directories.Table (Index).all = Dir_Name then
1072                Do_Process := False;
1073                exit;
1074             end if;
1075          end loop;
1076
1077          if Do_Process then
1078             if Opt.Verbose_Mode then
1079                Output.Write_Str ("Processing directory """);
1080                Output.Write_Str (Dir_Name);
1081                Output.Write_Line ("""");
1082             end if;
1083
1084             Processed_Directories. Increment_Last;
1085             Processed_Directories.Table (Processed_Directories.Last) :=
1086               new String'(Dir_Name);
1087
1088             --  Get the source file names from the directory. Fails if the
1089             --  directory does not exist.
1090
1091             begin
1092                Open (Dir, Dir_Name);
1093             exception
1094                when Directory_Error =>
1095                   Prj.Com.Fail ("cannot open directory """ & Dir_Name & """");
1096             end;
1097
1098             --  Process each regular file in the directory
1099
1100             File_Loop : loop
1101                Read (Dir, Str, Last);
1102                exit File_Loop when Last = 0;
1103
1104                --  Copy the file name and put it in canonical case to match
1105                --  against the patterns that have themselves already been put
1106                --  in canonical case.
1107
1108                Canon (1 .. Last) := Str (1 .. Last);
1109                Canonical_Case_File_Name (Canon (1 .. Last));
1110
1111                if Is_Regular_File
1112                  (Dir_Name & Directory_Separator & Str (1 .. Last))
1113                then
1114                   Matched := True;
1115
1116                   Name_Len := Last;
1117                   Name_Buffer (1 .. Name_Len) := Str (1 .. Last);
1118                   File_Name_Id := Name_Find;
1119
1120                   --  First, check if the file name matches at least one of
1121                   --  the excluded expressions;
1122
1123                   for Index in Excluded_Patterns'Range loop
1124                      if
1125                        Match (Canon (1 .. Last), Excluded_Patterns (Index))
1126                      then
1127                         Matched := Excluded;
1128                         exit;
1129                      end if;
1130                   end loop;
1131
1132                   --  If it does not match any of the excluded expressions,
1133                   --  check if the file name matches at least one of the
1134                   --  regular expressions.
1135
1136                   if Matched = True then
1137                      Matched := False;
1138
1139                      for Index in Name_Patterns'Range loop
1140                         if
1141                           Match
1142                             (Canon (1 .. Last), Name_Patterns (Index))
1143                         then
1144                            Matched := True;
1145                            exit;
1146                         end if;
1147                      end loop;
1148                   end if;
1149
1150                   if Very_Verbose
1151                     or else (Matched = True and then Opt.Verbose_Mode)
1152                   then
1153                      Output.Write_Str ("   Checking """);
1154                      Output.Write_Str (Str (1 .. Last));
1155                      Output.Write_Line (""": ");
1156                   end if;
1157
1158                   --  If the file name matches one of the regular expressions,
1159                   --  parse it to get its unit name.
1160
1161                   if Matched = True then
1162                      declare
1163                         FD : File_Descriptor;
1164                         Success : Boolean;
1165                         Saved_Output : File_Descriptor;
1166                         Saved_Error  : File_Descriptor;
1167
1168                      begin
1169                         --  If we don't have the path of the compiler yet,
1170                         --  get it now. The compiler name may have a prefix,
1171                         --  so we get the potentially prefixed name.
1172
1173                         if Gcc_Path = null then
1174                            declare
1175                               Prefix_Gcc : String_Access :=
1176                                              Program_Name (Gcc, "gnatname");
1177                            begin
1178                               Gcc_Path :=
1179                                 Locate_Exec_On_Path (Prefix_Gcc.all);
1180                               Free (Prefix_Gcc);
1181                            end;
1182
1183                            if Gcc_Path = null then
1184                               Prj.Com.Fail ("could not locate " & Gcc);
1185                            end if;
1186                         end if;
1187
1188                         --  If we don't have yet the file name of the
1189                         --  temporary file, get it now.
1190
1191                         if Temp_File_Name = null then
1192                            Create_Temp_File (FD, Temp_File_Name);
1193
1194                            if FD = Invalid_FD then
1195                               Prj.Com.Fail
1196                                 ("could not create temporary file");
1197                            end if;
1198
1199                            Close (FD);
1200                            Delete_File (Temp_File_Name.all, Success);
1201                         end if;
1202
1203                         Args (Args'Last) := new String'
1204                           (Dir_Name &
1205                            Directory_Separator &
1206                            Str (1 .. Last));
1207
1208                         --  Create the temporary file
1209
1210                         FD := Create_Output_Text_File
1211                           (Name => Temp_File_Name.all);
1212
1213                         if FD = Invalid_FD then
1214                            Prj.Com.Fail
1215                              ("could not create temporary file");
1216                         end if;
1217
1218                         --  Save the standard output and error
1219
1220                         Saved_Output := Dup (Standout);
1221                         Saved_Error  := Dup (Standerr);
1222
1223                         --  Set standard output and error to the temporary file
1224
1225                         Dup2 (FD, Standout);
1226                         Dup2 (FD, Standerr);
1227
1228                         --  And spawn the compiler
1229
1230                         Spawn (Gcc_Path.all, Args.all, Success);
1231
1232                         --  Restore the standard output and error
1233
1234                         Dup2 (Saved_Output, Standout);
1235                         Dup2 (Saved_Error, Standerr);
1236
1237                         --  Close the temporary file
1238
1239                         Close (FD);
1240
1241                         --  And close the saved standard output and error to
1242                         --  avoid too many file descriptors.
1243
1244                         Close (Saved_Output);
1245                         Close (Saved_Error);
1246
1247                         --  Now that standard output is restored, check if
1248                         --  the compiler ran correctly.
1249
1250                         --  Read the lines of the temporary file:
1251                         --  they should contain the kind and name of the unit.
1252
1253                         declare
1254                            File      : Text_File;
1255                            Text_Line : String (1 .. 1_000);
1256                            Text_Last : Natural;
1257
1258                         begin
1259                            Open (File, Temp_File_Name.all);
1260
1261                            if not Is_Valid (File) then
1262                               Prj.Com.Fail
1263                                 ("could not read temporary file");
1264                            end if;
1265
1266                            Save_Last_Source_Index := Sources.Last;
1267
1268                            if End_Of_File (File) then
1269                               if Opt.Verbose_Mode then
1270                                  if not Success then
1271                                     Output.Write_Str ("      (process died) ");
1272                                  end if;
1273                               end if;
1274
1275                            else
1276                               Line_Loop : while not End_Of_File (File) loop
1277                                  Get_Line (File, Text_Line, Text_Last);
1278
1279                                  --  Find the first closing parenthesis
1280
1281                                  Char_Loop : for J in 1 .. Text_Last loop
1282                                     if Text_Line (J) = ')' then
1283                                        if J >= 13 and then
1284                                          Text_Line (1 .. 4) = "Unit"
1285                                        then
1286                                           --  Add entry to Sources table
1287
1288                                           Name_Len := J - 12;
1289                                           Name_Buffer (1 .. Name_Len) :=
1290                                             Text_Line (6 .. J - 7);
1291                                           Current_Source :=
1292                                             (Unit_Name  => Name_Find,
1293                                              File_Name  => File_Name_Id,
1294                                              Index => 0,
1295                                              Spec  => Text_Line (J - 5 .. J) =
1296                                                         "(spec)");
1297
1298                                           Sources.Append (Current_Source);
1299                                        end if;
1300
1301                                        exit Char_Loop;
1302                                     end if;
1303                                  end loop Char_Loop;
1304                               end loop Line_Loop;
1305                            end if;
1306
1307                            if Save_Last_Source_Index = Sources.Last then
1308                               if Opt.Verbose_Mode then
1309                                  Output.Write_Line ("      not a unit");
1310                               end if;
1311
1312                            else
1313                               if Sources.Last >
1314                                    Save_Last_Source_Index + 1
1315                               then
1316                                  for Index in Save_Last_Source_Index + 1 ..
1317                                                 Sources.Last
1318                                  loop
1319                                     Sources.Table (Index).Index :=
1320                                       Int (Index - Save_Last_Source_Index);
1321                                  end loop;
1322                               end if;
1323
1324                               for Index in Save_Last_Source_Index + 1 ..
1325                                              Sources.Last
1326                               loop
1327                                  Current_Source := Sources.Table (Index);
1328
1329                                  if Opt.Verbose_Mode then
1330                                     if Current_Source.Spec then
1331                                        Output.Write_Str ("      spec of ");
1332
1333                                     else
1334                                        Output.Write_Str ("      body of ");
1335                                     end if;
1336
1337                                     Output.Write_Line
1338                                       (Get_Name_String
1339                                          (Current_Source.Unit_Name));
1340                                  end if;
1341                               end loop;
1342                            end if;
1343
1344                            Close (File);
1345
1346                            Delete_File (Temp_File_Name.all, Success);
1347                         end;
1348                      end;
1349
1350                   --  File name matches none of the regular expressions
1351
1352                   else
1353                      --  If file is not excluded, see if this is foreign source
1354
1355                      if Matched /= Excluded then
1356                         for Index in Foreign_Patterns'Range loop
1357                            if Match (Canon (1 .. Last),
1358                                      Foreign_Patterns (Index))
1359                            then
1360                               Matched := True;
1361                               exit;
1362                            end if;
1363                         end loop;
1364                      end if;
1365
1366                      if Very_Verbose then
1367                         case Matched is
1368                            when False =>
1369                               Output.Write_Line ("no match");
1370
1371                            when Excluded =>
1372                               Output.Write_Line ("excluded");
1373
1374                            when True =>
1375                               Output.Write_Line ("foreign source");
1376                         end case;
1377                      end if;
1378
1379                      if Matched = True then
1380
1381                         --  Add source file name without unit name
1382
1383                         Name_Len := 0;
1384                         Add_Str_To_Name_Buffer (Canon (1 .. Last));
1385                         Sources.Append
1386                           ((File_Name => Name_Find,
1387                             Unit_Name => No_Name,
1388                             Index     => 0,
1389                             Spec      => False));
1390                      end if;
1391                   end if;
1392                end if;
1393             end loop File_Loop;
1394
1395             Close (Dir);
1396          end if;
1397
1398          --  If Recursively is True, call itself for each subdirectory.
1399          --  We do that, even when this directory has already been processed,
1400          --  because all of its subdirectories may not have been processed.
1401
1402          if Recursively then
1403             Open (Dir, Dir_Name);
1404
1405             loop
1406                Read (Dir, Str, Last);
1407                exit when Last = 0;
1408
1409                --  Do not call itself for "." or ".."
1410
1411                if Is_Directory
1412                  (Dir_Name & Directory_Separator & Str (1 .. Last))
1413                  and then Str (1 .. Last) /= "."
1414                  and then Str (1 .. Last) /= ".."
1415                then
1416                   Process_Directory
1417                     (Dir_Name & Directory_Separator & Str (1 .. Last),
1418                      Recursively => True);
1419                end if;
1420             end loop;
1421
1422             Close (Dir);
1423          end if;
1424       end Process_Directory;
1425
1426    --  Start of processing for Process
1427
1428    begin
1429       Processed_Directories.Set_Last (0);
1430
1431       --  Process each directory
1432
1433       for Index in Directories'Range  loop
1434
1435          declare
1436             Dir_Name    : constant String := Directories (Index).all;
1437             Last        : Natural := Dir_Name'Last;
1438             Recursively : Boolean := False;
1439             Found       : Boolean;
1440             Canonical   : String (1 .. Dir_Name'Length) := Dir_Name;
1441
1442          begin
1443             Canonical_Case_File_Name (Canonical);
1444
1445             Found := False;
1446             for J in 1 .. Source_Directories.Last loop
1447                if Source_Directories.Table (J).all = Canonical then
1448                   Found := True;
1449                   exit;
1450                end if;
1451             end loop;
1452
1453             if not Found then
1454                Source_Directories.Append (new String'(Canonical));
1455             end if;
1456
1457             if Dir_Name'Length >= 4
1458               and then (Dir_Name (Last - 2 .. Last) = "/**")
1459             then
1460                Last := Last - 3;
1461                Recursively := True;
1462             end if;
1463
1464             Process_Directory (Dir_Name (Dir_Name'First .. Last), Recursively);
1465          end;
1466
1467       end loop;
1468    end Process;
1469
1470    ----------------
1471    -- Write_Char --
1472    ----------------
1473    procedure Write_A_Char (C : Character) is
1474    begin
1475       Write_A_String ((1 => C));
1476    end Write_A_Char;
1477
1478    ---------------
1479    -- Write_Eol --
1480    ---------------
1481
1482    procedure Write_Eol is
1483    begin
1484       Write_A_String ((1 => ASCII.LF));
1485    end Write_Eol;
1486
1487    --------------------
1488    -- Write_A_String --
1489    --------------------
1490
1491    procedure Write_A_String (S : String) is
1492       Str : String (1 .. S'Length);
1493
1494    begin
1495       if S'Length > 0 then
1496          Str := S;
1497
1498          if Write (Output_FD, Str (1)'Address, Str'Length) /= Str'Length then
1499             Prj.Com.Fail ("disk full");
1500          end if;
1501       end if;
1502    end Write_A_String;
1503
1504 end Prj.Makr;