gcc/ada/table.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                T A B L E                                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with Debug;   use Debug;
  33 with Opt;     use Opt;
  34 with Output;  use Output;
  35 with System;  use System;
  36 with Tree_IO; use Tree_IO;
  37
  38 with System.Memory; use System.Memory;
  39
  40 with Unchecked_Conversion;
  41
  42 pragma Elaborate_All (Output);
  43
  44 package body Table is
  45    package body Table is
  46
  47       Min : constant Int := Int (Table_Low_Bound);
  48       --  Subscript of the minimum entry in the currently allocated table
  49
  50       Length : Int := 0;
  51       --  Number of entries in currently allocated table. The value of zero
  52       --  ensures that we initially allocate the table.
  53
  54       -----------------------
  55       -- Local Subprograms --
  56       -----------------------
  57
  58       procedure Reallocate;
  59       --  Reallocate the existing table according to the current value stored
  60       --  in Max. Works correctly to do an initial allocation if the table
  61       --  is currently null.
  62
  63       function Tree_Get_Table_Address return Address;
  64       --  Return Null_Address if the table length is zero,
  65       --  Table (First)'Address if not.
  66
  67       pragma Warnings (Off);
  68       --  Turn off warnings. The following unchecked conversions are only used
  69       --  internally in this package, and cannot never result in any instances
  70       --  of improperly aliased pointers for the client of the package.
  71
  72       function To_Address is new Unchecked_Conversion (Table_Ptr, Address);
  73       function To_Pointer is new Unchecked_Conversion (Address, Table_Ptr);
  74
  75       pragma Warnings (On);
  76
  77       ------------
  78       -- Append --
  79       ------------
  80
  81       procedure Append (New_Val : Table_Component_Type) is
  82       begin
  83          Set_Item (Table_Index_Type (Last_Val + 1), New_Val);
  84       end Append;
  85
  86       ----------------
  87       -- Append_All --
  88       ----------------
  89
  90       procedure Append_All (New_Vals : Table_Type) is
  91       begin
  92          for J in New_Vals'Range loop
  93             Append (New_Vals (J));
  94          end loop;
  95       end Append_All;
  96
  97       --------------------
  98       -- Decrement_Last --
  99       --------------------
 100
 101       procedure Decrement_Last is
 102       begin
 103          Last_Val := Last_Val - 1;
 104       end Decrement_Last;
 105
 106       ----------
 107       -- Free --
 108       ----------
 109
 110       procedure Free is
 111       begin
 112          Free (To_Address (Table));
 113          Table := null;
 114          Length := 0;
 115       end Free;
 116
 117       --------------------
 118       -- Increment_Last --
 119       --------------------
 120
 121       procedure Increment_Last is
 122       begin
 123          Last_Val := Last_Val + 1;
 124
 125          if Last_Val > Max then
 126             Reallocate;
 127          end if;
 128       end Increment_Last;
 129
 130       ----------
 131       -- Init --
 132       ----------
 133
 134       procedure Init is
 135          Old_Length : constant Int := Length;
 136
 137       begin
 138          Locked   := False;
 139          Last_Val := Min - 1;
 140          Max      := Min + (Table_Initial * Table_Factor) - 1;
 141          Length   := Max - Min + 1;
 142
 143          --  If table is same size as before (happens when table is never
 144          --  expanded which is a common case), then simply reuse it. Note
 145          --  that this also means that an explicit Init call right after
 146          --  the implicit one in the package body is harmless.
 147
 148          if Old_Length = Length then
 149             return;
 150
 151          --  Otherwise we can use Reallocate to get a table of the right size.
 152          --  Note that Reallocate works fine to allocate a table of the right
 153          --  initial size when it is first allocated.
 154
 155          else
 156             Reallocate;
 157          end if;
 158       end Init;
 159
 160       ----------
 161       -- Last --
 162       ----------
 163
 164       function Last return Table_Index_Type is
 165       begin
 166          return Table_Index_Type (Last_Val);
 167       end Last;
 168
 169       ----------------
 170       -- Reallocate --
 171       ----------------
 172
 173       procedure Reallocate is
 174          New_Size   : Memory.size_t;
 175          New_Length : Long_Long_Integer;
 176
 177       begin
 178          if Max < Last_Val then
 179             pragma Assert (not Locked);
 180
 181             --  Make sure that we have at least the initial allocation. This
 182             --  is needed in cases where a zero length table is written out.
 183
 184             Length := Int'Max (Length, Table_Initial);
 185
 186             --  Now increment table length until it is sufficiently large. Use
 187             --  the increment value or 10, which ever is larger (the reason
 188             --  for the use of 10 here is to ensure that the table does really
 189             --  increase in size (which would not be the case for a table of
 190             --  length 10 increased by 3% for instance). Do the intermediate
 191             --  calculation in Long_Long_Integer to avoid overflow.
 192
 193             while Max < Last_Val loop
 194                New_Length :=
 195                  Long_Long_Integer (Length) *
 196                     (100 + Long_Long_Integer (Table_Increment)) / 100;
 197                Length := Int'Max (Int (New_Length), Length + 10);
 198                Max := Min + Length - 1;
 199             end loop;
 200
 201             if Debug_Flag_D then
 202                Write_Str ("--> Allocating new ");
 203                Write_Str (Table_Name);
 204                Write_Str (" table, size = ");
 205                Write_Int (Max - Min + 1);
 206                Write_Eol;
 207             end if;
 208          end if;
 209
 210          --  Do the intermediate calculation in size_t to avoid signed overflow
 211
 212          New_Size :=
 213            Memory.size_t (Max - Min + 1) *
 214                                     (Table_Type'Component_Size / Storage_Unit);
 215
 216          if Table = null then
 217             Table := To_Pointer (Alloc (New_Size));
 218
 219          elsif New_Size > 0 then
 220             Table :=
 221               To_Pointer (Realloc (Ptr  => To_Address (Table),
 222                                    Size => New_Size));
 223          end if;
 224
 225          if Length /= 0 and then Table = null then
 226             Set_Standard_Error;
 227             Write_Str ("available memory exhausted");
 228             Write_Eol;
 229             Set_Standard_Output;
 230             raise Unrecoverable_Error;
 231          end if;
 232
 233       end Reallocate;
 234
 235       -------------
 236       -- Release --
 237       -------------
 238
 239       procedure Release is
 240       begin
 241          Length := Last_Val - Int (Table_Low_Bound) + 1;
 242          Max    := Last_Val;
 243          Reallocate;
 244       end Release;
 245
 246       -------------
 247       -- Restore --
 248       -------------
 249
 250       procedure Restore (T : Saved_Table) is
 251       begin
 252          Free (To_Address (Table));
 253          Last_Val := T.Last_Val;
 254          Max      := T.Max;
 255          Table    := T.Table;
 256          Length   := Max - Min + 1;
 257       end Restore;
 258
 259       ----------
 260       -- Save --
 261       ----------
 262
 263       function Save return Saved_Table is
 264          Res : Saved_Table;
 265
 266       begin
 267          Res.Last_Val := Last_Val;
 268          Res.Max      := Max;
 269          Res.Table    := Table;
 270
 271          Table  := null;
 272          Length := 0;
 273          Init;
 274          return Res;
 275       end Save;
 276
 277       --------------
 278       -- Set_Item --
 279       --------------
 280
 281       procedure Set_Item
 282          (Index : Table_Index_Type;
 283           Item  : Table_Component_Type)
 284       is
 285          --  If Item is a value within the current allocation, and we are going
 286          --  to reallocate, then we must preserve an intermediate copy here
 287          --  before calling Increment_Last. Otherwise, if Table_Component_Type
 288          --  is passed by reference, we are going to end up copying from
 289          --  storage that might have been deallocated from Increment_Last
 290          --  calling Reallocate.
 291
 292          subtype Allocated_Table_T is
 293            Table_Type (Table'First .. Table_Index_Type (Max + 1));
 294          --  A constrained table subtype one element larger than the currently
 295          --  allocated table.
 296
 297          Allocated_Table_Address : constant System.Address :=
 298                                      Table.all'Address;
 299          --  Used for address clause below (we can't use non-static expression
 300          --  Table.all'Address directly in the clause because some older
 301          --  versions of the compiler do not allow it).
 302
 303          Allocated_Table : Allocated_Table_T;
 304          pragma Import (Ada, Allocated_Table);
 305          pragma Suppress (Range_Check, On => Allocated_Table);
 306          for Allocated_Table'Address use Allocated_Table_Address;
 307          --  Allocated_Table represents the currently allocated array, plus one
 308          --  element (the supplementary element is used to have a convenient
 309          --  way of computing the address just past the end of the current
 310          --  allocation). Range checks are suppressed because this unit
 311          --  uses direct calls to System.Memory for allocation, and this can
 312          --  yield misaligned storage (and we cannot rely on the bootstrap
 313          --  compiler supporting specifically disabling alignment checks, so we
 314          --  need to suppress all range checks). It is safe to suppress this
 315          --  check here because we know that a (possibly misaligned) object
 316          --  of that type does actually exist at that address.
 317          --  ??? We should really improve the allocation circuitry here to
 318          --  guarantee proper alignment.
 319
 320          Need_Realloc : constant Boolean := Int (Index) > Max;
 321          --  True if this operation requires storage reallocation (which may
 322          --  involve moving table contents around).
 323
 324       begin
 325          --  If we're going to reallocate, check whether Item references an
 326          --  element of the currently allocated table.
 327
 328          if Need_Realloc
 329            and then Allocated_Table'Address <= Item'Address
 330            and then Item'Address <
 331                       Allocated_Table (Table_Index_Type (Max + 1))'Address
 332          then
 333             --  If so, save a copy on the stack because Increment_Last will
 334             --  reallocate storage and might deallocate the current table.
 335
 336             declare
 337                Item_Copy : constant Table_Component_Type := Item;
 338             begin
 339                Set_Last (Index);
 340                Table (Index) := Item_Copy;
 341             end;
 342
 343          else
 344             --  Here we know that either we won't reallocate (case of Index <
 345             --  Max) or that Item is not in the currently allocated table.
 346
 347             if Int (Index) > Last_Val then
 348                Set_Last (Index);
 349             end if;
 350
 351             Table (Index) := Item;
 352          end if;
 353       end Set_Item;
 354
 355       --------------
 356       -- Set_Last --
 357       --------------
 358
 359       procedure Set_Last (New_Val : Table_Index_Type) is
 360       begin
 361          if Int (New_Val) < Last_Val then
 362             Last_Val := Int (New_Val);
 363
 364          else
 365             Last_Val := Int (New_Val);
 366
 367             if Last_Val > Max then
 368                Reallocate;
 369             end if;
 370          end if;
 371       end Set_Last;
 372
 373       ----------------------------
 374       -- Tree_Get_Table_Address --
 375       ----------------------------
 376
 377       function Tree_Get_Table_Address return Address is
 378       begin
 379          if Length = 0 then
 380             return Null_Address;
 381          else
 382             return Table (First)'Address;
 383          end if;
 384       end Tree_Get_Table_Address;
 385
 386       ---------------
 387       -- Tree_Read --
 388       ---------------
 389
 390       --  Note: we allocate only the space required to accommodate the data
 391       --  actually written, which means that a Tree_Write/Tree_Read sequence
 392       --  does an implicit Release.
 393
 394       procedure Tree_Read is
 395       begin
 396          Tree_Read_Int (Max);
 397          Last_Val := Max;
 398          Length := Max - Min + 1;
 399          Reallocate;
 400
 401          Tree_Read_Data
 402            (Tree_Get_Table_Address,
 403              (Last_Val - Int (First) + 1) *
 404
 405                --  Note the importance of parenthesizing the following division
 406                --  to avoid the possibility of intermediate overflow.
 407
 408                (Table_Type'Component_Size / Storage_Unit));
 409       end Tree_Read;
 410
 411       ----------------
 412       -- Tree_Write --
 413       ----------------
 414
 415       --  Note: we write out only the currently valid data, not the entire
 416       --  contents of the allocated array. See note above on Tree_Read.
 417
 418       procedure Tree_Write is
 419       begin
 420          Tree_Write_Int (Int (Last));
 421          Tree_Write_Data
 422            (Tree_Get_Table_Address,
 423             (Last_Val - Int (First) + 1) *
 424               (Table_Type'Component_Size / Storage_Unit));
 425       end Tree_Write;
 426
 427    begin
 428       Init;
 429    end Table;
 430 end Table;