gcc/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname).],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as.],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname).],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format.],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format.],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include.],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files.],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib      enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is no checking],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 [])
 218 if test x$ac_checking != x ; then
 219   AC_DEFINE(ENABLE_CHECKING, 1,
 220 [Define if you want more run-time sanity checks.  This one gets a grab
 221    bag of miscellaneous but relatively cheap checks.])
 222 fi
 223 if test x$ac_tree_checking != x ; then
 224   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 225 [Define if you want all operations on trees (the basic data
 226    structure of the front ends) to be checked for dynamic type safety
 227    at runtime.  This is moderately expensive.])
 228 fi
 229 if test x$ac_rtl_checking != x ; then
 230   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 231 [Define if you want all operations on RTL (the basic data structure
 232    of the optimizer and back end) to be checked for dynamic type safety
 233    at runtime.  This is quite expensive.])
 234 fi
 235 if test x$ac_gc_checking != x ; then
 236   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 237 [Define if you want the garbage collector to do object poisoning and
 238    other memory allocation checks.  This is quite expensive.])
 239 fi
 240 if test x$ac_gc_always_collect != x ; then
 241   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 242 [Define if you want the garbage collector to operate in maximally
 243    paranoid mode, validating the entire heap and collecting garbage at
 244    every opportunity.  This is extremely expensive.])
 245 fi
 246
 247
 248 AC_ARG_ENABLE(cpp,
 249 [  --disable-cpp           don't provide a user-visible C preprocessor.],
 250 [], [enable_cpp=yes])
 251
 252 AC_ARG_WITH(cpp_install_dir,
 253 [  --with-cpp-install-dir=DIR
 254                           install the user visible C preprocessor in DIR
 255                           (relative to PREFIX) as well as PREFIX/bin.],
 256 [if test x$withval = xyes; then
 257   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 258 elif test x$withval != xno; then
 259   cpp_install_dir=$withval
 260 fi])
 261
 262 # Enable Multibyte Characters for C/C++
 263 AC_ARG_ENABLE(c-mbchar,
 264 [  --enable-c-mbchar       Enable multibyte characters for C and C++.],
 265 if test x$enable_c_mbchar != xno; then
 266   AC_DEFINE(MULTIBYTE_CHARS, 1,
 267   [Define if you want the C and C++ compilers to support multibyte
 268    character sets for source code.])
 269 fi)
 270
 271 # Enable threads
 272 # Pass with no value to take the default
 273 # Pass with a value to specify a thread package
 274 AC_ARG_ENABLE(threads,
 275 [  --enable-threads        enable thread usage for target GCC.
 276   --enable-threads=LIB    use LIB thread package for target GCC.],,
 277 enable_threads='')
 278
 279 enable_threads_flag=$enable_threads
 280 # Check if a valid thread package
 281 case x${enable_threads_flag} in
 282         x | xno)
 283                 # No threads
 284                 target_thread_file='single'
 285                 ;;
 286         xyes)
 287                 # default
 288                 target_thread_file=''
 289                 ;;
 290         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 291         xsolaris | xwin32 | xdce | xvxworks | xaix)
 292                 target_thread_file=$enable_threads_flag
 293                 ;;
 294         *)
 295                 echo "$enable_threads is an unknown thread package" 1>&2
 296                 exit 1
 297                 ;;
 298 esac
 299
 300 AC_ARG_ENABLE(objc-gc,
 301 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 302                           the GNU Objective-C runtime.],
 303 if test x$enable_objc_gc = xno; then
 304         objc_boehm_gc=''
 305 else
 306         objc_boehm_gc=1
 307 fi,
 308 objc_boehm_gc='')
 309
 310 AC_ARG_WITH(dwarf2,
 311 [  --with-dwarf2          force the default debug format to be DWARF2.],
 312 dwarf2="$with_dwarf2",
 313 dwarf2=no)
 314
 315 AC_ARG_ENABLE(shared,
 316 [  --disable-shared       don't provide a shared libgcc.],
 317 [
 318   case $enable_shared in
 319   yes | no) ;;
 320   *)
 321     enable_shared=no
 322     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 323     for pkg in $enableval; do
 324       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 325         enable_shared=yes
 326       fi
 327     done
 328     IFS="$ac_save_ifs"
 329     ;;
 330   esac
 331 ], [enable_shared=yes])
 332 AC_SUBST(enable_shared)
 333
 334 # Determine the host, build, and target systems
 335 AC_CANONICAL_SYSTEM
 336
 337 # Find the native compiler
 338 AC_PROG_CC
 339 AC_PROG_CC_C_O
 340 # autoconf is lame and doesn't give us any substitution variable for this.
 341 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 342   NO_MINUS_C_MINUS_O=yes
 343 else
 344   OUTPUT_OPTION='-o $@'
 345 fi
 346 AC_SUBST(NO_MINUS_C_MINUS_O)
 347 AC_SUBST(OUTPUT_OPTION)
 348
 349 gcc_AC_C_LONG_DOUBLE
 350
 351 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 352 ac_cv_prog_cc_no_long_long,
 353 [save_CFLAGS="$CFLAGS"
 354 CFLAGS="-Wno-long-long"
 355 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 356                ac_cv_prog_cc_no_long_long=no)
 357 CFLAGS="$save_CFLAGS"])
 358 strict1_warn=
 359 if test $ac_cv_prog_cc_no_long_long = yes; then
 360   strict1_warn="-pedantic -Wno-long-long"
 361 fi
 362 AC_SUBST(strict1_warn)
 363
 364 # If the native compiler is GCC, we can enable warnings even in stage1.
 365 # That's useful for people building cross-compilers, or just running a
 366 # quick `make'.
 367 warn_cflags=
 368 if test "x$GCC" = "xyes"; then
 369   warn_cflags='$(GCC_WARN_CFLAGS)'
 370 fi
 371 AC_SUBST(warn_cflags)
 372
 373 # Stage specific cflags for build.
 374 stage1_cflags=
 375 case $build in
 376 vax-*-*)
 377   if test x$GCC = xyes
 378   then
 379     stage1_cflags="-Wa,-J"
 380   else
 381     stage1_cflags="-J"
 382   fi
 383   ;;
 384 esac
 385 AC_SUBST(stage1_cflags)
 386
 387 AC_PROG_MAKE_SET
 388
 389 AC_MSG_CHECKING([whether a default assembler was specified])
 390 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 391     if test x"$gas_flag" = x"no"; then
 392         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 393     else
 394         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 395     fi
 396 else
 397     AC_MSG_RESULT(no)
 398 fi
 399
 400 AC_MSG_CHECKING([whether a default linker was specified])
 401 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 402     if test x"$gnu_ld_flag" = x"no"; then
 403         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 404     else
 405         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 406     fi
 407 else
 408     AC_MSG_RESULT(no)
 409 fi
 410
 411 AC_MSG_CHECKING(for GNU C library)
 412 AC_CACHE_VAL(gcc_cv_glibc,
 413 [AC_TRY_COMPILE(
 414   [#include <features.h>],[
 415 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 416 #error Not a GNU C library system
 417 #endif],
 418   [gcc_cv_glibc=yes],
 419   gcc_cv_glibc=no)])
 420 AC_MSG_RESULT($gcc_cv_glibc)
 421 if test $gcc_cv_glibc = yes; then
 422   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 423 fi
 424
 425 AC_C_INLINE
 426
 427 # Find some useful tools
 428 AC_PROG_AWK
 429 gcc_AC_PROG_LN
 430 gcc_AC_PROG_LN_S
 431 gcc_AC_C_VOLATILE
 432 AC_PROG_RANLIB
 433 gcc_AC_PROG_INSTALL
 434
 435 AC_HEADER_STDC
 436 AC_HEADER_TIME
 437 gcc_AC_HEADER_STRING
 438 AC_HEADER_SYS_WAIT
 439 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 440                  fcntl.h unistd.h stab.h sys/file.h sys/time.h \
 441                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 442                  direct.h malloc.h langinfo.h iconv.h stdbool.h)
 443
 444 # Check for thread headers.
 445 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 446 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 447
 448 # See if GNAT has been installed
 449 AC_CHECK_PROG(gnat, gnatbind, yes, no)
 450
 451 # See if we have the mktemp command.
 452 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 453
 454 # Do we have a single-tree copy of texinfo?
 455 if test -f $srcdir/../texinfo/Makefile.in; then
 456   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 457   gcc_cv_prog_makeinfo_modern=yes
 458   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 459 else
 460   # See if makeinfo has been installed and is modern enough
 461   # that we can use it.
 462   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 463   [GNU texinfo.* \([0-9][0-9.]*\)],
 464   [4.*])
 465 fi
 466
 467 if test $gcc_cv_prog_makeinfo_modern = no; then
 468   AC_MSG_WARN([
 469 *** Makeinfo is missing or too old.
 470 *** Info documentation will not be built.])
 471   BUILD_INFO=
 472 else
 473   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 474 fi
 475
 476 # Is pod2man recent enough to regenerate manpages?
 477 AC_MSG_CHECKING([for recent Pod::Man])
 478 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 479   AC_MSG_RESULT(yes)
 480   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 481 else
 482   AC_MSG_RESULT(no)
 483   GENERATED_MANPAGES=
 484 fi
 485
 486 # How about lex?
 487 dnl Don't use AC_PROG_LEX; we insist on flex.
 488 dnl LEXLIB is not useful in gcc.
 489 if test -f $srcdir/../flex/skel.c; then
 490   FLEX='$(objdir)/../flex/flex'
 491 else
 492   AC_CHECK_PROG(FLEX, flex, flex, false)
 493 fi
 494
 495 # Bison?
 496 # The -L switch is so bison can find its skeleton file.
 497 if test -f $srcdir/../bison/bison.simple; then
 498   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 499 else
 500   AC_CHECK_PROG(BISON, bison, bison, false)
 501 fi
 502
 503 # See if the stage1 system preprocessor understands the ANSI C
 504 # preprocessor stringification operator.
 505 AC_C_STRINGIZE
 506
 507 # Use <inttypes.h> only if it exists,
 508 # doesn't clash with <sys/types.h>, and declares intmax_t.
 509 AC_MSG_CHECKING(for inttypes.h)
 510 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 511 [AC_TRY_COMPILE(
 512   [#include <sys/types.h>
 513 #include <inttypes.h>],
 514   [intmax_t i = -1;],
 515   [gcc_cv_header_inttypes_h=yes],
 516   gcc_cv_header_inttypes_h=no)])
 517 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 518 if test $gcc_cv_header_inttypes_h = yes; then
 519   AC_DEFINE(HAVE_INTTYPES_H, 1,
 520         [Define if you have a working <inttypes.h> header file.])
 521 fi
 522
 523 #
 524 # Determine if enumerated bitfields are unsigned.   ISO C says they can
 525 # be either signed or unsigned.
 526 #
 527 AC_CACHE_CHECK(for unsigned enumerated bitfields, gcc_cv_enum_bf_unsigned,
 528 [AC_TRY_RUN(#include <stdlib.h>
 529 enum t { BLAH = 128 } ;
 530 struct s_t { enum t member : 8; } s ;
 531 int main(void)
 532 {
 533         s.member = BLAH;
 534         if (s.member < 0) exit(1);
 535         exit(0);
 536
 537 }, gcc_cv_enum_bf_unsigned=yes, gcc_cv_enum_bf_unsigned=no, gcc_cv_enum_bf_unsigned=yes)])
 538 if test $gcc_cv_enum_bf_unsigned = yes; then
 539   AC_DEFINE(ENUM_BITFIELDS_ARE_UNSIGNED, 1,
 540     [Define if enumerated bitfields are treated as unsigned values.])
 541 fi
 542
 543 AC_CHECK_FUNCS(strtoul bsearch putenv popen bcopy \
 544         strchr strrchr kill getrlimit setrlimit atoll atoq \
 545         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 546         fputs_unlocked getrusage iconv nl_langinfo lstat)
 547
 548 AC_CHECK_TYPE(ssize_t, int)
 549
 550 # Try to determine the array type of the second argument of getgroups
 551 # for the target system (int or gid_t).
 552 AC_TYPE_GETGROUPS
 553 if test "${target}" = "${build}"; then
 554   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 555 else
 556   case "${target}" in
 557         # This condition may need some tweaking.  It should include all
 558         # targets where the array type of the second argument of getgroups
 559         # is int and the type of gid_t is not equivalent to int.
 560         *-*-sunos* | *-*-ultrix*)
 561                 TARGET_GETGROUPS_T=int
 562                 ;;
 563         *)
 564                 TARGET_GETGROUPS_T=gid_t
 565                 ;;
 566   esac
 567 fi
 568 AC_SUBST(TARGET_GETGROUPS_T)
 569
 570 gcc_AC_FUNC_VFPRINTF_DOPRNT
 571 gcc_AC_FUNC_STRSTR
 572 gcc_AC_FUNC_PRINTF_PTR
 573
 574 case "${host}" in
 575 *-*-uwin*)
 576   AC_MSG_ERROR([
 577 *** UWIN may not be used as a host platform because
 578 *** linking with posix.dll is not allowed by the GNU GPL])
 579   ;;
 580 esac
 581 AC_FUNC_VFORK
 582 AC_FUNC_MMAP_ANYWHERE
 583 AC_FUNC_MMAP_FILE
 584
 585 # We will need to find libiberty.h and ansidecl.h
 586 saved_CFLAGS="$CFLAGS"
 587 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 588 gcc_AC_CHECK_DECLS(bcopy \
 589         getenv atol sbrk abort atof getcwd getwd \
 590         strsignal putc_unlocked fputs_unlocked strstr environ \
 591         malloc realloc calloc free basename getopt, , ,[
 592 #include "gansidecl.h"
 593 #include "system.h"])
 594
 595 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 596 #include "gansidecl.h"
 597 #include "system.h"
 598 #ifdef HAVE_SYS_RESOURCE_H
 599 #include <sys/resource.h>
 600 #endif
 601 ])
 602
 603 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 604 CFLAGS="$saved_CFLAGS"
 605
 606 # mkdir takes a single argument on some systems.
 607 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 608
 609 # File extensions
 610 manext='.1'
 611 objext='.o'
 612 AC_SUBST(manext)
 613 AC_SUBST(objext)
 614
 615 build_xm_file=
 616 build_xm_defines=
 617 build_install_headers_dir=install-headers-tar
 618 build_exeext=
 619 host_xm_file=
 620 host_xm_defines=
 621 host_xmake_file=
 622 host_truncate_target=
 623 host_exeext=
 624
 625 # Decode the host machine, then the target machine.
 626 # For the host machine, we save the xm_file variable as host_xm_file;
 627 # then we decode the target machine and forget everything else
 628 # that came from the host machine.
 629 for machine in $build $host $target; do
 630         . ${srcdir}/config.gcc
 631 done
 632
 633 extra_objs="${host_extra_objs} ${extra_objs}"
 634
 635 # Default the target-machine variables that were not explicitly set.
 636 if test x"$tm_file" = x
 637 then tm_file=$cpu_type/$cpu_type.h; fi
 638
 639 if test x"$extra_headers" = x
 640 then extra_headers=; fi
 641
 642 if test x"$xm_file" = x
 643 then xm_file=$cpu_type/xm-$cpu_type.h; fi
 644
 645 if test x$md_file = x
 646 then md_file=$cpu_type/$cpu_type.md; fi
 647
 648 if test x$out_file = x
 649 then out_file=$cpu_type/$cpu_type.c; fi
 650
 651 if test x"$tmake_file" = x
 652 then tmake_file=$cpu_type/t-$cpu_type
 653 fi
 654
 655 if test x"$dwarf2" = xyes
 656 then tm_file="$tm_file tm-dwarf2.h"
 657 fi
 658
 659 if test x$float_format = x
 660 then float_format=i64
 661 fi
 662
 663 if test $float_format = none
 664 then float_h_file=Makefile.in
 665 else float_h_file=float-$float_format.h
 666 fi
 667
 668 # Handle cpp installation.
 669 if test x$enable_cpp != xno
 670 then
 671   tmake_file="$tmake_file t-install-cpp"
 672 fi
 673
 674 # Say what files are being used for the output code and MD file.
 675 echo "Using \`$srcdir/config/$out_file' to output insns."
 676 echo "Using \`$srcdir/config/$md_file' as machine description file."
 677
 678 count=a
 679 for f in $tm_file; do
 680         count=${count}x
 681 done
 682 if test $count = ax; then
 683         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 684 else
 685         echo "Using the following target machine macro files:"
 686         for f in $tm_file; do
 687                 echo "  $srcdir/config/$f"
 688         done
 689 fi
 690
 691 count=a
 692 for f in $host_xm_file; do
 693         count=${count}x
 694 done
 695 if test $count = ax; then
 696         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 697 else
 698         echo "Using the following host machine macro files:"
 699         for f in $host_xm_file; do
 700                 echo "  $srcdir/config/$f"
 701         done
 702 fi
 703
 704 if test "$host_xm_file" != "$build_xm_file"; then
 705         count=a
 706         for f in $build_xm_file; do
 707                 count=${count}x
 708         done
 709         if test $count = ax; then
 710                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 711         else
 712                 echo "Using the following build machine macro files:"
 713                 for f in $build_xm_file; do
 714                         echo "  $srcdir/config/$f"
 715                 done
 716         fi
 717 fi
 718
 719 if test x$thread_file = x; then
 720         if test x$target_thread_file != x; then
 721                 thread_file=$target_thread_file
 722         else
 723                 thread_file='single'
 724         fi
 725 fi
 726
 727 # Set up the header files.
 728 # $links is the list of header files to create.
 729 # $vars is the list of shell variables with file names to include.
 730 # auto-host.h is the file containing items generated by autoconf and is
 731 # the first file included by config.h.
 732 null_defines=
 733 host_xm_file="auto-host.h gansidecl.h ${host_xm_file} defaults.h hwint.h"
 734
 735 # If host=build, it is correct to have hconfig include auto-host.h
 736 # as well.  If host!=build, we are in error and need to do more
 737 # work to find out the build config parameters.
 738 if test x$host = x$build
 739 then
 740         build_xm_file="auto-host.h gansidecl.h ${build_xm_file} defaults.h hwint.h"
 741 else
 742         # We create a subdir, then run autoconf in the subdir.
 743         # To prevent recursion we set host and build for the new
 744         # invocation of configure to the build for this invocation
 745         # of configure.
 746         tempdir=build.$$
 747         rm -rf $tempdir
 748         mkdir $tempdir
 749         cd $tempdir
 750         case ${srcdir} in
 751         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 752         *) realsrcdir=../${srcdir};;
 753         esac
 754         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 755                 --target=$target --host=$build --build=$build
 756
 757         # We just finished tests for the build machine, so rename
 758         # the file auto-build.h in the gcc directory.
 759         mv auto-host.h ../auto-build.h
 760         cd ..
 761         rm -rf $tempdir
 762         build_xm_file="auto-build.h gansidecl.h ${build_xm_file} defaults.h hwint.h"
 763 fi
 764
 765 xm_file="gansidecl.h ${xm_file} defaults.h"
 766 tm_file="gansidecl.h ${tm_file} defaults.h"
 767
 768 vars="host_xm_file tm_file tm_p_file xm_file build_xm_file"
 769 links="config.h tm.h tm_p.h tconfig.h hconfig.h"
 770 defines="host_xm_defines null_defines null_defines xm_defines build_xm_defines"
 771
 772 rm -f config.bak
 773 if test -f config.status; then mv -f config.status config.bak; fi
 774
 775 # Make the links.
 776 while test -n "$vars"
 777 do
 778         set $vars; var=$1; shift; vars=$*
 779         set $links; link=$1; shift; links=$*
 780         set $defines; define=$1; shift; defines=$*
 781
 782         rm -f $link
 783         # Make sure the file is created, even if it is empty.
 784         echo >$link
 785
 786         # Define TARGET_CPU_DEFAULT if the system wants one.
 787         # This substitutes for lots of *.h files.
 788         if test "$target_cpu_default" != "" -a $link = tm.h
 789         then
 790                 echo "#define TARGET_CPU_DEFAULT ($target_cpu_default)" >>$link
 791         fi
 792
 793         for file in `eval echo '$'$var`; do
 794                 case $file in
 795                 auto-host.h | auto-build.h )
 796                         ;;
 797                 *)
 798                         echo '#ifdef IN_GCC' >>$link
 799                         ;;
 800                 esac
 801                 echo "#include \"$file\"" >>$link
 802                 case $file in
 803                 auto-host.h | auto-build.h )
 804                         ;;
 805                 *)
 806                         echo '#endif' >>$link
 807                         ;;
 808                 esac
 809         done
 810
 811         for def in `eval echo '$'$define`; do
 812                 echo "#ifndef $def" >>$link
 813                 echo "#define $def" >>$link
 814                 echo "#endif" >>$link
 815         done
 816
 817         if test $link = tm.h
 818         then
 819                 # Include insn-codes.h last, because it includes machmode.h,
 820                 # and we want EXTRA_CC_MODES to be taken into account.
 821                 echo "#ifndef GENERATOR_FILE" >>$link
 822                 echo "#include \"insn-codes.h\"" >>$link
 823                 echo "#endif" >>$link
 824         fi
 825 done
 826
 827 # Truncate the target if necessary
 828 if test x$host_truncate_target != x; then
 829         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 830 fi
 831
 832 # Get the version trigger filename from the toplevel
 833 if test "${with_gcc_version_trigger+set}" = set; then
 834         gcc_version_trigger=$with_gcc_version_trigger
 835 else
 836         gcc_version_trigger=${srcdir}/version.c
 837 fi
 838 changequote(,)dnl
 839 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 840 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 841
 842 # Compile in configure arguments.
 843 if test -f configargs.h ; then
 844         # Being re-configured.
 845         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 846         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 847 else
 848         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 849 fi
 850 cat > configargs.h <<EOF
 851 /* Generated automatically. */
 852 static const char configuration_arguments[] = "$gcc_config_arguments";
 853 static const char thread_model[] = "$thread_file";
 854 EOF
 855 changequote([,])dnl
 856
 857 # Internationalization
 858 PACKAGE=gcc
 859 VERSION="$gcc_version"
 860 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 861         [Define to the name of the distribution.])
 862 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 863         [Define to the version of the distribution.])
 864 AC_SUBST(PACKAGE)
 865 AC_SUBST(VERSION)
 866
 867 ALL_LINGUAS="sv"
 868
 869 # Enable NLS support by default
 870 AC_ARG_ENABLE(nls,
 871   [  --enable-nls            use Native Language Support (default)],
 872   , enable_nls=yes)
 873
 874 # if cross compiling, disable NLS support.
 875 # It's not worth the trouble, at least for now.
 876
 877 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 878   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 879   enable_nls=no
 880 fi
 881
 882 # if NLS is enabled, also enable check in po subdir
 883 if test $enable_nls = yes; then
 884   CHECK_PO=check-po
 885 else
 886   CHECK_PO=""
 887 fi
 888
 889 AC_SUBST(CHECK_PO)
 890
 891 AM_GNU_GETTEXT
 892 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 893
 894 # Windows32 Registry support for specifying GCC installation paths.
 895 AC_ARG_ENABLE(win32-registry,
 896 [  --disable-win32-registry
 897                           Disable lookup of installation paths in the
 898                          Registry on Windows hosts.
 899   --enable-win32-registry Enable registry lookup (default).
 900   --enable-win32-registry=KEY
 901                           Use KEY instead of GCC version as the last portion
 902                          of the registry key.],,)
 903
 904 AC_MSG_CHECKING(whether windows registry support is requested)
 905 if test x$enable_win32_registry != xno; then
 906   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 907 [Define to 1 if installation paths should be looked up in Windows32
 908    Registry. Ignored on non windows32 hosts.])
 909   AC_MSG_RESULT(yes)
 910 else
 911   AC_MSG_RESULT(no)
 912 fi
 913
 914 # Check if user specified a different registry key.
 915 case x${enable_win32_registry} in
 916 x | xyes)
 917   # default.
 918   gcc_cv_win32_registry_key="$VERSION"
 919   ;;
 920 xno)
 921   # no registry lookup.
 922   gcc_cv_win32_registry_key=''
 923   ;;
 924 *)
 925   # user-specified key.
 926   gcc_cv_win32_registry_key="$enable_win32_registry"
 927   ;;
 928 esac
 929
 930 if test x$enable_win32_registry != xno; then
 931   AC_MSG_CHECKING(registry key on windows hosts)
 932   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 933         [Define to be the last portion of registry key on windows hosts.])
 934   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 935 fi
 936
 937 # Get an absolute path to the GCC top-level source directory
 938 holddir=`pwd`
 939 cd $srcdir
 940 topdir=`pwd`
 941 cd $holddir
 942
 943 # Conditionalize the makefile for this host machine.
 944 # Make-host contains the concatenation of all host makefile fragments
 945 # [there can be more than one].  This file is built by configure.frag.
 946 host_overrides=Make-host
 947 dep_host_xmake_file=
 948 for f in .. ${host_xmake_file}
 949 do
 950         if test -f ${srcdir}/config/$f
 951         then
 952                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 953         fi
 954 done
 955
 956 # Conditionalize the makefile for this target machine.
 957 # Make-target contains the concatenation of all host makefile fragments
 958 # [there can be more than one].  This file is built by configure.frag.
 959 target_overrides=Make-target
 960 dep_tmake_file=
 961 for f in .. ${tmake_file}
 962 do
 963         if test -f ${srcdir}/config/$f
 964         then
 965                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
 966         fi
 967 done
 968
 969 # If the host doesn't support symlinks, modify CC in
 970 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
 971 # Otherwise, we can use "CC=$(CC)".
 972 rm -f symtest.tem
 973 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
 974 then
 975         cc_set_by_configure="\$(CC)"
 976         quoted_cc_set_by_configure="\$(CC)"
 977         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
 978 else
 979         rm -f symtest.tem
 980         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
 981         then
 982                 symbolic_link="cp -p"
 983         else
 984                 symbolic_link="cp"
 985         fi
 986         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
 987         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
 988         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
 989 fi
 990 rm -f symtest.tem
 991
 992 out_object_file=`basename $out_file .c`.o
 993
 994 tm_file_list=
 995 for f in $tm_file; do
 996   case $f in
 997     gansidecl.h | defaults.h )
 998        tm_file_list="${tm_file_list} $f" ;;
 999     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1000   esac
1001 done
1002
1003 host_xm_file_list=
1004 for f in $host_xm_file; do
1005   case $f in
1006     auto-host.h | gansidecl.h | defaults.h | hwint.h )
1007        host_xm_file_list="${host_xm_file_list} $f" ;;
1008     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1009   esac
1010 done
1011
1012 build_xm_file_list=
1013 for f in $build_xm_file; do
1014   case $f in
1015     auto-build.h | auto-host.h | gansidecl.h | defaults.h | hwint.h )
1016        build_xm_file_list="${build_xm_file_list} $f" ;;
1017     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1018   esac
1019 done
1020
1021 # Define macro CROSS_COMPILE in compilation
1022 # if this is a cross-compiler.
1023 # Also use all.cross instead of all.internal
1024 # and add cross-make to Makefile.
1025 cross_overrides="/dev/null"
1026 if test x$host != x$target
1027 then
1028         cross_defines="CROSS=-DCROSS_COMPILE"
1029         cross_overrides="${topdir}/cross-make"
1030 fi
1031
1032 # If this is a cross-compiler that does not
1033 # have its own set of headers then define
1034 # inhibit_libc
1035
1036 # If this is using newlib, then define inhibit_libc in
1037 # LIBGCC2_CFLAGS.  This will cause __eprintf to be left out of
1038 # libgcc.a, but that's OK because newlib should have its own version of
1039 # assert.h.
1040 inhibit_libc=
1041 if [test x$host != x$target] && [test x$with_headers = x]; then
1042        inhibit_libc=-Dinhibit_libc
1043 else
1044        if [test x$with_newlib = xyes]; then
1045                inhibit_libc=-Dinhibit_libc
1046        fi
1047 fi
1048 AC_SUBST(inhibit_libc)
1049
1050 # When building gcc with a cross-compiler, we need to fix a few things.
1051 # This must come after cross-make as we want all.build to override
1052 # all.cross.
1053 build_overrides="/dev/null"
1054 if test x$build != x$host
1055 then
1056         build_overrides="${topdir}/build-make"
1057 fi
1058
1059 # Expand extra_headers to include complete path.
1060 # This substitutes for lots of t-* files.
1061 extra_headers_list=
1062 if test "x$extra_headers" = x
1063 then true
1064 else
1065         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1066         for file in $extra_headers;
1067         do
1068                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1069         done
1070 fi
1071
1072 if test x$use_collect2 = xno; then
1073         use_collect2=
1074 fi
1075
1076 # Add a definition of USE_COLLECT2 if system wants one.
1077 # Also tell toplev.c what to do.
1078 # This substitutes for lots of t-* files.
1079 if test x$use_collect2 = x
1080 then
1081         will_use_collect2=
1082         maybe_use_collect2=
1083 else
1084         will_use_collect2="collect2"
1085         maybe_use_collect2="-DUSE_COLLECT2"
1086 fi
1087
1088 # If we have gas in the build tree, make a link to it.
1089 if test -f ../gas/Makefile; then
1090         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1091 fi
1092
1093 # If we have nm in the build tree, make a link to it.
1094 if test -f ../binutils/Makefile; then
1095         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1096 fi
1097
1098 # If we have ld in the build tree, make a link to it.
1099 if test -f ../ld/Makefile; then
1100 #       if test x$use_collect2 = x; then
1101 #               rm -f ld; $symbolic_link ../ld/ld-new$host_exeext ld$host_exeext 2>/dev/null
1102 #       else
1103                 rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1104 #       fi
1105 fi
1106
1107 # Figure out what assembler we will be using.
1108 AC_MSG_CHECKING(what assembler to use)
1109 gcc_cv_as=
1110 gcc_cv_gas_major_version=
1111 gcc_cv_gas_minor_version=
1112 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1113 if test -x "$DEFAULT_ASSEMBLER"; then
1114         gcc_cv_as="$DEFAULT_ASSEMBLER"
1115 elif test -x "$AS"; then
1116         gcc_cv_as="$AS"
1117 elif test -x as$host_exeext; then
1118         # Build using assembler in the current directory.
1119         gcc_cv_as=./as$host_exeext
1120 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1121         # Single tree build which includes gas.
1122         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1123         do
1124 changequote(,)dnl
1125                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1126 changequote([,])dnl
1127                 if test x$gcc_cv_gas_version != x; then
1128                         break
1129                 fi
1130         done
1131 changequote(,)dnl
1132         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1133         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1134 changequote([,])dnl
1135 fi
1136
1137 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1138         # Native build.
1139         # Search the same directories that the installed compiler will
1140         # search.  Else we may find the wrong assembler and lose.  If we
1141         # do not find a suitable assembler binary, then try the user's
1142         # path.
1143         #
1144         # Also note we have to check MD_EXEC_PREFIX before checking the
1145         # user's path.  Unfortunately, there is no good way to get at the
1146         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1147         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1148         # to be fixed as part of the make/configure rewrite too.
1149
1150         if test "x$exec_prefix" = xNONE; then
1151                 if test "x$prefix" = xNONE; then
1152                         test_prefix=/usr/local
1153                 else
1154                         test_prefix=$prefix
1155                 fi
1156         else
1157                 test_prefix=$exec_prefix
1158         fi
1159
1160         # If the loop below does not find an assembler, then use whatever
1161         # one we can find in the users's path.
1162         # user's path.
1163         gcc_cv_as=as$host_exeext
1164
1165         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1166                    $test_prefix/lib/gcc-lib/$target \
1167                    /usr/lib/gcc/$target/$gcc_version \
1168                    /usr/lib/gcc/$target \
1169                    $test_prefix/$target/bin/$target/$gcc_version \
1170                    $test_prefix/$target/bin \
1171                    /usr/libexec \
1172                    /usr/ccs/gcc \
1173                    /usr/ccs/bin \
1174                    /udk/usr/ccs/bin \
1175                    /bsd43/usr/lib/cmplrs/cc \
1176                    /usr/cross64/usr/bin \
1177                    /usr/lib/cmplrs/cc \
1178                    /sysv/usr/lib/cmplrs/cc \
1179                    /svr4/usr/lib/cmplrs/cc \
1180                    /usr/bin"
1181
1182         for dir in $test_dirs; do
1183                 if test -f $dir/as$host_exeext; then
1184                         gcc_cv_as=$dir/as$host_exeext
1185                         break;
1186                 fi
1187         done
1188 fi
1189 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1190   AC_MSG_RESULT("newly built gas")
1191 else
1192   AC_MSG_RESULT($gcc_cv_as)
1193 fi
1194
1195 # Figure out what nm we will be using.
1196 AC_MSG_CHECKING(what nm to use)
1197 if test -x nm$host_exeext; then
1198         gcc_cv_nm=./nm$host_exeext
1199 elif test x$host = x$target; then
1200         # Native build.
1201         gcc_cv_nm=nm$host_exeext
1202 fi
1203 AC_MSG_RESULT($gcc_cv_nm)
1204
1205 # Figure out what assembler alignment features are present.
1206 AC_MSG_CHECKING(assembler alignment features)
1207 gcc_cv_as_alignment_features=none
1208 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1209         # Gas version 2.6 and later support for .balign and .p2align.
1210         # bytes to skip when using .p2align.
1211         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1212                 gcc_cv_as_alignment_features=".balign and .p2align"
1213                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1214         fi
1215         # Gas version 2.8 and later support specifying the maximum
1216         # bytes to skip when using .p2align.
1217         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1218                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1219                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1220         fi
1221 elif test x$gcc_cv_as != x; then
1222         # Check if we have .balign and .p2align
1223         echo ".balign  4" > conftest.s
1224         echo ".p2align  2" >> conftest.s
1225         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1226                 gcc_cv_as_alignment_features=".balign and .p2align"
1227                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1228         fi
1229         rm -f conftest.s conftest.o
1230         # Check if specifying the maximum bytes to skip when
1231         # using .p2align is supported.
1232         echo ".p2align 4,,7" > conftest.s
1233         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1234                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1235                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1236         fi
1237         rm -f conftest.s conftest.o
1238 fi
1239 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1240
1241 AC_MSG_CHECKING(assembler subsection support)
1242 gcc_cv_as_subsections=no
1243 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1244   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1245     gcc_cv_as_subsections="working .subsection -1"
1246   fi
1247 elif test x$gcc_cv_as != x; then
1248         # Check if we have .subsection
1249         echo ".subsection 1" > conftest.s
1250         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1251                 gcc_cv_as_subsections=".subsection"
1252                 if test x$gcc_cv_nm != x; then
1253                         cat > conftest.s <<EOF
1254 conftest_label1: .word 0
1255 .subsection -1
1256 conftest_label2: .word 0
1257 .previous
1258 EOF
1259                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1260                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1261                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1262                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1263                                         :
1264                                 else
1265                                         gcc_cv_as_subsections="working .subsection -1"
1266                                 fi
1267                         fi
1268                 fi
1269         fi
1270         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1271 fi
1272 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1273         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1274 [Define if your assembler supports .subsection and .subsection -1 starts
1275    emitting at the beginning of your section.])
1276 fi
1277 AC_MSG_RESULT($gcc_cv_as_subsections)
1278
1279 AC_MSG_CHECKING(assembler weak support)
1280 gcc_cv_as_weak=no
1281 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1282   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1283     gcc_cv_as_weak="yes"
1284   fi
1285 elif test x$gcc_cv_as != x; then
1286         # Check if we have .weak
1287         echo "  .weak foobar" > conftest.s
1288         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1289                 gcc_cv_as_weak="yes"
1290         fi
1291         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1292 fi
1293 if test x"$gcc_cv_as_weak" = xyes; then
1294         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1295 fi
1296 AC_MSG_RESULT($gcc_cv_as_weak)
1297
1298 AC_MSG_CHECKING(assembler hidden support)
1299 gcc_cv_as_hidden=no
1300 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1301   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1302     gcc_cv_as_hidden="yes"
1303   fi
1304 elif test x$gcc_cv_as != x; then
1305         # Check if we have .hidden
1306         echo "  .hidden foobar" > conftest.s
1307         echo "foobar:" >> conftest.s
1308         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1309                 gcc_cv_as_hidden="yes"
1310         fi
1311         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1312 fi
1313 if test x"$gcc_cv_as_hidden" = xyes; then
1314         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1315                 [Define if your assembler supports .hidden.])
1316 fi
1317 AC_MSG_RESULT($gcc_cv_as_hidden)
1318
1319 case "$target" in
1320   sparc*-*-*)
1321     AC_CACHE_CHECK([assembler .register pseudo-op support],
1322         gcc_cv_as_register_pseudo_op, [
1323         gcc_cv_as_register_pseudo_op=unknown
1324         if test x$gcc_cv_as != x; then
1325             # Check if we have .register
1326             echo ".register %g2, #scratch" > conftest.s
1327             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1328                 gcc_cv_as_register_pseudo_op=yes
1329             else
1330                 gcc_cv_as_register_pseudo_op=no
1331             fi
1332             rm -f conftest.s conftest.o
1333         fi
1334     ])
1335     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1336         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1337                 [Define if your assembler supports .register.])
1338     fi
1339
1340     AC_CACHE_CHECK([assembler supports -relax],
1341         gcc_cv_as_relax_opt, [
1342         gcc_cv_as_relax_opt=unknown
1343         if test x$gcc_cv_as != x; then
1344             # Check if gas supports -relax
1345             echo ".text" > conftest.s
1346             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1347                 gcc_cv_as_relax_opt=yes
1348             else
1349                 gcc_cv_as_relax_opt=no
1350             fi
1351             rm -f conftest.s conftest.o
1352         fi
1353     ])
1354     if test "x$gcc_cv_as_relax_opt" = xyes; then
1355         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1356                 [Define if your assembler supports -relax option.])
1357     fi
1358
1359     case "$tm_file" in
1360     *64*)
1361         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1362             gcc_cv_as_flags64, [
1363                 if test -n "$gcc_cv_as"; then
1364                     echo ".xword foo" > conftest.s
1365                     gcc_cv_as_flags64=no
1366                     for flag in "-xarch=v9" "-64 -Av9"; do
1367                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1368                             > /dev/null 2>&1; then
1369                             gcc_cv_as_flags64=$flag
1370                             break
1371                         fi
1372                     done
1373                     rm -f conftest.s conftest.o
1374                 else
1375                     if test "$gas" = yes; then
1376                         gcc_cv_as_flags64="-64 -Av9"
1377                     else
1378                         gcc_cv_as_flags64="-xarch=v9"
1379                     fi
1380                 fi
1381         ])
1382         if test "x$gcc_cv_as_flags64" = xno; then
1383 changequote(, )
1384             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1385             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1386 changequote([, ])
1387         else
1388             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1389                         [Define if the assembler supports 64bit sparc.])
1390         fi
1391         ;;
1392     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1393         ;;
1394     esac
1395
1396     if test "x$gcc_cv_as_flags64" != xno; then
1397         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1398             gcc_cv_as_offsetable_lo10, [
1399             gcc_cv_as_offsetable_lo10=unknown
1400             if test "x$gcc_cv_as" != x; then
1401                 # Check if assembler has offsetable %lo()
1402                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1403                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1404                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1405                         > /dev/null 2>&1 &&
1406                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1407                         > /dev/null 2>&1; then
1408                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1409                         gcc_cv_as_offsetable_lo10=no
1410                     else
1411                         gcc_cv_as_offsetable_lo10=yes
1412                     fi
1413                 else
1414                     gcc_cv_as_offsetable_lo10=no
1415                 fi
1416                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1417             fi
1418         ])
1419         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1420             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1421                 [Define if your assembler supports offsetable %lo().])
1422         fi
1423     fi
1424     ;;
1425
1426 changequote(,)dnl
1427   i[34567]86-*-*)
1428 changequote([,])dnl
1429     AC_MSG_CHECKING(assembler instructions)
1430     gcc_cv_as_instructions=
1431     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1432       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1433         gcc_cv_as_instructions="filds fists"
1434       fi
1435     elif test x$gcc_cv_as != x; then
1436         set "filds fists" "filds mem; fists mem"
1437         while test $# -gt 0
1438         do
1439                 echo "$2" > conftest.s
1440                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1441                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1442                 fi
1443                 shift 2
1444         done
1445         rm -f conftest.s conftest.o
1446     fi
1447     if test x"$gcc_cv_as_instructions" != x; then
1448         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1449     fi
1450     AC_MSG_RESULT($gcc_cv_as_instructions)
1451     ;;
1452 esac
1453
1454 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1455 gcc_cv_as_dwarf2_debug_line=no
1456 # ??? Not all targets support dwarf2 debug_line, even within a version
1457 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1458 # info to the output file.  So, as supported targets are added to gas 2.11,
1459 # add some instruction here to (also) show we expect this might work.
1460 # ??? Once 2.11 is released, probably need to add first known working
1461 # version to the per-target configury.
1462 case "$target" in
1463   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-*)
1464     insn="nop"
1465     ;;
1466   ia64*-*-*)
1467     insn="nop 0"
1468     ;;
1469   esac
1470 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1471 then
1472   if test "$gcc_cv_gas_major_version" -eq 2 \
1473         -a "$gcc_cv_gas_minor_version" -ge 11 \
1474         -o "$gcc_cv_gas_major_version" -gt 2 \
1475      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1476      && test x"$insn" != x ; then
1477     gcc_cv_as_dwarf2_debug_line="yes"
1478   fi
1479 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1480         echo '  .file 1 "conftest.s"' > conftest.s
1481         echo '  .loc 1 3 0' >> conftest.s
1482         echo "  $insn" >> conftest.s
1483         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1484            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1485                 # The .debug_line file table must be in the exact order that
1486                 # we specified the files, since these indicies are also used
1487                 # by DW_AT_decl_file.  Approximate this test by testing if
1488                 # the assembler bitches if the same index is assigned twice.
1489                 echo '  .file 1 "foo.s"' > conftest.s
1490                 echo '  .file 1 "bar.s"' >> conftest.s
1491                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1492                 then
1493                   gcc_cv_as_dwarf2_debug_line="no"
1494                 else
1495                   gcc_cv_as_dwarf2_debug_line="yes"
1496                 fi
1497         fi
1498         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1499 fi
1500 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1501         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1502           [Define if your assembler supports dwarf2 .file/.loc directives.])
1503 fi
1504 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1505
1506 # Figure out what language subdirectories are present.
1507 # Look if the user specified --enable-languages="..."; if not, use
1508 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1509 # go away some day.
1510 if test x"${enable_languages+set}" != xset; then
1511         if test x"${LANGUAGES+set}" = xset; then
1512                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1513         else
1514                 enable_languages=all
1515         fi
1516 else
1517         if test x"${enable_languages}" = x; then
1518                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1519         fi
1520 fi
1521
1522 # First scan to see if an enabled language requires some other language.
1523 # We assume that a given config-lang.in will list all the language
1524 # front ends it requires, even if some are required indirectly.
1525 for lang in ${srcdir}/*/config-lang.in ..
1526 do
1527    case $lang in
1528     ..)
1529        ;;
1530     # The odd quoting in the next line works around
1531     # an apparent bug in bash 1.12 on linux.
1532 changequote(,)dnl
1533     ${srcdir}/[*]/config-lang.in)
1534        ;;
1535     *)
1536        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1537        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1538        for other in $this_lang_requires
1539        do
1540           case ,${enable_languages}, in
1541            *,$other,*)
1542               ;;
1543            *,all,*)
1544               ;;
1545            *,$lang_alias,*)
1546               enable_languages="$enable_languages,$other"
1547               ;;
1548           esac
1549        done
1550        ;;
1551 changequote([,])dnl
1552    esac
1553 done
1554
1555 subdirs=
1556 for lang in ${srcdir}/*/config-lang.in ..
1557 do
1558         case $lang in
1559         ..) ;;
1560         # The odd quoting in the next line works around
1561         # an apparent bug in bash 1.12 on linux.
1562 changequote(,)dnl
1563         ${srcdir}/[*]/config-lang.in) ;;
1564         *)
1565           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1566           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1567           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1568           if test "x$lang_alias" = x
1569           then
1570                 echo "$lang doesn't set \$language." 1>&2
1571                 exit 1
1572           fi
1573           case ${build_by_default},${enable_languages}, in
1574           *,$lang_alias,*) add_this_lang=yes ;;
1575           no,*) add_this_lang=no ;;
1576           *,all,*) add_this_lang=yes ;;
1577           *) add_this_lang=no ;;
1578           esac
1579           if test x"${add_this_lang}" = xyes; then
1580                 case $lang in
1581                     ${srcdir}/ada/config-lang.in)
1582                         if test x$gnat = xyes ; then
1583                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1584                         fi
1585                         ;;
1586                     *)
1587                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1588                         ;;
1589                 esac
1590           fi
1591           ;;
1592 changequote([,])dnl
1593         esac
1594 done
1595
1596 # Make gthr-default.h if we have a thread file.
1597 gthread_flags=
1598 if test $thread_file != single; then
1599     rm -f gthr-default.h
1600     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1601     gthread_flags=-DHAVE_GTHR_DEFAULT
1602 fi
1603 AC_SUBST(gthread_flags)
1604
1605 # Find out what GC implementation we want, or may, use.
1606 AC_ARG_WITH(gc,
1607 [  --with-gc={simple,page} Choose the garbage collection mechanism to use
1608                            with the compiler.],
1609 [case "$withval" in
1610   simple | page)
1611     GGC=ggc-$withval
1612     ;;
1613   *)
1614     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1615     ;;
1616 esac],
1617 [GGC=ggc-page])
1618 AC_SUBST(GGC)
1619 echo "Using $GGC for garbage collection."
1620
1621 # Use the system's zlib library.
1622 zlibdir=-L../zlib
1623 zlibinc="-I\$(srcdir)/../zlib"
1624 AC_ARG_WITH(system-zlib,
1625 [  --with-system-zlib      use installed libz],
1626 zlibdir=
1627 zlibinc=
1628 )
1629 AC_SUBST(zlibdir)
1630 AC_SUBST(zlibinc)
1631
1632 AC_DEFINE_UNQUOTED(ENABLE_STD_NAMESPACE, 1,
1633   [Define to 1 if you want to enable namespaces (-fhonor-std) by default.])
1634
1635 dnl Very limited version of automake's enable-maintainer-mode
1636
1637 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1638   dnl maintainer-mode is disabled by default
1639   AC_ARG_ENABLE(maintainer-mode,
1640 [  --enable-maintainer-mode enable make rules and dependencies not useful
1641                           (and sometimes confusing) to the casual installer],
1642       maintainer_mode=$enableval,
1643       maintainer_mode=no)
1644
1645 AC_MSG_RESULT($maintainer_mode)
1646
1647 if test "$maintainer_mode" = "yes"; then
1648   MAINT=''
1649 else
1650   MAINT='#'
1651 fi
1652 AC_SUBST(MAINT)dnl
1653
1654 # Make empty files to contain the specs and options for each language.
1655 # Then add #include lines to for a compiler that has specs and/or options.
1656
1657 lang_specs_files=
1658 lang_options_files=
1659 lang_tree_files=
1660 rm -f specs.h options.h gencheck.h
1661 touch specs.h options.h gencheck.h
1662 for subdir in . $subdirs
1663 do
1664         if test -f $srcdir/$subdir/lang-specs.h; then
1665                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1666                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1667         fi
1668         if test -f $srcdir/$subdir/lang-options.h; then
1669                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1670                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1671         fi
1672         if test -f $srcdir/$subdir/$subdir-tree.def; then
1673                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1674                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1675         fi
1676 done
1677
1678 # These (without "all_") are set in each config-lang.in.
1679 # `language' must be a single word so is spelled singularly.
1680 all_languages=
1681 all_boot_languages=
1682 all_compilers=
1683 all_stagestuff=
1684 all_diff_excludes=
1685 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1686 # List of language makefile fragments.
1687 all_lang_makefiles=
1688 all_headers=
1689 all_lib2funcs=
1690
1691 # Add the language fragments.
1692 # Languages are added via two mechanisms.  Some information must be
1693 # recorded in makefile variables, these are defined in config-lang.in.
1694 # We accumulate them and plug them into the main Makefile.
1695 # The other mechanism is a set of hooks for each of the main targets
1696 # like `clean', `install', etc.
1697
1698 language_fragments="Make-lang"
1699 language_hooks="Make-hooks"
1700
1701 for s in .. $subdirs
1702 do
1703         if test $s != ".."
1704         then
1705                 language=
1706                 boot_language=
1707                 compilers=
1708                 stagestuff=
1709                 diff_excludes=
1710                 headers=
1711                 outputs=
1712                 lib2funcs=
1713                 . ${srcdir}/$s/config-lang.in
1714                 if test "x$language" = x
1715                 then
1716                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1717                         exit 1
1718                 fi
1719                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1720                 if test -f ${srcdir}/$s/Makefile.in
1721                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1722                 fi
1723                 all_languages="$all_languages $language"
1724                 if test "x$boot_language" = xyes
1725                 then
1726                         all_boot_languages="$all_boot_languages $language"
1727                 fi
1728                 all_compilers="$all_compilers $compilers"
1729                 all_stagestuff="$all_stagestuff $stagestuff"
1730                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1731                 all_headers="$all_headers $headers"
1732                 all_outputs="$all_outputs $outputs"
1733                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1734         fi
1735 done
1736
1737 # Since we can't use `::' targets, we link each language in
1738 # with a set of hooks, reached indirectly via lang.${target}.
1739
1740 rm -f Make-hooks
1741 touch Make-hooks
1742 target_list="all.build all.cross start.encap rest.encap \
1743         info dvi \
1744         install-normal install-common install-info install-man \
1745         uninstall \
1746         mostlyclean clean distclean extraclean maintainer-clean \
1747         stage1 stage2 stage3 stage4"
1748 for t in $target_list
1749 do
1750         x=
1751         for lang in .. $all_languages
1752         do
1753                 if test $lang != ".."; then
1754                         x="$x $lang.$t"
1755                 fi
1756         done
1757         echo "lang.$t: $x" >> Make-hooks
1758 done
1759
1760 # If we're not building in srcdir, create .gdbinit.
1761
1762 if test ! -f Makefile.in; then
1763         echo "dir ." > .gdbinit
1764         echo "dir ${srcdir}" >> .gdbinit
1765         if test x$gdb_needs_out_file_path = xyes
1766         then
1767                 echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1768         fi
1769         if test "x$subdirs" != x; then
1770                 for s in $subdirs
1771                 do
1772                         echo "dir ${srcdir}/$s" >> .gdbinit
1773                 done
1774         fi
1775         echo "source ${srcdir}/.gdbinit" >> .gdbinit
1776 fi
1777
1778 # Define variables host_canonical and build_canonical
1779 # because some Cygnus local changes in the Makefile depend on them.
1780 build_canonical=${build}
1781 host_canonical=${host}
1782 target_subdir=
1783 if test "${host}" != "${target}" ; then
1784     target_subdir=${target_alias}/
1785 fi
1786 AC_SUBST(build_canonical)
1787 AC_SUBST(host_canonical)
1788 AC_SUBST(target_subdir)
1789
1790 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1791 # absolute path for gcc_tooldir based on inserting the number of up-directory
1792 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1793 # $(libsubdir)/@(unlibsubdir) based path.
1794 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1795 # make and thus we'd get different behavior depending on where we built the
1796 # sources.
1797 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
1798     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
1799 else
1800 changequote(<<, >>)dnl
1801 # An explanation of the sed strings:
1802 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
1803 #  -e 's|/$||'            match a trailing forward slash and eliminates it
1804 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
1805 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
1806 #
1807 # (*) Note this pattern overwrites the first character of the string
1808 # with a forward slash if one is not already present.  This is not a
1809 # problem because the exact names of the sub-directories concerned is
1810 # unimportant, just the number of them matters.
1811 #
1812 # The practical upshot of these patterns is like this:
1813 #
1814 #  prefix     exec_prefix        result
1815 #  ------     -----------        ------
1816 #   /foo        /foo/bar          ../
1817 #   /foo/       /foo/bar          ../
1818 #   /foo        /foo/bar/         ../
1819 #   /foo/       /foo/bar/         ../
1820 #   /foo        /foo/bar/ugg      ../../
1821 #
1822     dollar='$$'
1823     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
1824 changequote([, ])dnl
1825 fi
1826 AC_SUBST(gcc_tooldir)
1827 AC_SUBST(dollar)
1828
1829 # Find a directory in which to install a shared libgcc.
1830
1831 AC_ARG_ENABLE(version-specific-runtime-libs,
1832 [  --enable-version-specific-runtime-libs    Specify that runtime libraries shou
1833 ld be installed in a compiler-specific directory ])
1834
1835 AC_ARG_WITH(slibdir,
1836 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
1837 slibdir="$with_slibdir",
1838 if test "${enable_version_specific_runtime_libs+set}" = set; then
1839   slibdir='$(libsubdir)'
1840 elif test "$host" != "$target"; then
1841   slibdir='$(build_tooldir)/lib'
1842 else
1843   slibdir='$(libdir)'
1844 fi)
1845 AC_SUBST(slibdir)
1846
1847 # Nothing to do for FLOAT_H, float_format already handled.
1848 objdir=`pwd`
1849 AC_SUBST(objdir)
1850
1851 # Process the language and host/target makefile fragments.
1852 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
1853
1854 # Substitute configuration variables
1855 AC_SUBST(subdirs)
1856 AC_SUBST(all_boot_languages)
1857 AC_SUBST(all_compilers)
1858 AC_SUBST(all_diff_excludes)
1859 AC_SUBST(all_headers)
1860 AC_SUBST(all_lang_makefiles)
1861 AC_SUBST(all_languages)
1862 AC_SUBST(all_lib2funcs)
1863 AC_SUBST(all_stagestuff)
1864 AC_SUBST(build_exeext)
1865 AC_SUBST(build_install_headers_dir)
1866 AC_SUBST(build_xm_file_list)
1867 AC_SUBST(cc_set_by_configure)
1868 AC_SUBST(quoted_cc_set_by_configure)
1869 AC_SUBST(cpp_install_dir)
1870 AC_SUBST(dep_host_xmake_file)
1871 AC_SUBST(dep_tmake_file)
1872 AC_SUBST(extra_c_flags)
1873 AC_SUBST(extra_headers_list)
1874 AC_SUBST(extra_objs)
1875 AC_SUBST(extra_parts)
1876 AC_SUBST(extra_passes)
1877 AC_SUBST(extra_programs)
1878 AC_SUBST(float_h_file)
1879 AC_SUBST(gcc_config_arguments)
1880 AC_SUBST(gcc_gxx_include_dir)
1881 AC_SUBST(libstdcxx_incdir)
1882 AC_SUBST(gcc_version)
1883 AC_SUBST(gcc_version_full)
1884 AC_SUBST(gcc_version_trigger)
1885 AC_SUBST(host_exeext)
1886 AC_SUBST(host_extra_gcc_objs)
1887 AC_SUBST(host_xm_file_list)
1888 AC_SUBST(install)
1889 AC_SUBST(lang_options_files)
1890 AC_SUBST(lang_specs_files)
1891 AC_SUBST(lang_tree_files)
1892 AC_SUBST(local_prefix)
1893 AC_SUBST(maybe_use_collect2)
1894 AC_SUBST(md_file)
1895 AC_SUBST(objc_boehm_gc)
1896 AC_SUBST(out_file)
1897 AC_SUBST(out_object_file)
1898 AC_SUBST(stage_prefix_set_by_configure)
1899 AC_SUBST(symbolic_link)
1900 AC_SUBST(thread_file)
1901 AC_SUBST(tm_file_list)
1902 AC_SUBST(will_use_collect2)
1903 AC_SUBST(c_target_objs)
1904 AC_SUBST(cxx_target_objs)
1905
1906
1907 AC_SUBST_FILE(target_overrides)
1908 AC_SUBST_FILE(host_overrides)
1909 AC_SUBST(cross_defines)
1910 AC_SUBST_FILE(cross_overrides)
1911 AC_SUBST_FILE(build_overrides)
1912 AC_SUBST_FILE(language_fragments)
1913 AC_SUBST_FILE(language_hooks)
1914
1915 # Echo that links are built
1916 if test x$host = x$target
1917 then
1918         str1="native "
1919 else
1920         str1="cross-"
1921         str2=" from $host"
1922 fi
1923
1924 if test x$host != x$build
1925 then
1926         str3=" on a $build system"
1927 fi
1928
1929 if test "x$str2" != x || test "x$str3" != x
1930 then
1931         str4=
1932 fi
1933
1934 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
1935
1936 if test "x$str2" != x || test "x$str3" != x
1937 then
1938         echo " ${str2}${str3}." 1>&2
1939 fi
1940
1941 # Truncate the target if necessary
1942 if test x$host_truncate_target != x; then
1943         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
1944 fi
1945
1946 # Configure the subdirectories
1947 # AC_CONFIG_SUBDIRS($subdirs)
1948
1949 # Create the Makefile
1950 # and configure language subdirectories
1951 AC_OUTPUT($all_outputs,
1952 [
1953 case x$CONFIG_HEADERS in
1954 xauto-host.h:config.in)
1955 echo > cstamp-h ;;
1956 esac
1957 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
1958 # bootstrapping and the installation procedure can still use
1959 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
1960 # FLAGS_TO_PASS has been modified to solve the problem there.
1961 # This is virtually a duplicate of what happens in configure.lang; we do
1962 # an extra check to make sure this only happens if ln -s can be used.
1963 if test "$symbolic_link" = "ln -s"; then
1964  for d in .. ${subdirs} ; do
1965    if test $d != ..; then
1966         STARTDIR=`pwd`
1967         cd $d
1968         for t in stage1 stage2 stage3 stage4 include
1969         do
1970                 rm -f $t
1971                 $symbolic_link ../$t $t 2>/dev/null
1972         done
1973         cd $STARTDIR
1974    fi
1975  done
1976 else true ; fi
1977 # Avoid having to add intl to our include paths.
1978 if test -f intl/libintl.h; then
1979   echo creating libintl.h
1980   echo '#include "intl/libintl.h"' >libintl.h
1981 fi
1982 ],
1983 [
1984 host='${host}'
1985 build='${build}'
1986 target='${target}'
1987 target_alias='${target_alias}'
1988 srcdir='${srcdir}'
1989 subdirs='${subdirs}'
1990 symbolic_link='${symbolic_link}'
1991 program_transform_set='${program_transform_set}'
1992 program_transform_name='${program_transform_name}'
1993 dep_host_xmake_file='${dep_host_xmake_file}'
1994 host_xmake_file='${host_xmake_file}'
1995 dep_tmake_file='${dep_tmake_file}'
1996 tmake_file='${tmake_file}'
1997 thread_file='${thread_file}'
1998 gcc_config_arguments='${gcc_config_arguments}'
1999 gcc_version='${gcc_version}'
2000 gcc_version_full='${gcc_version_full}'
2001 gcc_version_trigger='${gcc_version_trigger}'
2002 local_prefix='${local_prefix}'
2003 build_install_headers_dir='${build_install_headers_dir}'
2004 build_exeext='${build_exeext}'
2005 host_exeext='${host_exeext}'
2006 out_file='${out_file}'
2007 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2008 SET_MAKE='${SET_MAKE}'
2009 target_list='${target_list}'
2010 target_overrides='${target_overrides}'
2011 host_overrides='${host_overrides}'
2012 cross_defines='${cross_defines}'
2013 cross_overrides='${cross_overrides}'
2014 build_overrides='${build_overrides}'
2015 cpp_install_dir='${cpp_install_dir}'
2016 ])