gcc/ada/s-valllu.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                       S Y S T E M . V A L _ L L U                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Unsigned_Types; use System.Unsigned_Types;
  35 with System.Val_Util;       use System.Val_Util;
  36
  37 package body System.Val_LLU is
  38
  39    ---------------------------------
  40    -- Scan_Raw_Long_Long_Unsigned --
  41    ---------------------------------
  42
  43    function Scan_Raw_Long_Long_Unsigned
  44      (Str : String;
  45       Ptr : access Integer;
  46       Max : Integer) return Long_Long_Unsigned
  47    is
  48       P : Integer;
  49       --  Local copy of the pointer
  50
  51       Uval : Long_Long_Unsigned;
  52       --  Accumulated unsigned integer result
  53
  54       Expon : Integer;
  55       --  Exponent value
  56
  57       Overflow : Boolean := False;
  58       --  Set True if overflow is detected at any point
  59
  60       Base_Char : Character;
  61       --  Base character (# or :) in based case
  62
  63       Base : Long_Long_Unsigned := 10;
  64       --  Base value (reset in based case)
  65
  66       Digit : Long_Long_Unsigned;
  67       --  Digit value
  68
  69    begin
  70       P := Ptr.all;
  71       Uval := Character'Pos (Str (P)) - Character'Pos ('0');
  72       P := P + 1;
  73
  74       --  Scan out digits of what is either the number or the base.
  75       --  In either case, we are definitely scanning out in base 10.
  76
  77       declare
  78          Umax : constant := (Long_Long_Unsigned'Last - 9) / 10;
  79          --  Max value which cannot overflow on accumulating next digit
  80
  81          Umax10 : constant := Long_Long_Unsigned'Last / 10;
  82          --  Numbers bigger than Umax10 overflow if multiplied by 10
  83
  84       begin
  85          --  Loop through decimal digits
  86          loop
  87             exit when P > Max;
  88
  89             Digit := Character'Pos (Str (P)) - Character'Pos ('0');
  90
  91             --  Non-digit encountered
  92
  93             if Digit > 9 then
  94                if Str (P) = '_' then
  95                   Scan_Underscore (Str, P, Ptr, Max, False);
  96                else
  97                   exit;
  98                end if;
  99
 100             --  Accumulate result, checking for overflow
 101
 102             else
 103                if Uval <= Umax then
 104                   Uval := 10 * Uval + Digit;
 105
 106                elsif Uval > Umax10 then
 107                   Overflow := True;
 108
 109                else
 110                   Uval := 10 * Uval + Digit;
 111
 112                   if Uval < Umax10 then
 113                      Overflow := True;
 114                   end if;
 115                end if;
 116
 117                P := P + 1;
 118             end if;
 119          end loop;
 120       end;
 121
 122       Ptr.all := P;
 123
 124       --  Deal with based case
 125
 126       if P < Max and then (Str (P) = ':' or else Str (P) = '#') then
 127          Base_Char := Str (P);
 128          P := P + 1;
 129          Base := Uval;
 130          Uval := 0;
 131
 132          --  Check base value. Overflow is set True if we find a bad base, or
 133          --  a digit that is out of range of the base. That way, we scan out
 134          --  the numeral that is still syntactically correct, though illegal.
 135          --  We use a safe base of 16 for this scan, to avoid zero divide.
 136
 137          if Base not in 2 .. 16 then
 138             Overflow := True;
 139             Base :=  16;
 140          end if;
 141
 142          --  Scan out based integer
 143
 144          declare
 145             Umax : constant Long_Long_Unsigned :=
 146                      (Long_Long_Unsigned'Last - Base + 1) / Base;
 147             --  Max value which cannot overflow on accumulating next digit
 148
 149             UmaxB : constant Long_Long_Unsigned :=
 150                       Long_Long_Unsigned'Last / Base;
 151             --  Numbers bigger than UmaxB overflow if multiplied by base
 152
 153          begin
 154             --  Loop to scan out based integer value
 155
 156             loop
 157                --  We require a digit at this stage
 158
 159                if Str (P) in '0' .. '9' then
 160                   Digit := Character'Pos (Str (P)) - Character'Pos ('0');
 161
 162                elsif Str (P) in 'A' .. 'F' then
 163                   Digit :=
 164                     Character'Pos (Str (P)) - (Character'Pos ('A') - 10);
 165
 166                elsif Str (P) in 'a' .. 'f' then
 167                   Digit :=
 168                     Character'Pos (Str (P)) - (Character'Pos ('a') - 10);
 169
 170                --  If we don't have a digit, then this is not a based number
 171                --  after all, so we use the value we scanned out as the base
 172                --  (now in Base), and the pointer to the base character was
 173                --  already stored in Ptr.all.
 174
 175                else
 176                   Uval := Base;
 177                   exit;
 178                end if;
 179
 180                --  If digit is too large, just signal overflow and continue.
 181                --  The idea here is to keep scanning as long as the input is
 182                --  syntactically valid, even if we have detected overflow
 183
 184                if Digit >= Base then
 185                   Overflow := True;
 186
 187                --  Here we accumulate the value, checking overflow
 188
 189                elsif Uval <= Umax then
 190                   Uval := Base * Uval + Digit;
 191
 192                elsif Uval > UmaxB then
 193                   Overflow := True;
 194
 195                else
 196                   Uval := Base * Uval + Digit;
 197
 198                   if Uval < UmaxB then
 199                      Overflow := True;
 200                   end if;
 201                end if;
 202
 203                --  If at end of string with no base char, not a based number
 204                --  but we signal Constraint_Error and set the pointer past
 205                --  the end of the field, since this is what the ACVC tests
 206                --  seem to require, see CE3704N, line 204.
 207
 208                P := P + 1;
 209
 210                if P > Max then
 211                   Ptr.all := P;
 212                   raise Constraint_Error;
 213                end if;
 214
 215                --  If terminating base character, we are done with loop
 216
 217                if Str (P) = Base_Char then
 218                   Ptr.all := P + 1;
 219                   exit;
 220
 221                --  Deal with underscore
 222
 223                elsif Str (P) = '_' then
 224                   Scan_Underscore (Str, P, Ptr, Max, True);
 225                end if;
 226
 227             end loop;
 228          end;
 229       end if;
 230
 231       --  Come here with scanned unsigned value in Uval. The only remaining
 232       --  required step is to deal with exponent if one is present.
 233
 234       Expon := Scan_Exponent (Str, Ptr, Max);
 235
 236       if Expon /= 0 and then Uval /= 0 then
 237
 238          --  For non-zero value, scale by exponent value. No need to do this
 239          --  efficiently, since use of exponent in integer literals is rare,
 240          --  and in any case the exponent cannot be very large.
 241
 242          declare
 243             UmaxB : constant Long_Long_Unsigned :=
 244                       Long_Long_Unsigned'Last / Base;
 245             --  Numbers bigger than UmaxB overflow if multiplied by base
 246
 247          begin
 248             for J in 1 .. Expon loop
 249                if Uval > UmaxB then
 250                   Overflow := True;
 251                   exit;
 252                end if;
 253
 254                Uval := Uval * Base;
 255             end loop;
 256          end;
 257       end if;
 258
 259       --  Return result, dealing with sign and overflow
 260
 261       if Overflow then
 262          raise Constraint_Error;
 263       else
 264          return Uval;
 265       end if;
 266    end Scan_Raw_Long_Long_Unsigned;
 267
 268    -----------------------------
 269    -- Scan_Long_Long_Unsigned --
 270    -----------------------------
 271
 272    function Scan_Long_Long_Unsigned
 273      (Str : String;
 274       Ptr : access Integer;
 275       Max : Integer) return Long_Long_Unsigned
 276    is
 277       Start : Positive;
 278       --  Save location of first non-blank character
 279
 280    begin
 281       Scan_Plus_Sign (Str, Ptr, Max, Start);
 282
 283       if Str (Ptr.all) not in '0' .. '9' then
 284          Ptr.all := Start;
 285          raise Constraint_Error;
 286       end if;
 287
 288       return Scan_Raw_Long_Long_Unsigned (Str, Ptr, Max);
 289    end Scan_Long_Long_Unsigned;
 290
 291    ------------------------------
 292    -- Value_Long_Long_Unsigned --
 293    ------------------------------
 294
 295    function Value_Long_Long_Unsigned
 296      (Str : String) return Long_Long_Unsigned
 297    is
 298       V : Long_Long_Unsigned;
 299       P : aliased Integer := Str'First;
 300    begin
 301       V := Scan_Long_Long_Unsigned (Str, P'Access, Str'Last);
 302       Scan_Trailing_Blanks (Str, P);
 303       return V;
 304    end Value_Long_Long_Unsigned;
 305
 306 end System.Val_LLU;