gcc/ada/lib-load.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . L O A D                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This child package contains the function used to load a separately
  28 --  compiled unit, as well as the routine used to initialize the unit
  29 --  table and load the main source file.
  30
  31 package Lib.Load is
  32
  33    -------------------------------
  34    -- Handling of Renamed Units --
  35    -------------------------------
  36
  37    --  A compilation unit can be a renaming of another compilation unit.
  38    --  Such renamed units are not allowed as parent units, that is you
  39    --  cannot declare a unit:
  40
  41    --     with x;
  42    --     package x.y is end;
  43
  44    --  where x is a renaming of some other package. However you can refer
  45    --  to a renamed unit in a with clause:
  46
  47    --     package p is end;
  48
  49    --     package p.q is end;
  50
  51    --     with p;
  52    --     package pr renames p;
  53
  54    --     with pr.q ....
  55
  56    --  This means that in the context of a with clause, the normal fixed
  57    --  correspondence between unit and file names is broken. In the above
  58    --  example, there is no file named pr-q.ads, since the actual child
  59    --  unit is p.q, and it will be found in file p-q.ads.
  60
  61    --  In order to deal with this case, we have to first load pr.ads, and
  62    --  then discover that it is a renaming of p, so that we know that pr.q
  63    --  really refers to p.q. Furthermore this can happen at any level:
  64
  65    --     with p.q;
  66    --     package p.r renames p.q;
  67
  68    --     with p.q;
  69    --     package p.q.s is end;
  70
  71    --     with p.r.s ...
  72
  73    --  Now we have a case where the parent p.r is a child unit and is
  74    --  a renaming. This shows that renaming can occur at any level.
  75
  76    --  Finally, consider:
  77
  78    --     with pr.q.s ...
  79
  80    --  Here the parent pr.q is not itself a renaming, but it really refers
  81    --  to the unit p.q, and again we cannot know this without loading the
  82    --  parent. The bottom line here is that while the file name of a unit
  83    --  always corresponds to the unit name, the unit name as given to the
  84    --  Load_Unit function may not be the real unit.
  85
  86    -----------------
  87    -- Subprograms --
  88    -----------------
  89
  90    procedure Initialize;
  91    --  Initialize internal tables
  92
  93    procedure Initialize_Version (U : Unit_Number_Type);
  94    --  This is called once the source file corresponding to unit U has been
  95    --  fully scanned. At that point the checksum is computed, and can be used
  96    --  to initialize the version number.
  97
  98    procedure Load_Main_Source;
  99    --  Called at the start of compiling a new main source unit to initialize
 100    --  the library processing for the new main source. Establishes and
 101    --  initializes the units table entry for the new main unit (leaving
 102    --  the Unit_File_Name entry of Main_Unit set to No_File if there are no
 103    --  more files. Otherwise the main source file has been opened and read
 104    --  and then closed on return.
 105
 106    function Load_Unit
 107      (Load_Name         : Unit_Name_Type;
 108       Required          : Boolean;
 109       Error_Node        : Node_Id;
 110       Subunit           : Boolean;
 111       Corr_Body         : Unit_Number_Type := No_Unit;
 112       Renamings         : Boolean          := False;
 113       From_Limited_With : Boolean          := False) return Unit_Number_Type;
 114    --  This function loads and parses the unit specified by Load_Name (or
 115    --  returns the unit number for the previously constructed units table
 116    --  entry if this is not the first call for this unit). Required indicates
 117    --  the behavior on a file not found condition, as further described below,
 118    --  and Error_Node is the node in the calling program to which error
 119    --  messages are to be attached.
 120    --
 121    --  If the corresponding file is found, the value returned by Load is the
 122    --  unit number that indexes the corresponding entry in the units table. If
 123    --  a serious enough parser error occurs to prevent subsequent semantic
 124    --  analysis, then the Fatal_Error flag of the returned entry is set and
 125    --  in addition, the fatal error flag of the calling unit is also set.
 126    --
 127    --  If the corresponding file is not found, then the behavior depends on
 128    --  the setting of Required. If Required is False, then No_Unit is returned
 129    --  and no error messages are issued. If Required is True, then an error
 130    --  message is posted, and No_Unit is returned.
 131    --
 132    --  A special case arises in the call from Rtsfind, where Error_Node is set
 133    --  to Empty. In this case Required is False, and the caller in any case
 134    --  treats any error as fatal.
 135    --
 136    --  The Subunit parameter is True to load a subunit, and False to load
 137    --  any other kind of unit (including all specs, package bodies, and
 138    --  subprogram bodies).
 139    --
 140    --  The Corr_Body argument is normally defaulted. It is set only in the
 141    --  case of loading the corresponding spec when the main unit is a body.
 142    --  In this case, Corr_Body is the unit number of this corresponding
 143    --  body. This is used to set the Serial_Ref_Unit field of the unit
 144    --  table entry. It is also used to deal with the special processing
 145    --  required by RM 10.1.4(4). See description in lib.ads.
 146    --
 147    --  Renamings activates the handling of renamed units as separately
 148    --  described in the documentation of this unit. If this parameter is
 149    --  set to True, then Load_Name may not be the real unit name and it
 150    --  is necessary to load parents to find the real name.
 151    --
 152    --  From_Limited_With is True if we are loading a unit X found in a
 153    --  limited-with clause, or some unit in the context of X. It is used to
 154    --  avoid the check on circular dependency (Ada 2005, AI-50217)
 155
 156    function Create_Dummy_Package_Unit
 157      (With_Node : Node_Id;
 158       Spec_Name : Unit_Name_Type) return Unit_Number_Type;
 159    --  With_Node is the Node_Id of a with statement for which the file could
 160    --  not be found, and Spec_Name is the corresponding unit name. This call
 161    --  creates a dummy package unit so that compilation can continue without
 162    --  blowing up when the missing unit is referenced.
 163
 164    procedure Make_Instance_Unit (N : Node_Id);
 165    --  When a compilation unit is an instantiation, it contains both the
 166    --  declaration and the body of the instance, each of which can have its
 167    --  own elaboration routine. The file itself corresponds to the declaration.
 168    --  We create an additional entry for the body, so that the binder can
 169    --  generate the proper elaboration calls to both. The argument N is the
 170    --  compilation unit node created for the body.
 171
 172    procedure Version_Update (U : Node_Id; From : Node_Id);
 173    --  This routine is called when unit U is found to be semantically
 174    --  dependent on unit From. It updates the version of U to register
 175    --  dependence on the version of From. The arguments are compilation
 176    --  unit nodes for the relevant library nodes.
 177
 178 end Lib.Load;