libstdc++-v3/config/linker-map.gnu

   1 ## Linker script for GNU ld 2.11.94+ only.
   2 ##
   3 ## Copyright (C) 2002 Free Software Foundation, Inc.
   4 ##
   5 ## This file is part of the libstdc++ version 3 distribution.
   6 ##
   7 ## This file is part of the GNU ISO C++ Library.  This library is free
   8 ## software; you can redistribute it and/or modify it under the
   9 ## terms of the GNU General Public License as published by the
  10 ## Free Software Foundation; either version 2, or (at your option)
  11 ## any later version.
  12 ##
  13 ## This library is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License along
  19 ## with this library; see the file COPYING.  If not, write to the Free
  20 ## Software Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  21 ## USA.
  22
  23
  24 GLIBCPP_3.2 {
  25
  26   global:
  27
  28     # Names inside the 'extern' block are demangled names.
  29     # All but the last are terminated with a semicolon.
  30     extern "C++"
  31     {
  32       std::[A-Za-z]*;
  33       std::__throw_*;
  34       std::__basic_file*;
  35       std::__num_base*;
  36       std::__timepunct*;
  37       std::__numeric_limits_base*;
  38       std::_S_bit_count;
  39       std::_S_first_one;
  40       std::__default_alloc_template*;
  41       std::__malloc_alloc_template*
  42     };
  43
  44     # Names not in an 'extern' block are mangled names.
  45
  46     # std::has_facet*
  47     _ZSt9has_facet*;
  48
  49     # operator new(unsigned)
  50     _Znwj;
  51     # operator new(unsigned, std::nothrow_t const&)
  52     _ZnwjRKSt9nothrow_t;
  53     # operator new(unsigned long)
  54     _Znwm;
  55     # operator new(unsigned long, std::nothrow_t const&)
  56     _ZnwmRKSt9nothrow_t;
  57
  58     # operator delete(void*)
  59     _ZdlPv;
  60     # operator delete(void*, std::nothrow_t const&)
  61     _ZdlPvRKSt9nothrow_t;
  62
  63     # operator new[](unsigned)
  64     _Znaj;
  65     # operator new[](unsigned, std::nothrow_t const&)
  66     _ZnajRKSt9nothrow_t;
  67     # operator new[](unsigned long)
  68     _Znam;
  69     # operator new[](unsigned long, std::nothrow_t const&)
  70     _ZnamRKSt9nothrow_t;
  71
  72     # operator delete[](void*)
  73     _ZdaPv;
  74     # operator delete[](void*, std::nothrow_t const&)
  75     _ZdaPvRKSt9nothrow_t;
  76
  77     # vtable
  78     _ZTV*;
  79     _ZTT*;
  80
  81     # typeinfo
  82     _ZTI*;
  83     _ZTS*;
  84
  85     # function-scope static objects requires a guard variable.
  86     _ZGV*;
  87
  88     # virtual function thunks
  89     _ZTh*;
  90     _ZTv*;
  91     _ZTc*;
  92
  93     # std::__convert_to_v
  94     _ZSt14__convert_to_v*;
  95
  96   local:
  97     *;
  98 };
  99
 100
 101 # Symbols in the support library (libsupc++) have their own tag.
 102 CXXABI_1.2 {
 103
 104   global:
 105     __cxa_*;
 106     __gxx_personality_v0;
 107     __gxx_personality_sj0;
 108     __dynamic_cast;
 109
 110     # __gnu_cxx::_verbose_terminate_handler()
 111     _ZN9__gnu_cxx27__verbose_terminate_handlerEv;
 112
 113   local:
 114     *;
 115 };