gcc/ada/snames.adb-tmpl

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               S N A M E S                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with Opt;   use Opt;
  33 with Table;
  34 with Types; use Types;
  35
  36 package body Snames is
  37
  38    --  Table used to record convention identifiers
  39
  40    type Convention_Id_Entry is record
  41       Name       : Name_Id;
  42       Convention : Convention_Id;
  43    end record;
  44
  45    package Convention_Identifiers is new Table.Table (
  46      Table_Component_Type => Convention_Id_Entry,
  47      Table_Index_Type     => Int,
  48      Table_Low_Bound      => 1,
  49      Table_Initial        => 50,
  50      Table_Increment      => 200,
  51      Table_Name           => "Name_Convention_Identifiers");
  52
  53    --  Table of names to be set by Initialize. Each name is terminated by a
  54    --  single #, and the end of the list is marked by a null entry, i.e. by
  55    --  two # marks in succession. Note that the table does not include the
  56    --  entries for a-z, since these are initialized by Namet itself.
  57
  58    Preset_Names : constant String :=
  59 !! TEMPLATE INSERTION POINT
  60      "#";
  61
  62    ---------------------
  63    -- Generated Names --
  64    ---------------------
  65
  66    --  This section lists the various cases of generated names which are
  67    --  built from existing names by adding unique leading and/or trailing
  68    --  upper case letters. In some cases these names are built recursively,
  69    --  in particular names built from types may be built from types which
  70    --  themselves have generated names. In this list, xxx represents an
  71    --  existing name to which identifying letters are prepended or appended,
  72    --  and a trailing n represents a serial number in an external name that
  73    --  has some semantic significance (e.g. the n'th index type of an array).
  74
  75    --    xxxA    access type for formal xxx in entry param record   (Exp_Ch9)
  76    --    xxxB    tag table for tagged type xxx                      (Exp_Ch3)
  77    --    xxxB    task body procedure for task xxx                   (Exp_Ch9)
  78    --    xxxD    dispatch table for tagged type xxx                 (Exp_Ch3)
  79    --    xxxD    discriminal for discriminant xxx                   (Sem_Ch3)
  80    --    xxxDn   n'th discr check function for rec type xxx         (Exp_Ch3)
  81    --    xxxE    elaboration boolean flag for task xxx              (Exp_Ch9)
  82    --    xxxE    dispatch table pointer type for tagged type xxx    (Exp_Ch3)
  83    --    xxxE    parameters for accept body for entry xxx           (Exp_Ch9)
  84    --    xxxFn   n'th primitive of a tagged type (named xxx)        (Exp_Ch3)
  85    --    xxxJ    tag table type index for tagged type xxx           (Exp_Ch3)
  86    --    xxxM    master Id value for access type xxx                (Exp_Ch3)
  87    --    xxxP    tag table pointer type for tagged type xxx         (Exp_Ch3)
  88    --    xxxP    parameter record type for entry xxx                (Exp_Ch9)
  89    --    xxxPA   access to parameter record type for entry xxx      (Exp_Ch9)
  90    --    xxxPn   pointer type for n'th primitive of tagged type xxx (Exp_Ch3)
  91    --    xxxR    dispatch table pointer for tagged type xxx         (Exp_Ch3)
  92    --    xxxT    tag table type for tagged type xxx                 (Exp_Ch3)
  93    --    xxxT    literal table for enumeration type xxx             (Sem_Ch3)
  94    --    xxxV    type for task value record for task xxx            (Exp_Ch9)
  95    --    xxxX    entry index constant                               (Exp_Ch9)
  96    --    xxxY    dispatch table type for tagged type xxx            (Exp_Ch3)
  97    --    xxxZ    size variable for task xxx                         (Exp_Ch9)
  98
  99    --  TSS names
 100
 101    --    xxxDA   deep adjust routine for type xxx                   (Exp_TSS)
 102    --    xxxDF   deep finalize routine for type xxx                 (Exp_TSS)
 103    --    xxxDI   deep initialize routine for type xxx               (Exp_TSS)
 104    --    xxxEQ   composite equality routine for record type xxx     (Exp_TSS)
 105    --    xxxFA   PolyORB/DSA From_Any converter for type xxx        (Exp_TSS)
 106    --    xxxIP   initialization procedure for type xxx              (Exp_TSS)
 107    --    xxxRA   RAS type access routine for type xxx               (Exp_TSS)
 108    --    xxxRD   RAS type dereference routine for type xxx          (Exp_TSS)
 109    --    xxxRP   Rep to Pos conversion for enumeration type xxx     (Exp_TSS)
 110    --    xxxSA   array/slice assignment for controlled comp. arrays (Exp_TSS)
 111    --    xxxSI   stream input attribute subprogram for type xxx     (Exp_TSS)
 112    --    xxxSO   stream output attribute subprogram for type xxx    (Exp_TSS)
 113    --    xxxSR   stream read attribute subprogram for type xxx      (Exp_TSS)
 114    --    xxxSW   stream write attribute subprogram for type xxx     (Exp_TSS)
 115    --    xxxTA   PolyORB/DSA To_Any converter for type xxx          (Exp_TSS)
 116    --    xxxTC   PolyORB/DSA Typecode for type xxx                  (Exp_TSS)
 117
 118    --  Implicit type names
 119
 120    --    TxxxT   type of literal table for enumeration type xxx     (Sem_Ch3)
 121
 122    --  (Note: this list is not complete or accurate ???)
 123
 124    ----------------------
 125    -- Get_Attribute_Id --
 126    ----------------------
 127
 128    function Get_Attribute_Id (N : Name_Id) return Attribute_Id is
 129    begin
 130       if N = Name_CPU then
 131          return Attribute_CPU;
 132       elsif N = Name_Dispatching_Domain then
 133          return Attribute_Dispatching_Domain;
 134       elsif N = Name_Interrupt_Priority then
 135          return Attribute_Interrupt_Priority;
 136       else
 137          return Attribute_Id'Val (N - First_Attribute_Name);
 138       end if;
 139    end Get_Attribute_Id;
 140
 141    -----------------------
 142    -- Get_Convention_Id --
 143    -----------------------
 144
 145    function Get_Convention_Id (N : Name_Id) return Convention_Id is
 146    begin
 147       case N is
 148          when Name_Ada                   => return Convention_Ada;
 149          when Name_Ada_Pass_By_Copy      => return Convention_Ada_Pass_By_Copy;
 150          when Name_Ada_Pass_By_Reference => return
 151                                               Convention_Ada_Pass_By_Reference;
 152          when Name_Assembler             => return Convention_Assembler;
 153          when Name_C                     => return Convention_C;
 154          when Name_CIL                   => return Convention_CIL;
 155          when Name_COBOL                 => return Convention_COBOL;
 156          when Name_CPP                   => return Convention_CPP;
 157          when Name_Fortran               => return Convention_Fortran;
 158          when Name_Intrinsic             => return Convention_Intrinsic;
 159          when Name_Java                  => return Convention_Java;
 160          when Name_Stdcall               => return Convention_Stdcall;
 161          when Name_Stubbed               => return Convention_Stubbed;
 162
 163          --  If no direct match, then we must have a convention
 164          --  identifier pragma that has specified this name.
 165
 166          when others                     =>
 167             for J in 1 .. Convention_Identifiers.Last loop
 168                if N = Convention_Identifiers.Table (J).Name then
 169                   return Convention_Identifiers.Table (J).Convention;
 170                end if;
 171             end loop;
 172
 173             raise Program_Error;
 174       end case;
 175    end Get_Convention_Id;
 176
 177    -------------------------
 178    -- Get_Convention_Name --
 179    -------------------------
 180
 181    function Get_Convention_Name (C : Convention_Id) return Name_Id is
 182    begin
 183       case C is
 184          when Convention_Ada                   => return Name_Ada;
 185          when Convention_Ada_Pass_By_Copy      => return Name_Ada_Pass_By_Copy;
 186          when Convention_Ada_Pass_By_Reference =>
 187             return Name_Ada_Pass_By_Reference;
 188          when Convention_Assembler             => return Name_Assembler;
 189          when Convention_C                     => return Name_C;
 190          when Convention_CIL                   => return Name_CIL;
 191          when Convention_COBOL                 => return Name_COBOL;
 192          when Convention_CPP                   => return Name_CPP;
 193          when Convention_Entry                 => return Name_Entry;
 194          when Convention_Fortran               => return Name_Fortran;
 195          when Convention_Intrinsic             => return Name_Intrinsic;
 196          when Convention_Java                  => return Name_Java;
 197          when Convention_Protected             => return Name_Protected;
 198          when Convention_Stdcall               => return Name_Stdcall;
 199          when Convention_Stubbed               => return Name_Stubbed;
 200       end case;
 201    end Get_Convention_Name;
 202
 203    ---------------------------
 204    -- Get_Locking_Policy_Id --
 205    ---------------------------
 206
 207    function Get_Locking_Policy_Id (N : Name_Id) return Locking_Policy_Id is
 208    begin
 209       return Locking_Policy_Id'Val (N - First_Locking_Policy_Name);
 210    end Get_Locking_Policy_Id;
 211
 212    -------------------
 213    -- Get_Pragma_Id --
 214    -------------------
 215
 216    function Get_Pragma_Id (N : Name_Id) return Pragma_Id is
 217    begin
 218       case N is
 219          when Name_CPU                              =>
 220             return Pragma_CPU;
 221          when Name_Default_Scalar_Storage_Order     =>
 222             return Pragma_Default_Scalar_Storage_Order;
 223          when Name_Dispatching_Domain               =>
 224             return Pragma_Dispatching_Domain;
 225          when Name_Fast_Math                        =>
 226             return Pragma_Fast_Math;
 227          when Name_Interface                        =>
 228             return Pragma_Interface;
 229          when Name_Interrupt_Priority               =>
 230             return Pragma_Interrupt_Priority;
 231          when Name_Lock_Free                        =>
 232             return Pragma_Lock_Free;
 233          when Name_Priority                         =>
 234             return Pragma_Priority;
 235          when Name_Storage_Size                     =>
 236             return Pragma_Storage_Size;
 237          when Name_Storage_Unit                     =>
 238             return Pragma_Storage_Unit;
 239          when First_Pragma_Name .. Last_Pragma_Name =>
 240             return Pragma_Id'Val (N - First_Pragma_Name);
 241          when others                                =>
 242             return Unknown_Pragma;
 243       end case;
 244    end Get_Pragma_Id;
 245
 246    ---------------------------
 247    -- Get_Queuing_Policy_Id --
 248    ---------------------------
 249
 250    function Get_Queuing_Policy_Id (N : Name_Id) return Queuing_Policy_Id is
 251    begin
 252       return Queuing_Policy_Id'Val (N - First_Queuing_Policy_Name);
 253    end Get_Queuing_Policy_Id;
 254
 255    ------------------------------------
 256    -- Get_Task_Dispatching_Policy_Id --
 257    ------------------------------------
 258
 259    function Get_Task_Dispatching_Policy_Id
 260      (N : Name_Id) return Task_Dispatching_Policy_Id
 261    is
 262    begin
 263       return Task_Dispatching_Policy_Id'Val
 264         (N - First_Task_Dispatching_Policy_Name);
 265    end Get_Task_Dispatching_Policy_Id;
 266
 267    ----------------
 268    -- Initialize --
 269    ----------------
 270
 271    procedure Initialize is
 272       P_Index      : Natural;
 273       Discard_Name : Name_Id;
 274
 275    begin
 276       P_Index := Preset_Names'First;
 277       loop
 278          Name_Len := 0;
 279          while Preset_Names (P_Index) /= '#' loop
 280             Name_Len := Name_Len + 1;
 281             Name_Buffer (Name_Len) := Preset_Names (P_Index);
 282             P_Index := P_Index + 1;
 283          end loop;
 284
 285          --  We do the Name_Find call to enter the name into the table, but
 286          --  we don't need to do anything with the result, since we already
 287          --  initialized all the preset names to have the right value (we
 288          --  are depending on the order of the names and Preset_Names).
 289
 290          Discard_Name := Name_Find;
 291          P_Index := P_Index + 1;
 292          exit when Preset_Names (P_Index) = '#';
 293       end loop;
 294
 295       --  Make sure that number of names in standard table is correct. If this
 296       --  check fails, run utility program XSNAMES to construct a new properly
 297       --  matching version of the body.
 298
 299       pragma Assert (Discard_Name = Last_Predefined_Name);
 300
 301       --  Initialize the convention identifiers table with the standard set of
 302       --  synonyms that we recognize for conventions.
 303
 304       Convention_Identifiers.Init;
 305
 306       Convention_Identifiers.Append ((Name_Asm,         Convention_Assembler));
 307       Convention_Identifiers.Append ((Name_Assembly,    Convention_Assembler));
 308
 309       Convention_Identifiers.Append ((Name_Default,     Convention_C));
 310       Convention_Identifiers.Append ((Name_External,    Convention_C));
 311
 312       Convention_Identifiers.Append ((Name_C_Plus_Plus, Convention_CPP));
 313
 314       Convention_Identifiers.Append ((Name_DLL,         Convention_Stdcall));
 315       Convention_Identifiers.Append ((Name_Win32,       Convention_Stdcall));
 316    end Initialize;
 317
 318    -----------------------
 319    -- Is_Attribute_Name --
 320    -----------------------
 321
 322    function Is_Attribute_Name (N : Name_Id) return Boolean is
 323    begin
 324       --  Don't consider Name_Elab_Subp_Body to be a valid attribute name
 325       --  unless we are working in CodePeer mode.
 326
 327       return N in First_Attribute_Name .. Last_Attribute_Name
 328         and then (CodePeer_Mode or else N /= Name_Elab_Subp_Body);
 329    end Is_Attribute_Name;
 330
 331    ----------------------------------
 332    -- Is_Configuration_Pragma_Name --
 333    ----------------------------------
 334
 335    function Is_Configuration_Pragma_Name (N : Name_Id) return Boolean is
 336    begin
 337       return N in First_Pragma_Name .. Last_Configuration_Pragma_Name
 338         or else N = Name_Default_Scalar_Storage_Order
 339         or else N = Name_Fast_Math;
 340    end Is_Configuration_Pragma_Name;
 341
 342    ------------------------
 343    -- Is_Convention_Name --
 344    ------------------------
 345
 346    function Is_Convention_Name (N : Name_Id) return Boolean is
 347    begin
 348       --  Check if this is one of the standard conventions
 349
 350       if N in First_Convention_Name .. Last_Convention_Name
 351         or else N = Name_C
 352       then
 353          return True;
 354
 355       --  Otherwise check if it is in convention identifier table
 356
 357       else
 358          for J in 1 .. Convention_Identifiers.Last loop
 359             if N = Convention_Identifiers.Table (J).Name then
 360                return True;
 361             end if;
 362          end loop;
 363
 364          return False;
 365       end if;
 366    end Is_Convention_Name;
 367
 368    ------------------------------
 369    -- Is_Entity_Attribute_Name --
 370    ------------------------------
 371
 372    function Is_Entity_Attribute_Name (N : Name_Id) return Boolean is
 373    begin
 374       return N in First_Entity_Attribute_Name .. Last_Entity_Attribute_Name;
 375    end Is_Entity_Attribute_Name;
 376
 377    --------------------------------
 378    -- Is_Function_Attribute_Name --
 379    --------------------------------
 380
 381    function Is_Function_Attribute_Name (N : Name_Id) return Boolean is
 382    begin
 383       return N in
 384         First_Renamable_Function_Attribute ..
 385           Last_Renamable_Function_Attribute;
 386    end Is_Function_Attribute_Name;
 387
 388    ---------------------
 389    -- Is_Keyword_Name --
 390    ---------------------
 391
 392    function Is_Keyword_Name (N : Name_Id) return Boolean is
 393    begin
 394       return Get_Name_Table_Byte (N) /= 0
 395         and then (Ada_Version >= Ada_95
 396                    or else N not in Ada_95_Reserved_Words)
 397         and then (Ada_Version >= Ada_2005
 398                    or else N not in Ada_2005_Reserved_Words)
 399         and then (Ada_Version >= Ada_2012
 400                    or else N not in Ada_2012_Reserved_Words);
 401    end Is_Keyword_Name;
 402
 403    --------------------------------
 404    -- Is_Internal_Attribute_Name --
 405    --------------------------------
 406
 407    function Is_Internal_Attribute_Name (N : Name_Id) return Boolean is
 408    begin
 409       return
 410         N in First_Internal_Attribute_Name .. Last_Internal_Attribute_Name;
 411    end Is_Internal_Attribute_Name;
 412
 413    ----------------------------
 414    -- Is_Locking_Policy_Name --
 415    ----------------------------
 416
 417    function Is_Locking_Policy_Name (N : Name_Id) return Boolean is
 418    begin
 419       return N in First_Locking_Policy_Name .. Last_Locking_Policy_Name;
 420    end Is_Locking_Policy_Name;
 421
 422    -------------------------------------
 423    -- Is_Partition_Elaboration_Policy --
 424    -------------------------------------
 425
 426    function Is_Partition_Elaboration_Policy_Name
 427      (N : Name_Id) return Boolean
 428    is
 429    begin
 430       return N in First_Partition_Elaboration_Policy_Name ..
 431                   Last_Partition_Elaboration_Policy_Name;
 432    end Is_Partition_Elaboration_Policy_Name;
 433
 434    -----------------------------
 435    -- Is_Operator_Symbol_Name --
 436    -----------------------------
 437
 438    function Is_Operator_Symbol_Name (N : Name_Id) return Boolean is
 439    begin
 440       return N in First_Operator_Name .. Last_Operator_Name;
 441    end Is_Operator_Symbol_Name;
 442
 443    --------------------
 444    -- Is_Pragma_Name --
 445    --------------------
 446
 447    function Is_Pragma_Name (N : Name_Id) return Boolean is
 448    begin
 449       return N in First_Pragma_Name .. Last_Pragma_Name
 450         or else N = Name_CPU
 451         or else N = Name_Default_Scalar_Storage_Order
 452         or else N = Name_Dispatching_Domain
 453         or else N = Name_Fast_Math
 454         or else N = Name_Interface
 455         or else N = Name_Interrupt_Priority
 456         or else N = Name_Lock_Free
 457         or else N = Name_Relative_Deadline
 458         or else N = Name_Priority
 459         or else N = Name_Storage_Size
 460         or else N = Name_Storage_Unit;
 461    end Is_Pragma_Name;
 462
 463    ---------------------------------
 464    -- Is_Procedure_Attribute_Name --
 465    ---------------------------------
 466
 467    function Is_Procedure_Attribute_Name (N : Name_Id) return Boolean is
 468    begin
 469       return N in First_Procedure_Attribute .. Last_Procedure_Attribute;
 470    end Is_Procedure_Attribute_Name;
 471
 472    ----------------------------
 473    -- Is_Queuing_Policy_Name --
 474    ----------------------------
 475
 476    function Is_Queuing_Policy_Name (N : Name_Id) return Boolean is
 477    begin
 478       return N in First_Queuing_Policy_Name .. Last_Queuing_Policy_Name;
 479    end Is_Queuing_Policy_Name;
 480
 481    -------------------------------------
 482    -- Is_Task_Dispatching_Policy_Name --
 483    -------------------------------------
 484
 485    function Is_Task_Dispatching_Policy_Name (N : Name_Id) return Boolean is
 486    begin
 487       return N in First_Task_Dispatching_Policy_Name ..
 488                   Last_Task_Dispatching_Policy_Name;
 489    end Is_Task_Dispatching_Policy_Name;
 490
 491    ----------------------------
 492    -- Is_Type_Attribute_Name --
 493    ----------------------------
 494
 495    function Is_Type_Attribute_Name (N : Name_Id) return Boolean is
 496    begin
 497       return N in First_Type_Attribute_Name .. Last_Type_Attribute_Name;
 498    end Is_Type_Attribute_Name;
 499
 500    ----------------------------------
 501    -- Record_Convention_Identifier --
 502    ----------------------------------
 503
 504    procedure Record_Convention_Identifier
 505      (Id         : Name_Id;
 506       Convention : Convention_Id)
 507    is
 508    begin
 509       Convention_Identifiers.Append ((Id, Convention));
 510    end Record_Convention_Identifier;
 511
 512 end Snames;