gcc/ada/a-except.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This version of Ada.Exceptions is a full Ada 95 version. It omits Ada 2005
  37 --  features such as the additional definitions of Exception_Name returning
  38 --  Wide_[Wide_]String. It differs from the Ada 95 version only in that it is
  39 --  declared Preelaborate (see declaration below for why this is done).
  40
  41 --  It is used for building the compiler and the basic tools, since these
  42 --  builds may be done with bootstrap compilers that cannot handle these
  43 --  additions. The full version of Ada.Exceptions can be found in the files
  44 --  a-except-2005.ads/adb, and is used for all other builds where full Ada
  45 --  2005 functionality is required. In particular, it is used for building
  46 --  run times on all targets.
  47
  48 pragma Compiler_Unit_Warning;
  49
  50 pragma Polling (Off);
  51 --  We must turn polling off for this unit, because otherwise we get
  52 --  elaboration circularities with ourself.
  53
  54 with System;
  55 with System.Parameters;
  56 with System.Standard_Library;
  57 with System.Traceback_Entries;
  58
  59 package Ada.Exceptions is
  60    pragma Preelaborate;
  61    --  We make this preelaborable. If we did not do this, then run time units
  62    --  used by the compiler (e.g. s-soflin.ads) would run into trouble.
  63    --  Conformance with Ada 95 is not an issue, since this version is used
  64    --  only by the compiler.
  65
  66    type Exception_Id is private;
  67
  68    Null_Id : constant Exception_Id;
  69
  70    type Exception_Occurrence is limited private;
  71
  72    type Exception_Occurrence_Access is access all Exception_Occurrence;
  73
  74    Null_Occurrence : constant Exception_Occurrence;
  75
  76    function Exception_Name (X : Exception_Occurrence) return String;
  77    --  Same as Exception_Name (Exception_Identity (X))
  78
  79    function Exception_Name (Id : Exception_Id) return String;
  80
  81    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  82    pragma No_Return (Raise_Exception);
  83    --  Note: In accordance with AI-466, CE is raised if E = Null_Id
  84
  85    function Exception_Message (X : Exception_Occurrence) return String;
  86
  87    procedure Reraise_Occurrence (X : Exception_Occurrence);
  88    --  Note: it would be really nice to give a pragma No_Return for this
  89    --  procedure, but it would be wrong, since Reraise_Occurrence does return
  90    --  if the argument is the null exception occurrence. See also procedure
  91    --  Reraise_Occurrence_Always in the private part of this package.
  92
  93    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
  94
  95    function Exception_Information (X : Exception_Occurrence) return String;
  96    --  The format of the exception information is as follows:
  97    --
  98    --    exception name (as in Exception_Name)
  99    --    message (or a null line if no message)
 100    --    PID=nnnn
 101    --    0xyyyyyyyy 0xyyyyyyyy ...
 102    --
 103    --  The lines are separated by a ASCII.LF character
 104    --  The nnnn is the partition Id given as decimal digits.
 105    --  The 0x... line represents traceback program counter locations,
 106    --  in order with the first one being the exception location.
 107
 108    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
 109    --  not the function from Rtsfind, so it is important that the procedure
 110    --  come first, since Rtsfind finds the first matching entity.
 111
 112    procedure Save_Occurrence
 113      (Target : out Exception_Occurrence;
 114       Source : Exception_Occurrence);
 115
 116    function Save_Occurrence
 117      (Source : Exception_Occurrence)
 118       return   Exception_Occurrence_Access;
 119
 120 private
 121    package SSL renames System.Standard_Library;
 122    package SP renames System.Parameters;
 123
 124    subtype EOA is Exception_Occurrence_Access;
 125
 126    Exception_Msg_Max_Length : constant := SP.Default_Exception_Msg_Max_Length;
 127
 128    ------------------
 129    -- Exception_Id --
 130    ------------------
 131
 132    subtype Code_Loc is System.Address;
 133    --  Code location used in building exception tables and for call addresses
 134    --  when propagating an exception. Values of this type are created by using
 135    --  Label'Address or extracted from machine states using Get_Code_Loc.
 136
 137    Null_Loc : constant Code_Loc := System.Null_Address;
 138    --  Null code location, used to flag outer level frame
 139
 140    type Exception_Id is new SSL.Exception_Data_Ptr;
 141
 142    function EId_To_String (X : Exception_Id) return String;
 143    function String_To_EId (S : String) return Exception_Id;
 144    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 145    --  Functions for implementing Exception_Id stream attributes
 146
 147    Null_Id : constant Exception_Id := null;
 148
 149    -------------------------
 150    -- Private Subprograms --
 151    -------------------------
 152
 153    function Current_Target_Exception return Exception_Occurrence;
 154    pragma Export
 155      (Ada, Current_Target_Exception,
 156       "__gnat_current_target_exception");
 157    --  This routine should return the current raised exception on targets
 158    --  which have built-in exception handling such as the Java Virtual
 159    --  Machine. For other targets this routine is simply ignored. Currently,
 160    --  only JGNAT uses this. See 4jexcept.ads for details. The pragma Export
 161    --  allows this routine to be accessed elsewhere in the run-time, even
 162    --  though it is in the private part of this package (it is not allowed
 163    --  to be in the visible part, since this is set by the reference manual).
 164
 165    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 166    --  Like Exception_Name, but returns the simple non-qualified name of the
 167    --  exception. This is used to implement the Exception_Name function in
 168    --  Current_Exceptions (the DEC compatible unit). It is called from the
 169    --  compiler generated code (using Rtsfind, which does not respect the
 170    --  private barrier, so we can place this function in the private part
 171    --  where the compiler can find it, but the spec is unchanged.)
 172
 173    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 174    pragma No_Return (Raise_Exception_Always);
 175    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 176    --  This differs from Raise_Exception only in that the caller has determined
 177    --  that for sure the parameter E is not null, and that therefore no check
 178    --  for Null_Id is required. The expander converts Raise_Exception calls to
 179    --  Raise_Exception_Always if it can determine this is the case. The Export
 180    --  allows this routine to be accessed from Pure units.
 181
 182    procedure Raise_From_Signal_Handler
 183      (E : Exception_Id;
 184       M : System.Address);
 185    pragma Export
 186      (Ada, Raise_From_Signal_Handler,
 187            "ada__exceptions__raise_from_signal_handler");
 188    pragma No_Return (Raise_From_Signal_Handler);
 189    --  This routine is used to raise an exception from a signal handler. The
 190    --  signal handler has already stored the machine state (i.e. the state that
 191    --  corresponds to the location at which the signal was raised). E is the
 192    --  Exception_Id specifying what exception is being raised, and M is a
 193    --  pointer to a null-terminated string which is the message to be raised.
 194    --  Note that this routine never returns, so it is permissible to simply
 195    --  jump to this routine, rather than call it. This may be appropriate for
 196    --  systems where the right way to get out of signal handler is to alter the
 197    --  PC value in the machine state or in some other way ask the operating
 198    --  system to return here rather than to the original location.
 199
 200    procedure Raise_From_Controlled_Operation
 201      (X : Ada.Exceptions.Exception_Occurrence);
 202    pragma No_Return (Raise_From_Controlled_Operation);
 203    pragma Export
 204      (Ada, Raise_From_Controlled_Operation,
 205            "__gnat_raise_from_controlled_operation");
 206    --  Raise Program_Error, providing information about X (an exception raised
 207    --  during a controlled operation) in the exception message.
 208
 209    procedure Reraise_Library_Exception_If_Any;
 210    pragma Export
 211      (Ada, Reraise_Library_Exception_If_Any,
 212            "__gnat_reraise_library_exception_if_any");
 213    --  If there was an exception raised during library-level finalization,
 214    --  reraise the exception.
 215
 216    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 217    pragma No_Return (Reraise_Occurrence_Always);
 218    --  This differs from Raise_Occurrence only in that the caller guarantees
 219    --  that for sure the parameter X is not the null occurrence, and that
 220    --  therefore this procedure cannot return. The expander uses this routine
 221    --  in the translation of a raise statement with no parameter (reraise).
 222
 223    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 224    pragma No_Return (Reraise_Occurrence_No_Defer);
 225    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 226    --  before the call and the parameter X is known not to be the null
 227    --  occurrence. This is used in generated code when it is known that
 228    --  abort is already deferred.
 229
 230    function Triggered_By_Abort return Boolean;
 231    --  Determine whether the current exception (if it exists) is an instance of
 232    --  Standard'Abort_Signal.
 233
 234    -----------------------
 235    -- Polling Interface --
 236    -----------------------
 237
 238    --  The GNAT compiler has an option to generate polling calls to the Poll
 239    --  routine in this package. Specifying the -gnatP option for a compilation
 240    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 241    --  entry and on every iteration of a loop, thus avoiding the possibility of
 242    --  a case of unbounded time between calls.
 243
 244    --  This polling interface may be used for instrumentation or debugging
 245    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 246
 247    --  In the GNAT technology itself, this interface is used to implement
 248    --  immediate asynchronous transfer of control and immediate abort on
 249    --  targets which do not provide for one thread interrupting another.
 250
 251    --  Note: this used to be in a separate unit called System.Poll, but that
 252    --  caused horrible circular elaboration problems between System.Poll and
 253    --  Ada.Exceptions.
 254
 255    procedure Poll;
 256    --  Check for asynchronous abort. Note that we do not inline the body.
 257    --  This makes the interface more useful for debugging purposes.
 258
 259    --------------------------
 260    -- Exception_Occurrence --
 261    --------------------------
 262
 263    package TBE renames System.Traceback_Entries;
 264
 265    Max_Tracebacks : constant := 50;
 266    --  Maximum number of trace backs stored in exception occurrence
 267
 268    type Tracebacks_Array is array (1 .. Max_Tracebacks) of TBE.Traceback_Entry;
 269    --  Traceback array stored in exception occurrence
 270
 271    type Exception_Occurrence is record
 272       Id : Exception_Id;
 273       --  Exception_Identity for this exception occurrence
 274
 275       Msg_Length : Natural := 0;
 276       --  Length of message (zero = no message)
 277
 278       Msg : String (1 .. Exception_Msg_Max_Length);
 279       --  Characters of message
 280
 281       Exception_Raised : Boolean := False;
 282       --  Set to true to indicate that this exception occurrence has actually
 283       --  been raised. When an exception occurrence is first created, this is
 284       --  set to False, then when it is processed by Raise_Current_Exception,
 285       --  it is set to True. If Raise_Current_Exception is used to raise an
 286       --  exception for which this flag is already True, then it knows that
 287       --  it is dealing with the reraise case (which is useful to distinguish
 288       --  for exception tracing purposes).
 289
 290       Pid : Natural := 0;
 291       --  Partition_Id for partition raising exception
 292
 293       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 294       --  Number of traceback entries stored
 295
 296       Tracebacks : Tracebacks_Array;
 297       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 298    end record;
 299
 300    function "=" (Left, Right : Exception_Occurrence) return Boolean
 301      is abstract;
 302    --  Don't allow comparison on exception occurrences, we should not need
 303    --  this, and it would not work right, because of the Msg and Tracebacks
 304    --  fields which have unused entries not copied by Save_Occurrence.
 305
 306    function EO_To_String (X : Exception_Occurrence) return String;
 307    function String_To_EO (S : String) return Exception_Occurrence;
 308    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 309    --  Functions for implementing Exception_Occurrence stream attributes
 310
 311    Null_Occurrence : constant Exception_Occurrence := (
 312      Id               => null,
 313      Msg_Length       => 0,
 314      Msg              => (others => ' '),
 315      Exception_Raised => False,
 316      Pid              => 0,
 317      Num_Tracebacks   => 0,
 318      Tracebacks       => (others => TBE.Null_TB_Entry));
 319
 320 end Ada.Exceptions;