gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference)). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for SPARK cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    -----------------------------
 155    -- SPARK Xrefs Information --
 156    -----------------------------
 157
 158    package body SPARK_Specific is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 165    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 166
 167    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 168    --  For a tagged type, generate implicit references to its primitive
 169    --  operations, for source navigation. This is done right before emitting
 170    --  cross-reference information rather than at the freeze point of the type
 171    --  in order to handle late bodies that are primitive operations.
 172
 173    function Lt (T1, T2 : Xref_Entry) return Boolean;
 174    --  Order cross-references
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added entry
 195
 196       else
 197          Xrefs.Decrement_Last;
 198       end if;
 199    end Add_Entry;
 200
 201    -----------
 202    -- Equal --
 203    -----------
 204
 205    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 206       Result : constant Boolean :=
 207                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 208    begin
 209       return Result;
 210    end Equal;
 211
 212    -------------------------
 213    -- Generate_Definition --
 214    -------------------------
 215
 216    procedure Generate_Definition (E : Entity_Id) is
 217    begin
 218       pragma Assert (Nkind (E) in N_Entity);
 219
 220       --  Note that we do not test Xref_Entity_Letters here. It is too early
 221       --  to do so, since we are often called before the entity is fully
 222       --  constructed, so that the Ekind is still E_Void.
 223
 224       if Opt.Xref_Active
 225
 226          --  Definition must come from source
 227
 228          --  We make an exception for subprogram child units that have no spec.
 229          --  For these we generate a subprogram declaration for library use,
 230          --  and the corresponding entity does not come from source.
 231          --  Nevertheless, all references will be attached to it and we have
 232          --  to treat is as coming from user code.
 233
 234          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 235
 236          --  And must have a reasonable source location that is not
 237          --  within an instance (all entities in instances are ignored)
 238
 239          and then Sloc (E) > No_Location
 240          and then Instantiation_Location (Sloc (E)) = No_Location
 241
 242          --  And must be a non-internal name from the main source unit
 243
 244          and then In_Extended_Main_Source_Unit (E)
 245          and then not Is_Internal_Name (Chars (E))
 246       then
 247          Add_Entry
 248            ((Ent => E,
 249              Loc => No_Location,
 250              Typ => ' ',
 251              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 252              Lun => No_Unit,
 253              Ref_Scope => Empty,
 254              Ent_Scope => Empty),
 255             Ent_Scope_File => No_Unit);
 256
 257          if In_Inlined_Body then
 258             Set_Referenced (E);
 259          end if;
 260       end if;
 261    end Generate_Definition;
 262
 263    ---------------------------------
 264    -- Generate_Operator_Reference --
 265    ---------------------------------
 266
 267    procedure Generate_Operator_Reference
 268      (N : Node_Id;
 269       T : Entity_Id)
 270    is
 271    begin
 272       if not In_Extended_Main_Source_Unit (N) then
 273          return;
 274       end if;
 275
 276       --  If the operator is not a Standard operator, then we generate a real
 277       --  reference to the user defined operator.
 278
 279       if Sloc (Entity (N)) /= Standard_Location then
 280          Generate_Reference (Entity (N), N);
 281
 282          --  A reference to an implicit inequality operator is also a reference
 283          --  to the user-defined equality.
 284
 285          if Nkind (N) = N_Op_Ne
 286            and then not Comes_From_Source (Entity (N))
 287            and then Present (Corresponding_Equality (Entity (N)))
 288          then
 289             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 290          end if;
 291
 292       --  For the case of Standard operators, we mark the result type as
 293       --  referenced. This ensures that in the case where we are using a
 294       --  derived operator, we mark an entity of the unit that implicitly
 295       --  defines this operator as used. Otherwise we may think that no entity
 296       --  of the unit is used. The actual entity marked as referenced is the
 297       --  first subtype, which is the relevant user defined entity.
 298
 299       --  Note: we only do this for operators that come from source. The
 300       --  generated code sometimes reaches for entities that do not need to be
 301       --  explicitly visible (for example, when we expand the code for
 302       --  comparing two record objects, the fields of the record may not be
 303       --  visible).
 304
 305       elsif Comes_From_Source (N) then
 306          Set_Referenced (First_Subtype (T));
 307       end if;
 308    end Generate_Operator_Reference;
 309
 310    ---------------------------------
 311    -- Generate_Prim_Op_References --
 312    ---------------------------------
 313
 314    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 315       Base_T    : Entity_Id;
 316       Prim      : Elmt_Id;
 317       Prim_List : Elist_Id;
 318
 319    begin
 320       --  Handle subtypes of synchronized types
 321
 322       if Ekind (Typ) = E_Protected_Subtype
 323         or else Ekind (Typ) = E_Task_Subtype
 324       then
 325          Base_T := Etype (Typ);
 326       else
 327          Base_T := Typ;
 328       end if;
 329
 330       --  References to primitive operations are only relevant for tagged types
 331
 332       if not Is_Tagged_Type (Base_T)
 333         or else Is_Class_Wide_Type (Base_T)
 334       then
 335          return;
 336       end if;
 337
 338       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 339       --  wrapper that allow us to dispatch calls through their implemented
 340       --  abstract interface types.
 341
 342       --  The check for Present here is to protect against previously reported
 343       --  critical errors.
 344
 345       Prim_List := Primitive_Operations (Base_T);
 346
 347       if No (Prim_List) then
 348          return;
 349       end if;
 350
 351       Prim := First_Elmt (Prim_List);
 352       while Present (Prim) loop
 353
 354          --  If the operation is derived, get the original for cross-reference
 355          --  reference purposes (it is the original for which we want the xref
 356          --  and for which the comes_from_source test must be performed).
 357
 358          Generate_Reference
 359            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 360          Next_Elmt (Prim);
 361       end loop;
 362    end Generate_Prim_Op_References;
 363
 364    ------------------------
 365    -- Generate_Reference --
 366    ------------------------
 367
 368    procedure Generate_Reference
 369      (E       : Entity_Id;
 370       N       : Node_Id;
 371       Typ     : Character := 'r';
 372       Set_Ref : Boolean   := True;
 373       Force   : Boolean   := False)
 374    is
 375       Actual_Typ : Character := Typ;
 376       Call       : Node_Id;
 377       Def        : Source_Ptr;
 378       Ent        : Entity_Id;
 379       Ent_Scope  : Entity_Id;
 380       Formal     : Entity_Id;
 381       Kind       : Entity_Kind;
 382       Nod        : Node_Id;
 383       Ref        : Source_Ptr;
 384       Ref_Scope  : Entity_Id;
 385
 386       function Get_Through_Renamings (E : Entity_Id) return Entity_Id;
 387       --  Get the enclosing entity through renamings, which may come from
 388       --  source or from the translation of generic instantiations.
 389
 390       function Is_On_LHS (Node : Node_Id) return Boolean;
 391       --  Used to check if a node is on the left hand side of an assignment.
 392       --  The following cases are handled:
 393       --
 394       --   Variable    Node is a direct descendant of left hand side of an
 395       --               assignment statement.
 396       --
 397       --   Prefix      Of an indexed or selected component that is present in
 398       --               a subtree rooted by an assignment statement. There is
 399       --               no restriction of nesting of components, thus cases
 400       --               such as A.B (C).D are handled properly. However a prefix
 401       --               of a dereference (either implicit or explicit) is never
 402       --               considered as on a LHS.
 403       --
 404       --   Out param   Same as above cases, but OUT parameter
 405
 406       function OK_To_Set_Referenced return Boolean;
 407       --  Returns True if the Referenced flag can be set. There are a few
 408       --  exceptions where we do not want to set this flag, see body for
 409       --  details of these exceptional cases.
 410
 411       ---------------------------
 412       -- Get_Through_Renamings --
 413       ---------------------------
 414
 415       function Get_Through_Renamings (E : Entity_Id) return Entity_Id is
 416          Result : Entity_Id := E;
 417
 418       begin
 419          while Present (Result)
 420            and then Is_Object (Result)
 421            and then Present (Renamed_Object (Result))
 422          loop
 423             Result := Get_Enclosing_Object (Renamed_Object (Result));
 424          end loop;
 425
 426          return Result;
 427       end Get_Through_Renamings;
 428
 429       ---------------
 430       -- Is_On_LHS --
 431       ---------------
 432
 433       --  ??? There are several routines here and there that perform a similar
 434       --      (but subtly different) computation, which should be factored:
 435
 436       --      Sem_Util.Is_LHS
 437       --      Sem_Util.May_Be_Lvalue
 438       --      Sem_Util.Known_To_Be_Assigned
 439       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 440       --      Exp_Smem.Is_Out_Actual
 441
 442       function Is_On_LHS (Node : Node_Id) return Boolean is
 443          N : Node_Id;
 444          P : Node_Id;
 445          K : Node_Kind;
 446
 447       begin
 448          --  Only identifiers are considered, is this necessary???
 449
 450          if Nkind (Node) /= N_Identifier then
 451             return False;
 452          end if;
 453
 454          --  Immediate return if appeared as OUT parameter
 455
 456          if Kind = E_Out_Parameter then
 457             return True;
 458          end if;
 459
 460          --  Search for assignment statement subtree root
 461
 462          N := Node;
 463          loop
 464             P := Parent (N);
 465             K := Nkind (P);
 466
 467             if K = N_Assignment_Statement then
 468                return Name (P) = N;
 469
 470             --  Check whether the parent is a component and the current node is
 471             --  its prefix, but return False if the current node has an access
 472             --  type, as in that case the selected or indexed component is an
 473             --  implicit dereference, and the LHS is the designated object, not
 474             --  the access object.
 475
 476             --  ??? case of a slice assignment?
 477
 478             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 479               and then Prefix (P) = N
 480             then
 481                --  Check for access type. First a special test, In some cases
 482                --  this is called too early (see comments in Find_Direct_Name),
 483                --  at a point where the tree is not fully typed yet. In that
 484                --  case we may lack an Etype for N, and we can't check the
 485                --  Etype. For now, we always return False in such a case,
 486                --  but this is clearly not right in all cases ???
 487
 488                if No (Etype (N)) then
 489                   return False;
 490
 491                elsif Is_Access_Type (Etype (N)) then
 492                   return False;
 493
 494                --  Access type case dealt with, keep going
 495
 496                else
 497                   N := P;
 498                end if;
 499
 500             --  All other cases, definitely not on left side
 501
 502             else
 503                return False;
 504             end if;
 505          end loop;
 506       end Is_On_LHS;
 507
 508       ---------------------------
 509       -- OK_To_Set_Referenced --
 510       ---------------------------
 511
 512       function OK_To_Set_Referenced return Boolean is
 513          P : Node_Id;
 514
 515       begin
 516          --  A reference from a pragma Unreferenced or pragma Unmodified or
 517          --  pragma Warnings does not cause the Referenced flag to be set.
 518          --  This avoids silly warnings about things being referenced and
 519          --  not assigned when the only reference is from the pragma.
 520
 521          if Nkind (N) = N_Identifier then
 522             P := Parent (N);
 523
 524             if Nkind (P) = N_Pragma_Argument_Association then
 525                P := Parent (P);
 526
 527                if Nkind (P) = N_Pragma then
 528                   if Nam_In (Pragma_Name_Unmapped (P),
 529                              Name_Warnings,
 530                              Name_Unmodified,
 531                              Name_Unreferenced)
 532                   then
 533                      return False;
 534                   end if;
 535                end if;
 536
 537             --  A reference to a formal in a named parameter association does
 538             --  not make the formal referenced. Formals that are unused in the
 539             --  subprogram body are properly flagged as such, even if calls
 540             --  elsewhere use named notation.
 541
 542             elsif Nkind (P) = N_Parameter_Association
 543               and then N = Selector_Name (P)
 544             then
 545                return False;
 546             end if;
 547          end if;
 548
 549          return True;
 550       end OK_To_Set_Referenced;
 551
 552    --  Start of processing for Generate_Reference
 553
 554    begin
 555       pragma Assert (Nkind (E) in N_Entity);
 556       Find_Actual (N, Formal, Call);
 557
 558       if Present (Formal) then
 559          Kind := Ekind (Formal);
 560       else
 561          Kind := E_Void;
 562       end if;
 563
 564       --  Check for obsolescent reference to package ASCII. GNAT treats this
 565       --  element of annex J specially since in practice, programs make a lot
 566       --  of use of this feature, so we don't include it in the set of features
 567       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 568       --  are required to note it as a violation of the RM defined restriction.
 569
 570       if E = Standard_ASCII then
 571          Check_Restriction (No_Obsolescent_Features, N);
 572       end if;
 573
 574       --  Check for reference to entity marked with Is_Obsolescent
 575
 576       --  Note that we always allow obsolescent references in the compiler
 577       --  itself and the run time, since we assume that we know what we are
 578       --  doing in such cases. For example the calls in Ada.Characters.Handling
 579       --  to its own obsolescent subprograms are just fine.
 580
 581       --  In any case we only generate warnings if we are in the extended main
 582       --  source unit, and the entity itself is not in the extended main source
 583       --  unit, since we assume the source unit itself knows what is going on
 584       --  (and for sure we do not want silly warnings, e.g. on the end line of
 585       --  an obsolescent procedure body).
 586
 587       if Is_Obsolescent (E)
 588         and then not GNAT_Mode
 589         and then not In_Extended_Main_Source_Unit (E)
 590         and then In_Extended_Main_Source_Unit (N)
 591       then
 592          Check_Restriction (No_Obsolescent_Features, N);
 593
 594          if Warn_On_Obsolescent_Feature then
 595             Output_Obsolescent_Entity_Warnings (N, E);
 596          end if;
 597       end if;
 598
 599       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 600       --  detect real explicit references (modifications and references).
 601
 602       if Comes_From_Source (N)
 603         and then Is_Ada_2005_Only (E)
 604         and then Ada_Version < Ada_2005
 605         and then Warn_On_Ada_2005_Compatibility
 606         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 607       then
 608          Error_Msg_NE ("& is only defined in Ada 2005?y?", N, E);
 609       end if;
 610
 611       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 612       --  detect real explicit references (modifications and references).
 613
 614       if Comes_From_Source (N)
 615         and then Is_Ada_2012_Only (E)
 616         and then Ada_Version < Ada_2012
 617         and then Warn_On_Ada_2012_Compatibility
 618         and then (Typ = 'm' or else Typ = 'r')
 619       then
 620          Error_Msg_NE ("& is only defined in Ada 2012?y?", N, E);
 621       end if;
 622
 623       --  Do not generate references if we are within a postcondition sub-
 624       --  program, because the reference does not comes from source, and the
 625       --  pre-analysis of the aspect has already created an entry for the ALI
 626       --  file at the proper source location.
 627
 628       if Chars (Current_Scope) = Name_uPostconditions then
 629          return;
 630       end if;
 631
 632       --  Never collect references if not in main source unit. However, we omit
 633       --  this test if Typ is 'e' or 'k', since these entries are structural,
 634       --  and it is useful to have them in units that reference packages as
 635       --  well as units that define packages. We also omit the test for the
 636       --  case of 'p' since we want to include inherited primitive operations
 637       --  from other packages.
 638
 639       --  We also omit this test is this is a body reference for a subprogram
 640       --  instantiation. In this case the reference is to the generic body,
 641       --  which clearly need not be in the main unit containing the instance.
 642       --  For the same reason we accept an implicit reference generated for
 643       --  a default in an instance.
 644
 645       --  We also set the referenced flag in a generic package that is not in
 646       --  then main source unit, when the variable is of a formal private type,
 647       --  to warn in the instance if the corresponding type is not a fully
 648       --  initialized type.
 649
 650       if not In_Extended_Main_Source_Unit (N) then
 651          if Typ = 'e' or else
 652             Typ = 'I' or else
 653             Typ = 'p' or else
 654             Typ = 'i' or else
 655             Typ = 'k'
 656            or else (Typ = 'b' and then Is_Generic_Instance (E))
 657
 658             --  Allow the generation of references to reads, writes and calls
 659             --  in SPARK mode when the related context comes from an instance.
 660
 661            or else
 662              (GNATprove_Mode
 663                and then In_Extended_Main_Code_Unit (N)
 664                and then (Typ = 'm' or else Typ = 'r' or else Typ = 's'))
 665          then
 666             null;
 667
 668          elsif In_Instance_Body
 669            and then In_Extended_Main_Code_Unit (N)
 670            and then Is_Generic_Type (Etype (E))
 671          then
 672             Set_Referenced (E);
 673             return;
 674
 675          elsif Inside_A_Generic
 676            and then Is_Generic_Type (Etype (E))
 677          then
 678             Set_Referenced (E);
 679             return;
 680
 681          else
 682             return;
 683          end if;
 684       end if;
 685
 686       --  For reference type p, the entity must be in main source unit
 687
 688       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 689          return;
 690       end if;
 691
 692       --  Unless the reference is forced, we ignore references where the
 693       --  reference itself does not come from source.
 694
 695       if not Force and then not Comes_From_Source (N) then
 696          return;
 697       end if;
 698
 699       --  Deal with setting entity as referenced, unless suppressed. Note that
 700       --  we still do Set_Referenced on entities that do not come from source.
 701       --  This situation arises when we have a source reference to a derived
 702       --  operation, where the derived operation itself does not come from
 703       --  source, but we still want to mark it as referenced, since we really
 704       --  are referencing an entity in the corresponding package (this avoids
 705       --  wrong complaints that the package contains no referenced entities).
 706
 707       if Set_Ref then
 708
 709          --  Assignable object appearing on left side of assignment or as
 710          --  an out parameter.
 711
 712          if Is_Assignable (E)
 713            and then Is_On_LHS (N)
 714            and then Ekind (E) /= E_In_Out_Parameter
 715          then
 716             --  For objects that are renamings, just set as simply referenced
 717             --  we do not try to do assignment type tracking in this case.
 718
 719             if Present (Renamed_Object (E)) then
 720                Set_Referenced (E);
 721
 722             --  Out parameter case
 723
 724             elsif Kind = E_Out_Parameter then
 725
 726                --  If warning mode for all out parameters is set, or this is
 727                --  the only warning parameter, then we want to mark this for
 728                --  later warning logic by setting Referenced_As_Out_Parameter
 729
 730                if Warn_On_Modified_As_Out_Parameter (Formal) then
 731                   Set_Referenced_As_Out_Parameter (E, True);
 732                   Set_Referenced_As_LHS (E, False);
 733
 734                --  For OUT parameter not covered by the above cases, we simply
 735                --  regard it as a normal reference (in this case we do not
 736                --  want any of the warning machinery for out parameters).
 737
 738                else
 739                   Set_Referenced (E);
 740                end if;
 741
 742             --  For the left hand of an assignment case, we do nothing here.
 743             --  The processing for Analyze_Assignment_Statement will set the
 744             --  Referenced_As_LHS flag.
 745
 746             else
 747                null;
 748             end if;
 749
 750          --  Check for a reference in a pragma that should not count as a
 751          --  making the variable referenced for warning purposes.
 752
 753          elsif Is_Non_Significant_Pragma_Reference (N) then
 754             null;
 755
 756          --  A reference in an attribute definition clause does not count as a
 757          --  reference except for the case of Address. The reason that 'Address
 758          --  is an exception is that it creates an alias through which the
 759          --  variable may be referenced.
 760
 761          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 762            and then Chars (Parent (N)) /= Name_Address
 763            and then N = Name (Parent (N))
 764          then
 765             null;
 766
 767          --  Constant completion does not count as a reference
 768
 769          elsif Typ = 'c'
 770            and then Ekind (E) = E_Constant
 771          then
 772             null;
 773
 774          --  Record representation clause does not count as a reference
 775
 776          elsif Nkind (N) = N_Identifier
 777            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 778          then
 779             null;
 780
 781          --  Discriminants do not need to produce a reference to record type
 782
 783          elsif Typ = 'd'
 784            and then Nkind (Parent (N)) = N_Discriminant_Specification
 785          then
 786             null;
 787
 788          --  All other cases
 789
 790          else
 791             --  Special processing for IN OUT parameters, where we have an
 792             --  implicit assignment to a simple variable.
 793
 794             if Kind = E_In_Out_Parameter
 795               and then Is_Assignable (E)
 796             then
 797                --  For sure this counts as a normal read reference
 798
 799                Set_Referenced (E);
 800                Set_Last_Assignment (E, Empty);
 801
 802                --  We count it as being referenced as an out parameter if the
 803                --  option is set to warn on all out parameters, except that we
 804                --  have a special exclusion for an intrinsic subprogram, which
 805                --  is most likely an instantiation of Unchecked_Deallocation
 806                --  which we do not want to consider as an assignment since it
 807                --  generates false positives. We also exclude the case of an
 808                --  IN OUT parameter if the name of the procedure is Free,
 809                --  since we suspect similar semantics.
 810
 811                if Warn_On_All_Unread_Out_Parameters
 812                  and then Is_Entity_Name (Name (Call))
 813                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 814                  and then Chars (Name (Call)) /= Name_Free
 815                then
 816                   Set_Referenced_As_Out_Parameter (E, True);
 817                   Set_Referenced_As_LHS (E, False);
 818                end if;
 819
 820             --  Don't count a recursive reference within a subprogram as a
 821             --  reference (that allows detection of a recursive subprogram
 822             --  whose only references are recursive calls as unreferenced).
 823
 824             elsif Is_Subprogram (E)
 825               and then E = Nearest_Dynamic_Scope (Current_Scope)
 826             then
 827                null;
 828
 829             --  Any other occurrence counts as referencing the entity
 830
 831             elsif OK_To_Set_Referenced then
 832                Set_Referenced (E);
 833
 834                --  If variable, this is an OK reference after an assignment
 835                --  so we can clear the Last_Assignment indication.
 836
 837                if Is_Assignable (E) then
 838                   Set_Last_Assignment (E, Empty);
 839                end if;
 840             end if;
 841          end if;
 842
 843          --  Check for pragma Unreferenced given and reference is within
 844          --  this source unit (occasion for possible warning to be issued).
 845          --  Note that the entity may be marked as unreferenced by pragma
 846          --  Unused.
 847
 848          if Has_Unreferenced (E)
 849            and then In_Same_Extended_Unit (E, N)
 850          then
 851             --  A reference as a named parameter in a call does not count
 852             --  as a violation of pragma Unreferenced for this purpose...
 853
 854             if Nkind (N) = N_Identifier
 855               and then Nkind (Parent (N)) = N_Parameter_Association
 856               and then Selector_Name (Parent (N)) = N
 857             then
 858                null;
 859
 860             --  ... Neither does a reference to a variable on the left side
 861             --  of an assignment.
 862
 863             elsif Is_On_LHS (N) then
 864                null;
 865
 866             --  No warning if the reference is in a call that does not come
 867             --  from source (e.g. a call to a controlled type primitive).
 868
 869             elsif not Comes_From_Source (Parent (N))
 870               and then Nkind (Parent (N)) = N_Procedure_Call_Statement
 871             then
 872                null;
 873
 874             --  For entry formals, we want to place the warning message on the
 875             --  corresponding entity in the accept statement. The current scope
 876             --  is the body of the accept, so we find the formal whose name
 877             --  matches that of the entry formal (there is no link between the
 878             --  two entities, and the one in the accept statement is only used
 879             --  for conformance checking).
 880
 881             elsif Ekind (Scope (E)) = E_Entry then
 882                declare
 883                   BE : Entity_Id;
 884
 885                begin
 886                   BE := First_Entity (Current_Scope);
 887                   while Present (BE) loop
 888                      if Chars (BE) = Chars (E) then
 889                         if Has_Pragma_Unused (E) then
 890                            Error_Msg_NE -- CODEFIX
 891                              ("??pragma Unused given for&!", N, BE);
 892                         else
 893                            Error_Msg_NE -- CODEFIX
 894                              ("??pragma Unreferenced given for&!", N, BE);
 895                         end if;
 896                         exit;
 897                      end if;
 898
 899                      Next_Entity (BE);
 900                   end loop;
 901                end;
 902
 903             --  Here we issue the warning, since this is a real reference
 904
 905             elsif Has_Pragma_Unused (E) then
 906                Error_Msg_NE -- CODEFIX
 907                  ("??pragma Unused given for&!", N, E);
 908             else
 909                Error_Msg_NE -- CODEFIX
 910                  ("??pragma Unreferenced given for&!", N, E);
 911             end if;
 912          end if;
 913
 914          --  If this is a subprogram instance, mark as well the internal
 915          --  subprogram in the wrapper package, which may be a visible
 916          --  compilation unit.
 917
 918          if Is_Overloadable (E)
 919            and then Is_Generic_Instance (E)
 920            and then Present (Alias (E))
 921          then
 922             Set_Referenced (Alias (E));
 923          end if;
 924       end if;
 925
 926       --  Generate reference if all conditions are met:
 927
 928       if
 929          --  Cross referencing must be active
 930
 931          Opt.Xref_Active
 932
 933          --  The entity must be one for which we collect references
 934
 935          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 936
 937          --  Both Sloc values must be set to something sensible
 938
 939          and then Sloc (E) > No_Location
 940          and then Sloc (N) > No_Location
 941
 942          --  Ignore references from within an instance. The only exceptions to
 943          --  this are default subprograms, for which we generate an implicit
 944          --  reference and compilations in SPARK mode.
 945
 946          and then
 947            (Instantiation_Location (Sloc (N)) = No_Location
 948              or else Typ = 'i'
 949              or else GNATprove_Mode)
 950
 951         --  Ignore dummy references
 952
 953         and then Typ /= ' '
 954       then
 955          if Nkind_In (N, N_Identifier,
 956                          N_Defining_Identifier,
 957                          N_Defining_Operator_Symbol,
 958                          N_Operator_Symbol,
 959                          N_Defining_Character_Literal)
 960            or else Nkind (N) in N_Op
 961            or else (Nkind (N) = N_Character_Literal
 962                      and then Sloc (Entity (N)) /= Standard_Location)
 963          then
 964             Nod := N;
 965
 966          elsif Nkind_In (N, N_Expanded_Name, N_Selected_Component) then
 967             Nod := Selector_Name (N);
 968
 969          else
 970             return;
 971          end if;
 972
 973          --  Normal case of source entity comes from source
 974
 975          if Comes_From_Source (E) then
 976             Ent := E;
 977
 978          --  Because a declaration may be generated for a subprogram body
 979          --  without declaration in GNATprove mode, for inlining, some
 980          --  parameters may end up being marked as not coming from source
 981          --  although they are. Take these into account specially.
 982
 983          elsif GNATprove_Mode and then Ekind (E) in Formal_Kind then
 984             Ent := E;
 985
 986          --  Entity does not come from source, but is a derived subprogram and
 987          --  the derived subprogram comes from source (after one or more
 988          --  derivations) in which case the reference is to parent subprogram.
 989
 990          elsif Is_Overloadable (E)
 991            and then Present (Alias (E))
 992          then
 993             Ent := Alias (E);
 994             while not Comes_From_Source (Ent) loop
 995                if No (Alias (Ent)) then
 996                   return;
 997                end if;
 998
 999                Ent := Alias (Ent);
1000             end loop;
1001
1002          --  The internally created defining entity for a child subprogram
1003          --  that has no previous spec has valid references.
1004
1005          elsif Is_Overloadable (E)
1006            and then Is_Child_Unit (E)
1007          then
1008             Ent := E;
1009
1010          --  Ditto for the formals of such a subprogram
1011
1012          elsif Is_Overloadable (Scope (E))
1013            and then Is_Child_Unit (Scope (E))
1014          then
1015             Ent := E;
1016
1017          --  Record components of discriminated subtypes or derived types must
1018          --  be treated as references to the original component.
1019
1020          elsif Ekind (E) = E_Component
1021            and then Comes_From_Source (Original_Record_Component (E))
1022          then
1023             Ent := Original_Record_Component (E);
1024
1025          --  If this is an expanded reference to a discriminant, recover the
1026          --  original discriminant, which gets the reference.
1027
1028          elsif Ekind (E) = E_In_Parameter
1029            and then  Present (Discriminal_Link (E))
1030          then
1031             Ent := Discriminal_Link (E);
1032             Set_Referenced (Ent);
1033
1034          --  Ignore reference to any other entity that is not from source
1035
1036          else
1037             return;
1038          end if;
1039
1040          --  In SPARK mode, consider the underlying entity renamed instead of
1041          --  the renaming, which is needed to compute a valid set of effects
1042          --  (reads, writes) for the enclosing subprogram.
1043
1044          if GNATprove_Mode then
1045             Ent := Get_Through_Renamings (Ent);
1046
1047             --  If no enclosing object, then it could be a reference to any
1048             --  location not tracked individually, like heap-allocated data.
1049             --  Conservatively approximate this possibility by generating a
1050             --  dereference, and return.
1051
1052             if No (Ent) then
1053                if Actual_Typ = 'w' then
1054                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1055                   SPARK_Specific.Generate_Dereference (Nod, 'w');
1056                else
1057                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1058                end if;
1059
1060                return;
1061             end if;
1062          end if;
1063
1064          --  Record reference to entity
1065
1066          if Actual_Typ = 'p'
1067            and then Is_Subprogram (Nod)
1068            and then Present (Overridden_Operation (Nod))
1069          then
1070             Actual_Typ := 'P';
1071          end if;
1072
1073          --  Comment needed here for special SPARK code ???
1074
1075          if GNATprove_Mode then
1076             Ref := Sloc (Nod);
1077             Def := Sloc (Ent);
1078
1079             Ref_Scope :=
1080               SPARK_Specific.Enclosing_Subprogram_Or_Library_Package (Nod);
1081             Ent_Scope :=
1082               SPARK_Specific.Enclosing_Subprogram_Or_Library_Package (Ent);
1083
1084             --  Since we are reaching through renamings in SPARK mode, we may
1085             --  end up with standard constants. Ignore those.
1086
1087             if Sloc (Ent_Scope) <= Standard_Location
1088               or else Def <= Standard_Location
1089             then
1090                return;
1091             end if;
1092
1093             Add_Entry
1094               ((Ent       => Ent,
1095                 Loc       => Ref,
1096                 Typ       => Actual_Typ,
1097                 Eun       => Get_Top_Level_Code_Unit (Def),
1098                 Lun       => Get_Top_Level_Code_Unit (Ref),
1099                 Ref_Scope => Ref_Scope,
1100                 Ent_Scope => Ent_Scope),
1101                Ent_Scope_File => Get_Top_Level_Code_Unit (Ent));
1102
1103          else
1104             Ref := Original_Location (Sloc (Nod));
1105             Def := Original_Location (Sloc (Ent));
1106
1107             --  If this is an operator symbol, skip the initial quote for
1108             --  navigation purposes. This is not done for the end label,
1109             --  where we want the actual position after the closing quote.
1110
1111             if Typ = 't' then
1112                null;
1113
1114             elsif Nkind (N) = N_Defining_Operator_Symbol
1115               or else Nkind (Nod) = N_Operator_Symbol
1116             then
1117                Ref := Ref + 1;
1118             end if;
1119
1120             Add_Entry
1121               ((Ent       => Ent,
1122                 Loc       => Ref,
1123                 Typ       => Actual_Typ,
1124                 Eun       => Get_Source_Unit (Def),
1125                 Lun       => Get_Source_Unit (Ref),
1126                 Ref_Scope => Empty,
1127                 Ent_Scope => Empty),
1128                Ent_Scope_File => No_Unit);
1129
1130             --  Generate reference to the first private entity
1131
1132             if Typ = 'e'
1133               and then Comes_From_Source (E)
1134               and then Nkind (Ent) = N_Defining_Identifier
1135               and then (Is_Package_Or_Generic_Package (Ent)
1136                          or else Is_Concurrent_Type (Ent))
1137               and then Present (First_Private_Entity (E))
1138               and then In_Extended_Main_Source_Unit (N)
1139             then
1140                --  Handle case in which the full-view and partial-view of the
1141                --  first private entity are swapped.
1142
1143                declare
1144                   First_Private : Entity_Id := First_Private_Entity (E);
1145
1146                begin
1147                   if Is_Private_Type (First_Private)
1148                     and then Present (Full_View (First_Private))
1149                   then
1150                      First_Private := Full_View (First_Private);
1151                   end if;
1152
1153                   Add_Entry
1154                     ((Ent       => Ent,
1155                       Loc       => Sloc (First_Private),
1156                       Typ       => 'E',
1157                       Eun       => Get_Source_Unit (Def),
1158                       Lun       => Get_Source_Unit (Ref),
1159                       Ref_Scope => Empty,
1160                       Ent_Scope => Empty),
1161                      Ent_Scope_File => No_Unit);
1162                end;
1163             end if;
1164          end if;
1165       end if;
1166    end Generate_Reference;
1167
1168    -----------------------------------
1169    -- Generate_Reference_To_Formals --
1170    -----------------------------------
1171
1172    procedure Generate_Reference_To_Formals (E : Entity_Id) is
1173       Formal : Entity_Id;
1174
1175    begin
1176       if Is_Generic_Subprogram (E) then
1177          Formal := First_Entity (E);
1178
1179          while Present (Formal)
1180            and then not Is_Formal (Formal)
1181          loop
1182             Next_Entity (Formal);
1183          end loop;
1184
1185       elsif Ekind (E) in Access_Subprogram_Kind then
1186          Formal := First_Formal (Designated_Type (E));
1187
1188       else
1189          Formal := First_Formal (E);
1190       end if;
1191
1192       while Present (Formal) loop
1193          if Ekind (Formal) = E_In_Parameter then
1194
1195             if Nkind (Parameter_Type (Parent (Formal))) = N_Access_Definition
1196             then
1197                Generate_Reference (E, Formal, '^', False);
1198             else
1199                Generate_Reference (E, Formal, '>', False);
1200             end if;
1201
1202          elsif Ekind (Formal) = E_In_Out_Parameter then
1203             Generate_Reference (E, Formal, '=', False);
1204
1205          else
1206             Generate_Reference (E, Formal, '<', False);
1207          end if;
1208
1209          Next_Formal (Formal);
1210       end loop;
1211    end Generate_Reference_To_Formals;
1212
1213    -------------------------------------------
1214    -- Generate_Reference_To_Generic_Formals --
1215    -------------------------------------------
1216
1217    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1218       Formal : Entity_Id;
1219
1220    begin
1221       Formal := First_Entity (E);
1222       while Present (Formal) loop
1223          if Comes_From_Source (Formal) then
1224             Generate_Reference (E, Formal, 'z', False);
1225          end if;
1226
1227          Next_Entity (Formal);
1228       end loop;
1229    end Generate_Reference_To_Generic_Formals;
1230
1231    -------------
1232    -- Get_Key --
1233    -------------
1234
1235    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1236    begin
1237       return E;
1238    end Get_Key;
1239
1240    ----------------------------
1241    -- Has_Deferred_Reference --
1242    ----------------------------
1243
1244    function Has_Deferred_Reference (Ent : Entity_Id) return Boolean is
1245    begin
1246       for J in Deferred_References.First .. Deferred_References.Last loop
1247          if Deferred_References.Table (J).E = Ent then
1248             return True;
1249          end if;
1250       end loop;
1251
1252       return False;
1253    end Has_Deferred_Reference;
1254
1255    ----------
1256    -- Hash --
1257    ----------
1258
1259    function Hash (F : Xref_Entry_Number) return Header_Num is
1260       --  It is unlikely to have two references to the same entity at the same
1261       --  source location, so the hash function depends only on the Ent and Loc
1262       --  fields.
1263
1264       XE : Xref_Entry renames Xrefs.Table (F);
1265       type M is mod 2**32;
1266
1267       H : constant M := M (XE.Key.Ent) + 2 ** 7 * M (abs XE.Key.Loc);
1268       --  It would be more natural to write:
1269       --
1270       --    H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1271       --
1272       --  But we can't use M'Mod, because it prevents bootstrapping with older
1273       --  compilers. Loc can be negative, so we do "abs" before converting.
1274       --  One day this can be cleaned up ???
1275
1276    begin
1277       return Header_Num (H mod Num_Buckets);
1278    end Hash;
1279
1280    -----------------
1281    -- HT_Set_Next --
1282    -----------------
1283
1284    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1285    begin
1286       Xrefs.Table (E).HTable_Next := Next;
1287    end HT_Set_Next;
1288
1289    -------------
1290    -- HT_Next --
1291    -------------
1292
1293    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1294    begin
1295       return Xrefs.Table (E).HTable_Next;
1296    end HT_Next;
1297
1298    ----------------
1299    -- Initialize --
1300    ----------------
1301
1302    procedure Initialize is
1303    begin
1304       Xrefs.Init;
1305    end Initialize;
1306
1307    --------
1308    -- Lt --
1309    --------
1310
1311    function Lt (T1, T2 : Xref_Entry) return Boolean is
1312    begin
1313       --  First test: if entity is in different unit, sort by unit
1314
1315       if T1.Key.Eun /= T2.Key.Eun then
1316          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1317
1318       --  Second test: within same unit, sort by entity Sloc
1319
1320       elsif T1.Def /= T2.Def then
1321          return T1.Def < T2.Def;
1322
1323       --  Third test: sort definitions ahead of references
1324
1325       elsif T1.Key.Loc = No_Location then
1326          return True;
1327
1328       elsif T2.Key.Loc = No_Location then
1329          return False;
1330
1331       --  Fourth test: for same entity, sort by reference location unit
1332
1333       elsif T1.Key.Lun /= T2.Key.Lun then
1334          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1335
1336       --  Fifth test: order of location within referencing unit
1337
1338       elsif T1.Key.Loc /= T2.Key.Loc then
1339          return T1.Key.Loc < T2.Key.Loc;
1340
1341       --  Finally, for two locations at the same address, we prefer
1342       --  the one that does NOT have the type 'r' so that a modification
1343       --  or extension takes preference, when there are more than one
1344       --  reference at the same location. As a result, in the case of
1345       --  entities that are in-out actuals, the read reference follows
1346       --  the modify reference.
1347
1348       else
1349          return T2.Key.Typ = 'r';
1350       end if;
1351    end Lt;
1352
1353    -----------------------
1354    -- Output_References --
1355    -----------------------
1356
1357    procedure Output_References is
1358
1359       procedure Get_Type_Reference
1360         (Ent   : Entity_Id;
1361          Tref  : out Entity_Id;
1362          Left  : out Character;
1363          Right : out Character);
1364       --  Given an Entity_Id Ent, determines whether a type reference is
1365       --  required. If so, Tref is set to the entity for the type reference
1366       --  and Left and Right are set to the left/right brackets to be output
1367       --  for the reference. If no type reference is required, then Tref is
1368       --  set to Empty, and Left/Right are set to space.
1369
1370       procedure Output_Import_Export_Info (Ent : Entity_Id);
1371       --  Output language and external name information for an interfaced
1372       --  entity, using the format <language, external_name>.
1373
1374       ------------------------
1375       -- Get_Type_Reference --
1376       ------------------------
1377
1378       procedure Get_Type_Reference
1379         (Ent   : Entity_Id;
1380          Tref  : out Entity_Id;
1381          Left  : out Character;
1382          Right : out Character)
1383       is
1384          Sav : Entity_Id;
1385
1386       begin
1387          --  See if we have a type reference
1388
1389          Tref := Ent;
1390          Left := '{';
1391          Right := '}';
1392
1393          loop
1394             Sav := Tref;
1395
1396             --  Processing for types
1397
1398             if Is_Type (Tref) then
1399
1400                --  Case of base type
1401
1402                if Base_Type (Tref) = Tref then
1403
1404                   --  If derived, then get first subtype
1405
1406                   if Tref /= Etype (Tref) then
1407                      Tref := First_Subtype (Etype (Tref));
1408
1409                      --  Set brackets for derived type, but don't override
1410                      --  pointer case since the fact that something is a
1411                      --  pointer is more important.
1412
1413                      if Left /= '(' then
1414                         Left := '<';
1415                         Right := '>';
1416                      end if;
1417
1418                   --  If the completion of a private type is itself a derived
1419                   --  type, we need the parent of the full view.
1420
1421                   elsif Is_Private_Type (Tref)
1422                     and then Present (Full_View (Tref))
1423                     and then Etype (Full_View (Tref)) /= Full_View (Tref)
1424                   then
1425                      Tref := Etype (Full_View (Tref));
1426
1427                      if Left /= '(' then
1428                         Left := '<';
1429                         Right := '>';
1430                      end if;
1431
1432                   --  If non-derived pointer, get directly designated type.
1433                   --  If the type has a full view, all references are on the
1434                   --  partial view that is seen first.
1435
1436                   elsif Is_Access_Type (Tref) then
1437                      Tref := Directly_Designated_Type (Tref);
1438                      Left := '(';
1439                      Right := ')';
1440
1441                   elsif Is_Private_Type (Tref)
1442                     and then Present (Full_View (Tref))
1443                   then
1444                      if Is_Access_Type (Full_View (Tref)) then
1445                         Tref := Directly_Designated_Type (Full_View (Tref));
1446                         Left := '(';
1447                         Right := ')';
1448
1449                      --  If the full view is an array type, we also retrieve
1450                      --  the corresponding component type, because the ali
1451                      --  entry already indicates that this is an array.
1452
1453                      elsif Is_Array_Type (Full_View (Tref)) then
1454                         Tref := Component_Type (Full_View (Tref));
1455                         Left := '(';
1456                         Right := ')';
1457                      end if;
1458
1459                   --  If non-derived array, get component type. Skip component
1460                   --  type for case of String or Wide_String, saves worthwhile
1461                   --  space.
1462
1463                   elsif Is_Array_Type (Tref)
1464                     and then Tref /= Standard_String
1465                     and then Tref /= Standard_Wide_String
1466                   then
1467                      Tref := Component_Type (Tref);
1468                      Left := '(';
1469                      Right := ')';
1470
1471                   --  For other non-derived base types, nothing
1472
1473                   else
1474                      exit;
1475                   end if;
1476
1477                --  For a subtype, go to ancestor subtype
1478
1479                else
1480                   Tref := Ancestor_Subtype (Tref);
1481
1482                   --  If no ancestor subtype, go to base type
1483
1484                   if No (Tref) then
1485                      Tref := Base_Type (Sav);
1486                   end if;
1487                end if;
1488
1489             --  For objects, functions, enum literals, just get type from
1490             --  Etype field.
1491
1492             elsif Is_Object (Tref)
1493               or else Ekind (Tref) = E_Enumeration_Literal
1494               or else Ekind (Tref) = E_Function
1495               or else Ekind (Tref) = E_Operator
1496             then
1497                Tref := Etype (Tref);
1498
1499                --  Another special case: an object of a classwide type
1500                --  initialized with a tag-indeterminate call gets a subtype
1501                --  of the classwide type during expansion. See if the original
1502                --  type in the declaration is named, and return it instead
1503                --  of going to the root type. The expression may be a class-
1504                --  wide function call whose result is on the secondary stack,
1505                --  which forces the declaration to be rewritten as a renaming,
1506                --  so examine the source declaration.
1507
1508                if Ekind (Tref) = E_Class_Wide_Subtype then
1509                   declare
1510                      Decl : constant Node_Id := Original_Node (Parent (Ent));
1511                   begin
1512                      if Nkind (Decl) = N_Object_Declaration
1513                        and then Is_Entity_Name
1514                                   (Original_Node (Object_Definition (Decl)))
1515                      then
1516                         Tref :=
1517                           Entity (Original_Node (Object_Definition (Decl)));
1518                      end if;
1519                   end;
1520
1521                --  For a function that returns a class-wide type, Tref is
1522                --  already correct.
1523
1524                elsif Is_Overloadable (Ent)
1525                  and then Is_Class_Wide_Type (Tref)
1526                then
1527                   return;
1528                end if;
1529
1530             --  For anything else, exit
1531
1532             else
1533                exit;
1534             end if;
1535
1536             --  Exit if no type reference, or we are stuck in some loop trying
1537             --  to find the type reference, or if the type is standard void
1538             --  type (the latter is an implementation artifact that should not
1539             --  show up in the generated cross-references).
1540
1541             exit when No (Tref)
1542               or else Tref = Sav
1543               or else Tref = Standard_Void_Type;
1544
1545             --  If we have a usable type reference, return, otherwise keep
1546             --  looking for something useful (we are looking for something
1547             --  that either comes from source or standard)
1548
1549             if Sloc (Tref) = Standard_Location
1550               or else Comes_From_Source (Tref)
1551             then
1552                --  If the reference is a subtype created for a generic actual,
1553                --  go actual directly, the inner subtype is not user visible.
1554
1555                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1556                  and then not Comes_From_Source (Parent (Tref))
1557                  and then
1558                   (Is_Wrapper_Package (Scope (Tref))
1559                      or else Is_Generic_Instance (Scope (Tref)))
1560                then
1561                   Tref := First_Subtype (Base_Type (Tref));
1562                end if;
1563
1564                return;
1565             end if;
1566          end loop;
1567
1568          --  If we fall through the loop, no type reference
1569
1570          Tref := Empty;
1571          Left := ' ';
1572          Right := ' ';
1573       end Get_Type_Reference;
1574
1575       -------------------------------
1576       -- Output_Import_Export_Info --
1577       -------------------------------
1578
1579       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1580          Language_Name : Name_Id;
1581          Conv          : constant Convention_Id := Convention (Ent);
1582
1583       begin
1584          --  Generate language name from convention
1585
1586          if Conv  = Convention_C then
1587             Language_Name := Name_C;
1588
1589          elsif Conv = Convention_CPP then
1590             Language_Name := Name_CPP;
1591
1592          elsif Conv = Convention_Ada then
1593             Language_Name := Name_Ada;
1594
1595          else
1596             --  For the moment we ignore all other cases ???
1597
1598             return;
1599          end if;
1600
1601          Write_Info_Char ('<');
1602          Get_Unqualified_Name_String (Language_Name);
1603
1604          for J in 1 .. Name_Len loop
1605             Write_Info_Char (Name_Buffer (J));
1606          end loop;
1607
1608          if Present (Interface_Name (Ent)) then
1609             Write_Info_Char (',');
1610             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1611
1612             for J in 1 .. Name_Len loop
1613                Write_Info_Char (Name_Buffer (J));
1614             end loop;
1615          end if;
1616
1617          Write_Info_Char ('>');
1618       end Output_Import_Export_Info;
1619
1620    --  Start of processing for Output_References
1621
1622    begin
1623       --  First we add references to the primitive operations of tagged types
1624       --  declared in the main unit.
1625
1626       Handle_Prim_Ops : declare
1627          Ent  : Entity_Id;
1628
1629       begin
1630          for J in 1 .. Xrefs.Last loop
1631             Ent := Xrefs.Table (J).Key.Ent;
1632
1633             if Is_Type (Ent)
1634               and then Is_Tagged_Type (Ent)
1635               and then Is_Base_Type (Ent)
1636               and then In_Extended_Main_Source_Unit (Ent)
1637             then
1638                Generate_Prim_Op_References (Ent);
1639             end if;
1640          end loop;
1641       end Handle_Prim_Ops;
1642
1643       --  Before we go ahead and output the references we have a problem
1644       --  that needs dealing with. So far we have captured things that are
1645       --  definitely referenced by the main unit, or defined in the main
1646       --  unit. That's because we don't want to clutter up the ali file
1647       --  for this unit with definition lines for entities in other units
1648       --  that are not referenced.
1649
1650       --  But there is a glitch. We may reference an entity in another unit,
1651       --  and it may have a type reference to an entity that is not directly
1652       --  referenced in the main unit, which may mean that there is no xref
1653       --  entry for this entity yet in the list of references.
1654
1655       --  If we don't do something about this, we will end with an orphan type
1656       --  reference, i.e. it will point to an entity that does not appear
1657       --  within the generated references in the ali file. That is not good for
1658       --  tools using the xref information.
1659
1660       --  To fix this, we go through the references adding definition entries
1661       --  for any unreferenced entities that can be referenced in a type
1662       --  reference. There is a recursion problem here, and that is dealt with
1663       --  by making sure that this traversal also traverses any entries that
1664       --  get added by the traversal.
1665
1666       Handle_Orphan_Type_References : declare
1667          J    : Nat;
1668          Tref : Entity_Id;
1669          Ent  : Entity_Id;
1670
1671          L, R : Character;
1672          pragma Warnings (Off, L);
1673          pragma Warnings (Off, R);
1674
1675          procedure New_Entry (E : Entity_Id);
1676          --  Make an additional entry into the Xref table for a type entity
1677          --  that is related to the current entity (parent, type ancestor,
1678          --  progenitor, etc.).
1679
1680          ----------------
1681          -- New_Entry --
1682          ----------------
1683
1684          procedure New_Entry (E : Entity_Id) is
1685          begin
1686             pragma Assert (Present (E));
1687
1688             if not Has_Xref_Entry (Implementation_Base_Type (E))
1689               and then Sloc (E) > No_Location
1690             then
1691                Add_Entry
1692                  ((Ent       => E,
1693                    Loc       => No_Location,
1694                    Typ       => Character'First,
1695                    Eun       => Get_Source_Unit (Original_Location (Sloc (E))),
1696                    Lun       => No_Unit,
1697                    Ref_Scope => Empty,
1698                    Ent_Scope => Empty),
1699                   Ent_Scope_File => No_Unit);
1700             end if;
1701          end New_Entry;
1702
1703       --  Start of processing for Handle_Orphan_Type_References
1704
1705       begin
1706          --  Note that this is not a for loop for a very good reason. The
1707          --  processing of items in the table can add new items to the table,
1708          --  and they must be processed as well.
1709
1710          J := 1;
1711          while J <= Xrefs.Last loop
1712             Ent := Xrefs.Table (J).Key.Ent;
1713
1714             --  Do not generate reference information for an ignored Ghost
1715             --  entity because neither the entity nor its references will
1716             --  appear in the final tree.
1717
1718             if Is_Ignored_Ghost_Entity (Ent) then
1719                goto Orphan_Continue;
1720             end if;
1721
1722             Get_Type_Reference (Ent, Tref, L, R);
1723
1724             if Present (Tref)
1725               and then not Has_Xref_Entry (Tref)
1726               and then Sloc (Tref) > No_Location
1727             then
1728                New_Entry (Tref);
1729
1730                if Is_Record_Type (Ent)
1731                  and then Present (Interfaces (Ent))
1732                then
1733                   --  Add an entry for each one of the given interfaces
1734                   --  implemented by type Ent.
1735
1736                   declare
1737                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1738                   begin
1739                      while Present (Elmt) loop
1740                         New_Entry (Node (Elmt));
1741                         Next_Elmt (Elmt);
1742                      end loop;
1743                   end;
1744                end if;
1745             end if;
1746
1747             --  Collect inherited primitive operations that may be declared in
1748             --  another unit and have no visible reference in the current one.
1749
1750             if Is_Type (Ent)
1751               and then Is_Tagged_Type (Ent)
1752               and then Is_Derived_Type (Ent)
1753               and then Is_Base_Type (Ent)
1754               and then In_Extended_Main_Source_Unit (Ent)
1755             then
1756                declare
1757                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1758                   Op      : Elmt_Id;
1759                   Prim    : Entity_Id;
1760
1761                   function Parent_Op (E : Entity_Id) return Entity_Id;
1762                   --  Find original operation, which may be inherited through
1763                   --  several derivations.
1764
1765                   function Parent_Op (E : Entity_Id) return Entity_Id is
1766                      Orig_Op : constant Entity_Id := Alias (E);
1767
1768                   begin
1769                      if No (Orig_Op) then
1770                         return Empty;
1771
1772                      elsif not Comes_From_Source (E)
1773                        and then not Has_Xref_Entry (Orig_Op)
1774                        and then Comes_From_Source (Orig_Op)
1775                      then
1776                         return Orig_Op;
1777                      else
1778                         return Parent_Op (Orig_Op);
1779                      end if;
1780                   end Parent_Op;
1781
1782                begin
1783                   Op := First_Elmt (Op_List);
1784                   while Present (Op) loop
1785                      Prim := Parent_Op (Node (Op));
1786
1787                      if Present (Prim) then
1788                         Add_Entry
1789                           ((Ent       => Prim,
1790                             Loc       => No_Location,
1791                             Typ       => Character'First,
1792                             Eun       => Get_Source_Unit (Sloc (Prim)),
1793                             Lun       => No_Unit,
1794                             Ref_Scope => Empty,
1795                             Ent_Scope => Empty),
1796                            Ent_Scope_File => No_Unit);
1797                      end if;
1798
1799                      Next_Elmt (Op);
1800                   end loop;
1801                end;
1802             end if;
1803
1804             <<Orphan_Continue>>
1805             J := J + 1;
1806          end loop;
1807       end Handle_Orphan_Type_References;
1808
1809       --  Now we have all the references, including those for any embedded type
1810       --  references, so we can sort them, and output them.
1811
1812       Output_Refs : declare
1813          Nrefs : constant Nat := Xrefs.Last;
1814          --  Number of references in table
1815
1816          Rnums : array (0 .. Nrefs) of Nat;
1817          --  This array contains numbers of references in the Xrefs table.
1818          --  This list is sorted in output order. The extra 0'th entry is
1819          --  convenient for the call to sort. When we sort the table, we
1820          --  move the entries in Rnums around, but we do not move the
1821          --  original table entries.
1822
1823          Curxu : Unit_Number_Type;
1824          --  Current xref unit
1825
1826          Curru : Unit_Number_Type;
1827          --  Current reference unit for one entity
1828
1829          Curent : Entity_Id;
1830          --  Current entity
1831
1832          Curnam : String (1 .. Name_Buffer'Length);
1833          Curlen : Natural;
1834          --  Simple name and length of current entity
1835
1836          Curdef : Source_Ptr;
1837          --  Original source location for current entity
1838
1839          Crloc : Source_Ptr;
1840          --  Current reference location
1841
1842          Ctyp : Character;
1843          --  Entity type character
1844
1845          Prevt : Character;
1846          --  reference kind of previous reference
1847
1848          Tref : Entity_Id;
1849          --  Type reference
1850
1851          Rref : Node_Id;
1852          --  Renaming reference
1853
1854          Trunit : Unit_Number_Type;
1855          --  Unit number for type reference
1856
1857          function Lt (Op1, Op2 : Natural) return Boolean;
1858          --  Comparison function for Sort call
1859
1860          function Name_Change (X : Entity_Id) return Boolean;
1861          --  Determines if entity X has a different simple name from Curent
1862
1863          procedure Move (From : Natural; To : Natural);
1864          --  Move procedure for Sort call
1865
1866          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1867
1868          --------
1869          -- Lt --
1870          --------
1871
1872          function Lt (Op1, Op2 : Natural) return Boolean is
1873             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1874             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1875
1876          begin
1877             return Lt (T1, T2);
1878          end Lt;
1879
1880          ----------
1881          -- Move --
1882          ----------
1883
1884          procedure Move (From : Natural; To : Natural) is
1885          begin
1886             Rnums (Nat (To)) := Rnums (Nat (From));
1887          end Move;
1888
1889          -----------------
1890          -- Name_Change --
1891          -----------------
1892
1893          --  Why a string comparison here??? Why not compare Name_Id values???
1894
1895          function Name_Change (X : Entity_Id) return Boolean is
1896          begin
1897             Get_Unqualified_Name_String (Chars (X));
1898
1899             if Name_Len /= Curlen then
1900                return True;
1901             else
1902                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1903             end if;
1904          end Name_Change;
1905
1906       --  Start of processing for Output_Refs
1907
1908       begin
1909          --  Capture the definition Sloc values. We delay doing this till now,
1910          --  since at the time the reference or definition is made, private
1911          --  types may be swapped, and the Sloc value may be incorrect. We
1912          --  also set up the pointer vector for the sort.
1913
1914          --  For user-defined operators we need to skip the initial quote and
1915          --  point to the first character of the name, for navigation purposes.
1916
1917          for J in 1 .. Nrefs loop
1918             declare
1919                E   : constant Entity_Id  := Xrefs.Table (J).Key.Ent;
1920                Loc : constant Source_Ptr := Original_Location (Sloc (E));
1921
1922             begin
1923                Rnums (J) := J;
1924
1925                if Nkind (E) = N_Defining_Operator_Symbol then
1926                   Xrefs.Table (J).Def := Loc + 1;
1927                else
1928                   Xrefs.Table (J).Def := Loc;
1929                end if;
1930             end;
1931          end loop;
1932
1933          --  Sort the references
1934
1935          Sorting.Sort (Integer (Nrefs));
1936
1937          --  Initialize loop through references
1938
1939          Curxu  := No_Unit;
1940          Curent := Empty;
1941          Curdef := No_Location;
1942          Curru  := No_Unit;
1943          Crloc  := No_Location;
1944          Prevt  := 'm';
1945
1946          --  Loop to output references
1947
1948          for Refno in 1 .. Nrefs loop
1949             Output_One_Ref : declare
1950                Ent : Entity_Id;
1951
1952                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1953                --  The current entry to be accessed
1954
1955                Left  : Character;
1956                Right : Character;
1957                --  Used for {} or <> or () for type reference
1958
1959                procedure Check_Type_Reference
1960                  (Ent            : Entity_Id;
1961                   List_Interface : Boolean;
1962                   Is_Component   : Boolean := False);
1963                --  Find whether there is a meaningful type reference for
1964                --  Ent, and display it accordingly. If List_Interface is
1965                --  true, then Ent is a progenitor interface of the current
1966                --  type entity being listed. In that case list it as is,
1967                --  without looking for a type reference for it. Flag is also
1968                --  used for index types of an array type, where the caller
1969                --  supplies the intended type reference. Is_Component serves
1970                --  the same purpose, to display the component type of a
1971                --  derived array type, for which only the parent type has
1972                --  ben displayed so far.
1973
1974                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1975                --  Recursive procedure to output instantiation references for
1976                --  the given source ptr in [file|line[...]] form. No output
1977                --  if the given location is not a generic template reference.
1978
1979                procedure Output_Overridden_Op (Old_E : Entity_Id);
1980                --  For a subprogram that is overriding, display information
1981                --  about the inherited operation that it overrides.
1982
1983                --------------------------
1984                -- Check_Type_Reference --
1985                --------------------------
1986
1987                procedure Check_Type_Reference
1988                  (Ent            : Entity_Id;
1989                   List_Interface : Boolean;
1990                   Is_Component   : Boolean := False)
1991                is
1992                begin
1993                   if List_Interface then
1994
1995                      --  This is a progenitor interface of the type for which
1996                      --  xref information is being generated.
1997
1998                      Tref  := Ent;
1999                      Left  := '<';
2000                      Right := '>';
2001
2002                   --  The following is not documented in lib-xref.ads ???
2003
2004                   elsif Is_Component then
2005                      Tref  := Ent;
2006                      Left  := '(';
2007                      Right := ')';
2008
2009                   else
2010                      Get_Type_Reference (Ent, Tref, Left, Right);
2011                   end if;
2012
2013                   if Present (Tref) then
2014
2015                      --  Case of standard entity, output name
2016
2017                      if Sloc (Tref) = Standard_Location then
2018                         Write_Info_Char (Left);
2019                         Write_Info_Name (Chars (Tref));
2020                         Write_Info_Char (Right);
2021
2022                      --  Case of source entity, output location
2023
2024                      else
2025                         Write_Info_Char (Left);
2026                         Trunit := Get_Source_Unit (Sloc (Tref));
2027
2028                         if Trunit /= Curxu then
2029                            Write_Info_Nat (Dependency_Num (Trunit));
2030                            Write_Info_Char ('|');
2031                         end if;
2032
2033                         Write_Info_Nat
2034                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
2035
2036                         declare
2037                            Ent  : Entity_Id;
2038                            Ctyp : Character;
2039
2040                         begin
2041                            Ent := Tref;
2042                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
2043
2044                            if Ctyp = '+'
2045                              and then Present (Full_View (Ent))
2046                            then
2047                               Ent := Underlying_Type (Ent);
2048
2049                               if Present (Ent) then
2050                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
2051                               end if;
2052                            end if;
2053
2054                            Write_Info_Char (Ctyp);
2055                         end;
2056
2057                         Write_Info_Nat
2058                           (Int (Get_Column_Number (Sloc (Tref))));
2059
2060                         --  If the type comes from an instantiation, add the
2061                         --  corresponding info.
2062
2063                         Output_Instantiation_Refs (Sloc (Tref));
2064                         Write_Info_Char (Right);
2065                      end if;
2066                   end if;
2067                end Check_Type_Reference;
2068
2069                -------------------------------
2070                -- Output_Instantiation_Refs --
2071                -------------------------------
2072
2073                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
2074                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
2075                   Lun  : Unit_Number_Type;
2076                   Cu   : constant Unit_Number_Type := Curru;
2077
2078                begin
2079                   --  Nothing to do if this is not an instantiation
2080
2081                   if Iloc = No_Location then
2082                      return;
2083                   end if;
2084
2085                   --  Output instantiation reference
2086
2087                   Write_Info_Char ('[');
2088                   Lun := Get_Source_Unit (Iloc);
2089
2090                   if Lun /= Curru then
2091                      Curru := Lun;
2092                      Write_Info_Nat (Dependency_Num (Curru));
2093                      Write_Info_Char ('|');
2094                   end if;
2095
2096                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
2097
2098                   --  Recursive call to get nested instantiations
2099
2100                   Output_Instantiation_Refs (Iloc);
2101
2102                   --  Output final ] after call to get proper nesting
2103
2104                   Write_Info_Char (']');
2105                   Curru := Cu;
2106                   return;
2107                end Output_Instantiation_Refs;
2108
2109                --------------------------
2110                -- Output_Overridden_Op --
2111                --------------------------
2112
2113                procedure Output_Overridden_Op (Old_E : Entity_Id) is
2114                   Op : Entity_Id;
2115
2116                begin
2117                   --  The overridden operation has an implicit declaration
2118                   --  at the point of derivation. What we want to display
2119                   --  is the original operation, which has the actual body
2120                   --  (or abstract declaration) that is being overridden.
2121                   --  The overridden operation is not always set, e.g. when
2122                   --  it is a predefined operator.
2123
2124                   if No (Old_E) then
2125                      return;
2126
2127                   --  Follow alias chain if one is present
2128
2129                   elsif Present (Alias (Old_E)) then
2130
2131                      --  The subprogram may have been implicitly inherited
2132                      --  through several levels of derivation, so find the
2133                      --  ultimate (source) ancestor.
2134
2135                      Op := Ultimate_Alias (Old_E);
2136
2137                   --  Normal case of no alias present. We omit generated
2138                   --  primitives like tagged equality, that have no source
2139                   --  representation.
2140
2141                   else
2142                      Op := Old_E;
2143                   end if;
2144
2145                   if Present (Op)
2146                     and then Sloc (Op) /= Standard_Location
2147                     and then Comes_From_Source (Op)
2148                   then
2149                      declare
2150                         Loc      : constant Source_Ptr := Sloc (Op);
2151                         Par_Unit : constant Unit_Number_Type :=
2152                                      Get_Source_Unit (Loc);
2153
2154                      begin
2155                         Write_Info_Char ('<');
2156
2157                         if Par_Unit /= Curxu then
2158                            Write_Info_Nat (Dependency_Num (Par_Unit));
2159                            Write_Info_Char ('|');
2160                         end if;
2161
2162                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
2163                         Write_Info_Char ('p');
2164                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
2165                         Write_Info_Char ('>');
2166                      end;
2167                   end if;
2168                end Output_Overridden_Op;
2169
2170             --  Start of processing for Output_One_Ref
2171
2172             begin
2173                Ent := XE.Key.Ent;
2174
2175                --  Do not generate reference information for an ignored Ghost
2176                --  entity because neither the entity nor its references will
2177                --  appear in the final tree.
2178
2179                if Is_Ignored_Ghost_Entity (Ent) then
2180                   goto Continue;
2181                end if;
2182
2183                Ctyp := Xref_Entity_Letters (Ekind (Ent));
2184
2185                --  Skip reference if it is the only reference to an entity,
2186                --  and it is an END line reference, and the entity is not in
2187                --  the current extended source. This prevents junk entries
2188                --  consisting only of packages with END lines, where no
2189                --  entity from the package is actually referenced.
2190
2191                if XE.Key.Typ = 'e'
2192                  and then Ent /= Curent
2193                  and then (Refno = Nrefs
2194                             or else
2195                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
2196                  and then not In_Extended_Main_Source_Unit (Ent)
2197                then
2198                   goto Continue;
2199                end if;
2200
2201                --  For private type, get full view type
2202
2203                if Ctyp = '+'
2204                  and then Present (Full_View (XE.Key.Ent))
2205                then
2206                   Ent := Underlying_Type (Ent);
2207
2208                   if Present (Ent) then
2209                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
2210                   end if;
2211                end if;
2212
2213                --  Special exception for Boolean
2214
2215                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
2216                   Ctyp := 'B';
2217                end if;
2218
2219                --  For variable reference, get corresponding type
2220
2221                if Ctyp = '*' then
2222                   Ent := Etype (XE.Key.Ent);
2223                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2224
2225                   --  If variable is private type, get full view type
2226
2227                   if Ctyp = '+'
2228                     and then Present (Full_View (Etype (XE.Key.Ent)))
2229                   then
2230                      Ent := Underlying_Type (Etype (XE.Key.Ent));
2231
2232                      if Present (Ent) then
2233                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2234                      end if;
2235
2236                   elsif Is_Generic_Type (Ent) then
2237
2238                      --  If the type of the entity is a generic private type,
2239                      --  there is no usable full view, so retain the indication
2240                      --  that this is an object.
2241
2242                      Ctyp := '*';
2243                   end if;
2244
2245                   --  Special handling for access parameters and objects and
2246                   --  components of an anonymous access type.
2247
2248                   if Ekind_In (Etype (XE.Key.Ent),
2249                                E_Anonymous_Access_Type,
2250                                E_Anonymous_Access_Subprogram_Type,
2251                                E_Anonymous_Access_Protected_Subprogram_Type)
2252                   then
2253                      if Is_Formal (XE.Key.Ent)
2254                        or else
2255                          Ekind_In
2256                            (XE.Key.Ent, E_Variable, E_Constant, E_Component)
2257                      then
2258                         Ctyp := 'p';
2259                      end if;
2260
2261                      --  Special handling for Boolean
2262
2263                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
2264                      Ctyp := 'b';
2265                   end if;
2266                end if;
2267
2268                --  Special handling for abstract types and operations
2269
2270                if Is_Overloadable (XE.Key.Ent)
2271                  and then Is_Abstract_Subprogram (XE.Key.Ent)
2272                then
2273                   if Ctyp = 'U' then
2274                      Ctyp := 'x';            --  Abstract procedure
2275
2276                   elsif Ctyp = 'V' then
2277                      Ctyp := 'y';            --  Abstract function
2278                   end if;
2279
2280                elsif Is_Type (XE.Key.Ent)
2281                  and then Is_Abstract_Type (XE.Key.Ent)
2282                then
2283                   if Is_Interface (XE.Key.Ent) then
2284                      Ctyp := 'h';
2285
2286                   elsif Ctyp = 'R' then
2287                      Ctyp := 'H';            --  Abstract type
2288                   end if;
2289                end if;
2290
2291                --  Only output reference if interesting type of entity
2292
2293                if Ctyp = ' '
2294
2295                --  Suppress references to object definitions, used for local
2296                --  references.
2297
2298                  or else XE.Key.Typ = 'D'
2299                  or else XE.Key.Typ = 'I'
2300
2301                --  Suppress self references, except for bodies that act as
2302                --  specs.
2303
2304                  or else (XE.Key.Loc = XE.Def
2305                            and then
2306                              (XE.Key.Typ /= 'b'
2307                                or else not Is_Subprogram (XE.Key.Ent)))
2308
2309                --  Also suppress definitions of body formals (we only
2310                --  treat these as references, and the references were
2311                --  separately recorded).
2312
2313                  or else (Is_Formal (XE.Key.Ent)
2314                            and then Present (Spec_Entity (XE.Key.Ent)))
2315                then
2316                   null;
2317
2318                else
2319                   --  Start new Xref section if new xref unit
2320
2321                   if XE.Key.Eun /= Curxu then
2322                      if Write_Info_Col > 1 then
2323                         Write_Info_EOL;
2324                      end if;
2325
2326                      Curxu := XE.Key.Eun;
2327
2328                      Write_Info_Initiate ('X');
2329                      Write_Info_Char (' ');
2330                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2331                      Write_Info_Char (' ');
2332                      Write_Info_Name
2333                        (Reference_Name (Source_Index (XE.Key.Eun)));
2334                   end if;
2335
2336                   --  Start new Entity line if new entity. Note that we
2337                   --  consider two entities the same if they have the same
2338                   --  name and source location. This causes entities in
2339                   --  instantiations to be treated as though they referred
2340                   --  to the template.
2341
2342                   if No (Curent)
2343                     or else
2344                       (XE.Key.Ent /= Curent
2345                          and then
2346                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2347                   then
2348                      Curent := XE.Key.Ent;
2349                      Curdef := XE.Def;
2350
2351                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2352                      Curlen := Name_Len;
2353                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2354
2355                      if Write_Info_Col > 1 then
2356                         Write_Info_EOL;
2357                      end if;
2358
2359                      --  Write column number information
2360
2361                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2362                      Write_Info_Char (Ctyp);
2363                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2364
2365                      --  Write level information
2366
2367                      Write_Level_Info : declare
2368                         function Is_Visible_Generic_Entity
2369                           (E : Entity_Id) return Boolean;
2370                         --  Check whether E is declared in the visible part
2371                         --  of a generic package. For source navigation
2372                         --  purposes, treat this as a visible entity.
2373
2374                         function Is_Private_Record_Component
2375                           (E : Entity_Id) return Boolean;
2376                         --  Check whether E is a non-inherited component of a
2377                         --  private extension. Even if the enclosing record is
2378                         --  public, we want to treat the component as private
2379                         --  for navigation purposes.
2380
2381                         ---------------------------------
2382                         -- Is_Private_Record_Component --
2383                         ---------------------------------
2384
2385                         function Is_Private_Record_Component
2386                           (E : Entity_Id) return Boolean
2387                         is
2388                            S : constant Entity_Id := Scope (E);
2389                         begin
2390                            return
2391                              Ekind (E) = E_Component
2392                                and then Nkind (Declaration_Node (S)) =
2393                                  N_Private_Extension_Declaration
2394                                and then Original_Record_Component (E) = E;
2395                         end Is_Private_Record_Component;
2396
2397                         -------------------------------
2398                         -- Is_Visible_Generic_Entity --
2399                         -------------------------------
2400
2401                         function Is_Visible_Generic_Entity
2402                           (E : Entity_Id) return Boolean
2403                         is
2404                            Par : Node_Id;
2405
2406                         begin
2407                            --  The Present check here is an error defense
2408
2409                            if Present (Scope (E))
2410                              and then Ekind (Scope (E)) /= E_Generic_Package
2411                            then
2412                               return False;
2413                            end if;
2414
2415                            Par := Parent (E);
2416                            while Present (Par) loop
2417                               if
2418                                 Nkind (Par) = N_Generic_Package_Declaration
2419                               then
2420                                  --  Entity is a generic formal
2421
2422                                  return False;
2423
2424                               elsif
2425                                 Nkind (Parent (Par)) = N_Package_Specification
2426                               then
2427                                  return
2428                                    Is_List_Member (Par)
2429                                      and then List_Containing (Par) =
2430                                        Visible_Declarations (Parent (Par));
2431                               else
2432                                  Par := Parent (Par);
2433                               end if;
2434                            end loop;
2435
2436                            return False;
2437                         end Is_Visible_Generic_Entity;
2438
2439                      --  Start of processing for Write_Level_Info
2440
2441                      begin
2442                         if Is_Hidden (Curent)
2443                           or else Is_Private_Record_Component (Curent)
2444                         then
2445                            Write_Info_Char (' ');
2446
2447                         elsif
2448                            Is_Public (Curent)
2449                              or else Is_Visible_Generic_Entity (Curent)
2450                         then
2451                            Write_Info_Char ('*');
2452
2453                         else
2454                            Write_Info_Char (' ');
2455                         end if;
2456                      end Write_Level_Info;
2457
2458                      --  Output entity name. We use the occurrence from the
2459                      --  actual source program at the definition point.
2460
2461                      declare
2462                         Ent_Name : constant String :=
2463                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2464                      begin
2465                         for C in Ent_Name'Range loop
2466                            Write_Info_Char (Ent_Name (C));
2467                         end loop;
2468                      end;
2469
2470                      --  See if we have a renaming reference
2471
2472                      if Is_Object (XE.Key.Ent)
2473                        and then Present (Renamed_Object (XE.Key.Ent))
2474                      then
2475                         Rref := Renamed_Object (XE.Key.Ent);
2476
2477                      elsif Is_Overloadable (XE.Key.Ent)
2478                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2479                                            = N_Subprogram_Renaming_Declaration
2480                      then
2481                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2482
2483                      elsif Ekind (XE.Key.Ent) = E_Package
2484                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2485                                          N_Package_Renaming_Declaration
2486                      then
2487                         Rref := Name (Declaration_Node (XE.Key.Ent));
2488
2489                      else
2490                         Rref := Empty;
2491                      end if;
2492
2493                      if Present (Rref) then
2494                         if Nkind (Rref) = N_Expanded_Name then
2495                            Rref := Selector_Name (Rref);
2496                         end if;
2497
2498                         if Nkind (Rref) = N_Identifier
2499                           or else Nkind (Rref) = N_Operator_Symbol
2500                         then
2501                            null;
2502
2503                         --  For renamed array components, use the array name
2504                         --  for the renamed entity, which reflect the fact that
2505                         --  in general the whole array is aliased.
2506
2507                         elsif Nkind (Rref) = N_Indexed_Component then
2508                            if Nkind (Prefix (Rref)) = N_Identifier then
2509                               Rref := Prefix (Rref);
2510                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2511                               Rref := Selector_Name (Prefix (Rref));
2512                            else
2513                               Rref := Empty;
2514                            end if;
2515
2516                         else
2517                            Rref := Empty;
2518                         end if;
2519                      end if;
2520
2521                      --  Write out renaming reference if we have one
2522
2523                      if Present (Rref) then
2524                         Write_Info_Char ('=');
2525                         Write_Info_Nat
2526                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2527                         Write_Info_Char (':');
2528                         Write_Info_Nat
2529                           (Int (Get_Column_Number (Sloc (Rref))));
2530                      end if;
2531
2532                      --  Indicate that the entity is in the unit of the current
2533                      --  xref section.
2534
2535                      Curru := Curxu;
2536
2537                      --  Write out information about generic parent, if entity
2538                      --  is an instance.
2539
2540                      if Is_Generic_Instance (XE.Key.Ent) then
2541                         declare
2542                            Gen_Par : constant Entity_Id :=
2543                                        Generic_Parent
2544                                          (Specification
2545                                             (Unit_Declaration_Node
2546                                                (XE.Key.Ent)));
2547                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2548                            Gen_U   : constant Unit_Number_Type :=
2549                                        Get_Source_Unit (Loc);
2550
2551                         begin
2552                            Write_Info_Char ('[');
2553
2554                            if Curru /= Gen_U then
2555                               Write_Info_Nat (Dependency_Num (Gen_U));
2556                               Write_Info_Char ('|');
2557                            end if;
2558
2559                            Write_Info_Nat
2560                              (Int (Get_Logical_Line_Number (Loc)));
2561                            Write_Info_Char (']');
2562                         end;
2563                      end if;
2564
2565                      --  See if we have a type reference and if so output
2566
2567                      Check_Type_Reference (XE.Key.Ent, False);
2568
2569                      --  Additional information for types with progenitors,
2570                      --  including synchronized tagged types.
2571
2572                      declare
2573                         Typ  : constant Entity_Id := XE.Key.Ent;
2574                         Elmt : Elmt_Id;
2575
2576                      begin
2577                         if Is_Record_Type (Typ)
2578                           and then Present (Interfaces (Typ))
2579                         then
2580                            Elmt := First_Elmt (Interfaces (Typ));
2581
2582                         elsif Is_Concurrent_Type (Typ)
2583                           and then Present (Corresponding_Record_Type (Typ))
2584                           and then Present (
2585                             Interfaces (Corresponding_Record_Type (Typ)))
2586                         then
2587                            Elmt :=
2588                              First_Elmt (
2589                               Interfaces (Corresponding_Record_Type (Typ)));
2590
2591                         else
2592                            Elmt := No_Elmt;
2593                         end if;
2594
2595                         while Present (Elmt) loop
2596                            Check_Type_Reference (Node (Elmt), True);
2597                            Next_Elmt (Elmt);
2598                         end loop;
2599                      end;
2600
2601                      --  For array types, list index types as well. (This is
2602                      --  not C, indexes have distinct types).
2603
2604                      if Is_Array_Type (XE.Key.Ent) then
2605                         declare
2606                            A_Typ : constant Entity_Id := XE.Key.Ent;
2607                            Indx : Node_Id;
2608
2609                         begin
2610                            --  If this is a derived array type, we have
2611                            --  output the parent type, so add the component
2612                            --  type now.
2613
2614                            if Is_Derived_Type (A_Typ) then
2615                               Check_Type_Reference
2616                                 (Component_Type (A_Typ), False, True);
2617                            end if;
2618
2619                            --  Add references to index types.
2620
2621                            Indx := First_Index (XE.Key.Ent);
2622                            while Present (Indx) loop
2623                               Check_Type_Reference
2624                                 (First_Subtype (Etype (Indx)), True);
2625                               Next_Index (Indx);
2626                            end loop;
2627                         end;
2628                      end if;
2629
2630                      --  If the entity is an overriding operation, write info
2631                      --  on operation that was overridden.
2632
2633                      if Is_Subprogram (XE.Key.Ent)
2634                        and then Present (Overridden_Operation (XE.Key.Ent))
2635                      then
2636                         Output_Overridden_Op
2637                           (Overridden_Operation (XE.Key.Ent));
2638                      end if;
2639
2640                      --  End of processing for entity output
2641
2642                      Crloc := No_Location;
2643                   end if;
2644
2645                   --  Output the reference if it is not as the same location
2646                   --  as the previous one, or it is a read-reference that
2647                   --  indicates that the entity is an in-out actual in a call.
2648
2649                   if XE.Key.Loc /= No_Location
2650                     and then
2651                       (XE.Key.Loc /= Crloc
2652                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2653                   then
2654                      Crloc := XE.Key.Loc;
2655                      Prevt := XE.Key.Typ;
2656
2657                      --  Start continuation if line full, else blank
2658
2659                      if Write_Info_Col > 72 then
2660                         Write_Info_EOL;
2661                         Write_Info_Initiate ('.');
2662                      end if;
2663
2664                      Write_Info_Char (' ');
2665
2666                      --  Output file number if changed
2667
2668                      if XE.Key.Lun /= Curru then
2669                         Curru := XE.Key.Lun;
2670                         Write_Info_Nat (Dependency_Num (Curru));
2671                         Write_Info_Char ('|');
2672                      end if;
2673
2674                      Write_Info_Nat
2675                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2676                      Write_Info_Char (XE.Key.Typ);
2677
2678                      if Is_Overloadable (XE.Key.Ent) then
2679                         if (Is_Imported (XE.Key.Ent) and then XE.Key.Typ = 'b')
2680                              or else
2681                            (Is_Exported (XE.Key.Ent) and then XE.Key.Typ = 'i')
2682                         then
2683                            Output_Import_Export_Info (XE.Key.Ent);
2684                         end if;
2685                      end if;
2686
2687                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2688
2689                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2690                   end if;
2691                end if;
2692             end Output_One_Ref;
2693
2694          <<Continue>>
2695             null;
2696          end loop;
2697
2698          Write_Info_EOL;
2699       end Output_Refs;
2700    end Output_References;
2701
2702    ---------------------------------
2703    -- Process_Deferred_References --
2704    ---------------------------------
2705
2706    procedure Process_Deferred_References is
2707    begin
2708       for J in Deferred_References.First .. Deferred_References.Last loop
2709          declare
2710             D : Deferred_Reference_Entry renames Deferred_References.Table (J);
2711
2712          begin
2713             case Is_LHS (D.N) is
2714                when Yes =>
2715                   Generate_Reference (D.E, D.N, 'm');
2716
2717                when No =>
2718                   Generate_Reference (D.E, D.N, 'r');
2719
2720                --  Not clear if Unknown can occur at this stage, but if it
2721                --  does we will treat it as a normal reference.
2722
2723                when Unknown =>
2724                   Generate_Reference (D.E, D.N, 'r');
2725             end case;
2726          end;
2727       end loop;
2728
2729       --  Clear processed entries from table
2730
2731       Deferred_References.Init;
2732    end Process_Deferred_References;
2733
2734 --  Start of elaboration for Lib.Xref
2735
2736 begin
2737    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2738    --  because it's not an access type.
2739
2740    Xref_Set.Reset;
2741 end Lib.Xref;