libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1994-2017 Free Software Foundation, Inc.
   3 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GCC.
   6 #
   7 #GCC is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 3, or (at your option)
  10 #any later version.
  11 #
  12 #GCC is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GCC; see the file COPYING3.  If not see
  19 #<http://www.gnu.org/licenses/>.
  20
  21 AC_PREREQ(2.64)
  22 AC_INIT(package-unused, version-unused,, libobjc)
  23 AC_CONFIG_SRCDIR([objc/objc.h])
  24 GCC_TOPLEV_SUBDIRS
  25
  26 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  27 PACKAGE=libobjc
  28 # Version is pulled out to make it a bit easier to change using sed.
  29 VERSION=4:0:0
  30 AC_SUBST(VERSION)
  31
  32 # This works around the fact that libtool configuration may change LD
  33 # for this particular configuration, but some shells, instead of
  34 # keeping the changes in LD private, export them just because LD is
  35 # exported.
  36 ORIGINAL_LD_FOR_MULTILIBS=$LD
  37
  38 # -------
  39 # Options
  40 # -------
  41
  42 # We use these options to decide which functions to include.
  43 AC_ARG_WITH(target-subdir,
  44 [  --with-target-subdir=SUBDIR
  45                            configuring in a subdirectory])
  46 AC_ARG_WITH(cross-host,
  47 [  --with-cross-host=HOST  configuring with a cross compiler])
  48
  49 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  50 AC_ARG_ENABLE(version-specific-runtime-libs,
  51 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  52 [case "$enableval" in
  53  yes) version_specific_libs=yes ;;
  54  no)  version_specific_libs=no ;;
  55  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  56  esac],
  57 [version_specific_libs=no])
  58 AC_MSG_RESULT($version_specific_libs)
  59
  60 # -----------
  61 # Directories
  62 # -----------
  63
  64 # Find the rest of the source tree framework.
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 AC_CANONICAL_SYSTEM
  68 ACX_NONCANONICAL_TARGET
  69
  70 # Export source directory.
  71 # These need to be absolute paths, yet at the same time need to
  72 # canonicalize only relative paths, because then amd will not unmount
  73 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  74 case $srcdir in
  75   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  76   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  77 esac
  78 AC_SUBST(glibcpp_srcdir)
  79
  80 # Calculate toolexeclibdir
  81 # Also toolexecdir, though it's only used in toolexeclibdir
  82 case ${version_specific_libs} in
  83   yes)
  84     # Need the gcc compiler version to know where to install libraries
  85     # and header files if --enable-version-specific-runtime-libs option
  86     # is selected.
  87     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
  88     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  89     ;;
  90   no)
  91     if test -n "$with_cross_host" &&
  92        test x"$with_cross_host" != x"no"; then
  93       # Install a library built with a cross compiler in tooldir, not libdir.
  94       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
  95       toolexeclibdir='$(toolexecdir)/lib'
  96     else
  97       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
  98       toolexeclibdir='$(libdir)'
  99     fi
 100     multi_os_directory=`$CC -print-multi-os-directory`
 101     case $multi_os_directory in
 102       .) ;; # Avoid trailing /.
 103       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 104     esac
 105     ;;
 106 esac
 107 AC_SUBST(toolexecdir)
 108 AC_SUBST(toolexeclibdir)
 109
 110 # Figure out if we want to name the include directory and the
 111 #  library name changes differently.
 112 includedirname=include
 113 libsuffix=
 114 case "${host}" in
 115   *-darwin*)
 116     # Darwin is the only target so far that needs a different include directory.
 117     includedirname=include-gnu-runtime
 118     libsuffix=-gnu
 119     ;;
 120 esac
 121 AC_SUBST(includedirname)
 122 AC_SUBST(libsuffix)
 123
 124 AC_CONFIG_HEADERS(config.h)
 125
 126 # --------
 127 # Programs
 128 # --------
 129
 130 GCC_NO_EXECUTABLES
 131
 132 # We must force CC to /not/ be a precious variable; otherwise
 133 # the wrong, non-multilib-adjusted value will be used in multilibs.
 134 # As a side effect, we have to subst CFLAGS ourselves.
 135 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 136 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 137 AC_PROG_CC
 138 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 139
 140 # extra LD Flags which are required for targets
 141 ACX_LT_HOST_FLAGS
 142 case "${host}" in
 143   *-darwin*)
 144     # Darwin needs -single_module when linking libobjc
 145     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 146     ;;
 147   *-cygwin*|*-mingw*)
 148     # Tell libtool to build DLLs on Windows
 149     extra_ldflags_libobjc='$(lt_host_flags)'
 150     ;;
 151 esac
 152 AC_SUBST(extra_ldflags_libobjc)
 153
 154 AC_SUBST(CFLAGS)
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(AR, ar)
 158 AC_CHECK_TOOL(RANLIB, ranlib, :)
 159 AC_PROG_INSTALL
 160
 161 AM_MAINTAINER_MODE
 162
 163 # Enable Win32 DLL on MS Windows - FIXME
 164 AC_LIBTOOL_WIN32_DLL
 165
 166 AC_PROG_LIBTOOL
 167
 168 AM_PROG_CC_C_O
 169
 170 AC_PROG_MAKE_SET
 171
 172 # -------
 173 # Headers
 174 # -------
 175
 176 # Sanity check for the cross-compilation case:
 177 AC_CHECK_HEADER(stdio.h,:,
 178   [AC_MSG_ERROR([Can't find stdio.h.
 179 You must have a usable C system for the target already installed, at least
 180 including headers and, preferably, the library, before you can configure
 181 the Objective C runtime system.  If necessary, install gcc now with
 182 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 183
 184 AC_HEADER_STDC
 185
 186 AC_CHECK_HEADERS(sched.h)
 187
 188 # -----------
 189 # Miscellanea
 190 # -----------
 191
 192 # Check if we have thread-local storage
 193 GCC_CHECK_TLS
 194
 195 gt_BITFIELD_TYPE_MATTERS
 196
 197 # -----------
 198 # boehm-gc
 199 # -----------
 200
 201 AC_ARG_ENABLE(objc-gc,
 202 [AS_HELP_STRING([--enable-objc-gc],
 203                 [enable use of Boehm's garbage collector with the
 204                  GNU Objective-C runtime])],,enable_objc_gc=no)
 205 AC_ARG_WITH([target-bdw-gc],
 206 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
 207                 [specify prefix directory for installed bdw-gc package.
 208                  Equivalent to --with-target-bdw-gc-include=PATH/include
 209                  plus --with-target-bdw-gc-lib=PATH/lib])])
 210 AC_ARG_WITH([target-bdw-gc-include],
 211 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
 212                 [specify directories for installed bdw-gc include files])])
 213 AC_ARG_WITH([target-bdw-gc-lib],
 214 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
 215                 [specify directories for installed bdw-gc library])])
 216
 217 case "$enable_objc_gc" in
 218 no)
 219   use_bdw_gc=no
 220   ;;
 221 *)
 222   AC_MSG_CHECKING([for bdw garbage collector])
 223   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
 224     dnl no bdw-gw options, assuming bdw-gc in default locations
 225     BDW_GC_CFLAGS=
 226     BDW_GC_LIBS="-lgc"
 227   else
 228     dnl bdw-gw options passed by configure flags
 229     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
 230       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
 231     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
 232       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
 233     else
 234       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
 235     fi
 236     mldir=`${CC-gcc} --print-multi-directory 2>/dev/null`
 237     bdw_val=
 238     if test "x$with_target_bdw_gc" != x; then
 239       for i in `echo $with_target_bdw_gc | tr ',' ' '`; do
 240         case "$i" in
 241           *=*) sd=${i%%=*}; d=${i#*=} ;;
 242           *) sd=.; d=$i ;;
 243         esac
 244         if test "$mldir" = "$sd"; then
 245           bdw_val=$d
 246         fi
 247       done
 248       if test "x$bdw_val" = x; then
 249         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc])
 250       fi
 251       bdw_inc_dir="$bdw_val/include"
 252       bdw_lib_dir="$bdw_val/lib"
 253     fi
 254     bdw_val=
 255     if test "x$with_target_bdw_gc_include" != x; then
 256       for i in `echo $with_target_bdw_gc_include | tr ',' ' '`; do
 257         case "$i" in
 258           *=*) sd=${i%%=*}; d=${i#*=} ;;
 259           *) sd=.; d=$i; fallback=$i ;;
 260         esac
 261         if test "$mldir" = "$sd"; then
 262           bdw_val=$d
 263         fi
 264       done
 265       if test "x$bdw_val" = x && test "x$bdw_inc_dir" = x && test "x$fallback" != x; then
 266         bdw_inc_dir="$fallback"
 267       elif test "x$bdw_val" = x; then
 268         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 269       else
 270         bdw_inc_dir="$bdw_val"
 271       fi
 272     fi
 273     bdw_val=
 274     if test "x$with_target_bdw_gc_lib" != x; then
 275       for i in `echo $with_target_bdw_gc_lib | tr ',' ' '`; do
 276         case "$i" in
 277           *=*) sd=${i%%=*}; d=${i#*=} ;;
 278           *) sd=.; d=$i ;;
 279         esac
 280         if test "$mldir" = "$sd"; then
 281           bdw_val=$d
 282         fi
 283       done
 284       if test "x$bdw_val" = x; then
 285         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 286       fi
 287       bdw_lib_dir="$bdw_val"
 288     fi
 289     if test "x$bdw_inc_dir" = x; then
 290       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 291     fi
 292     if test "x$bdw_lib_dir" = x; then
 293       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 294     fi
 295     BDW_GC_CFLAGS="-I$bdw_inc_dir"
 296     if test -f $bdw_lib_dir/libgc.la; then
 297       BDW_GC_LIBS="$bdw_lib_dir/libgc.la"
 298     else
 299       BDW_GC_LIBS="-L$bdw_lib_dir -lgc"
 300     fi
 301     AC_MSG_RESULT([found])
 302   fi
 303
 304   case "$BDW_GC_LIBS" in
 305   *libgc.la)
 306     use_bdw_gc=yes
 307     ;;
 308   *)
 309     AC_MSG_CHECKING([for system boehm-gc])
 310     save_CFLAGS=$CFLAGS
 311     save_LIBS=$LIBS
 312     CFLAGS="$CFLAGS $BDW_GC_CFLAGS"
 313     LIBS="$LIBS $BDW_GC_LIBS"
 314     dnl the link test is not good enough for ARM32 multilib detection,
 315     dnl first check to link, then to run
 316     AC_LINK_IFELSE(
 317       [AC_LANG_PROGRAM([#include <gc/gc.h>],[GC_init()])],
 318       [
 319         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 320           #include <gc/gc.h>
 321           int main() {
 322             GC_init();
 323             return 0;
 324           }
 325           ]])],
 326           [system_bdw_gc_found=yes],
 327           [system_bdw_gc_found=no],
 328           dnl assume no system boehm-gc for cross builds ...
 329           [system_bdw_gc_found=no]
 330         )
 331       ],
 332       [system_bdw_gc_found=no])
 333     CFLAGS=$save_CFLAGS
 334     LIBS=$save_LIBS
 335     if test x$enable_objc_gc = xauto && test x$system_bdw_gc_found = xno; then
 336       AC_MSG_WARN([system bdw-gc not found, not building libobjc_gc])
 337       use_bdw_gc=no
 338     elif test x$enable_objc_gc = xyes && test x$system_bdw_gc_found = xno; then
 339       AC_MSG_ERROR([system bdw-gc required but not found])
 340     else
 341       use_bdw_gc=yes
 342       AC_MSG_RESULT([found])
 343     fi
 344   esac
 345 esac
 346
 347 if test "$use_bdw_gc" = no; then
 348   OBJC_GCFLAGS=''
 349   OBJC_BOEHM_GC=''
 350   OBJC_BOEHM_GC_INCLUDES=''
 351   OBJC_BOEHM_GC_LIBS=''
 352 else
 353   OBJC_GCFLAGS='-DOBJC_WITH_GC=1'
 354   OBJC_BOEHM_GC='libobjc_gc$(libsuffix).la'
 355   OBJC_BOEHM_GC_INCLUDES=$BDW_GC_CFLAGS
 356   OBJC_BOEHM_GC_LIBS=$BDW_GC_LIBS
 357 fi
 358 AC_SUBST(OBJC_GCFLAGS)
 359 AC_SUBST(OBJC_BOEHM_GC)
 360 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
 361 AC_SUBST(OBJC_BOEHM_GC_LIBS)
 362
 363 # Determine what GCC version number to use in filesystem paths.
 364 GCC_BASE_VER
 365
 366 # ------
 367 # Output
 368 # ------
 369
 370 if test ${multilib} = yes; then
 371   multilib_arg="--enable-multilib"
 372 else
 373   multilib_arg=
 374 fi
 375
 376 AC_CONFIG_FILES([Makefile])
 377 AC_OUTPUT