libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209
 210 libgcj_cflags=
 211 libgcj_cxxflags=
 212 libgcj_javaflags=
 213
 214 . ${srcdir}/configure.host
 215
 216 ACX_PROG_LD_GNU_SYMBOLIC
 217 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 218 if test -z "$libgcj_ld_symbolic"; then
 219   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 220 fi
 221
 222 LIBGCJ_CFLAGS="${libgcj_cflags}"
 223 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 224 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 225 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 226 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 227 AC_SUBST(LIBGCJ_CFLAGS)
 228 AC_SUBST(LIBGCJ_CXXFLAGS)
 229 AC_SUBST(LIBGCJ_JAVAFLAGS)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 231 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 232
 233 # Only use libltdl for non-newlib builds.
 234 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 235    AC_LTDL_SHLIBPATH
 236 fi
 237
 238 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 239
 240 # See if the user has requested runtime debugging.
 241 LIBGCJDEBUG="disable"
 242 AC_SUBST(LIBGCJDEBUG)
 243 AC_ARG_ENABLE(libgcj-debug,
 244   AS_HELP_STRING([--enable-libgcj-debug],
 245                  [enable runtime debugging code]),
 246   [if test "$enable_libgcj_debug" = yes; then
 247     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 248     LIBGCJDEBUG="enable"
 249   fi])
 250
 251 AC_ARG_WITH([escher],
 252          AS_HELP_STRING([--with-escher=ABS.PATH],
 253                         [specify path to escher dir or JAR for X peers]))
 254 case "$with_escher" in
 255 "")
 256         use_escher=false
 257         ;;
 258 "no")
 259         use_escher=false
 260         ;;
 261 "yes")
 262         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 263         ;;
 264 *)
 265         use_escher=true
 266         ;;
 267 esac
 268
 269 # Determine which AWT peer libraries to build
 270 AC_ARG_ENABLE(java-awt,
 271   AS_HELP_STRING([--enable-java-awt],
 272                  [list of AWT peer implementations to be built]))
 273
 274 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 275 use_xlib_awt=""
 276 use_gtk_awt=""
 277 use_qt_awt=""
 278 use_x_awt=""
 279 # The default toolkit to use is the first one specified.
 280 TOOLKIT=
 281 AC_SUBST(TOOLKIT)
 282
 283 for peer in $peerlibs ; do
 284   case $peer in
 285     xlib)
 286       if test "$no_x" = yes; then
 287         echo "*** xlib peers requested but no X library available" 1>&2
 288         exit 1
 289       else
 290         use_xlib_awt="yes"
 291         if test -z "$TOOLKIT"; then
 292            TOOLKIT=gnu.awt.xlib.XToolkit
 293         fi
 294       fi
 295       ;;
 296     gtk)
 297       if test "$no_x" = yes; then
 298          echo "*** gtk peers requested but no X library available" 1>&2
 299          exit 1
 300       else
 301          use_gtk_awt=yes
 302          if test -z "$TOOLKIT"; then
 303             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 304          fi
 305       fi
 306       ;;
 307     qt)
 308       if test "$no_x" = yes; then
 309          # Perhaps we should admit the possibility of embedded Qt.
 310          echo "*** Qt peers requested but no X library available" 1>&2
 311          exit 1
 312       else
 313          use_qt_awt=yes
 314          if test -z "$TOOLKIT"; then
 315             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 316          fi
 317       fi
 318       ;;
 319     x)
 320       use_x_awt=yes
 321       if test -z "$TOOLKIT"; then
 322          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 323       fi
 324       ;;
 325     no)
 326       use_xlib_awt=
 327       use_gtk_awt=
 328       use_qt_awt=
 329       use_x_awt=
 330       break
 331       ;;
 332     *)
 333       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 334       exit 1
 335   esac
 336 done
 337
 338 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 339 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 340
 341 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 342
 343 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 344
 345 # Create standard.omit based on decisions we just made.
 346 cp $srcdir/standard.omit.in standard.omit
 347 if test "$use_xlib_awt" != yes; then
 348    echo gnu/awt/xlib >> standard.omit
 349    echo gnu/gcj/xlib >> standard.omit
 350 fi
 351 if test "$use_x_awt" != yes; then
 352    echo gnu/java/awt/peer/x >> standard.omit
 353 fi
 354
 355 # Tools that need to be compiled against classpath's tools classes
 356 : > vm-tools-packages
 357 for package in gnu/gcj/tools/gc_analyze ; do
 358     echo $package >> standard.omit
 359     echo $package >> vm-tools-packages
 360 done
 361
 362 if test -z "${with_multisubdir}"; then
 363    builddotdot=.
 364 else
 365    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 366 fi
 367
 368 NATIVE=yes
 369
 370 # Which gcj and host gcj (for ecjx) do we use?
 371 which_gcj=default
 372 host_exeext=${ac_exeext}
 373 GCJ_FOR_ECJX=
 374 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 375 if test -n "${with_cross_host}"; then
 376   # We are being configured with a cross compiler. We can't
 377   # use ac_exeext, because that is for the target platform.
 378   NATIVE=no
 379   cross_host_exeext=
 380   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 381   case "${with_cross_host}" in
 382      *mingw* | *cygwin*)
 383          cross_host_exeext=.exe
 384      ;;
 385   esac
 386   host_exeext=${cross_host_exeext}
 387   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 388      if test x"$build_noncanonical" = x"$with_cross_host"; then
 389         # Ordinary cross (host!=target and host=build)
 390         which_gcj=built
 391      else
 392         # Canadian cross (host!=target and host!=build)
 393         which_gcj=cross
 394      fi
 395   else
 396      which_gcj=cross
 397   fi
 398 else
 399   # We are being configured with a native or crossed-native compiler
 400   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 401      if test x"$build" = x"$host"; then
 402         # True native build (host=target and host=build)
 403         which_gcj=built
 404      else
 405         # Crossed-native build (host=target and host!=build)
 406         which_gcj=cross
 407      fi
 408   else
 409      which_gcj=path
 410   fi
 411 fi
 412 libgcjdir=`${PWDCMD-pwd}`
 413 case $GCJ in
 414 *" -B"*)
 415   # Just in case there is a comma in the build dir, quote it for the
 416   # sed command below.
 417   case $libgcjdir in
 418   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 419   *) qlibgcjdir=$libgcjdir;;
 420   esac
 421   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 422   ;;
 423 *)
 424   GCJ=$GCJ" -B$libgcjdir/"
 425   ;;
 426 esac
 427 case "${which_gcj}" in
 428    built)
 429       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 430    ;;
 431    cross)
 432       if test "x${with_newlib}" = "xyes"; then
 433          # FIXME (comment): Why is this needed?
 434          GCC_UNWIND_INCLUDE=
 435       fi
 436       GCJH='$(target_noncanonical)-gcjh'
 437    ;;
 438    path)
 439       GCJH=gcjh
 440    ;;
 441 esac
 442 JAVAC="$GCJ -C"
 443 export JAVAC
 444
 445 AC_SUBST(GCJ_FOR_ECJX)
 446 AC_SUBST(GCJH)
 447 AC_SUBST(host_exeext)
 448
 449 # Create it, so that compile/link tests don't fail
 450 test -f libgcj.spec || touch libgcj.spec
 451
 452
 453
 454 # Set up to configure Classpath.
 455 # FIXME: no supported way to pass args in autoconf.
 456 # Disable tool wrappers to avoid ltdl.h configure check.
 457 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 458 ac_configure_args="$ac_configure_args --disable-load-library"
 459 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 460 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 461 dir1=`cd $srcdir && pwd`
 462 dir2=`pwd`
 463 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 464 ac_configure_args="$ac_configure_args --disable-core-jni"
 465 dnl FIXME?
 466 ac_configure_args="$ac_configure_args --disable-examples"
 467 ac_configure_args="$ac_configure_args --with-glibj=build"
 468 if test "$plugin_enabled" != yes; then
 469   ac_configure_args="$ac_configure_args --disable-plugin"
 470 fi
 471 if test "$gconf_enabled" != yes; then
 472   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 473   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 474 fi
 475 if test "$use_gtk_awt" != yes; then
 476   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 477 fi
 478 if test "$use_qt_awt" != yes; then
 479   ac_configure_args="$ac_configure_args --disable-qt-peer"
 480 else
 481   # We need this as qt is disabled by default in classpath.
 482   ac_configure_args="$ac_configure_args --enable-qt-peer"
 483 fi
 484 if test "$use_x_awt" != yes; then
 485   ac_configure_args="$ac_configure_args --without-escher"
 486 else
 487   # We need this as escher is disabled by default in classpath.
 488   if test "$use_escher" != true; then
 489     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 490   else
 491     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 492   fi
 493 fi
 494 if test "x$BUILD_GJDOC" = xno; then
 495   ac_configure_args="$ac_configure_args --disable-gjdoc"
 496 fi
 497 # -Werror causes unavoidable problems in code using alsa.
 498 ac_configure_args="$ac_configure_args --disable-regen-headers"
 499 ac_configure_args="$ac_configure_args --disable-Werror"
 500 dnl --with-gcj=$GCJ
 501 dnl --with-javah=$GCJH
 502 dnl gtk-cairo -- just export here...
 503 dnl --enable-regen-headers?
 504
 505 # Only use libltdl for non-newlib builds.
 506 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 507    AC_LIBLTDL_CONVENIENCE
 508    AC_LIBTOOL_DLOPEN
 509    DIRLTDL=libltdl
 510    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 511    # Sigh.  Libtool's macro doesn't do the right thing.
 512    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 513    # FIXME: this is a hack.
 514    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 515    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 516 fi
 517 AC_SUBST(INCLTDL)
 518 AC_SUBST(LIBLTDL)
 519 AC_SUBST(DIRLTDL)
 520 AC_PROG_LIBTOOL
 521 AM_PROG_GCJ
 522 AM_PROG_CC_C_O
 523
 524 AC_CONFIG_SUBDIRS(classpath libltdl)
 525
 526 # The -no-testsuite modules omit the test subdir.
 527 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 528
 529 # Should the runtime set system properties by examining the
 530 # environment variable GCJ_PROPERTIES?
 531 AC_ARG_ENABLE(getenv-properties,
 532   AS_HELP_STRING([--disable-getenv-properties],
 533                  [don't set system properties from GCJ_PROPERTIES]))
 534
 535 # Whether GCJ_PROPERTIES is used depends on the target.
 536 if test -z "$enable_getenv_properties"; then
 537    enable_getenv_properties=${enable_getenv_properties_default-yes}
 538 fi
 539 if test "$enable_getenv_properties" = no; then
 540    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 541      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 542 fi
 543
 544 # Whether we should use arguments to main()
 545 if test -z "$enable_main_args"; then
 546    enable_main_args=${enable_main_args_default-yes}
 547 fi
 548 if test "$enable_main_args" = no; then
 549    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 550 fi
 551
 552
 553 # Should we use hashtable-based synchronization?
 554 # Currently works only for Linux X86/ia64
 555 # Typically faster and more space-efficient
 556 AC_ARG_ENABLE(hash-synchronization,
 557   AS_HELP_STRING([--enable-hash-synchronization],
 558                  [use global hash table for monitor locks]))
 559
 560 if test -z "$enable_hash_synchronization"; then
 561    enable_hash_synchronization=$enable_hash_synchronization_default
 562 fi
 563
 564
 565 install_ecj_jar=no
 566 ECJ_BUILD_JAR=
 567 ECJ_JAR=
 568 AC_ARG_WITH(ecj-jar,
 569         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 570         [ECJ_JAR=$withval],
 571         [if test -f $multi_basedir/ecj.jar; then
 572            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 573            ECJ_JAR='$(jardir)/ecj.jar'
 574            install_ecj_jar=yes
 575          fi])
 576 AC_SUBST(ECJ_BUILD_JAR)
 577 AC_SUBST(ECJ_JAR)
 578 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 579 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 580
 581 AC_ARG_WITH(java-home,
 582   AS_HELP_STRING([--with-java-home=DIRECTORY],
 583                  [value of java.home system property]),
 584                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 585 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 586 AC_SUBST(JAVA_HOME)
 587
 588 suppress_libgcj_bc=no
 589 AC_ARG_ENABLE(libgcj-bc,
 590   AS_HELP_STRING([--enable-libgcj-bc],
 591                  [enable(default) or disable BC ABI for portions of libgcj]),
 592   [if test "$enable_libgcj_bc" = "no"; then
 593      suppress_libgcj_bc=yes
 594    fi])
 595 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 596
 597 build_libgcj_reduced_reflection=no
 598 AC_ARG_ENABLE(reduced-reflection,
 599   AS_HELP_STRING([--enable-reduced-reflection],
 600                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 601   [if test "$enable_reduced_reflection" = "yes"; then
 602      build_libgcj_reduced_reflection=yes
 603    fi])
 604 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 605
 606 # What is the native OS API for MinGW?
 607 AC_ARG_WITH(win32-nlsapi,
 608   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 609                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 610 [case "${withval}" in
 611   ansi) with_win32_nlsapi=ansi ;;
 612   unicows) with_win32_nlsapi=unicows ;;
 613   unicode) with_win32_nlsapi=unicode ;;
 614   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 615 esac],[with_win32_nlsapi=ansi])
 616
 617 case "${with_win32_nlsapi}" in
 618   unicows | unicode)
 619     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 620       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 621     ;;
 622 esac
 623
 624 # configure.host sets slow_pthread_self if the synchronization code should
 625 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 626 if test "${slow_pthread_self}" = "yes"; then
 627   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 628     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 629 fi
 630
 631 # Check for gc debugging.  This option is handled both here and in the GC.
 632 AC_ARG_ENABLE(gc-debug,
 633    AS_HELP_STRING([--enable-gc-debug],
 634                   [include full support for pointer backtracing etc.]),
 635 [ if test "$enable_gc_debug" = "yes"; then
 636     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 637               [Define if we want to use debug calls into the garbage collector.])
 638   fi])
 639
 640 # See if the user has the interpreter included.
 641 AC_ARG_ENABLE(interpreter,
 642   AS_HELP_STRING([--enable-interpreter],
 643                  [enable interpreter]),
 644   [if test "$enable_interpreter" = yes; then
 645     # This can also be set in configure.host.
 646     libgcj_interpreter=yes
 647   elif test "$enable_interpreter" = no; then
 648     libgcj_interpreter=no
 649   fi])
 650
 651 if test "$libgcj_interpreter" = yes; then
 652    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 653 fi
 654 INTERPRETER="$libgcj_interpreter"
 655 AC_SUBST(INTERPRETER)
 656 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 657
 658 AC_MSG_CHECKING([for exception model to use])
 659 AC_LANG_PUSH(C++)
 660 AC_ARG_ENABLE(sjlj-exceptions,
 661   AS_HELP_STRING([--enable-sjlj-exceptions],
 662                  [force use of builtin_setjmp for exceptions]),
 663 [:],
 664 [dnl Botheration.  Now we've got to detect the exception model.
 665 dnl Link tests against libgcc.a are problematic since -- at least
 666 dnl as of this writing -- we've not been given proper -L bits for
 667 dnl single-tree newlib and libgloss.
 668 dnl
 669 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 670 dnl conftest files before we got a change to grep them first.
 671 cat > conftest.$ac_ext << EOF
 672 [#]line __oline__ "configure"
 673 struct S { ~S(); };
 674 void bar();
 675 void foo()
 676 {
 677   S s;
 678   bar();
 679 }
 680 EOF
 681 old_CXXFLAGS="$CXXFLAGS"
 682 CXXFLAGS=-S
 683 if AC_TRY_EVAL(ac_compile); then
 684   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 685     enable_sjlj_exceptions=yes
 686   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 687     enable_sjlj_exceptions=no
 688   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 689     # ARM EH ABI.
 690     enable_sjlj_exceptions=no
 691   fi
 692 fi
 693 CXXFLAGS="$old_CXXFLAGS"
 694 rm -f conftest*])
 695 if test x$enable_sjlj_exceptions = xyes; then
 696   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 697         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 698   ac_exception_model_name=sjlj
 699 elif test x$enable_sjlj_exceptions = xno; then
 700   ac_exception_model_name="call frame"
 701 else
 702   AC_MSG_ERROR([unable to detect exception model])
 703 fi
 704 AC_LANG_POP(C++)
 705 AC_MSG_RESULT($ac_exception_model_name)
 706
 707 # If we are non using SJLJ exceptions, and this host does not have support
 708 # for unwinding from a signal handler, enable checked dereferences and divides.
 709 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 710   CHECKREFSPEC=-fcheck-references
 711   DIVIDESPEC=-fuse-divide-subroutine
 712   EXCEPTIONSPEC=
 713 fi
 714
 715 # See if the user wants to disable java.net.  This is the mildly
 716 # ugly way that we admit that target-side configuration sucks.
 717 AC_ARG_ENABLE(java-net,
 718   AS_HELP_STRING([--disable-java-net],
 719                  [disable java.net]))
 720
 721 # Whether java.net is built by default can depend on the target.
 722 if test -z "$enable_java_net"; then
 723    enable_java_net=${enable_java_net_default-yes}
 724 fi
 725 if test "$enable_java_net" = no; then
 726    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 727 fi
 728
 729 # See if the user wants to configure without libffi.  Some
 730 # architectures don't support it, and default values are set in
 731 # configure.host.
 732 AC_ARG_WITH(libffi,
 733   AS_HELP_STRING([--without-libffi],
 734                  [don't use libffi]),
 735   [:],
 736   [with_libffi=${with_libffi_default-yes}])
 737
 738 LIBFFI=
 739 LIBFFIINCS=
 740 if test "$with_libffi" != no; then
 741    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 742    LIBFFI=../libffi/libffi_convenience.la
 743    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 744 fi
 745 AC_SUBST(LIBFFI)
 746 AC_SUBST(LIBFFIINCS)
 747
 748 # See if the user wants to disable JVMPI support.
 749 AC_ARG_ENABLE(jvmpi,
 750   AS_HELP_STRING([--disable-jvmpi],
 751                  [disable JVMPI support]))
 752
 753 if test "$enable_jvmpi" != no; then
 754     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 755 fi
 756
 757 # If the target is an eCos system, use the appropriate eCos
 758 # I/O routines.
 759 # FIXME: this should not be a local option but a global target
 760 # system; at present there is no eCos target.
 761 TARGET_ECOS=${PROCESS-"no"}
 762 AC_ARG_WITH(ecos,
 763 [  --with-ecos             enable runtime eCos target support],
 764 TARGET_ECOS="$with_ecos"
 765 )
 766
 767 case "$TARGET_ECOS" in
 768    no) case "$host" in
 769       *mingw*)
 770             PLATFORM=Win32
 771             PLATFORMNET=Win32
 772             PLATFORMH=win32.h
 773         CHECK_FOR_BROKEN_MINGW_LD
 774       ;;
 775       *)
 776             PLATFORM=Posix
 777             PLATFORMNET=Posix
 778             PLATFORMH=posix.h
 779       ;;
 780       esac
 781       ;;
 782    *)
 783       PLATFORM=Ecos
 784       PLATFORMNET=NoNet
 785       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 786       PLATFORMH=posix.h
 787       ;;
 788 esac
 789 AC_SUBST(PLATFORM)
 790 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 791
 792 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 793                                       [Define if you have int32_t and uint32_t.]))
 794 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 795                                         [Define if you have int32_t and uint32_t.]))
 796 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 797                                           [Define if you have u_int32_t]))
 798 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 799                                            [Define if you have u_int32_t]))
 800
 801 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 802 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 803
 804 case "$host" in
 805   *-darwin*) DARWIN_CRT=true ;;
 806   *) DARWIN_CRT=false ;;
 807 esac
 808 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 809
 810 # This may not be defined in a non-ANS conformant embedded system.
 811 # FIXME: Should these case a runtime exception in that case?
 812 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 813                                   [Define is you have 'localtime' in <time.h>]))
 814
 815 # Create the subdirectory for natFile.cc, or the attempt
 816 # to create the link will fail.
 817 test -d java || mkdir java
 818 test -d java/io || mkdir java/io
 819 test -d gnu || mkdir gnu
 820 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 821
 822 # Likewise for natConcreteProcess.cc.
 823 test -d java/lang || mkdir java/lang
 824 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 825
 826 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 827 test -d java/net || mkdir java/net
 828 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 829 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 830
 831 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 832 test -d gnu/java || mkdir gnu/java
 833 test -d gnu/java/net || mkdir gnu/java/net
 834 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 835 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 836
 837 # Likewise for natVMPipe.cc and natVMSelector.cc.
 838 test -d gnu/java/nio || mkdir gnu/java/nio
 839 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 840 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 841
 842 # Likewise for natFileChannelImpl.cc
 843 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 844 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 845
 846 # Likewise for natVMSecureRandom.cc
 847 test -d gnu/java/security || mkdir gnu/java/security
 848 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 849 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 850 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 851
 852 case "${host}" in
 853     *mingw*)
 854       SYSTEMSPEC="-lgdi32 -lws2_32"
 855       if test "${with_win32_nlsapi}" = "unicows"; then
 856         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 857       fi
 858     ;;
 859     *)
 860       SYSTEMSPEC=
 861     ;;
 862 esac
 863 AC_SUBST(SYSTEMSPEC)
 864
 865 AC_ARG_WITH(system-zlib,
 866   AS_HELP_STRING([--with-system-zlib],
 867                  [use installed libz]))
 868 ZLIBSPEC=
 869 AC_SUBST(ZLIBSPEC)
 870 ZLIBTESTSPEC=
 871 AC_SUBST(ZLIBTESTSPEC)
 872
 873 AC_PATH_XTRA
 874
 875 # FIXME: this should be _libs on some hosts.
 876 libsubdir=.libs
 877
 878 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 879
 880 LIBSTDCXXSPEC=
 881 # extra LD Flags which are required for targets
 882 case "${host}" in
 883 *-*-darwin[[0-7]].*)
 884     # For now we have to disable it on darwin[8-9] because it slows down
 885     # the linking phase. A possible bug in ld?
 886     # on Darwin -single_module speeds up loading of the dynamic libraries.
 887     extra_ldflags_libjava=-Wl,-single_module
 888     ;;
 889 *-*-darwin[[912]]*)
 890     extra_gij_ldflags=-Wl,-allow_stack_execute
 891     ;;
 892 arm*linux*eabi)
 893     # Some of the ARM unwinder code is actually in libstdc++.  We
 894     # could in principle replicate it in libgcj, but it's better to
 895     # have a dependency on libstdc++.
 896     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 897     LIBSTDCXXSPEC=-lstdc++
 898     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 899     ;;
 900 esac
 901 AC_SUBST(extra_ldflags_libjava)
 902 AC_SUBST(extra_gij_ldflags)
 903 AC_SUBST(extra_ldflags)
 904 AC_SUBST(LIBSTDCXXSPEC)
 905
 906 AC_SUBST(LIBGCJTESTSPEC)
 907
 908 # Allow the GC to be disabled.  Can be useful when debugging.
 909 AC_MSG_CHECKING([for garbage collector to use])
 910 AC_ARG_ENABLE(java-gc,
 911   AS_HELP_STRING([--enable-java-gc=TYPE],
 912                  [choose garbage collector (default is boehm)]),
 913   [GC=$enableval],
 914   [GC=boehm])
 915 GCLIBS=
 916 GCINCS=
 917 GCDEPS=
 918 GCSPEC=
 919 JC1GCSPEC=
 920 GCTESTSPEC=
 921 case "$GC" in
 922  boehm)
 923     AC_MSG_RESULT(boehm)
 924     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 925     JC1GCSPEC='-fuse-boehm-gc'
 926     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 927     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 928     GCOBJS=boehm.lo
 929     GCHDR=boehm-gc.h
 930     # The POSIX thread support needs to know this.
 931     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 932     ;;
 933  no)
 934     AC_MSG_RESULT(none)
 935     GCHDR=no-gc.h
 936     ;;
 937  *)
 938     AC_MSG_ERROR([unrecognized collector "$GC"])
 939     ;;
 940 esac
 941 AC_SUBST(GCLIBS)
 942 AC_SUBST(GCINCS)
 943 AC_SUBST(GCDEPS)
 944 AC_SUBST(GCSPEC)
 945 AC_SUBST(JC1GCSPEC)
 946 AC_SUBST(GCTESTSPEC)
 947 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 948 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 949 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 950
 951
 952 AC_MSG_CHECKING([for thread model used by GCC])
 953 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 954 AC_MSG_RESULT([$THREADS])
 955
 956 case "$THREADS" in
 957  no | none | single)
 958     THREADS=none
 959     ;;
 960  aix | posix | posix95 | pthreads)
 961     THREADS=posix
 962     case "$host" in
 963      *-*-linux*)
 964         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 965         ;;
 966     esac
 967     ;;
 968  win32)
 969     ;;
 970  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 971     AC_MSG_ERROR(thread package $THREADS not yet supported)
 972     ;;
 973  *)
 974     AC_MSG_ERROR($THREADS is an unknown thread package)
 975     ;;
 976 esac
 977
 978 THREADCXXFLAGS=
 979 THREADLDFLAGS=
 980 THREADLIBS=
 981 THREADINCS=
 982 THREADDEPS=
 983 THREADH=
 984 THREADSPEC=
 985 THREADSTARTFILESPEC=
 986 case "$THREADS" in
 987  posix)
 988     case "$host" in
 989      *-*-cygwin*)
 990         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 991         ;;
 992      *-*-freebsd[[1234]]*)
 993         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 994         # merely adds pthread_* functions) but it does have a -pthread switch
 995         # which is required at link-time to select -lc_r *instead* of -lc.
 996         THREADLDFLAGS=-pthread
 997         # Don't set THREADSPEC here as might be expected since -pthread is
 998         # not processed when found within a spec file, it must come from
 999         # the command line.  For now, the user must provide the -pthread
1000         # switch to link code compiled with gcj.  In future, consider adding
1001         # support for weak references to pthread_* functions ala gthr.h API.
1002         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1003         ;;
1004      *-*-freebsd*)
1005         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1006         # systems which support threads and -lpthread.
1007         THREADLDFLAGS=-pthread
1008         THREADSPEC=-lpthread
1009         ;;
1010      alpha*-dec-osf* | hppa*-hp-hpux*)
1011         THREADCXXFLAGS=-pthread
1012         # boehm-gc needs some functions from librt, so link that too.
1013         THREADLIBS='-lpthread -lrt'
1014         THREADSPEC='-lpthread -lrt'
1015         ;;
1016      *)
1017         THREADLIBS=-lpthread
1018         THREADSPEC=-lpthread
1019         ;;
1020     esac
1021     THREADH=posix-threads.h
1022     # MIT pthreads doesn't seem to have the mutexattr functions.
1023     # But for now we don't check for it.  We just assume you aren't
1024     # using MIT pthreads.
1025     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1026
1027     # If we're using the Boehm GC, then we happen to know that it
1028     # defines _REENTRANT, so we don't bother.  Eww.
1029     if test "$GC" != boehm; then
1030        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1031     fi
1032     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1033     ;;
1034
1035  win32)
1036     THREADH=win32-threads.h
1037     THREADCXXFLAGS=-mthreads
1038     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1039     # But we do not want the executables created to be dependent on
1040     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1041     # exception handling contexts.  The following kludge achieves this effect
1042     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1043     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1044     # A workaround is to explicitly use -mthreads while linking Java programs.
1045     # See PR libgcj/28263.
1046     #
1047     # FIXME: In Java we are able to detect thread death at the end of
1048     # Thread.run() so we should be able to clean up the exception handling
1049     # contexts ourselves.
1050     THREADSTARTFILESPEC='crtmt%O%s'
1051     ;;
1052
1053  none)
1054     THREADH=no-threads.h
1055     ;;
1056 esac
1057 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1058 AC_SUBST(THREADLIBS)
1059 AC_SUBST(THREADINCS)
1060 AC_SUBST(THREADDEPS)
1061 AC_SUBST(THREADSPEC)
1062 AC_SUBST(THREADSTARTFILESPEC)
1063 AC_SUBST(THREADLDFLAGS)
1064 AC_SUBST(THREADCXXFLAGS)
1065 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1066 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1067 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1068 if test "$enable_shared" != yes; then
1069   use_libgcj_bc=no
1070 fi
1071 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1072
1073 if test -d sysdep; then true; else mkdir sysdep; fi
1074 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1075 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1076 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1077
1078 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
1079 if test "$use_libgcj_bc" = yes; then
1080   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:-lgcj;:-lgcj_bc}"
1081 fi
1082 AC_SUBST(LIBGCJ_SPEC)
1083
1084 HASH_SYNC_SPEC=
1085 # Hash synchronization is only useful with posix threads right now.
1086 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1087    HASH_SYNC_SPEC=-fhash-synchronization
1088    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1089 fi
1090 AC_SUBST(HASH_SYNC_SPEC)
1091
1092 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1093
1094 # We're in the tree with gcc, and need to include some of its headers.
1095 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1096
1097 if test "x${with_newlib}" = "xyes"; then
1098    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1099    # may not work correctly, because the compiler may not be able to
1100    # link executables.
1101
1102    # We assume newlib.  This lets us hard-code the functions we know
1103    # we'll have.
1104    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1105    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1106    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1107    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1108    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1109    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1110    # This is only for POSIX threads.
1111    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1112
1113    # Assume we do not have getuid and friends.
1114    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1115    PLATFORMNET=NoNet
1116 else
1117    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1118                    localtime_r getpwuid_r getcwd \
1119                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1120                    nl_langinfo setlocale \
1121                    inet_pton uname inet_ntoa \
1122                    getrlimit sigaction ftruncate mmap \
1123                    getifaddrs])
1124    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1125    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1126    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1127    AC_CHECK_LIB(dl, dladdr, [
1128        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1129        AC_CHECK_LIB(dld, dladdr, [
1130        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1131
1132    if test x"$cross_compiling" = x"no"; then
1133      AC_CHECK_FILES(/proc/self/exe, [
1134        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1135      AC_CHECK_FILES(/proc/self/maps, [
1136        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1137          [Define if you have /proc/self/maps])])
1138    else
1139      case $host in
1140      *-linux*)
1141        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1142        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1143        ;;
1144      esac
1145    fi
1146
1147    AM_ICONV
1148    AM_LC_MESSAGES
1149    AC_STRUCT_TIMEZONE
1150
1151    AC_CHECK_FUNCS(gethostbyname_r, [
1152      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1153        [Define if you have the 'gethostbyname_r' function.])
1154      # There are two different kinds of gethostbyname_r.
1155      # We look for the one that returns `int'.
1156      # Hopefully this check is robust enough.
1157      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1158        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1159
1160      case " $GCINCS " in
1161      *" -D_REENTRANT "*) ;;
1162      *)
1163         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1164         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1165         [libjava_cv_gethostbyname_r_needs_reentrant],
1166         [ AC_LANG_PUSH(C++)
1167           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1168             [[gethostbyname_r("", 0, 0);]])],
1169             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1170                 CPPFLAGS_SAVE="$CPPFLAGS"
1171                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1172                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1173                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1174                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1175                 CPPFLAGS="$CPPFLAGS_SAVE"
1176           ])
1177           AC_LANG_POP(C++)
1178         ])
1179         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1180           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1181         fi
1182      ;;
1183      esac
1184
1185      AC_CACHE_CHECK([for struct hostent_data],
1186         [libjava_cv_struct_hostent_data], [dnl
1187         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1188 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1189 # define _REENTRANT 1
1190 #endif
1191 #include <netdb.h>]], [[struct hostent_data data;]])],
1192           [libjava_cv_struct_hostent_data=yes],
1193           [libjava_cv_struct_hostent_data=no])])
1194      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1195        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1196          [Define if struct hostent_data is defined in netdb.h])
1197      fi
1198    ])
1199
1200    # FIXME: libjava source code expects to find a prototype for
1201    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1202    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1203    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1204    # linkage check is enough, yet C++ code requires proper prototypes.)
1205    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1206    AC_CHECK_FUNCS(gethostbyaddr_r, [
1207      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1208        [Define if you have the 'gethostbyaddr_r' function.])
1209      # There are two different kinds of gethostbyaddr_r.
1210      # We look for the one that returns `int'.
1211      # Hopefully this check is robust enough.
1212      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1213        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1214          [Define if gethostbyaddr_r returns 'int'.])])])])
1215
1216    AC_CHECK_FUNCS(gethostname, [
1217      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1218        [Define if you have the 'gethostname' function.])
1219      AC_EGREP_HEADER(gethostname, unistd.h, [
1220        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1221          [Define if gethostname is declared in <unistd.h>.])])])
1222
1223    AC_CHECK_FUNCS(usleep, [
1224      AC_EGREP_HEADER(usleep, unistd.h, [
1225        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1226           [Define if usleep is declared in <unistd.h>.])])])
1227
1228    # Look for these functions in the thread library, but only bother
1229    # if using POSIX threads.
1230    if test "$THREADS" = posix; then
1231       save_LIBS="$LIBS"
1232       LIBS="$LIBS $THREADLIBS"
1233
1234       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1235       # Solaris 7 the name librt is preferred.
1236       AC_CHECK_FUNCS(sched_yield, , [
1237         AC_CHECK_LIB(rt, sched_yield, [
1238           AC_DEFINE(HAVE_SCHED_YIELD)
1239           THREADLIBS="$THREADLIBS -lrt"
1240           THREADSPEC="$THREADSPEC -lrt"], [
1241           AC_CHECK_LIB(posix4, sched_yield, [
1242             AC_DEFINE(HAVE_SCHED_YIELD)
1243             THREADLIBS="$THREADLIBS -lposix4"
1244             THREADSPEC="$THREADSPEC -lposix4"])])])
1245
1246       AC_CHECK_LIB(rt, clock_gettime, [
1247          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1248          case "$THREADSPEC" in
1249            *-lrt*) ;;
1250            *)
1251              THREADSPEC="$THREADSPEC -lrt"
1252              THREADLIBS="$THREADLIBS -lrt"
1253              ;;
1254          esac])
1255
1256       LIBS="$save_LIBS"
1257
1258       # We can save a little space at runtime if the mutex has m_count
1259       # or __m_count.  This is a nice hack for Linux.
1260       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1261           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1262         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1263              [Define if pthread_mutex_t has m_count member.]), [
1264         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1265             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1266           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1267             [Define if pthread_mutex_t has __m_count member.]))])
1268    fi
1269
1270    # We require a way to get the time.
1271    time_found=no
1272    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1273    if test "$time_found" = no; then
1274       AC_MSG_ERROR([no function found to get the time])
1275    fi
1276
1277    AC_CHECK_FUNCS(memmove)
1278
1279    # We require memcpy.
1280    memcpy_found=no
1281    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1282    if test "$memcpy_found" = no; then
1283       AC_MSG_ERROR([memcpy is required])
1284    fi
1285    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1286    AC_CHECK_LIB(dl, dlopen, [
1287        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1288        AC_CHECK_LIB(dld, dlopen, [
1289        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1290
1291    # Some library-finding code we stole from Tcl.
1292    #--------------------------------------------------------------------
1293    #    Check for the existence of the -lsocket and -lnsl libraries.
1294    #    The order here is important, so that they end up in the right
1295    #    order in the command line generated by make.  Here are some
1296    #    special considerations:
1297    #    1. Use "connect" and "accept" to check for -lsocket, and
1298    #       "gethostbyname" to check for -lnsl.
1299    #    2. Use each function name only once:  can't redo a check because
1300    #       autoconf caches the results of the last check and won't redo it.
1301    #    3. Use -lnsl and -lsocket only if they supply procedures that
1302    #       aren't already present in the normal libraries.  This is because
1303    #       IRIX 5.2 has libraries, but they aren't needed and they're
1304    #       bogus:  they goof up name resolution if used.
1305    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1306    #       To get around this problem, check for both libraries together
1307    #       if -lsocket doesn't work by itself.
1308    #--------------------------------------------------------------------
1309
1310    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1311     [gcj_cv_lib_sockets=
1312      gcj_checkBoth=0
1313      unset ac_cv_func_connect
1314      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1315      if test "$gcj_checkSocket" = 1; then
1316          unset ac_cv_func_connect
1317          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1318                       gcj_checkBoth=1)
1319      fi
1320      if test "$gcj_checkBoth" = 1; then
1321          gcj_oldLibs=$LIBS
1322          LIBS="$LIBS -lsocket -lnsl"
1323          unset ac_cv_func_accept
1324          AC_CHECK_FUNC(accept,
1325                        [gcj_checkNsl=0
1326                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1327          unset ac_cv_func_accept
1328          LIBS=$gcj_oldLibs
1329      fi
1330      unset ac_cv_func_gethostbyname
1331      gcj_oldLibs=$LIBS
1332      LIBS="$LIBS $gcj_cv_lib_sockets"
1333      AC_CHECK_FUNC(gethostbyname, ,
1334                    [AC_CHECK_LIB(nsl, main,
1335                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1336      unset ac_cv_func_gethostbyname
1337      LIBS=$gcj_oldLIBS
1338    ])
1339    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1340
1341    if test "$with_system_zlib" = yes; then
1342       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1343    fi
1344
1345    # Test for Gtk stuff, if asked for.
1346    if test "$use_gtk_awt" = yes; then
1347       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1348       AC_SUBST(GTK_CFLAGS)
1349       AC_SUBST(GTK_LIBS)
1350
1351       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1352       AC_SUBST(GLIB_CFLAGS)
1353       AC_SUBST(GLIB_LIBS)
1354
1355       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1356       AC_SUBST(LIBART_CFLAGS)
1357       AC_SUBST(LIBART_LIBS)
1358
1359       # We require the XTest Extension to support java.awt.Robot.
1360       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1361                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1362                    [${X_LIBS}])
1363    fi
1364
1365    # On Solaris, and maybe other architectures, the Boehm collector
1366    # requires -ldl.
1367    if test "$GC" = boehm; then
1368       case "${host}" in
1369           mips-sgi-irix6*)
1370             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1371             # libgcj.spec is used, so override here
1372             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1373           ;;
1374           *)
1375             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1376           ;;
1377       esac
1378    fi
1379 fi
1380
1381 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1382 case $build in
1383     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1384     *)         CLASSPATH_SEPARATOR=':' ;;
1385 esac
1386 AC_SUBST(CLASSPATH_SEPARATOR)
1387
1388 # We must search the source tree for java.lang, since we still don't
1389 # have libgcj.jar nor java/lang/*.class
1390 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1391 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1392
1393 # Since some classes depend on this one, we need its source available
1394 # before we can do any GCJ compilation test :-(
1395 if test ! -f gnu/classpath/Configuration.java; then
1396   test -d gnu || mkdir gnu
1397   test -d gnu/classpath || mkdir gnu/classpath
1398   # Note that it is not crucial that all the values here be correct.
1399   sed -e "s,@prefix@,$prefix," \
1400       -e "s,@VERSION@,$VERSION," \
1401       -e "s,@LIBDEBUG@,false," \
1402       -e "s,@INIT_LOAD_LIBRARY@,false," \
1403       -e "s,@@,$LIBGCJDEBUG," \
1404       -e "s,@default_toolkit@,$TOOLKIT," \
1405       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1406       -e "s,@GTK_CAIRO_ENABLED@,false," \
1407       -e "s,@ECJ_JAR@,," \
1408       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1409         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1410         > gnu/classpath/Configuration.java
1411   # We do not want to redirect the output of the grep below to /dev/null,
1412   # but we add /dev/null to the input list so that grep will print the
1413   # filename of Configuration.java in case it finds any matches.
1414   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1415     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1416   fi
1417 fi
1418
1419 LT_AC_PROG_GCJ
1420
1421 # Now remove it.
1422 rm -f gnu/classpath/Configuration.java
1423
1424 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1425
1426 AC_CHECK_SIZEOF(void *)
1427
1428 AC_C_BIGENDIAN
1429
1430 ZLIBS=
1431 SYS_ZLIBS=
1432 ZINCS=
1433
1434 if test -z "$ZLIBSPEC"; then
1435    # Use zlib from the GCC tree.
1436    ZINCS='-I$(top_srcdir)/../zlib'
1437    ZLIBS=../zlib/libzgcj_convenience.la
1438 else
1439    # System's zlib.
1440    SYS_ZLIBS="$ZLIBSPEC"
1441 fi
1442 AC_SUBST(ZLIBS)
1443 AC_SUBST(SYS_ZLIBS)
1444 AC_SUBST(ZINCS)
1445 AC_SUBST(DIVIDESPEC)
1446 AC_SUBST(CHECKREFSPEC)
1447 AC_SUBST(EXCEPTIONSPEC)
1448 AC_SUBST(BACKTRACESPEC)
1449 AC_SUBST(IEEESPEC)
1450
1451 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1452 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1453 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1454 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1455 AC_SUBST(GCC_UNWIND_INCLUDE)
1456
1457 # Process the option "--enable-version-specific-runtime-libs"
1458 # Calculate toolexeclibdir
1459 case ${version_specific_libs} in
1460   yes)
1461     # Need the gcc compiler version to know where to install libraries
1462     # and header files if --enable-version-specific-runtime-libs option
1463     # is selected.
1464     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1465     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1466     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1467     toolexeclibdir=$toolexecmainlibdir
1468     ;;
1469   no)
1470     if test -n "$with_cross_host" &&
1471        test x"$with_cross_host" != x"no"; then
1472       # Install a library built with a cross compiler in tooldir, not libdir.
1473       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1474       toolexecmainlibdir='$(toolexecdir)/lib'
1475     else
1476       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1477       toolexecmainlibdir='$(libdir)'
1478     fi
1479     multi_os_directory=`$CC -print-multi-os-directory`
1480     case $multi_os_directory in
1481       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1482       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1483     esac
1484     ;;
1485 esac
1486 AC_SUBST(toolexecdir)
1487 AC_SUBST(toolexecmainlibdir)
1488 AC_SUBST(toolexeclibdir)
1489
1490 # Determine gcj and libgcj version number.
1491 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1492 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1493 GCJVERSION=$gcjversion
1494 AC_SUBST(GCJVERSION)
1495 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1496
1497 # Determine where the standard .db file and GNU Classpath JNI
1498 # libraries are found.
1499 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1500 multi_os_directory=`$CC -print-multi-os-directory`
1501 case $multi_os_directory in
1502   .)
1503    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1504    ;;
1505   *)
1506    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1507    ;;
1508 esac
1509 AC_SUBST(dbexecdir)
1510 AC_SUBST(gcjsubdir)
1511
1512 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1513 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1514
1515 TL_AC_GXX_INCLUDE_DIR
1516
1517 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1518 # On that system, sys/ioctl.h will not include sys/filio.h unless
1519 # BSD_COMP is defined; just including sys/filio.h is simpler.
1520 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1521 # for now.  If you change this, you also must update natFile.cc.
1522 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1523                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1524                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1525                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1526                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1527 AC_CHECK_HEADERS(inttypes.h, [
1528     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1529     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1530 ])
1531
1532 AC_CHECK_TYPE([ssize_t], [int])
1533 AC_CHECK_TYPE([magic_t], [
1534     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1535 #ifdef HAVE_MAGIC_H
1536 #include <magic.h>
1537 #endif])
1538
1539 AC_MSG_CHECKING([for in_addr_t])
1540 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1541 #if STDC_HEADERS
1542 #include <stdlib.h>
1543 #include <stddef.h>
1544 #endif
1545 #if HAVE_NETINET_IN_H
1546 #include <netinet/in.h>
1547 #endif]], [[in_addr_t foo;]])],
1548   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1549      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1550    AC_MSG_RESULT(yes)],
1551   [AC_MSG_RESULT(no)])
1552
1553 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1554 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1555   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1556      [Define if struct ip_mreq is defined in netinet/in.h.])
1557    AC_MSG_RESULT(yes)],
1558   [AC_MSG_RESULT(no)])
1559
1560 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1561 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1562   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1563      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1564    AC_MSG_RESULT(yes)],
1565   [AC_MSG_RESULT(no)])
1566
1567 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1568 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1569   [AC_DEFINE(HAVE_INET6, 1,
1570      [Define if inet6 structures are defined in netinet/in.h.])
1571    AC_MSG_RESULT(yes)],
1572   [AC_MSG_RESULT(no)])
1573
1574 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1575 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1576 #include <sys/types.h>
1577 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1578   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1579    AC_MSG_RESULT(yes)],
1580   [AC_MSG_RESULT(no)])
1581
1582 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1583 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1584   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1585    AC_MSG_RESULT(yes)],
1586   [AC_MSG_RESULT(no)
1587    AC_MSG_CHECKING([for global timezone variable])
1588    dnl FIXME: we don't want a link check here because that won't work
1589    dnl when cross-compiling.  So instead we make an assumption that
1590    dnl the header file will mention timezone if it exists.
1591    dnl Don't find the win32 function timezone
1592    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1593      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1594       AC_MSG_RESULT(yes)],
1595      [AC_MSG_RESULT(no)
1596        AC_MSG_CHECKING([for global _timezone variable])
1597        dnl FIXME: As above, don't want link check
1598        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1599          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1600             [Define if your platform has the global _timezone variable.])
1601           AC_MSG_RESULT(yes)],
1602           [AC_MSG_RESULT(no)])])])
1603
1604 AC_CHECK_PROGS(PERL, perl, false)
1605
1606 SYSDEP_SOURCES=
1607 SIGNAL_HANDLER_AUX=
1608
1609 case "${host}" in
1610  i?86-*-linux*)
1611     SIGNAL_HANDLER=include/i386-signal.h
1612     ;;
1613  sparc*-sun-solaris*)
1614     SIGNAL_HANDLER=include/sparc-signal.h
1615     ;;
1616 # ia64-*)
1617 #    SYSDEP_SOURCES=sysdep/ia64.c
1618 #    test -d sysdep || mkdir sysdep
1619 #    ;;
1620  hppa*-*-linux*)
1621     SIGNAL_HANDLER=include/pa-signal.h
1622     ;;
1623  hppa*-hp-hpux*)
1624     SIGNAL_HANDLER=include/hppa-signal.h
1625     ;;
1626  ia64-*-linux*)
1627     SIGNAL_HANDLER=include/dwarf2-signal.h
1628     ;;
1629  powerpc*-*-linux*)
1630     SIGNAL_HANDLER=include/powerpc-signal.h
1631     ;;
1632  alpha*-*-linux*)
1633     SIGNAL_HANDLER=include/dwarf2-signal.h
1634     ;;
1635  s390*-*-linux*)
1636     SIGNAL_HANDLER=include/s390-signal.h
1637     ;;
1638  x86_64*-*-linux*)
1639     SIGNAL_HANDLER=include/x86_64-signal.h
1640     SIGNAL_HANDLER_AUX=include/i386-signal.h
1641     ;;
1642  sparc*-*-linux*)
1643     SIGNAL_HANDLER=include/dwarf2-signal.h
1644     ;;
1645  sh*-*-linux*)
1646     SIGNAL_HANDLER=include/sh-signal.h
1647     ;;
1648  *mingw*)
1649     SIGNAL_HANDLER=include/win32-signal.h
1650     ;;
1651  mips*-*-linux*)
1652     SIGNAL_HANDLER=include/mips-signal.h
1653     ;;
1654  m68*-*-linux*)
1655     SIGNAL_HANDLER=include/dwarf2-signal.h
1656     ;;
1657  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1658     SIGNAL_HANDLER=include/darwin-signal.h
1659     ;;
1660  powerpc*-*-aix*)
1661     SIGNAL_HANDLER=include/aix-signal.h
1662     ;;
1663  *)
1664     SIGNAL_HANDLER=include/default-signal.h
1665     ;;
1666 esac
1667
1668 # If we're using sjlj exceptions, forget what we just learned.
1669 if test "$enable_sjlj_exceptions" = yes; then
1670    SIGNAL_HANDLER=include/default-signal.h
1671    SIGNAL_HANDLER_AUX=
1672 fi
1673
1674 AC_SUBST(SYSDEP_SOURCES)
1675
1676 if test -z "$SIGNAL_HANDLER_AUX"; then
1677   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1678 fi
1679
1680 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1681                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1682
1683 if test "${multilib}" = "yes"; then
1684   multilib_arg="--enable-multilib"
1685 else
1686   multilib_arg=
1687 fi
1688
1689 # See if we support thread-local storage.
1690 GCC_CHECK_TLS
1691
1692 # For _Unwind_GetIPInfo.
1693 GCC_CHECK_UNWIND_GETIPINFO
1694
1695 # See if linker supports anonymous version scripts.
1696 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1697   [libjava_cv_anon_version_script],
1698   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1699    libjava_cv_anon_version_script=no
1700    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1701    echo '{ global: globalsymb*; local: *; };' > conftest.map
1702    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1703                [libjava_cv_anon_version_script=yes], [])
1704    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1705   ])
1706 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1707
1708 # Check if linker supports static linking on a per library basis
1709 LD_START_STATIC_SPEC=
1710 LD_FINISH_STATIC_SPEC=
1711 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1712   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1713     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1714     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1715   fi
1716 fi
1717 AC_SUBST(LD_START_STATIC_SPEC)
1718 AC_SUBST(LD_FINISH_STATIC_SPEC)
1719
1720 here=`${PWDCMD-pwd}`
1721 AC_SUBST(here)
1722
1723 # We get this from the environment.
1724 AC_SUBST(GCJFLAGS)
1725
1726 AC_ARG_WITH([python-dir],
1727             AS_HELP_STRING([--with-python-dir],
1728                            [the location to install Python modules. This path should NOT include the prefix.]),
1729             [with_python_dir=$withval], [with_python_dir=""])
1730
1731 if test "x${with_python_dir}" = "x"
1732 then
1733   # Needed for installing Python modules during make install.
1734   python_mod_dir="\${prefix}/share/python"
1735   # Needed for substituting into aot-compile*
1736   python_mod_dir_expanded="${prefix}/share/python"
1737 else
1738   python_mod_dir="\${prefix}${with_python_dir}"
1739   python_mod_dir_expanded="${prefix}${with_python_dir}"
1740 fi
1741 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1742 AC_SUBST(python_mod_dir)
1743 AC_SUBST(python_mod_dir_expanded)
1744
1745 # needed for aot-compile-rpm
1746 MAKE=`which make`
1747 AC_SUBST(MAKE)
1748
1749 AC_ARG_ENABLE([aot-compile-rpm],
1750   [AS_HELP_STRING([--enable-aot-compile-rpm],
1751                  [enable installation of aot-compile-rpm [default=no]])],
1752   [case "${enableval}" in
1753     yes) AOT_RPM_ENABLED=yes ;;
1754     no)  AOT_RPM_ENABLED=no ;;
1755     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1756   esac],
1757   [AOT_RPM_ENABLED=no]
1758 )
1759 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1760
1761 AC_ARG_ENABLE([java-home],
1762   [AS_HELP_STRING([--enable-java-home],
1763                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1764   [case "${enableval}" in
1765     yes) JAVA_HOME_ENABLED=yes ;;
1766     no)  JAVA_HOME_ENABLED=no ;;
1767     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1768   esac],
1769   [JAVA_HOME_ENABLED=no]
1770 )
1771 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1772
1773 # Only do these checks if java-home above is enabled.
1774 if test "x${JAVA_HOME_ENABLED}" = xyes
1775 then
1776
1777   AC_ARG_WITH([gcc-suffix],
1778               AS_HELP_STRING([--with-gcc-suffix],
1779                              [the GCC tool suffix (defaults to empty string)]),
1780               [gcc_suffix=$withval], [gcc_suffix=""])
1781   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1782   AC_SUBST(gcc_suffix)
1783
1784   AC_ARG_WITH([arch-directory],
1785               AS_HELP_STRING([--with-arch-directory],
1786                              [the arch directory under jre/lib (defaults to auto-detect)]),
1787               [host_cpu=$withval], [host_cpu=""])
1788
1789   AC_ARG_WITH([os-directory],
1790               AS_HELP_STRING([--with-os-directory],
1791                              [the os directory under include (defaults to auto-detect)]),
1792               [host_os=$withval], [host_os=""])
1793
1794   AC_ARG_WITH([origin-name],
1795               AS_HELP_STRING([--with-origin-name],
1796                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1797               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1798   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1799
1800   AC_ARG_WITH([arch-suffix],
1801               AS_HELP_STRING([--with-arch-suffix],
1802                              [the arch directory suffix (default is the empty string]),
1803               [arch_suffix=$withval], [arch_suffix=""])
1804   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1805
1806   AC_ARG_WITH([jvm-root-dir],
1807               AS_HELP_STRING([--with-jvm-root-dir],
1808                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1809               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1810   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1811
1812   AC_ARG_WITH([jvm-jar-dir],
1813               AS_HELP_STRING([--with-jvm-jar-dir],
1814                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1815               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1816   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1817
1818   JAVA_VERSION=1.5.0
1819   BUILD_VERSION=0
1820   AC_SUBST(JAVA_VERSION)
1821   AC_SUBST(BUILD_VERSION)
1822   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1823
1824   jre_dir=jre
1825   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1826   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1827
1828   JVM_ROOT_DIR=${jvm_root_dir}
1829   AC_SUBST(JVM_ROOT_DIR)
1830   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1831
1832   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1833   AC_SUBST(JVM_JAR_ROOT_DIR)
1834   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1835
1836   JVM_JAR_DIR=${jvm_jar_dir}
1837   AC_SUBST(JVM_JAR_DIR)
1838   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1839
1840   JRE_DIR=${jre_dir}
1841   AC_SUBST(JRE_DIR)
1842
1843   JRE_LNK=${jre_lnk}
1844   AC_SUBST(JRE_LNK)
1845
1846   SDK_LNK=${sdk_lnk}
1847   AC_SUBST(SDK_LNK)
1848
1849   SDK_BIN_DIR=${jvm_root_dir}/bin
1850   AC_SUBST(SDK_BIN_DIR)
1851   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1852
1853   SDK_LIB_DIR=${jvm_root_dir}/lib
1854   AC_SUBST(SDK_LIB_DIR)
1855   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1856
1857   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1858   AC_SUBST(SDK_INCLUDE_DIR)
1859   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1860
1861   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1862   AC_SUBST(JRE_BIN_DIR)
1863   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1864
1865   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1866   AC_SUBST(JRE_LIB_DIR)
1867   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1868
1869   # Find gcj prefix using gcj found in PATH.
1870   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1871
1872   # Where do the gcj binaries live?
1873   # For jhbuild based builds, they all live in a sibling of bin called
1874   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1875   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1876   AC_SUBST(GCJ_BIN_DIR)
1877   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1878
1879   AC_MSG_RESULT(host is ${host})
1880   if test "x${host_cpu}" = "x"
1881   then
1882     case ${host} in
1883       *-mingw* | *-cygwin*)
1884         host_cpu=x86;;
1885       i486-* | i586-* | i686-*)
1886         host_cpu=i386;;
1887       x86_64-*)
1888         host_cpu=amd64;;
1889       *)
1890         host_cpu=${host_cpu};;
1891     esac
1892   fi
1893   AC_MSG_RESULT(arch directory: ${host_cpu})
1894   CPU=${host_cpu}
1895   AC_SUBST(CPU)
1896
1897   if test "x${host_os}" = "x"
1898   then
1899     case ${host} in
1900       *-mingw* | *-cygwin*)
1901         host_os=win32;;
1902       *-linux*)
1903         host_os=linux;;
1904       *)
1905         host_os=${host_os};;
1906     esac
1907   fi
1908   echo os directory: ${host_os}
1909   OS=${host_os}
1910   AC_SUBST(OS)
1911
1912   # make an expanded $libdir, for substituting into
1913   # scripts (and other non-Makefile things).
1914   LIBDIR=$libdir
1915   if test "x${exec_prefix}" = "xNONE"
1916   then
1917       lib_exec_prefix=$prefix
1918   else
1919       lib_exec_prefix=$exec_prefix
1920   fi
1921   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1922   AC_SUBST(LIBDIR)
1923 fi
1924
1925 AC_CONFIG_FILES([
1926 Makefile
1927 libgcj.pc
1928 libgcj.spec
1929 libgcj-test.spec
1930 gcj/Makefile
1931 include/Makefile
1932 testsuite/Makefile
1933 contrib/aotcompile.py
1934 contrib/aot-compile
1935 contrib/aot-compile-rpm
1936 contrib/generate-cacerts.pl
1937 contrib/rebuild-gcj-db
1938 ])
1939
1940 if test ${multilib} = yes; then
1941   multilib_arg="--enable-multilib"
1942 else
1943   multilib_arg=
1944 fi
1945
1946 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1947 AC_OUTPUT