| blob | 9c98411819bf2fd99aa4133ecb38855f97dac663 |
1 $! Set the def dir to proper place for use in batch. Works for interactive too.
2 $flnm = f$enviroment("PROCEDURE") ! get current procedure name
3 $set default 'f$parse(flnm,,,"DEVICE")''f$parse(flnm,,,"DIRECTORY")'
4 $!
5 $ v=f$verify(0)
6 $set symbol/scope=(nolocal,noglobal)
7 $!
8 $! CAUTION: If you want to link gcc-cc1 to the sharable image library
9 $! VAXCRTL, see the notes in gcc.texinfo (or INSTALL) first.
10 $!
11 $! Build the GNU "C" compiler on VMS
12 $!
13 $! Note: to build with DEC's VAX C compiler, uncomment the 2nd CC, CFLAGS,
14 $! and LIBS alternatives, and also execute the following command:
15 $! DEFINE SYS SYS$LIBRARY:
16 $! After a successful build, restore those items and rebuild with gcc.
17 $
18 $! C compiler
19 $!
20 $ CC := gcc
21 $! CC := cc !uncomment for VAXC
22 $ BISON := bison
23 $ RENAME := rename/new_vers
24 $ LINK := link
25 $ EDIT := edit
26 $!
27 $! Compiler options
28 $!
29 $ CFLAGS = "/noVerbose/Debug/CC1=""-mpcc-alignment"""
30 $! CFLAGS = "/noOpt" !uncomment for VAXC
31 $ CINCL1 = "/Incl=[]" !stage 1 -I flags
32 $ CINCL2 = "/Incl=([],[.ginclude])" !stage 2,3,... flags
33 $!
34 $! Link options
35 $!
36 $ LDFLAGS := /nomap
37 $!
38 $! Link libraries
39 $!
40 $ LIBS := gnu_cc:[000000]gcclib.olb/libr,sys$library:vaxcrtl.olb/libr
41 $! LIBS := alloca.obj,sys$library:vaxcrtl.olb/Libr !uncomment for VAXC
42 $!
43 $!
44 $! First we figure out what needs to be done. This is sort of like a limited
45 $! make facility - the command line options specify exactly what components
46 $! we want to build. The following options are understood:
47 $!
48 $! LINK: Assume that the object modules for the selected compiler(s)
49 $! have already been compiled, perform link phase only.
50 $!
51 $! CC1: Compile and link "C" compiler.
52 $!
53 $! CC1PLUS:Compile and link "C++" compiler.
54 $!
55 $! CC1OBJ: Compile and link objective C compiler.
56 $!
57 $! ALL: Compile and link all of the CC1 passes.
58 $!
59 $! INDEPENDENT:
60 $! Compile language independent source modules. (On by default).
61 $!
62 $! BC:
63 $! Compile byte compiler source modules. (On by default).
64 $!
65 $! DEBUG: Link images with /debug.
66 $!
67 $! If you want to list more than one option, you should use a spaces to
68 $! separate them.
69 $!
70 $! Any one of the above options can be prefaced with a "NO". For example,
71 $! if you had already built GCC, and you wanted to build G++, you could use the
72 $! "CC1PLUS NOINDEPENDENT" options, which would only compile the C++ language
73 $! specific source files, and then link the C++ compiler.
74 $!
75 $! If you do not specify which compiler you want to build, it is assumed that
76 $! you want to build GNU-C ("CC1").
77 $!
78 $! Now figure out what we have been requested to do.
79 $p1 = p1+" "+p2+" "+p3+" "+p4+" "+p5+" "+p6+" "+p7
80 $p1 = f$edit(p1,"COMPRESS")
81 $i=0
82 $DO_ALL = 0
83 $DO_LINK = 0
84 $DO_DEBUG = 0
85 $DO_CC1PLUS = 0
86 $open cfile$ compilers.list
87 $cinit:read cfile$ compilername/end=cinit_done
88 $DO_'compilername'=0
89 $goto cinit
90 $cinit_done: close cfile$
91 $DO_INDEPENDENT = 1
92 $DO_DEFAULT = 1
93 $DO_BC = 1
94 $loop:
95 $string = f$element(i," ",p1)
96 $if string.eqs." " then goto done
97 $flag = 1
98 $if string.eqs."CC1PLUS" then DO_DEFAULT = 0
99 $if string.eqs."CC1OBJ" then DO_DEFAULT = 0
100 $if f$extract(0,2,string).nes."NO" then goto parse_option
101 $ string=f$extract(2,f$length(string)-2,string)
102 $ flag = 0
103 $parse_option:
104 $DO_'string' = flag
105 $i=i+1
106 $goto loop
107 $!
108 $done:
109 $if DO_DEFAULT.eq.1 then DO_CC1 = 1
110 $echo := write sys$Output
111 $echo "This command file will now perform the following actions:
112 $if DO_LINK.eq.1 then goto link_only
113 $if DO_ALL.eq.1 then echo " Compile all language specific object modules."
114 $if DO_CC1.eq.1 then echo " Compile C specific object modules."
115 $if DO_CC1PLUS.eq.1 then echo " Compile C++ specific object modules."
116 $if DO_CC1OBJ.eq.1 then echo " Compile obj-C specific object modules."
117 $if DO_INDEPENDENT.eq.1 then echo " Compile language independent object modules."
118 $if DO_BC.eq.1 then echo " Compile byte compiler object modules."
119 $link_only:
120 $if DO_CC1.eq.1 then echo " Link C compiler (gcc-cc1.exe)."
121 $if DO_CC1PLUS.eq.1 then echo " Link C++ compiler (gcc-cc1plus.exe)."
122 $if DO_CC1OBJ.eq.1 then echo " Link objective-C compiler (gcc-cc1obj.exe)."
123 $if DO_DEBUG.eq.1 then echo " Link images to run under debugger."
124 $!
125 $! Update CFLAGS with appropriate CINCLx value.
126 $!
127 $if f$edit(f$extract(0,3,CC),"LOWERCASE").nes."gcc" then goto stage1
128 $if f$search("gcc-cc1.exe").eqs."" then goto stage1
129 $if f$file_attr("gnu_cc:[000000]gcc-cc1.exe","FID").nes.-
130 f$file_attr("gcc-cc1.exe","FID") then goto stage1
131 $ CFLAGS = CFLAGS + CINCL2
132 $ goto cinclX
133 $stage1:
134 $ CFLAGS = CFLAGS + CINCL1
135 $cinclX:
136 $!
137 $! Test and see if we need these messages or not. The -1 switch gives it away.
138 $!
139 $gas := $gnu_cc:[000000]gcc-as.exe
140 $if f$search(gas-"$").eqs."" then goto gas_message !must be VAXC
141 $define/user sys$error sys$scratch:gas_test.tmp
142 $gas -1 nla0: -o nla0:
143 $size=f$file_attributes("sys$scratch:gas_test.tmp","ALQ")
144 $delete/nolog sys$scratch:gas_test.tmp;*
145 $if size.eq.0 then goto no_message
146 $gas_message:
147 $type sys$input
149 Note: GCC 2.0 treats external variables differently than GCC 1.40 does.
150 Before you use GCC 2.0, you should obtain a version of the assembler which
151 contains the patches to work with GCC 2.0 (GCC-AS 1.38 does not contain
152 these patches - whatever comes after this probably will). The assembler
153 in gcc-vms-1.40.tar.Z from prep does contain the proper patches.
155 If you do not update the assembler, the compiler will still work,
156 but `extern const' variables will be treated as `extern'. This will result
157 in linker warning messages about mismatched psect attributes, and these
158 variables will be placed in read/write storage.
160 $!
161 $no_message:
162 $!
163 $!
164 $ if DO_DEBUG.eq.1 then LDFLAGS :='LDFLAGS'/debug
165 $!
166 $if DO_LINK.eq.1 then goto compile_cc1
167 $!
168 $! Build alloca if necessary (in 'LIBS for use with VAXC)
169 $!
170 $ if f$locate("alloca.obj",f$edit(LIBS,"lowercase")).ge.f$length(LIBS) then -
171 goto skip_alloca
172 $ if f$search("alloca.obj").nes."" then - !does .obj exist? is it up to date?
173 if f$cvtime(f$file_attributes("alloca.obj","RDT")).gts.-
174 f$cvtime(f$file_attributes("alloca.c","RDT")) then goto skip_alloca
175 $set verify
176 $ 'CC 'CFLAGS /define="STACK_DIRECTION=(-1)" alloca.c
177 $!'f$verify(0)
178 $skip_alloca:
179 $!
180 $if DO_BC.eq.1
181 $ THEN
182 $ call compile bi_all.opt ""
183 $ open ifile$ bc_all.opt
184 $ read ifile$ bc_line
185 $ close ifile$
186 $ bc_index = 0
187 $bc_loop:
188 $ tfile = f$element(bc_index, " ", bc_line)
189 $ if tfile.eqs." " then goto bc_done
190 $ call bc_generate 'tfile' "bi_all.opt/opt,"
191 $ bc_index = bc_index + 1
192 $ goto bc_loop
193 $bc_done:
194 $ endif
195 $!
196 $!
197 $if DO_INDEPENDENT.eq.1
198 $ THEN
199 $!
200 $! First build a couple of header files from the machine description
201 $! These are used by many of the source modules, so we build them now.
202 $!
203 $set verify
204 $ 'CC 'CFLAGS rtl.C
205 $ 'CC 'CFLAGS obstack.C
206 $!'f$verify(0)
207 $! Generate insn-attr.h
208 $ call generate insn-attr.h
209 $ call generate insn-flags.h
210 $ call generate insn-codes.h
211 $ call generate insn-config.h
212 $!
213 $call compile independent.opt "rtl,obstack,insn-attrtab"
214 $!
215 $ call generate insn-attrtab.c "rtlanal,"
216 $set verify
217 $ 'CC 'CFLAGS insn-attrtab.c
218 $!'f$verify(0)
219 $ endif
220 $!
221 $compile_cc1:
222 $if (DO_CC1 + DO_CC1OBJ) .ne.0
223 $ then
224 $if (f$search("C-PARSE.Y") .eqs. "") then goto yes_yfiles
225 $if (f$cvtime(f$file_attributes("C-PARSE.IN","RDT")).gts. -
226 f$cvtime(f$file_attributes("C-PARSE.Y","RDT"))) -
227 then goto yes_yfiles
228 $if (f$search("OBJC-PARSE.Y") .eqs. "") then goto yes_yfiles
229 $if (f$cvtime(f$file_attributes("C-PARSE.IN","RDT")).gts. -
230 f$cvtime(f$file_attributes("OBJC-PARSE.Y","RDT"))) -
231 then goto yes_yfiles
232 $GOTO no_yfiles
233 $yes_yfiles:
234 $echo "Now processing c-parse.in to generate c-parse.y and objc-parse.y."
235 $ edit/tpu/nojournal/nosection/nodisplay/command=sys$input
236 !
237 ! Read c-parse.in, write c-parse.y and objc-parse.y, depending on
238 ! paired lines of "ifc" & "end ifc" and "ifobjc" & "end ifobjc" to
239 ! control what goes into each file. Most lines will be common to
240 ! both (hence not bracketed by either control pair). Mismatched
241 ! pairs aren't detected--garbage in, garbage out...
242 !
244 PROCEDURE do_output()
245 IF NOT objc_only THEN POSITION(END_OF(c)); COPY_TEXT(input_line); ENDIF;
246 IF NOT c_only THEN POSITION(END_OF(objc)); COPY_TEXT(input_line); ENDIF;
247 POSITION(input_file); !reset
248 ENDPROCEDURE;
250 input_file := CREATE_BUFFER("input", "c-parse.in"); !load data
251 SET(NO_WRITE, input_file);
252 c := CREATE_BUFFER("c_output"); !1st output file
253 objc := CREATE_BUFFER("objc_output"); !2nd output file
255 POSITION(BEGINNING_OF(input_file));
256 c_only := 0;
257 objc_only := 0;
259 LOOP
260 EXITIF MARK(NONE) = END_OF(input_file); !are we done yet?
262 input_line := CURRENT_LINE; !access current_line just once
263 CASE EDIT(input_line, TRIM_TRAILING, OFF, NOT_IN_PLACE)
264 ["ifc"] : c_only := 1;
265 ["end ifc"] : c_only := 0;
266 ["ifobjc"] : objc_only := 1;
267 ["end ifobjc"] : objc_only := 0;
268 ! default -- add non-control line to either or both output files
269 [INRANGE] : do_output(); !between "end" and "if"
270 [OUTRANGE] : do_output(); !before "end" or after "if"
271 ENDCASE;
273 MOVE_VERTICAL(1); !go to next line
274 ENDLOOP;
276 WRITE_FILE(c, "c-parse.y");
277 WRITE_FILE(objc, "objc-parse.y");
278 QUIT
279 $ endif
280 $no_yfiles:
281 $!
282 $open cfile$ compilers.list
283 $cloop:read cfile$ compilername/end=cdone
284 $! language specific modules
285 $!
286 $if (DO_ALL + DO_'compilername').eq.0 then goto cloop
287 $if DO_LINK.eq.0 then call compile 'compilername'-objs.opt "obstack"
288 $!
289 $! CAUTION: If you want to link gcc-cc1* to the sharable image library
290 $! VAXCRTL, see the notes in gcc.texinfo (or INSTALL) first.
291 $!
292 $set verify
293 $ link 'LDFLAGS' /exe=gcc-'compilername' version.opt/opt, -
294 'compilername'-objs.opt/opt, independent.opt/opt, -
295 'LIBS'
296 $!'f$verify(0)
297 $goto cloop
298 $!
299 $!
300 $cdone: close cfile$
301 $!
302 $! Done
303 $!
304 $! 'f$verify(v)
305 $exit
306 $!
307 $! Various DCL subroutines follow...
308 $!
309 $! This routine takes parameter p1 to be a linker options file with a list
310 $! of object files that are needed. It extracts the names, and compiles
311 $! each source module, one by one. File names that begin with an
312 $! "INSN-" are assumed to be generated by a GEN*.C program.
313 $!
314 $! Parameter P2 is a list of files which will appear in the options file
315 $! that should not be compiled. This allows us to handle special cases.
316 $!
317 $compile:
318 $subroutine
319 $on error then goto c_err
320 $on control_y then goto c_err
321 $open ifile$ 'p1'
322 $loop: read ifile$ line/end=c_done
323 $!
324 $i=0
325 $loop1:
326 $flnm=f$element(i,",",line)
327 $i=i+1
328 $if flnm.eqs."" then goto loop
329 $if flnm.eqs."," then goto loop
330 $if f$locate(flnm,"''p2'").nes.f$length("''p2'") then goto loop1
331 $!
332 $if f$locate("-parse",flnm).nes.f$length(flnm)
333 $ then
334 $ if (f$search("''flnm'.C") .eqs. "") then goto yes_bison
335 $ if (f$cvtime(f$file_attributes("''flnm'.Y","RDT")).les. -
336 f$cvtime(f$file_attributes("''flnm'.C","RDT"))) -
337 then goto no_bison
338 $yes_bison:
339 $set verify
340 $ 'BISON' /define /verbose 'flnm'.y
341 $ 'RENAME' 'flnm'_tab.c 'flnm'.c
342 $ 'RENAME' 'flnm'_tab.h 'flnm'.h
343 $ if flnm.eqs."cp-parse"
344 $ then ! fgrep '#define YYEMPTY' cp-parse.c >>cp-parse.h
345 $ open/append jfile$ cp-parse.h
346 $ search/exact/output=jfile$ cp-parse.c "#define YYEMPTY"
347 $ close jfile$
348 $ endif
349 $!'f$verify(0)
350 $no_bison:
351 $ echo " (Ignore any warning about not finding file ""bison.simple"".)"
352 $ endif
353 $!
354 $if f$extract(0,5,flnm).eqs."insn-" then call generate 'flnm'.c
355 $!
356 $set verify
357 $ 'CC 'CFLAGS 'flnm'.c
358 $!'f$verify(0)
359 $goto loop1
360 $!
361 $goto loop
362 $!
363 $! In case of error or abort, go here (In order to close file).
364 $!
365 $c_err: !'f$verify(0)
366 $close ifile$
367 $exit %x2c
368 $!
369 $c_done:
370 $close ifile$
371 $endsubroutine
372 $!
373 $! This subroutine generates the insn-* files. The first argument is the
374 $! name of the insn-* file to generate. The second argument contains a
375 $! list of any other object modules which must be linked to the gen*.c
376 $! program.
377 $!
378 $generate:
379 $subroutine
380 $if f$extract(0,5,p1).nes."INSN-"
381 $ then
382 $ write sys$error "Unknown file passed to generate."
383 $ exit 1
384 $ endif
385 $root1=f$parse(f$extract(5,255,p1),,,"NAME")
386 $ set verify
387 $ 'CC 'CFLAGS GEN'root1'.C
388 $ link 'LDFLAGS' GEN'root1',rtl,obstack,'p2' -
389 'LIBS'
390 $! 'f$verify(0)
391 $!
392 $set verify
393 $ assign/user 'p1' sys$output:
394 $ mcr sys$disk:[]GEN'root1' md
395 $!'f$verify(0)
396 $endsubroutine
397 $!
398 $! This subroutine generates the bc-* files. The first argument is the
399 $! name of the bc-* file to generate. The second argument contains a
400 $! list of any other object modules which must be linked to the bi*.c
401 $! program.
402 $!
403 $bc_generate:
404 $subroutine
405 $if f$extract(0,3,p1).nes."BC-"
406 $ then
407 $ write sys$error "Unknown file passed to generate."
408 $ exit 1
409 $ endif
410 $root1=f$parse(f$extract(3,255,p1),,,"NAME")
411 $ set verify
412 $ 'CC 'CFLAGS BI-'root1'.C
413 $ link 'LDFLAGS' BI-'root1','p2' -
414 'LIBS'
415 $! 'f$verify(0)
416 $!
417 $set verify
418 $ assign/user bytecode.def sys$input:
419 $ assign/user 'p1' sys$output:
420 $ mcr sys$disk:[]BI-'root1'
421 $!'f$verify(0)
422 $endsubroutine