gcc/ada/nlists.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               N L I S T S                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.1 $                             --
  10 --                                                                          --
  11 --          Copyright (C) 1992-2000 Free Software Foundation, Inc.          --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This package provides facilities for manipulating lists of nodes (see
  37 --  package Atree for format and implementation of tree nodes). The Link field
  38 --  of the nodes is used as the forward pointer for these lists. See also
  39 --  package Elists which provides another form of lists that are not threaded
  40 --  through the nodes (and therefore allow nodes to be on multiple lists).
  41
  42 with System;
  43 with Types; use Types;
  44
  45 package Nlists is
  46
  47    --  A node list is a list of nodes in a special format that means that
  48    --  nodes can be on at most one such list. For each node list, a list
  49    --  header is allocated in the lists table, and a List_Id value references
  50    --  this header, which may be used to access the nodes in the list using
  51    --  the set of routines that define this interface.
  52
  53    --  Note: node lists can contain either nodes or entities (extended nodes)
  54    --  or a mixture of nodes and extended nodes.
  55
  56    function Last_List_Id return List_Id;
  57    pragma Inline (Last_List_Id);
  58    --  Returns Id of last allocated list header
  59
  60    function Lists_Address return System.Address;
  61    pragma Inline (Lists_Address);
  62    --  Return address of Lists table (used in Back_End for Gigi call)
  63
  64    function Num_Lists return Nat;
  65    pragma Inline (Num_Lists);
  66    --  Number of currently allocated lists
  67
  68    function New_List return List_Id;
  69    --  Creates a new empty node list. Typically this is used to initialize
  70    --  a field in some other node which points to a node list where the list
  71    --  is then subsequently filled in using Append calls.
  72
  73    function Empty_List return List_Id renames New_List;
  74    --  Used in contexts where an empty list (as opposed to an initially empty
  75    --  list to be filled in) is required.
  76
  77    function New_List (Node : Node_Id) return List_Id;
  78    --  Build a new list initially containing the given node
  79
  80    function New_List (Node1, Node2 : Node_Id) return List_Id;
  81    --  Build a new list initially containing the two given nodes
  82
  83    function New_List (Node1, Node2, Node3 : Node_Id) return List_Id;
  84    --  Build a new list initially containing the three given nodes
  85
  86    function New_List (Node1, Node2, Node3, Node4 : Node_Id) return List_Id;
  87    --  Build a new list initially containing the four given nodes
  88
  89    function New_List
  90      (Node1 : Node_Id;
  91       Node2 : Node_Id;
  92       Node3 : Node_Id;
  93       Node4 : Node_Id;
  94       Node5 : Node_Id)
  95       return  List_Id;
  96    --  Build a new list initially containing the five given nodes
  97
  98    function New_List
  99      (Node1 : Node_Id;
 100       Node2 : Node_Id;
 101       Node3 : Node_Id;
 102       Node4 : Node_Id;
 103       Node5 : Node_Id;
 104       Node6 : Node_Id)
 105       return  List_Id;
 106    --  Build a new list initially containing the five given nodes
 107
 108    function New_Copy_List (List : List_Id) return List_Id;
 109    --  Creates a new list containing copies (made with Atree.New_Copy) of every
 110    --  node in the original list. If the argument is No_List, then the returned
 111    --  result is No_List. If the argument is an empty list, then the returned
 112    --  result is a new empty list.
 113
 114    function New_Copy_List_Original (List : List_Id) return List_Id;
 115    --  Same as New_Copy_List but copies only nodes coming from source
 116
 117    function New_Copy_List_Tree (List : List_Id) return List_Id;
 118    --  Similar to New_Copy_List, except that the copies are done using the
 119    --  Atree.New_Copy_Tree function, which means that a full recursive copy
 120    --  of the subtrees in the list is performed, setting proper parents. As
 121    --  for New_Copy_Tree, it is illegal to attempt to copy extended nodes
 122    --  (entities) either directly or indirectly using this function.
 123
 124    function First (List : List_Id) return Node_Id;
 125    pragma Inline (First);
 126    --  Obtains the first element of the given node list or, if the node list
 127    --  has no items or is equal to No_List, then Empty is returned.
 128
 129    function First_Non_Pragma (List : List_Id) return Node_Id;
 130    --  Used when dealing with a list that can contain pragmas to skip past
 131    --  any initial pragmas and return the first element that is not a pragma.
 132    --  If the list is empty, or if it contains only pragmas, then Empty is
 133    --  returned. It is an error to call First_Non_Pragma with a Node_Id value
 134    --  or No_List (No_List is not considered to be the same as an empty list).
 135    --  This function also skips N_Null nodes which can result from rewriting
 136    --  unrecognized or incorrrect pragmas.
 137
 138    function Last (List : List_Id) return Node_Id;
 139    pragma Inline (Last);
 140    --  Obtains the last element of the given node list or, if the node list
 141    --  has no items, then Empty is returned. It is an error to call Last with
 142    --  a Node_Id or No_List. (No_List is not considered to be the same as an
 143    --  empty node list).
 144
 145    function Last_Non_Pragma (List : List_Id) return Node_Id;
 146    --  Obtains the last element of a given node list that is not a pragma.
 147    --  If the list is empty, or if it contains only pragmas, then Empty is
 148    --  returned. It is an error to call Last_Non_Pragma with a Node_Id or
 149    --  No_List. (No_List is not considered to be the same as an empty list).
 150
 151    function List_Length (List : List_Id) return Nat;
 152    pragma Inline (List_Length);
 153    --  Returns number of items in the given list. It is an error to call
 154    --  this function with No_List (No_List is not considered to be the same
 155    --  as an empty list).
 156
 157    function Next (Node : Node_Id) return Node_Id;
 158    pragma Inline (Next);
 159    --  This function returns the next node on a node list, or Empty if Node is
 160    --  the last element of the node list. The argument must be a member of a
 161    --  node list.
 162
 163    procedure Next (Node : in out Node_Id);
 164    pragma Inline (Next);
 165    --  Equivalent to Node := Next (Node);
 166
 167    function Next_Non_Pragma (Node : Node_Id) return Node_Id;
 168    --  This function returns the next node on a node list, skipping past any
 169    --  pragmas, or Empty if there is no non-pragma entry left. The argument
 170    --  must be a member of a node list. This function also skips N_Null nodes
 171    --  which can result from rewriting unrecognized or incorrect pragmas.
 172
 173    procedure Next_Non_Pragma (Node : in out Node_Id);
 174    pragma Inline (Next_Non_Pragma);
 175    --  Equivalent to Node := Next_Non_Pragma (Node);
 176
 177    function Prev (Node : Node_Id) return Node_Id;
 178    pragma Inline (Prev);
 179    --  This function returns the previous node on a node list list, or Empty if
 180    --  Node is the first element of the node list. The argument must be a
 181    --  member of a node list. Note that the implementation does not maintain
 182    --  back pointers, so this function potentially requires traversal of the
 183    --  entire list, or more accurately of the part of the list preceding Node.
 184
 185    function Pick (List : List_Id; Index : Pos) return Node_Id;
 186    --  Given a list, picks out the Index'th entry (1 = first entry). The
 187    --  caller must ensure that Index is in range.
 188
 189    procedure Prev (Node : in out Node_Id);
 190    pragma Inline (Prev);
 191    --  Equivalent to Node := Prev (Node);
 192
 193    function Prev_Non_Pragma (Node : Node_Id) return Node_Id;
 194    pragma Inline (Prev_Non_Pragma);
 195    --  This function returns the previous node on a node list, skipping any
 196    --  pragmas. If Node is the first element of the list, or if the only
 197    --  elements preceding it are pragmas, then Empty is returned. The
 198    --  argument must be a member of a node list. Like Prev, this function
 199    --  may require expensive traversal of the head section of the list.
 200
 201    procedure Prev_Non_Pragma (Node : in out Node_Id);
 202    pragma Inline (Prev_Non_Pragma);
 203    --  Equivalent to Node := Prev_Non_Pragma (Node);
 204
 205    function Is_Empty_List (List : List_Id) return Boolean;
 206    pragma Inline (Is_Empty_List);
 207    --  This function determines if a given list id references a node list that
 208    --  contains no items. No_List is a not a legitimate argument.
 209
 210    function Is_Non_Empty_List (List : List_Id) return Boolean;
 211    pragma Inline (Is_Non_Empty_List);
 212    --  This function determines if a given list id references a node list that
 213    --  contains at least one item. No_List as an argument returns False.
 214
 215    function Is_List_Member (Node : Node_Id) return Boolean;
 216    pragma Inline (Is_List_Member);
 217    --  This function determines if a given node is a member of a node list.
 218    --  It is an error for Node to be Empty, or to be a node list.
 219
 220    function List_Containing (Node : Node_Id) return List_Id;
 221    pragma Inline (List_Containing);
 222    --  This function provides a pointer to the node list containing Node.
 223    --  Node must be a member of a node list.
 224
 225    procedure Append (Node : Node_Id; To : List_Id);
 226    --  Appends Node at the end of node list To. Node must be a non-empty node
 227    --  that is not already a member of a node list, and To must be a
 228    --  node list. An attempt to append an error node is ignored without
 229    --  complaint and the list is unchanged.
 230
 231    procedure Append_To (To : List_Id; Node : Node_Id);
 232    pragma Inline (Append_To);
 233    --  Like Append, but arguments are the other way round
 234
 235    procedure Append_List (List : List_Id; To : List_Id);
 236    --  Appends node list List to the end of node list To. On return,
 237    --  List is reset to be empty.
 238
 239    procedure Append_List_To (To : List_Id; List : List_Id);
 240    pragma Inline (Append_List_To);
 241    --  Like Append_List, but arguments are the other way round
 242
 243    procedure Insert_After (After : Node_Id; Node : Node_Id);
 244    --  Insert Node, which must be a non-empty node that is not already a
 245    --  member of a node list, immediately past node After, which must be a
 246    --  node that is currently a member of a node list. An attempt to insert
 247    --  an error node is ignored without complaint (and the list is unchanged).
 248
 249    procedure Insert_List_After (After : Node_Id; List : List_Id);
 250    --  Inserts the entire contents of node list List immediately after node
 251    --  After, which must be a member of a node list. On return, the node list
 252    --  List is reset to be the empty node list.
 253
 254    procedure Insert_Before (Before : Node_Id; Node : Node_Id);
 255    --  Insert Node, which must be a non-empty node that is not already a
 256    --  member of a node list, immediately before Before, which must be a node
 257    --  that is currently a member of a node list. An attempt to insert an
 258    --  error node is ignored without complaint (and the list is unchanged).
 259
 260    procedure Insert_List_Before (Before : Node_Id; List : List_Id);
 261    --  Inserts the entire contents of node list List immediately before node
 262    --  Before, which must be a member of a node list. On return, the node list
 263    --  List is reset to be the empty node list.
 264
 265    procedure Prepend (Node : Node_Id; To : List_Id);
 266    pragma Inline (Prepend);
 267    --  Prepends Node at the start of node list To. Node must be a non-empty
 268    --  node that is not already a member of a node list, and To must be a
 269    --  node list. An attempt to prepend an error node is ignored without
 270    --  complaint and the list is unchanged.
 271
 272    procedure Prepend_To (To : List_Id; Node : Node_Id);
 273    pragma Inline (Prepend_To);
 274    --  Like Prepend, but arguments are the other way round
 275
 276    procedure Remove (Node : Node_Id);
 277    --  Removes Node, which must be a node that is a member of a node list,
 278    --  from this node list. The contents of Node are not otherwise affected.
 279
 280    function Remove_Head (List : List_Id) return Node_Id;
 281    --  Removes the head element of a node list, and returns the node (whose
 282    --  contents are not otherwise affected) as the result. If the node list
 283    --  is empty, then Empty is returned.
 284
 285    function Remove_Next (Node : Node_Id) return Node_Id;
 286    pragma Inline (Remove_Next);
 287    --  Removes the item immediately following the given node, and returns it
 288    --  as the result. If Node is the last element of the list, then Empty is
 289    --  returned. Node must be a member of a list. Unlike Remove, Remove_Next
 290    --  is fast and does not involve any list traversal.
 291
 292    procedure Initialize;
 293    --  Called at the start of compilation of each new main source file to
 294    --  initialize the allocation of the list table. Note that Initialize
 295    --  must not be called if Tree_Read is used.
 296
 297    procedure Lock;
 298    --  Called to lock tables before back end is called
 299
 300    procedure Tree_Read;
 301    --  Initializes internal tables from current tree file using Tree_Read.
 302    --  Note that Initialize should not be called if Tree_Read is used.
 303    --  Tree_Read includes all necessary initialization.
 304
 305    procedure Tree_Write;
 306    --  Writes out internal tables to current tree file using Tree_Write
 307
 308    function Parent (List : List_Id) return Node_Id;
 309    pragma Inline (Parent);
 310    --  Node lists may have a parent in the same way as a node. The function
 311    --  accesses the Parent value, which is either Empty when a list header
 312    --  is first created, or the value that has been set by Set_Parent.
 313
 314    procedure Set_Parent (List : List_Id; Node : Node_Id);
 315    pragma Inline (Set_Parent);
 316    --  Sets the parent field of the given list to reference the given node
 317
 318    function No (List : List_Id) return Boolean;
 319    pragma Inline (No);
 320    --  Tests given Id for equality with No_List. This allows notations like
 321    --  "if No (Statements)" as opposed to "if Statements = No_List".
 322
 323    function Present (List : List_Id) return Boolean;
 324    pragma Inline (Present);
 325    --  Tests given Id for inequality with No_List. This allows notations like
 326    --  "if Present (Statements)" as opposed to "if Statements /= No_List".
 327
 328    procedure Allocate_List_Tables (N : Node_Id);
 329    --  Called when nodes table is expanded to include node N. This call
 330    --  makes sure that list structures internal to Nlists are adjusted
 331    --  appropriately to reflect this increase in the size of the nodes table.
 332
 333    function Next_Node_Address return System.Address;
 334    function Prev_Node_Address return System.Address;
 335    --  These functions return the addresses of the Next_Node and Prev_Node
 336    --  tables (used in Back_End for Gigi).
 337
 338    procedure Delete_List (L : List_Id);
 339    --  Removes all elements of the given list, and calls Delete_Tree on each
 340
 341    function p (U : Union_Id) return Node_Id;
 342    --  This function is intended for use from the debugger, it determines
 343    --  whether U is a Node_Id or List_Id, and calls the appropriate Parent
 344    --  function and returns the parent Node in either case. This is shorter
 345    --  to type, and avoids the overloading problem of using Parent. It
 346    --  should NEVER be used except from the debugger. If p is called with
 347    --  other than a node or list id value, it returns 99_999_999.
 348
 349 end Nlists;