gcc/ada/libgnarl/s-tasinf__solaris.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                     S Y S T E M . T A S K _ I N F O                      --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2020, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This package contains the definitions and routines associated with the
  33 --  implementation and use of the Task_Info pragma. It is specialized
  34 --  appropriately for targets that make use of this pragma.
  35
  36 --  Note: the compiler generates direct calls to this interface, via Rtsfind.
  37 --  Any changes to this interface may require corresponding compiler changes.
  38
  39 --  The functionality in this unit is now provided by the predefined package
  40 --  System.Multiprocessors and the CPU aspect. This package is obsolescent.
  41
  42 --  This is the Solaris (native) version of this module
  43
  44 with System.OS_Interface;
  45
  46 package System.Task_Info is
  47    pragma Obsolescent (Task_Info, "use System.Multiprocessors and CPU aspect");
  48    pragma Preelaborate;
  49    pragma Elaborate_Body;
  50    --  To ensure that a body is allowed
  51
  52    -----------------------------------------------------
  53    -- Binding of Tasks to LWPs and LWPs to processors --
  54    -----------------------------------------------------
  55
  56    --  The Solaris implementation of the GNU Low-Level Interface (GNULLI)
  57    --  implements each Ada task as a Solaris thread.  The Solaris thread
  58    --  library distributes threads across one or more LWPs (Light Weight
  59    --  Process) that are members of the same process. Solaris distributes
  60    --  processes and LWPs across the available CPUs on a given machine. The
  61    --  pragma Task_Info provides the mechanism to control the distribution
  62    --  of tasks to LWPs, and LWPs to processors.
  63
  64    --  Each thread has a number of attributes that dictate it's scheduling.
  65    --  These attributes are:
  66    --
  67    --      New_LWP:       whether a new LWP is created for this thread.
  68    --
  69    --      Bound_To_LWP:  whether the thread is bound to a specific LWP
  70    --                     for its entire lifetime.
  71    --
  72    --      CPU:           the CPU number associated to the LWP
  73    --
  74
  75    --  The Task_Info pragma:
  76
  77    --    pragma Task_Info (EXPRESSION);
  78
  79    --  allows the specification on a task by task basis of a value of type
  80    --  System.Task_Info.Task_Info_Type to be passed to a task when it is
  81    --  created. The specification of this type, and the effect on the task
  82    --  that is created is target dependent.
  83
  84    --  The Task_Info pragma appears within a task definition (compare the
  85    --  definition and implementation of pragma Priority). If no such pragma
  86    --  appears, then the value Unspecified_Task_Info is passed. If a pragma
  87    --  is present, then it supplies an alternative value. If the argument of
  88    --  the pragma is a discriminant reference, then the value can be set on
  89    --  a task by task basis by supplying the appropriate discriminant value.
  90
  91    --  Note that this means that the type used for Task_Info_Type must be
  92    --  suitable for use as a discriminant (i.e. a scalar or access type).
  93
  94    -----------------------
  95    -- Thread Attributes --
  96    -----------------------
  97
  98    subtype CPU_Number is System.OS_Interface.processorid_t;
  99
 100    CPU_UNCHANGED : constant CPU_Number := System.OS_Interface.PBIND_QUERY;
 101    --  Do not bind the LWP to a specific processor
 102
 103    ANY_CPU       : constant CPU_Number := System.OS_Interface.PBIND_NONE;
 104    --  Bind the LWP to any processor
 105
 106    Invalid_CPU_Number : exception;
 107
 108    type Thread_Attributes (New_LWP : Boolean) is record
 109       Bound_To_LWP     : Boolean    := True;
 110       case New_LWP is
 111          when False =>
 112             null;
 113          when True =>
 114             CPU        : CPU_Number := CPU_UNCHANGED;
 115       end case;
 116    end record;
 117
 118    Default_Thread_Attributes : constant Thread_Attributes := (False, True);
 119
 120    function Unbound_Thread_Attributes
 121       return Thread_Attributes;
 122
 123    function Bound_Thread_Attributes
 124       return Thread_Attributes;
 125
 126    function Bound_Thread_Attributes (CPU : CPU_Number)
 127       return Thread_Attributes;
 128
 129    type Task_Info_Type is access all Thread_Attributes;
 130
 131    function New_Unbound_Thread_Attributes
 132       return Task_Info_Type;
 133
 134    function New_Bound_Thread_Attributes
 135       return Task_Info_Type;
 136
 137    function New_Bound_Thread_Attributes (CPU : CPU_Number)
 138       return Task_Info_Type;
 139
 140    Unspecified_Task_Info : constant Task_Info_Type := null;
 141
 142    function Number_Of_Processors return Positive;
 143    --  Returns the number of processors on the running host
 144
 145 end System.Task_Info;