gcc/ada/g-semaph.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      G N A T . S E M A P H O R E S                       --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 2003-2005, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package provides classic counting semaphores and binary semaphores.
  35 --  Both types are visibly defined as protected types so that users can make
  36 --  conditional and timed calls when appropriate.
  37
  38 with System;
  39
  40 package GNAT.Semaphores is
  41
  42    Default_Ceiling : constant System.Priority := System.Default_Priority;
  43    --  A convenient value for the priority discriminants that follow
  44
  45    ------------------------
  46    -- Counting_Semaphore --
  47    ------------------------
  48
  49    protected type Counting_Semaphore
  50       (Initial_Value : Natural;
  51       --  A counting semaphore contains an internal counter.  The initial
  52       --  value of this counter is set by clients via the discriminant.
  53
  54       Ceiling : System.Priority)
  55       --  Users must specify the ceiling priority for the object. If the
  56       --  Real-Time Systems Annex is not in use this value is not important.
  57    is
  58       pragma Priority (Ceiling);
  59
  60       entry Seize;
  61       --  Blocks caller until/unless the semaphore's internal counter is
  62       --  greater than zero. Decrements the semaphore's internal counter when
  63       --  executed.
  64
  65       procedure Release;
  66       --  Increments the semaphore's internal counter
  67
  68    private
  69       Count : Natural := Initial_Value;
  70    end Counting_Semaphore;
  71
  72    ----------------------
  73    -- Binary_Semaphore --
  74    ----------------------
  75
  76    protected type Binary_Semaphore
  77      (Initially_Available : Boolean;
  78       --  Binary semaphores are either available or not; there is no internal
  79       --  count involved. The discriminant value determines whether the
  80       --  individual object is initially available.
  81
  82       Ceiling : System.Priority)
  83       --  Users must specify the ceiling priority for the object. If the
  84       --  Real-Time Systems Annex is not in use this value is not important.
  85    is
  86       pragma Priority (Ceiling);
  87
  88       entry Seize;
  89       --  Blocks the caller unless/until semaphore is available. After
  90       --  execution the semaphore is no longer available.
  91
  92       procedure Release;
  93       --  Makes the semaphore available
  94
  95    private
  96       Available : Boolean := Initially_Available;
  97    end Binary_Semaphore;
  98
  99 end GNAT.Semaphores;