gcc/ada/sem_aux.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ A U X                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- As a special exception,  if other files  instantiate  generics from this --
  22 -- unit, or you link  this unit with other files  to produce an executable, --
  23 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  24 -- covered  by the  GNU  General  Public  License.  This exception does not --
  25 -- however invalidate  any other reasons why  the executable file  might be --
  26 -- covered by the  GNU Public License.                                      --
  27 --                                                                          --
  28 -- GNAT was originally developed  by the GNAT team at  New York University. --
  29 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 with Atree;  use Atree;
  34 with Einfo;  use Einfo;
  35 with Snames; use Snames;
  36 with Stand;  use Stand;
  37 with Uintp;  use Uintp;
  38
  39 package body Sem_Aux is
  40
  41    ----------------------
  42    -- Ancestor_Subtype --
  43    ----------------------
  44
  45    function Ancestor_Subtype (Typ : Entity_Id) return Entity_Id is
  46    begin
  47       --  If this is first subtype, or is a base type, then there is no
  48       --  ancestor subtype, so we return Empty to indicate this fact.
  49
  50       if Is_First_Subtype (Typ) or else Is_Base_Type (Typ) then
  51          return Empty;
  52       end if;
  53
  54       declare
  55          D : constant Node_Id := Declaration_Node (Typ);
  56
  57       begin
  58          --  If we have a subtype declaration, get the ancestor subtype
  59
  60          if Nkind (D) = N_Subtype_Declaration then
  61             if Nkind (Subtype_Indication (D)) = N_Subtype_Indication then
  62                return Entity (Subtype_Mark (Subtype_Indication (D)));
  63             else
  64                return Entity (Subtype_Indication (D));
  65             end if;
  66
  67          --  If not, then no subtype indication is available
  68
  69          else
  70             return Empty;
  71          end if;
  72       end;
  73    end Ancestor_Subtype;
  74
  75    --------------------
  76    -- Available_View --
  77    --------------------
  78
  79    function Available_View (Ent : Entity_Id) return Entity_Id is
  80    begin
  81       --  Obtain the non-limited view (if available)
  82
  83       if Has_Non_Limited_View (Ent) then
  84          return Get_Full_View (Non_Limited_View (Ent));
  85
  86       --  In all other cases, return entity unchanged
  87
  88       else
  89          return Ent;
  90       end if;
  91    end Available_View;
  92
  93    --------------------
  94    -- Constant_Value --
  95    --------------------
  96
  97    function Constant_Value (Ent : Entity_Id) return Node_Id is
  98       D      : constant Node_Id := Declaration_Node (Ent);
  99       Full_D : Node_Id;
 100
 101    begin
 102       --  If we have no declaration node, then return no constant value. Not
 103       --  clear how this can happen, but it does sometimes and this is the
 104       --  safest approach.
 105
 106       if No (D) then
 107          return Empty;
 108
 109       --  Normal case where a declaration node is present
 110
 111       elsif Nkind (D) = N_Object_Renaming_Declaration then
 112          return Renamed_Object (Ent);
 113
 114       --  If this is a component declaration whose entity is a constant, it is
 115       --  a prival within a protected function (and so has no constant value).
 116
 117       elsif Nkind (D) = N_Component_Declaration then
 118          return Empty;
 119
 120       --  If there is an expression, return it
 121
 122       elsif Present (Expression (D)) then
 123          return Expression (D);
 124
 125       --  For a constant, see if we have a full view
 126
 127       elsif Ekind (Ent) = E_Constant
 128         and then Present (Full_View (Ent))
 129       then
 130          Full_D := Parent (Full_View (Ent));
 131
 132          --  The full view may have been rewritten as an object renaming
 133
 134          if Nkind (Full_D) = N_Object_Renaming_Declaration then
 135             return Name (Full_D);
 136          else
 137             return Expression (Full_D);
 138          end if;
 139
 140       --  Otherwise we have no expression to return
 141
 142       else
 143          return Empty;
 144       end if;
 145    end Constant_Value;
 146
 147    ---------------------------------
 148    -- Corresponding_Unsigned_Type --
 149    ---------------------------------
 150
 151    function Corresponding_Unsigned_Type (Typ : Entity_Id) return Entity_Id is
 152       pragma Assert (Is_Signed_Integer_Type (Typ));
 153       Siz : constant Uint := Esize (Base_Type (Typ));
 154    begin
 155       if Siz = Esize (Standard_Short_Short_Integer) then
 156          return Standard_Short_Short_Unsigned;
 157       elsif Siz = Esize (Standard_Short_Integer) then
 158          return Standard_Short_Unsigned;
 159       elsif Siz = Esize (Standard_Unsigned) then
 160          return Standard_Unsigned;
 161       elsif Siz = Esize (Standard_Long_Integer) then
 162          return Standard_Long_Unsigned;
 163       elsif Siz = Esize (Standard_Long_Long_Integer) then
 164          return Standard_Long_Long_Unsigned;
 165       else
 166          raise Program_Error;
 167       end if;
 168    end Corresponding_Unsigned_Type;
 169
 170    -----------------------------
 171    -- Enclosing_Dynamic_Scope --
 172    -----------------------------
 173
 174    function Enclosing_Dynamic_Scope (Ent : Entity_Id) return Entity_Id is
 175       S : Entity_Id;
 176
 177    begin
 178       --  The following test is an error defense against some syntax errors
 179       --  that can leave scopes very messed up.
 180
 181       if Ent = Standard_Standard then
 182          return Ent;
 183       end if;
 184
 185       --  Normal case, search enclosing scopes
 186
 187       --  Note: the test for Present (S) should not be required, it defends
 188       --  against an ill-formed tree.
 189
 190       S := Scope (Ent);
 191       loop
 192          --  If we somehow got an empty value for Scope, the tree must be
 193          --  malformed. Rather than blow up we return Standard in this case.
 194
 195          if No (S) then
 196             return Standard_Standard;
 197
 198          --  Quit if we get to standard or a dynamic scope. We must also
 199          --  handle enclosing scopes that have a full view; required to
 200          --  locate enclosing scopes that are synchronized private types
 201          --  whose full view is a task type.
 202
 203          elsif S = Standard_Standard
 204            or else Is_Dynamic_Scope (S)
 205            or else (Is_Private_Type (S)
 206                      and then Present (Full_View (S))
 207                      and then Is_Dynamic_Scope (Full_View (S)))
 208          then
 209             return S;
 210
 211          --  Otherwise keep climbing
 212
 213          else
 214             S := Scope (S);
 215          end if;
 216       end loop;
 217    end Enclosing_Dynamic_Scope;
 218
 219    ------------------------
 220    -- First_Discriminant --
 221    ------------------------
 222
 223    function First_Discriminant (Typ : Entity_Id) return Entity_Id is
 224       Ent : Entity_Id;
 225
 226    begin
 227       pragma Assert
 228         (Has_Discriminants (Typ) or else Has_Unknown_Discriminants (Typ));
 229
 230       Ent := First_Entity (Typ);
 231
 232       --  The discriminants are not necessarily contiguous, because access
 233       --  discriminants will generate itypes. They are not the first entities
 234       --  either because the tag must be ahead of them.
 235
 236       if Chars (Ent) = Name_uTag then
 237          Ent := Next_Entity (Ent);
 238       end if;
 239
 240       --  Skip all hidden stored discriminants if any
 241
 242       while Present (Ent) loop
 243          exit when Ekind (Ent) = E_Discriminant
 244            and then not Is_Completely_Hidden (Ent);
 245
 246          Ent := Next_Entity (Ent);
 247       end loop;
 248
 249       --  Call may be on a private type with unknown discriminants, in which
 250       --  case Ent is Empty, and as per the spec, we return Empty in this case.
 251
 252       --  Historical note: The assertion in previous versions that Ent is a
 253       --  discriminant was overly cautious and prevented convenient application
 254       --  of this function in the gnatprove context.
 255
 256       return Ent;
 257    end First_Discriminant;
 258
 259    -------------------------------
 260    -- First_Stored_Discriminant --
 261    -------------------------------
 262
 263    function First_Stored_Discriminant (Typ : Entity_Id) return Entity_Id is
 264       Ent : Entity_Id;
 265
 266       function Has_Completely_Hidden_Discriminant
 267         (Typ : Entity_Id) return Boolean;
 268       --  Scans the Discriminants to see whether any are Completely_Hidden
 269       --  (the mechanism for describing non-specified stored discriminants)
 270       --  Note that the entity list for the type may contain anonymous access
 271       --  types created by expressions that constrain access discriminants.
 272
 273       ----------------------------------------
 274       -- Has_Completely_Hidden_Discriminant --
 275       ----------------------------------------
 276
 277       function Has_Completely_Hidden_Discriminant
 278         (Typ : Entity_Id) return Boolean
 279       is
 280          Ent : Entity_Id;
 281
 282       begin
 283          pragma Assert (Ekind (Typ) = E_Discriminant);
 284
 285          Ent := Typ;
 286          while Present (Ent) loop
 287
 288             --  Skip anonymous types that may be created by expressions
 289             --  used as discriminant constraints on inherited discriminants.
 290
 291             if Is_Itype (Ent) then
 292                null;
 293
 294             elsif Ekind (Ent) = E_Discriminant
 295               and then Is_Completely_Hidden (Ent)
 296             then
 297                return True;
 298             end if;
 299
 300             Ent := Next_Entity (Ent);
 301          end loop;
 302
 303          return False;
 304       end Has_Completely_Hidden_Discriminant;
 305
 306    --  Start of processing for First_Stored_Discriminant
 307
 308    begin
 309       pragma Assert
 310         (Has_Discriminants (Typ)
 311           or else Has_Unknown_Discriminants (Typ));
 312
 313       Ent := First_Entity (Typ);
 314
 315       if Chars (Ent) = Name_uTag then
 316          Ent := Next_Entity (Ent);
 317       end if;
 318
 319       if Has_Completely_Hidden_Discriminant (Ent) then
 320          while Present (Ent) loop
 321             exit when Ekind (Ent) = E_Discriminant
 322               and then Is_Completely_Hidden (Ent);
 323             Ent := Next_Entity (Ent);
 324          end loop;
 325       end if;
 326
 327       pragma Assert (Ekind (Ent) = E_Discriminant);
 328
 329       return Ent;
 330    end First_Stored_Discriminant;
 331
 332    -------------------
 333    -- First_Subtype --
 334    -------------------
 335
 336    function First_Subtype (Typ : Entity_Id) return Entity_Id is
 337       B   : constant Entity_Id := Base_Type (Typ);
 338       F   : constant Node_Id   := Freeze_Node (B);
 339       Ent : Entity_Id;
 340
 341    begin
 342       --  If the base type has no freeze node, it is a type in Standard, and
 343       --  always acts as its own first subtype, except where it is one of the
 344       --  predefined integer types. If the type is formal, it is also a first
 345       --  subtype, and its base type has no freeze node. On the other hand, a
 346       --  subtype of a generic formal is not its own first subtype. Its base
 347       --  type, if anonymous, is attached to the formal type decl. from which
 348       --  the first subtype is obtained.
 349
 350       if No (F) then
 351          if B = Base_Type (Standard_Integer) then
 352             return Standard_Integer;
 353
 354          elsif B = Base_Type (Standard_Long_Integer) then
 355             return Standard_Long_Integer;
 356
 357          elsif B = Base_Type (Standard_Short_Short_Integer) then
 358             return Standard_Short_Short_Integer;
 359
 360          elsif B = Base_Type (Standard_Short_Integer) then
 361             return Standard_Short_Integer;
 362
 363          elsif B = Base_Type (Standard_Long_Long_Integer) then
 364             return Standard_Long_Long_Integer;
 365
 366          elsif Is_Generic_Type (Typ) then
 367             if Present (Parent (B)) then
 368                return Defining_Identifier (Parent (B));
 369             else
 370                return Defining_Identifier (Associated_Node_For_Itype (B));
 371             end if;
 372
 373          else
 374             return B;
 375          end if;
 376
 377       --  Otherwise we check the freeze node, if it has a First_Subtype_Link
 378       --  then we use that link, otherwise (happens with some Itypes), we use
 379       --  the base type itself.
 380
 381       else
 382          Ent := First_Subtype_Link (F);
 383
 384          if Present (Ent) then
 385             return Ent;
 386          else
 387             return B;
 388          end if;
 389       end if;
 390    end First_Subtype;
 391
 392    -------------------------
 393    -- First_Tag_Component --
 394    -------------------------
 395
 396    function First_Tag_Component (Typ : Entity_Id) return Entity_Id is
 397       Comp : Entity_Id;
 398       Ctyp : Entity_Id;
 399
 400    begin
 401       Ctyp := Typ;
 402       pragma Assert (Is_Tagged_Type (Ctyp));
 403
 404       if Is_Class_Wide_Type (Ctyp) then
 405          Ctyp := Root_Type (Ctyp);
 406       end if;
 407
 408       if Is_Private_Type (Ctyp) then
 409          Ctyp := Underlying_Type (Ctyp);
 410
 411          --  If the underlying type is missing then the source program has
 412          --  errors and there is nothing else to do (the full-type declaration
 413          --  associated with the private type declaration is missing).
 414
 415          if No (Ctyp) then
 416             return Empty;
 417          end if;
 418       end if;
 419
 420       Comp := First_Entity (Ctyp);
 421       while Present (Comp) loop
 422          if Is_Tag (Comp) then
 423             return Comp;
 424          end if;
 425
 426          Comp := Next_Entity (Comp);
 427       end loop;
 428
 429       --  No tag component found
 430
 431       return Empty;
 432    end First_Tag_Component;
 433
 434    ---------------------
 435    -- Get_Binary_Nkind --
 436    ---------------------
 437
 438    function Get_Binary_Nkind (Op : Entity_Id) return Node_Kind is
 439    begin
 440       case Chars (Op) is
 441          when Name_Op_Add      => return N_Op_Add;
 442          when Name_Op_Concat   => return N_Op_Concat;
 443          when Name_Op_Expon    => return N_Op_Expon;
 444          when Name_Op_Subtract => return N_Op_Subtract;
 445          when Name_Op_Mod      => return N_Op_Mod;
 446          when Name_Op_Multiply => return N_Op_Multiply;
 447          when Name_Op_Divide   => return N_Op_Divide;
 448          when Name_Op_Rem      => return N_Op_Rem;
 449          when Name_Op_And      => return N_Op_And;
 450          when Name_Op_Eq       => return N_Op_Eq;
 451          when Name_Op_Ge       => return N_Op_Ge;
 452          when Name_Op_Gt       => return N_Op_Gt;
 453          when Name_Op_Le       => return N_Op_Le;
 454          when Name_Op_Lt       => return N_Op_Lt;
 455          when Name_Op_Ne       => return N_Op_Ne;
 456          when Name_Op_Or       => return N_Op_Or;
 457          when Name_Op_Xor      => return N_Op_Xor;
 458          when others           => raise Program_Error;
 459       end case;
 460    end Get_Binary_Nkind;
 461
 462    -------------------
 463    -- Get_Low_Bound --
 464    -------------------
 465
 466    function Get_Low_Bound (E : Entity_Id) return Node_Id is
 467    begin
 468       if Ekind (E) = E_String_Literal_Subtype then
 469          return String_Literal_Low_Bound (E);
 470       else
 471          return Type_Low_Bound (E);
 472       end if;
 473    end Get_Low_Bound;
 474
 475    ------------------
 476    -- Get_Rep_Item --
 477    ------------------
 478
 479    function Get_Rep_Item
 480      (E             : Entity_Id;
 481       Nam           : Name_Id;
 482       Check_Parents : Boolean := True) return Node_Id
 483    is
 484       N : Node_Id;
 485
 486    begin
 487       N := First_Rep_Item (E);
 488       while Present (N) loop
 489
 490          --  Only one of Priority / Interrupt_Priority can be specified, so
 491          --  return whichever one is present to catch illegal duplication.
 492
 493          if Nkind (N) = N_Pragma
 494            and then
 495              (Pragma_Name_Unmapped (N) = Nam
 496                or else (Nam = Name_Priority
 497                          and then Pragma_Name (N) =
 498                            Name_Interrupt_Priority)
 499                or else (Nam = Name_Interrupt_Priority
 500                          and then Pragma_Name (N) = Name_Priority))
 501          then
 502             if Check_Parents then
 503                return N;
 504
 505             --  If Check_Parents is False, return N if the pragma doesn't
 506             --  appear in the Rep_Item chain of the parent.
 507
 508             else
 509                declare
 510                   Par : constant Entity_Id := Nearest_Ancestor (E);
 511                   --  This node represents the parent type of type E (if any)
 512
 513                begin
 514                   if No (Par) then
 515                      return N;
 516
 517                   elsif not Present_In_Rep_Item (Par, N) then
 518                      return N;
 519                   end if;
 520                end;
 521             end if;
 522
 523          elsif Nkind (N) = N_Attribute_Definition_Clause
 524            and then
 525              (Chars (N) = Nam
 526                or else (Nam = Name_Priority
 527                          and then Chars (N) = Name_Interrupt_Priority))
 528          then
 529             if Check_Parents or else Entity (N) = E then
 530                return N;
 531             end if;
 532
 533          elsif Nkind (N) = N_Aspect_Specification
 534            and then
 535              (Chars (Identifier (N)) = Nam
 536                or else
 537                  (Nam = Name_Priority
 538                    and then Chars (Identifier (N)) = Name_Interrupt_Priority))
 539          then
 540             if Check_Parents then
 541                return N;
 542
 543             elsif Entity (N) = E then
 544                return N;
 545             end if;
 546          end if;
 547
 548          Next_Rep_Item (N);
 549       end loop;
 550
 551       return Empty;
 552    end Get_Rep_Item;
 553
 554    function Get_Rep_Item
 555      (E             : Entity_Id;
 556       Nam1          : Name_Id;
 557       Nam2          : Name_Id;
 558       Check_Parents : Boolean := True) return Node_Id
 559    is
 560       Nam1_Item : constant Node_Id := Get_Rep_Item (E, Nam1, Check_Parents);
 561       Nam2_Item : constant Node_Id := Get_Rep_Item (E, Nam2, Check_Parents);
 562
 563       N : Node_Id;
 564
 565    begin
 566       --  Check both Nam1_Item and Nam2_Item are present
 567
 568       if No (Nam1_Item) then
 569          return Nam2_Item;
 570       elsif No (Nam2_Item) then
 571          return Nam1_Item;
 572       end if;
 573
 574       --  Return the first node encountered in the list
 575
 576       N := First_Rep_Item (E);
 577       while Present (N) loop
 578          if N = Nam1_Item or else N = Nam2_Item then
 579             return N;
 580          end if;
 581
 582          Next_Rep_Item (N);
 583       end loop;
 584
 585       return Empty;
 586    end Get_Rep_Item;
 587
 588    --------------------
 589    -- Get_Rep_Pragma --
 590    --------------------
 591
 592    function Get_Rep_Pragma
 593      (E             : Entity_Id;
 594       Nam           : Name_Id;
 595       Check_Parents : Boolean := True) return Node_Id
 596    is
 597       N : constant Node_Id := Get_Rep_Item (E, Nam, Check_Parents);
 598
 599    begin
 600       if Present (N) and then Nkind (N) = N_Pragma then
 601          return N;
 602       end if;
 603
 604       return Empty;
 605    end Get_Rep_Pragma;
 606
 607    function Get_Rep_Pragma
 608      (E             : Entity_Id;
 609       Nam1          : Name_Id;
 610       Nam2          : Name_Id;
 611       Check_Parents : Boolean := True) return Node_Id
 612    is
 613       Nam1_Item : constant Node_Id := Get_Rep_Pragma (E, Nam1, Check_Parents);
 614       Nam2_Item : constant Node_Id := Get_Rep_Pragma (E, Nam2, Check_Parents);
 615
 616       N : Node_Id;
 617
 618    begin
 619       --  Check both Nam1_Item and Nam2_Item are present
 620
 621       if No (Nam1_Item) then
 622          return Nam2_Item;
 623       elsif No (Nam2_Item) then
 624          return Nam1_Item;
 625       end if;
 626
 627       --  Return the first node encountered in the list
 628
 629       N := First_Rep_Item (E);
 630       while Present (N) loop
 631          if N = Nam1_Item or else N = Nam2_Item then
 632             return N;
 633          end if;
 634
 635          Next_Rep_Item (N);
 636       end loop;
 637
 638       return Empty;
 639    end Get_Rep_Pragma;
 640
 641    ---------------------
 642    -- Get_Unary_Nkind --
 643    ---------------------
 644
 645    function Get_Unary_Nkind (Op : Entity_Id) return Node_Kind is
 646    begin
 647       case Chars (Op) is
 648          when Name_Op_Abs      => return N_Op_Abs;
 649          when Name_Op_Subtract => return N_Op_Minus;
 650          when Name_Op_Not      => return N_Op_Not;
 651          when Name_Op_Add      => return N_Op_Plus;
 652          when others           => raise Program_Error;
 653       end case;
 654    end Get_Unary_Nkind;
 655
 656    ---------------------------------
 657    -- Has_External_Tag_Rep_Clause --
 658    ---------------------------------
 659
 660    function Has_External_Tag_Rep_Clause (T : Entity_Id) return Boolean is
 661    begin
 662       pragma Assert (Is_Tagged_Type (T));
 663       return Has_Rep_Item (T, Name_External_Tag, Check_Parents => False);
 664    end Has_External_Tag_Rep_Clause;
 665
 666    ------------------
 667    -- Has_Rep_Item --
 668    ------------------
 669
 670    function Has_Rep_Item
 671      (E             : Entity_Id;
 672       Nam           : Name_Id;
 673       Check_Parents : Boolean := True) return Boolean
 674    is
 675    begin
 676       return Present (Get_Rep_Item (E, Nam, Check_Parents));
 677    end Has_Rep_Item;
 678
 679    function Has_Rep_Item
 680      (E             : Entity_Id;
 681       Nam1          : Name_Id;
 682       Nam2          : Name_Id;
 683       Check_Parents : Boolean := True) return Boolean
 684    is
 685    begin
 686       return Present (Get_Rep_Item (E, Nam1, Nam2, Check_Parents));
 687    end Has_Rep_Item;
 688
 689    function Has_Rep_Item (E : Entity_Id; N : Node_Id) return Boolean is
 690       Item : Node_Id;
 691
 692    begin
 693       pragma Assert
 694         (Nkind_In (N, N_Aspect_Specification,
 695                       N_Attribute_Definition_Clause,
 696                       N_Enumeration_Representation_Clause,
 697                       N_Pragma,
 698                       N_Record_Representation_Clause));
 699
 700       Item := First_Rep_Item (E);
 701       while Present (Item) loop
 702          if Item = N then
 703             return True;
 704          end if;
 705
 706          Item := Next_Rep_Item (Item);
 707       end loop;
 708
 709       return False;
 710    end Has_Rep_Item;
 711
 712    --------------------
 713    -- Has_Rep_Pragma --
 714    --------------------
 715
 716    function Has_Rep_Pragma
 717      (E             : Entity_Id;
 718       Nam           : Name_Id;
 719       Check_Parents : Boolean := True) return Boolean
 720    is
 721    begin
 722       return Present (Get_Rep_Pragma (E, Nam, Check_Parents));
 723    end Has_Rep_Pragma;
 724
 725    function Has_Rep_Pragma
 726      (E             : Entity_Id;
 727       Nam1          : Name_Id;
 728       Nam2          : Name_Id;
 729       Check_Parents : Boolean := True) return Boolean
 730    is
 731    begin
 732       return Present (Get_Rep_Pragma (E, Nam1, Nam2, Check_Parents));
 733    end Has_Rep_Pragma;
 734
 735    --------------------------------
 736    -- Has_Unconstrained_Elements --
 737    --------------------------------
 738
 739    function Has_Unconstrained_Elements (T : Entity_Id) return Boolean is
 740       U_T : constant Entity_Id := Underlying_Type (T);
 741    begin
 742       if No (U_T) then
 743          return False;
 744       elsif Is_Record_Type (U_T) then
 745          return Has_Discriminants (U_T) and then not Is_Constrained (U_T);
 746       elsif Is_Array_Type (U_T) then
 747          return Has_Unconstrained_Elements (Component_Type (U_T));
 748       else
 749          return False;
 750       end if;
 751    end Has_Unconstrained_Elements;
 752
 753    ----------------------
 754    -- Has_Variant_Part --
 755    ----------------------
 756
 757    function Has_Variant_Part (Typ : Entity_Id) return Boolean is
 758       FSTyp : Entity_Id;
 759       Decl  : Node_Id;
 760       TDef  : Node_Id;
 761       CList : Node_Id;
 762
 763    begin
 764       if not Is_Type (Typ) then
 765          return False;
 766       end if;
 767
 768       FSTyp := First_Subtype (Typ);
 769
 770       if not Has_Discriminants (FSTyp) then
 771          return False;
 772       end if;
 773
 774       --  Proceed with cautious checks here, return False if tree is not
 775       --  as expected (may be caused by prior errors).
 776
 777       Decl := Declaration_Node (FSTyp);
 778
 779       if Nkind (Decl) /= N_Full_Type_Declaration then
 780          return False;
 781       end if;
 782
 783       TDef := Type_Definition (Decl);
 784
 785       if Nkind (TDef) /= N_Record_Definition then
 786          return False;
 787       end if;
 788
 789       CList := Component_List (TDef);
 790
 791       if Nkind (CList) /= N_Component_List then
 792          return False;
 793       else
 794          return Present (Variant_Part (CList));
 795       end if;
 796    end Has_Variant_Part;
 797
 798    ---------------------
 799    -- In_Generic_Body --
 800    ---------------------
 801
 802    function In_Generic_Body (Id : Entity_Id) return Boolean is
 803       S : Entity_Id;
 804
 805    begin
 806       --  Climb scopes looking for generic body
 807
 808       S := Id;
 809       while Present (S) and then S /= Standard_Standard loop
 810
 811          --  Generic package body
 812
 813          if Ekind (S) = E_Generic_Package
 814            and then In_Package_Body (S)
 815          then
 816             return True;
 817
 818          --  Generic subprogram body
 819
 820          elsif Is_Subprogram (S)
 821            and then Nkind (Unit_Declaration_Node (S)) =
 822                       N_Generic_Subprogram_Declaration
 823          then
 824             return True;
 825          end if;
 826
 827          S := Scope (S);
 828       end loop;
 829
 830       --  False if top of scope stack without finding a generic body
 831
 832       return False;
 833    end In_Generic_Body;
 834
 835    -------------------------------
 836    -- Initialization_Suppressed --
 837    -------------------------------
 838
 839    function Initialization_Suppressed (Typ : Entity_Id) return Boolean is
 840    begin
 841       return Suppress_Initialization (Typ)
 842         or else Suppress_Initialization (Base_Type (Typ));
 843    end Initialization_Suppressed;
 844
 845    ----------------
 846    -- Initialize --
 847    ----------------
 848
 849    procedure Initialize is
 850    begin
 851       Obsolescent_Warnings.Init;
 852    end Initialize;
 853
 854    -------------
 855    -- Is_Body --
 856    -------------
 857
 858    function Is_Body (N : Node_Id) return Boolean is
 859    begin
 860       return
 861         Nkind (N) in N_Body_Stub
 862           or else Nkind_In (N, N_Entry_Body,
 863                                N_Package_Body,
 864                                N_Protected_Body,
 865                                N_Subprogram_Body,
 866                                N_Task_Body);
 867    end Is_Body;
 868
 869    ---------------------
 870    -- Is_By_Copy_Type --
 871    ---------------------
 872
 873    function Is_By_Copy_Type (Ent : Entity_Id) return Boolean is
 874    begin
 875       --  If Id is a private type whose full declaration has not been seen,
 876       --  we assume for now that it is not a By_Copy type. Clearly this
 877       --  attribute should not be used before the type is frozen, but it is
 878       --  needed to build the associated record of a protected type. Another
 879       --  place where some lookahead for a full view is needed ???
 880
 881       return
 882         Is_Elementary_Type (Ent)
 883           or else (Is_Private_Type (Ent)
 884                      and then Present (Underlying_Type (Ent))
 885                      and then Is_Elementary_Type (Underlying_Type (Ent)));
 886    end Is_By_Copy_Type;
 887
 888    --------------------------
 889    -- Is_By_Reference_Type --
 890    --------------------------
 891
 892    function Is_By_Reference_Type (Ent : Entity_Id) return Boolean is
 893       Btype : constant Entity_Id := Base_Type (Ent);
 894
 895    begin
 896       if Error_Posted (Ent) or else Error_Posted (Btype) then
 897          return False;
 898
 899       elsif Is_Private_Type (Btype) then
 900          declare
 901             Utyp : constant Entity_Id := Underlying_Type (Btype);
 902          begin
 903             if No (Utyp) then
 904                return False;
 905             else
 906                return Is_By_Reference_Type (Utyp);
 907             end if;
 908          end;
 909
 910       elsif Is_Incomplete_Type (Btype) then
 911          declare
 912             Ftyp : constant Entity_Id := Full_View (Btype);
 913          begin
 914             --  Return true for a tagged incomplete type built as a shadow
 915             --  entity in Build_Limited_Views. It can appear in the profile
 916             --  of a thunk and the back end needs to know how it is passed.
 917
 918             if No (Ftyp) then
 919                return Is_Tagged_Type (Btype);
 920             else
 921                return Is_By_Reference_Type (Ftyp);
 922             end if;
 923          end;
 924
 925       elsif Is_Concurrent_Type (Btype) then
 926          return True;
 927
 928       elsif Is_Record_Type (Btype) then
 929          if Is_Limited_Record (Btype)
 930            or else Is_Tagged_Type (Btype)
 931            or else Is_Volatile (Btype)
 932          then
 933             return True;
 934
 935          else
 936             declare
 937                C : Entity_Id;
 938
 939             begin
 940                C := First_Component (Btype);
 941                while Present (C) loop
 942
 943                   --  For each component, test if its type is a by reference
 944                   --  type and if its type is volatile. Also test the component
 945                   --  itself for being volatile. This happens for example when
 946                   --  a Volatile aspect is added to a component.
 947
 948                   if Is_By_Reference_Type (Etype (C))
 949                     or else Is_Volatile (Etype (C))
 950                     or else Is_Volatile (C)
 951                   then
 952                      return True;
 953                   end if;
 954
 955                   C := Next_Component (C);
 956                end loop;
 957             end;
 958
 959             return False;
 960          end if;
 961
 962       elsif Is_Array_Type (Btype) then
 963          return
 964            Is_Volatile (Btype)
 965              or else Is_By_Reference_Type (Component_Type (Btype))
 966              or else Is_Volatile (Component_Type (Btype))
 967              or else Has_Volatile_Components (Btype);
 968
 969       else
 970          return False;
 971       end if;
 972    end Is_By_Reference_Type;
 973
 974    -------------------------
 975    -- Is_Definite_Subtype --
 976    -------------------------
 977
 978    function Is_Definite_Subtype (T : Entity_Id) return Boolean is
 979       pragma Assert (Is_Type (T));
 980       K : constant Entity_Kind := Ekind (T);
 981
 982    begin
 983       if Is_Constrained (T) then
 984          return True;
 985
 986       elsif K in Array_Kind
 987         or else K in Class_Wide_Kind
 988         or else Has_Unknown_Discriminants (T)
 989       then
 990          return False;
 991
 992       --  Known discriminants: definite if there are default values. Note that
 993       --  if any discriminant has a default, they all do.
 994
 995       elsif Has_Discriminants (T) then
 996          return Present (Discriminant_Default_Value (First_Discriminant (T)));
 997
 998       else
 999          return True;
1000       end if;
1001    end Is_Definite_Subtype;
1002
1003    ---------------------
1004    -- Is_Derived_Type --
1005    ---------------------
1006
1007    function Is_Derived_Type (Ent : E) return B is
1008       Par : Node_Id;
1009
1010    begin
1011       if Is_Type (Ent)
1012         and then Base_Type (Ent) /= Root_Type (Ent)
1013         and then not Is_Class_Wide_Type (Ent)
1014
1015         --  An access_to_subprogram whose result type is a limited view can
1016         --  appear in a return statement, without the full view of the result
1017         --  type being available. Do not interpret this as a derived type.
1018
1019         and then Ekind (Ent) /= E_Subprogram_Type
1020       then
1021          if not Is_Numeric_Type (Root_Type (Ent)) then
1022             return True;
1023
1024          else
1025             Par := Parent (First_Subtype (Ent));
1026
1027             return Present (Par)
1028               and then Nkind (Par) = N_Full_Type_Declaration
1029               and then Nkind (Type_Definition (Par)) =
1030                          N_Derived_Type_Definition;
1031          end if;
1032
1033       else
1034          return False;
1035       end if;
1036    end Is_Derived_Type;
1037
1038    -----------------------
1039    -- Is_Generic_Formal --
1040    -----------------------
1041
1042    function Is_Generic_Formal (E : Entity_Id) return Boolean is
1043       Kind : Node_Kind;
1044    begin
1045       if No (E) then
1046          return False;
1047       else
1048          Kind := Nkind (Parent (E));
1049          return
1050            Nkind_In (Kind, N_Formal_Object_Declaration,
1051                            N_Formal_Package_Declaration,
1052                            N_Formal_Type_Declaration)
1053              or else Is_Formal_Subprogram (E);
1054       end if;
1055    end Is_Generic_Formal;
1056
1057    -------------------------------
1058    -- Is_Immutably_Limited_Type --
1059    -------------------------------
1060
1061    function Is_Immutably_Limited_Type (Ent : Entity_Id) return Boolean is
1062       Btype : constant Entity_Id := Available_View (Base_Type (Ent));
1063
1064    begin
1065       if Is_Limited_Record (Btype) then
1066          return True;
1067
1068       elsif Ekind (Btype) = E_Limited_Private_Type
1069         and then Nkind (Parent (Btype)) = N_Formal_Type_Declaration
1070       then
1071          return not In_Package_Body (Scope ((Btype)));
1072
1073       elsif Is_Private_Type (Btype) then
1074
1075          --  AI05-0063: A type derived from a limited private formal type is
1076          --  not immutably limited in a generic body.
1077
1078          if Is_Derived_Type (Btype)
1079            and then Is_Generic_Type (Etype (Btype))
1080          then
1081             if not Is_Limited_Type (Etype (Btype)) then
1082                return False;
1083
1084             --  A descendant of a limited formal type is not immutably limited
1085             --  in the generic body, or in the body of a generic child.
1086
1087             elsif Ekind (Scope (Etype (Btype))) = E_Generic_Package then
1088                return not In_Package_Body (Scope (Btype));
1089
1090             else
1091                return False;
1092             end if;
1093
1094          else
1095             declare
1096                Utyp : constant Entity_Id := Underlying_Type (Btype);
1097             begin
1098                if No (Utyp) then
1099                   return False;
1100                else
1101                   return Is_Immutably_Limited_Type (Utyp);
1102                end if;
1103             end;
1104          end if;
1105
1106       elsif Is_Concurrent_Type (Btype) then
1107          return True;
1108
1109       else
1110          return False;
1111       end if;
1112    end Is_Immutably_Limited_Type;
1113
1114    ---------------------
1115    -- Is_Limited_Type --
1116    ---------------------
1117
1118    function Is_Limited_Type (Ent : Entity_Id) return Boolean is
1119       Btype : constant E := Base_Type (Ent);
1120       Rtype : constant E := Root_Type (Btype);
1121
1122    begin
1123       if not Is_Type (Ent) then
1124          return False;
1125
1126       elsif Ekind (Btype) = E_Limited_Private_Type
1127         or else Is_Limited_Composite (Btype)
1128       then
1129          return True;
1130
1131       elsif Is_Concurrent_Type (Btype) then
1132          return True;
1133
1134          --  The Is_Limited_Record flag normally indicates that the type is
1135          --  limited. The exception is that a type does not inherit limitedness
1136          --  from its interface ancestor. So the type may be derived from a
1137          --  limited interface, but is not limited.
1138
1139       elsif Is_Limited_Record (Ent)
1140         and then not Is_Interface (Ent)
1141       then
1142          return True;
1143
1144       --  Otherwise we will look around to see if there is some other reason
1145       --  for it to be limited, except that if an error was posted on the
1146       --  entity, then just assume it is non-limited, because it can cause
1147       --  trouble to recurse into a murky entity resulting from other errors.
1148
1149       elsif Error_Posted (Ent) then
1150          return False;
1151
1152       elsif Is_Record_Type (Btype) then
1153
1154          if Is_Limited_Interface (Ent) then
1155             return True;
1156
1157          --  AI-419: limitedness is not inherited from a limited interface
1158
1159          elsif Is_Limited_Record (Rtype) then
1160             return not Is_Interface (Rtype)
1161               or else Is_Protected_Interface (Rtype)
1162               or else Is_Synchronized_Interface (Rtype)
1163               or else Is_Task_Interface (Rtype);
1164
1165          elsif Is_Class_Wide_Type (Btype) then
1166             return Is_Limited_Type (Rtype);
1167
1168          else
1169             declare
1170                C : E;
1171
1172             begin
1173                C := First_Component (Btype);
1174                while Present (C) loop
1175                   if Is_Limited_Type (Etype (C)) then
1176                      return True;
1177                   end if;
1178
1179                   C := Next_Component (C);
1180                end loop;
1181             end;
1182
1183             return False;
1184          end if;
1185
1186       elsif Is_Array_Type (Btype) then
1187          return Is_Limited_Type (Component_Type (Btype));
1188
1189       else
1190          return False;
1191       end if;
1192    end Is_Limited_Type;
1193
1194    ---------------------
1195    -- Is_Limited_View --
1196    ---------------------
1197
1198    function Is_Limited_View (Ent : Entity_Id) return Boolean is
1199       Btype : constant Entity_Id := Available_View (Base_Type (Ent));
1200
1201    begin
1202       if Is_Limited_Record (Btype) then
1203          return True;
1204
1205       elsif Ekind (Btype) = E_Limited_Private_Type
1206         and then Nkind (Parent (Btype)) = N_Formal_Type_Declaration
1207       then
1208          return not In_Package_Body (Scope ((Btype)));
1209
1210       elsif Is_Private_Type (Btype) then
1211
1212          --  AI05-0063: A type derived from a limited private formal type is
1213          --  not immutably limited in a generic body.
1214
1215          if Is_Derived_Type (Btype)
1216            and then Is_Generic_Type (Etype (Btype))
1217          then
1218             if not Is_Limited_Type (Etype (Btype)) then
1219                return False;
1220
1221             --  A descendant of a limited formal type is not immutably limited
1222             --  in the generic body, or in the body of a generic child.
1223
1224             elsif Ekind (Scope (Etype (Btype))) = E_Generic_Package then
1225                return not In_Package_Body (Scope (Btype));
1226
1227             else
1228                return False;
1229             end if;
1230
1231          else
1232             declare
1233                Utyp : constant Entity_Id := Underlying_Type (Btype);
1234             begin
1235                if No (Utyp) then
1236                   return False;
1237                else
1238                   return Is_Limited_View (Utyp);
1239                end if;
1240             end;
1241          end if;
1242
1243       elsif Is_Concurrent_Type (Btype) then
1244          return True;
1245
1246       elsif Is_Record_Type (Btype) then
1247
1248          --  Note that we return True for all limited interfaces, even though
1249          --  (unsynchronized) limited interfaces can have descendants that are
1250          --  nonlimited, because this is a predicate on the type itself, and
1251          --  things like functions with limited interface results need to be
1252          --  handled as build in place even though they might return objects
1253          --  of a type that is not inherently limited.
1254
1255          if Is_Class_Wide_Type (Btype) then
1256             return Is_Limited_View (Root_Type (Btype));
1257
1258          else
1259             declare
1260                C : Entity_Id;
1261
1262             begin
1263                C := First_Component (Btype);
1264                while Present (C) loop
1265
1266                   --  Don't consider components with interface types (which can
1267                   --  only occur in the case of a _parent component anyway).
1268                   --  They don't have any components, plus it would cause this
1269                   --  function to return true for nonlimited types derived from
1270                   --  limited interfaces.
1271
1272                   if not Is_Interface (Etype (C))
1273                     and then Is_Limited_View (Etype (C))
1274                   then
1275                      return True;
1276                   end if;
1277
1278                   C := Next_Component (C);
1279                end loop;
1280             end;
1281
1282             return False;
1283          end if;
1284
1285       elsif Is_Array_Type (Btype) then
1286          return Is_Limited_View (Component_Type (Btype));
1287
1288       else
1289          return False;
1290       end if;
1291    end Is_Limited_View;
1292
1293    ----------------------
1294    -- Nearest_Ancestor --
1295    ----------------------
1296
1297    function Nearest_Ancestor (Typ : Entity_Id) return Entity_Id is
1298       D : constant Node_Id := Declaration_Node (Typ);
1299
1300    begin
1301       --  If we have a subtype declaration, get the ancestor subtype
1302
1303       if Nkind (D) = N_Subtype_Declaration then
1304          if Nkind (Subtype_Indication (D)) = N_Subtype_Indication then
1305             return Entity (Subtype_Mark (Subtype_Indication (D)));
1306          else
1307             return Entity (Subtype_Indication (D));
1308          end if;
1309
1310       --  If derived type declaration, find who we are derived from
1311
1312       elsif Nkind (D) = N_Full_Type_Declaration
1313         and then Nkind (Type_Definition (D)) = N_Derived_Type_Definition
1314       then
1315          declare
1316             DTD : constant Entity_Id := Type_Definition (D);
1317             SI  : constant Entity_Id := Subtype_Indication (DTD);
1318          begin
1319             if Is_Entity_Name (SI) then
1320                return Entity (SI);
1321             else
1322                return Entity (Subtype_Mark (SI));
1323             end if;
1324          end;
1325
1326       --  If derived type and private type, get the full view to find who we
1327       --  are derived from.
1328
1329       elsif Is_Derived_Type (Typ)
1330         and then Is_Private_Type (Typ)
1331         and then Present (Full_View (Typ))
1332       then
1333          return Nearest_Ancestor (Full_View (Typ));
1334
1335       --  Otherwise, nothing useful to return, return Empty
1336
1337       else
1338          return Empty;
1339       end if;
1340    end Nearest_Ancestor;
1341
1342    ---------------------------
1343    -- Nearest_Dynamic_Scope --
1344    ---------------------------
1345
1346    function Nearest_Dynamic_Scope (Ent : Entity_Id) return Entity_Id is
1347    begin
1348       if Is_Dynamic_Scope (Ent) then
1349          return Ent;
1350       else
1351          return Enclosing_Dynamic_Scope (Ent);
1352       end if;
1353    end Nearest_Dynamic_Scope;
1354
1355    ------------------------
1356    -- Next_Tag_Component --
1357    ------------------------
1358
1359    function Next_Tag_Component (Tag : Entity_Id) return Entity_Id is
1360       Comp : Entity_Id;
1361
1362    begin
1363       pragma Assert (Is_Tag (Tag));
1364
1365       --  Loop to look for next tag component
1366
1367       Comp := Next_Entity (Tag);
1368       while Present (Comp) loop
1369          if Is_Tag (Comp) then
1370             pragma Assert (Chars (Comp) /= Name_uTag);
1371             return Comp;
1372          end if;
1373
1374          Comp := Next_Entity (Comp);
1375       end loop;
1376
1377       --  No tag component found
1378
1379       return Empty;
1380    end Next_Tag_Component;
1381
1382    -----------------------
1383    -- Number_Components --
1384    -----------------------
1385
1386    function Number_Components (Typ : Entity_Id) return Nat is
1387       N    : Nat := 0;
1388       Comp : Entity_Id;
1389
1390    begin
1391       --  We do not call Einfo.First_Component_Or_Discriminant, as this
1392       --  function does not skip completely hidden discriminants, which we
1393       --  want to skip here.
1394
1395       if Has_Discriminants (Typ) then
1396          Comp := First_Discriminant (Typ);
1397       else
1398          Comp := First_Component (Typ);
1399       end if;
1400
1401       while Present (Comp) loop
1402          N := N + 1;
1403          Comp := Next_Component_Or_Discriminant (Comp);
1404       end loop;
1405
1406       return N;
1407    end Number_Components;
1408
1409    --------------------------
1410    -- Number_Discriminants --
1411    --------------------------
1412
1413    function Number_Discriminants (Typ : Entity_Id) return Pos is
1414       N     : Nat       := 0;
1415       Discr : Entity_Id := First_Discriminant (Typ);
1416
1417    begin
1418       while Present (Discr) loop
1419          N := N + 1;
1420          Discr := Next_Discriminant (Discr);
1421       end loop;
1422
1423       return N;
1424    end Number_Discriminants;
1425
1426    ----------------------------------------------
1427    -- Object_Type_Has_Constrained_Partial_View --
1428    ----------------------------------------------
1429
1430    function Object_Type_Has_Constrained_Partial_View
1431      (Typ  : Entity_Id;
1432       Scop : Entity_Id) return Boolean
1433    is
1434    begin
1435       return Has_Constrained_Partial_View (Typ)
1436         or else (In_Generic_Body (Scop)
1437                   and then Is_Generic_Type (Base_Type (Typ))
1438                   and then Is_Private_Type (Base_Type (Typ))
1439                   and then not Is_Tagged_Type (Typ)
1440                   and then not (Is_Array_Type (Typ)
1441                                  and then not Is_Constrained (Typ))
1442                   and then Has_Discriminants (Typ));
1443    end Object_Type_Has_Constrained_Partial_View;
1444
1445    ------------------
1446    -- Package_Body --
1447    ------------------
1448
1449    function Package_Body (E : Entity_Id) return Node_Id is
1450       N : Node_Id;
1451
1452    begin
1453       if Ekind (E) = E_Package_Body then
1454          N := Parent (E);
1455
1456          if Nkind (N) = N_Defining_Program_Unit_Name then
1457             N := Parent (N);
1458          end if;
1459
1460       else
1461          N := Package_Spec (E);
1462
1463          if Present (Corresponding_Body (N)) then
1464             N := Parent (Corresponding_Body (N));
1465
1466             if Nkind (N) = N_Defining_Program_Unit_Name then
1467                N := Parent (N);
1468             end if;
1469          else
1470             N := Empty;
1471          end if;
1472       end if;
1473
1474       return N;
1475    end Package_Body;
1476
1477    ------------------
1478    -- Package_Spec --
1479    ------------------
1480
1481    function Package_Spec (E : Entity_Id) return Node_Id is
1482    begin
1483       return Parent (Package_Specification (E));
1484    end Package_Spec;
1485
1486    ---------------------------
1487    -- Package_Specification --
1488    ---------------------------
1489
1490    function Package_Specification (E : Entity_Id) return Node_Id is
1491       N : Node_Id;
1492
1493    begin
1494       N := Parent (E);
1495
1496       if Nkind (N) = N_Defining_Program_Unit_Name then
1497          N := Parent (N);
1498       end if;
1499
1500       return N;
1501    end Package_Specification;
1502
1503    ---------------------
1504    -- Subprogram_Body --
1505    ---------------------
1506
1507    function Subprogram_Body (E : Entity_Id) return Node_Id is
1508       Body_E : constant Entity_Id := Subprogram_Body_Entity (E);
1509
1510    begin
1511       if No (Body_E) then
1512          return Empty;
1513       else
1514          return Parent (Subprogram_Specification (Body_E));
1515       end if;
1516    end Subprogram_Body;
1517
1518    ----------------------------
1519    -- Subprogram_Body_Entity --
1520    ----------------------------
1521
1522    function Subprogram_Body_Entity (E : Entity_Id) return Entity_Id is
1523       N : constant Node_Id := Parent (Subprogram_Specification (E));
1524       --  Declaration for E
1525
1526    begin
1527       --  If this declaration is not a subprogram body, then it must be a
1528       --  subprogram declaration or body stub, from which we can retrieve the
1529       --  entity for the corresponding subprogram body if any, or an abstract
1530       --  subprogram declaration, for which we return Empty.
1531
1532       case Nkind (N) is
1533          when N_Subprogram_Body =>
1534             return E;
1535
1536          when N_Subprogram_Body_Stub
1537             | N_Subprogram_Declaration
1538          =>
1539             return Corresponding_Body (N);
1540
1541          when others =>
1542             return Empty;
1543       end case;
1544    end Subprogram_Body_Entity;
1545
1546    ---------------------
1547    -- Subprogram_Spec --
1548    ---------------------
1549
1550    function Subprogram_Spec (E : Entity_Id) return Node_Id is
1551       N : constant Node_Id := Parent (Subprogram_Specification (E));
1552       --  Declaration for E
1553
1554    begin
1555       --  This declaration is either subprogram declaration or a subprogram
1556       --  body, in which case return Empty.
1557
1558       if Nkind (N) = N_Subprogram_Declaration then
1559          return N;
1560       else
1561          return Empty;
1562       end if;
1563    end Subprogram_Spec;
1564
1565    ------------------------------
1566    -- Subprogram_Specification --
1567    ------------------------------
1568
1569    function Subprogram_Specification (E : Entity_Id) return Node_Id is
1570       N : Node_Id;
1571
1572    begin
1573       N := Parent (E);
1574
1575       if Nkind (N) = N_Defining_Program_Unit_Name then
1576          N := Parent (N);
1577       end if;
1578
1579       --  If the Parent pointer of E is not a subprogram specification node
1580       --  (going through an intermediate N_Defining_Program_Unit_Name node
1581       --  for subprogram units), then E is an inherited operation. Its parent
1582       --  points to the type derivation that produces the inheritance: that's
1583       --  the node that generates the subprogram specification. Its alias
1584       --  is the parent subprogram, and that one points to a subprogram
1585       --  declaration, or to another type declaration if this is a hierarchy
1586       --  of derivations.
1587
1588       if Nkind (N) not in N_Subprogram_Specification then
1589          pragma Assert (Present (Alias (E)));
1590          N := Subprogram_Specification (Alias (E));
1591       end if;
1592
1593       return N;
1594    end Subprogram_Specification;
1595
1596    ---------------
1597    -- Tree_Read --
1598    ---------------
1599
1600    procedure Tree_Read is
1601    begin
1602       Obsolescent_Warnings.Tree_Read;
1603    end Tree_Read;
1604
1605    ----------------
1606    -- Tree_Write --
1607    ----------------
1608
1609    procedure Tree_Write is
1610    begin
1611       Obsolescent_Warnings.Tree_Write;
1612    end Tree_Write;
1613
1614    --------------------
1615    -- Ultimate_Alias --
1616    --------------------
1617
1618    function Ultimate_Alias (Prim : Entity_Id) return Entity_Id is
1619       E : Entity_Id := Prim;
1620
1621    begin
1622       while Present (Alias (E)) loop
1623          pragma Assert (Alias (E) /= E);
1624          E := Alias (E);
1625       end loop;
1626
1627       return E;
1628    end Ultimate_Alias;
1629
1630    --------------------------
1631    -- Unit_Declaration_Node --
1632    --------------------------
1633
1634    function Unit_Declaration_Node (Unit_Id : Entity_Id) return Node_Id is
1635       N : Node_Id := Parent (Unit_Id);
1636
1637    begin
1638       --  Predefined operators do not have a full function declaration
1639
1640       if Ekind (Unit_Id) = E_Operator then
1641          return N;
1642       end if;
1643
1644       --  Isn't there some better way to express the following ???
1645
1646       while Nkind (N) /= N_Abstract_Subprogram_Declaration
1647         and then Nkind (N) /= N_Entry_Body
1648         and then Nkind (N) /= N_Entry_Declaration
1649         and then Nkind (N) /= N_Formal_Package_Declaration
1650         and then Nkind (N) /= N_Function_Instantiation
1651         and then Nkind (N) /= N_Generic_Package_Declaration
1652         and then Nkind (N) /= N_Generic_Subprogram_Declaration
1653         and then Nkind (N) /= N_Package_Declaration
1654         and then Nkind (N) /= N_Package_Body
1655         and then Nkind (N) /= N_Package_Instantiation
1656         and then Nkind (N) /= N_Package_Renaming_Declaration
1657         and then Nkind (N) /= N_Procedure_Instantiation
1658         and then Nkind (N) /= N_Protected_Body
1659         and then Nkind (N) /= N_Subprogram_Declaration
1660         and then Nkind (N) /= N_Subprogram_Body
1661         and then Nkind (N) /= N_Subprogram_Body_Stub
1662         and then Nkind (N) /= N_Subprogram_Renaming_Declaration
1663         and then Nkind (N) /= N_Task_Body
1664         and then Nkind (N) /= N_Task_Type_Declaration
1665         and then Nkind (N) not in N_Formal_Subprogram_Declaration
1666         and then Nkind (N) not in N_Generic_Renaming_Declaration
1667       loop
1668          N := Parent (N);
1669
1670          --  We don't use Assert here, because that causes an infinite loop
1671          --  when assertions are turned off. Better to crash.
1672
1673          if No (N) then
1674             raise Program_Error;
1675          end if;
1676       end loop;
1677
1678       return N;
1679    end Unit_Declaration_Node;
1680
1681 end Sem_Aux;