gcc/ada/back_end.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            B A C K _ E N D                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;     use Atree;
  27 with Debug;     use Debug;
  28 with Elists;    use Elists;
  29 with Errout;    use Errout;
  30 with Lib;       use Lib;
  31 with Osint;     use Osint;
  32 with Opt;       use Opt;
  33 with Osint.C;   use Osint.C;
  34 with Namet;     use Namet;
  35 with Nlists;    use Nlists;
  36 with Stand;     use Stand;
  37 with Sinput;    use Sinput;
  38 with Stringt;   use Stringt;
  39 with Switch;    use Switch;
  40 with Switch.C;  use Switch.C;
  41 with System;    use System;
  42 with Types;     use Types;
  43
  44 with System.OS_Lib; use System.OS_Lib;
  45
  46 package body Back_End is
  47
  48    type Arg_Array is array (Nat) of Big_String_Ptr;
  49    type Arg_Array_Ptr is access Arg_Array;
  50    --  Types to access compiler arguments
  51
  52    flag_stack_check : Int;
  53    pragma Import (C, flag_stack_check);
  54    --  Indicates if stack checking is enabled, imported from misc.c
  55
  56    save_argc : Nat;
  57    pragma Import (C, save_argc);
  58    --  Saved value of argc (number of arguments), imported from misc.c
  59
  60    save_argv : Arg_Array_Ptr;
  61    pragma Import (C, save_argv);
  62    --  Saved value of argv (argument pointers), imported from misc.c
  63
  64    function Len_Arg (Arg : Pos) return Nat;
  65    --  Determine length of argument number Arg on original gnat1 command line
  66
  67    -------------------
  68    -- Call_Back_End --
  69    -------------------
  70
  71    procedure Call_Back_End (Mode : Back_End_Mode_Type) is
  72
  73       --  The Source_File_Record type has a lot of components that are
  74       --  meaningless to the back end, so a new record type is created
  75       --  here to contain the needed information for each file.
  76
  77       type File_Info_Type is record
  78          File_Name        : File_Name_Type;
  79          Instance         : Instance_Id;
  80          Num_Source_Lines : Nat;
  81       end record;
  82
  83       File_Info_Array : array (1 .. Last_Source_File) of File_Info_Type;
  84
  85       procedure gigi
  86         (gnat_root                     : Int;
  87          max_gnat_node                 : Int;
  88          number_name                   : Nat;
  89          nodes_ptr                     : Address;
  90          flags_ptr                     : Address;
  91
  92          next_node_ptr                 : Address;
  93          prev_node_ptr                 : Address;
  94          elists_ptr                    : Address;
  95          elmts_ptr                     : Address;
  96
  97          strings_ptr                   : Address;
  98          string_chars_ptr              : Address;
  99          list_headers_ptr              : Address;
 100          number_file                   : Nat;
 101
 102          file_info_ptr                 : Address;
 103          gigi_standard_boolean         : Entity_Id;
 104          gigi_standard_integer         : Entity_Id;
 105          gigi_standard_character       : Entity_Id;
 106          gigi_standard_long_long_float : Entity_Id;
 107          gigi_standard_exception_type  : Entity_Id;
 108          gigi_operating_mode           : Back_End_Mode_Type);
 109
 110       pragma Import (C, gigi);
 111
 112    begin
 113       --  Skip call if in -gnatdH mode
 114
 115       if Debug_Flag_HH then
 116          return;
 117       end if;
 118
 119       --  The back end needs to know the maximum line number that can appear
 120       --  in a Sloc, in other words the maximum logical line number.
 121
 122       for J in 1 .. Last_Source_File loop
 123          File_Info_Array (J).File_Name        := Full_Debug_Name (J);
 124          File_Info_Array (J).Instance         := Instance (J);
 125          File_Info_Array (J).Num_Source_Lines :=
 126            Nat (Physical_To_Logical (Last_Source_Line (J), J));
 127       end loop;
 128
 129       if Generate_SCIL then
 130          Error_Msg_N ("'S'C'I'L generation not available", Cunit (Main_Unit));
 131
 132          if CodePeer_Mode
 133            or else (Mode /= Generate_Object
 134                      and then not Back_Annotate_Rep_Info)
 135          then
 136             return;
 137          end if;
 138       end if;
 139
 140       gigi
 141         (gnat_root          => Int (Cunit (Main_Unit)),
 142          max_gnat_node      => Int (Last_Node_Id - First_Node_Id + 1),
 143          number_name        => Name_Entries_Count,
 144          nodes_ptr          => Nodes_Address,
 145          flags_ptr          => Flags_Address,
 146
 147          next_node_ptr      => Next_Node_Address,
 148          prev_node_ptr      => Prev_Node_Address,
 149          elists_ptr         => Elists_Address,
 150          elmts_ptr          => Elmts_Address,
 151
 152          strings_ptr        => Strings_Address,
 153          string_chars_ptr   => String_Chars_Address,
 154          list_headers_ptr   => Lists_Address,
 155          number_file        => Num_Source_Files,
 156
 157          file_info_ptr                 => File_Info_Array'Address,
 158          gigi_standard_boolean         => Standard_Boolean,
 159          gigi_standard_integer         => Standard_Integer,
 160          gigi_standard_character       => Standard_Character,
 161          gigi_standard_long_long_float => Standard_Long_Long_Float,
 162          gigi_standard_exception_type  => Standard_Exception_Type,
 163          gigi_operating_mode           => Mode);
 164    end Call_Back_End;
 165
 166    -------------
 167    -- Len_Arg --
 168    -------------
 169
 170    function Len_Arg (Arg : Pos) return Nat is
 171    begin
 172       for J in 1 .. Nat'Last loop
 173          if save_argv (Arg).all (Natural (J)) = ASCII.NUL then
 174             return J - 1;
 175          end if;
 176       end loop;
 177
 178       raise Program_Error;
 179    end Len_Arg;
 180
 181    -----------------------------
 182    -- Scan_Compiler_Arguments --
 183    -----------------------------
 184
 185    procedure Scan_Compiler_Arguments is
 186       Next_Arg : Positive;
 187       --  Next argument to be scanned
 188
 189       Output_File_Name_Seen : Boolean := False;
 190       --  Set to True after having scanned file_name for switch "-gnatO file"
 191
 192       procedure Scan_Back_End_Switches (Switch_Chars : String);
 193       --  Procedure to scan out switches stored in Switch_Chars. The first
 194       --  character is known to be a valid switch character, and there are no
 195       --  blanks or other switch terminator characters in the string, so the
 196       --  entire string should consist of valid switch characters, except that
 197       --  an optional terminating NUL character is allowed.
 198       --
 199       --  Back end switches have already been checked and processed by GCC in
 200       --  toplev.c, so no errors can occur and control will always return. The
 201       --  switches must still be scanned to skip "-o" or internal GCC switches
 202       --  with their argument.
 203
 204       ----------------------------
 205       -- Scan_Back_End_Switches --
 206       ----------------------------
 207
 208       procedure Scan_Back_End_Switches (Switch_Chars : String) is
 209          First : constant Positive := Switch_Chars'First + 1;
 210          Last  : constant Natural  := Switch_Last (Switch_Chars);
 211
 212       begin
 213          --  Skip -o or internal GCC switches together with their argument
 214
 215          if Switch_Chars (First .. Last) = "o"
 216            or else Is_Internal_GCC_Switch (Switch_Chars)
 217          then
 218             Next_Arg := Next_Arg + 1;
 219
 220          --  Do not record -quiet switch
 221
 222          elsif Switch_Chars (First .. Last) = "quiet" then
 223             null;
 224
 225          --  Store any other GCC switches. Also do special processing for some
 226          --  specific switches that the Ada front-end knows about.
 227
 228          else
 229             Store_Compilation_Switch (Switch_Chars);
 230
 231             --  Back end switch -fno-inline also sets the Suppress_All_Inlining
 232             --  front end flag to entirely inhibit all inlining.
 233
 234             if Switch_Chars (First .. Last) = "fno-inline" then
 235                Opt.Suppress_All_Inlining := True;
 236
 237             --  Back end switch -fpreserve-control-flow also sets the front end
 238             --  flag that inhibits improper control flow transformations.
 239
 240             elsif Switch_Chars (First .. Last) = "fpreserve-control-flow" then
 241                Opt.Suppress_Control_Flow_Optimizations := True;
 242
 243             --  Back end switch -fdump-scos, which exists primarily for C, is
 244             --  also accepted for Ada as a synonym of -gnateS.
 245
 246             elsif Switch_Chars (First .. Last) = "fdump-scos" then
 247                Opt.Generate_SCO := True;
 248                Opt.Generate_SCO_Instance_Table := True;
 249             end if;
 250          end if;
 251       end Scan_Back_End_Switches;
 252
 253       --  Local variables
 254
 255       Arg_Count : constant Natural := Natural (save_argc - 1);
 256       Args      : Argument_List (1 .. Arg_Count);
 257
 258    --  Start of processing for Scan_Compiler_Arguments
 259
 260    begin
 261       --  Acquire stack checking mode directly from GCC. The reason we do this
 262       --  is to make sure that the indication of stack checking being enabled
 263       --  is the same in the front end and the back end. This status obtained
 264       --  from gcc is affected by more than just the switch -fstack-check.
 265
 266       Opt.Stack_Checking_Enabled := (flag_stack_check /= 0);
 267
 268       --  Put the arguments in Args
 269
 270       for Arg in Pos range 1 .. save_argc - 1 loop
 271          declare
 272             Argv_Ptr : constant Big_String_Ptr := save_argv (Arg);
 273             Argv_Len : constant Nat            := Len_Arg (Arg);
 274             Argv     : constant String         :=
 275                          Argv_Ptr (1 .. Natural (Argv_Len));
 276          begin
 277             Args (Positive (Arg)) := new String'(Argv);
 278          end;
 279       end loop;
 280
 281       --  Loop through command line arguments, storing them for later access
 282
 283       Next_Arg := 1;
 284       while Next_Arg <= Args'Last loop
 285          Look_At_Arg : declare
 286             Argv : constant String := Args (Next_Arg).all;
 287
 288          begin
 289             --  If the previous switch has set the Output_File_Name_Present
 290             --  flag (that is we have seen a -gnatO), then the next argument
 291             --  is the name of the output object file.
 292
 293             if Output_File_Name_Present and then not Output_File_Name_Seen then
 294                if Is_Switch (Argv) then
 295                   Fail ("Object file name missing after -gnatO");
 296                else
 297                   Set_Output_Object_File_Name (Argv);
 298                   Output_File_Name_Seen := True;
 299                end if;
 300
 301             --  If the previous switch has set the Search_Directory_Present
 302             --  flag (that is if we have just seen -I), then the next argument
 303             --  is a search directory path.
 304
 305             elsif Search_Directory_Present then
 306                if Is_Switch (Argv) then
 307                   Fail ("search directory missing after -I");
 308                else
 309                   Add_Src_Search_Dir (Argv);
 310                   Search_Directory_Present := False;
 311                end if;
 312
 313             --  If not a switch, must be a file name
 314
 315             elsif not Is_Switch (Argv) then
 316                Add_File (Argv);
 317
 318             --  We must recognize -nostdinc to suppress visibility on the
 319             --  standard GNAT RTL sources. This is also a gcc switch.
 320
 321             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdinc" then
 322                Opt.No_Stdinc := True;
 323                Scan_Back_End_Switches (Argv);
 324
 325             --  We must recognize -nostdlib to suppress visibility on the
 326             --  standard GNAT RTL objects.
 327
 328             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdlib" then
 329                Opt.No_Stdlib := True;
 330
 331             elsif Is_Front_End_Switch (Argv) then
 332                Scan_Front_End_Switches (Argv, Args, Next_Arg);
 333
 334             --  All non-front-end switches are back-end switches
 335
 336             else
 337                Scan_Back_End_Switches (Argv);
 338             end if;
 339          end Look_At_Arg;
 340
 341          Next_Arg := Next_Arg + 1;
 342       end loop;
 343    end Scan_Compiler_Arguments;
 344
 345    -------------------------------
 346    -- Gen_Or_Update_Object_File --
 347    -------------------------------
 348
 349    procedure Gen_Or_Update_Object_File is
 350    begin
 351       null;
 352    end Gen_Or_Update_Object_File;
 353
 354 end Back_End;