libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 # We would like our source tree to be readonly. However when releases or
  19 # pre-releases are generated, the flex/bison generated files as well as the
  20 # various formats of manuals need to be included along with the rest of the
  21 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  22 # just that.
  23 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  24 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  25    [put copies of generated files in source dir intended for creating source
  26     tarballs for users without texinfo bison or flex.],
  27    permit yes|no)
  28 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  29 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  30
  31
  32 # -------
  33 # -------
  34
  35 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  36 #
  37 # You will slowly go insane if you do not grok the following fact:  when
  38 # building this library, the top-level /target/ becomes the library's /host/.
  39 #
  40 # configure then causes --target to default to --host, exactly like any
  41 # other package using autoconf.  Therefore, 'target' and 'host' will
  42 # always be the same.  This makes sense both for native and cross compilers
  43 # just think about it for a little while.  :-)
  44 #
  45 # Also, if this library is being configured as part of a cross compiler, the
  46 # top-level configure script will pass the "real" host as $with_cross_host.
  47 #
  48 # Do not delete or change the following two lines.  For why, see
  49 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  50 AC_CANONICAL_SYSTEM
  51 target_alias=${target_alias-$host_alias}
  52
  53 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  54 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  55 #  1.9.0:  minimum required version
  56 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  57 #              of other PACKAGE_* variables will, however, and there's nothing
  58 #              we can do about that; they come from AC_INIT).
  59 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  60 #            file in the top srcdir, etc, etc), so stop complaining.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 # Calculate toolexeclibdir
  68 # Also toolexecdir, though it's only used in toolexeclibdir
  69 case ${enable_version_specific_runtime_libs} in
  70   yes)
  71     # Need the gcc compiler version to know where to install libraries
  72     # and header files if --enable-version-specific-runtime-libs option
  73     # is selected.
  74     toolexecdir='$(libdir)/gcc/$(target_alias)'
  75     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  76     ;;
  77   no)
  78     if test -n "$with_cross_host" &&
  79        test x"$with_cross_host" != x"no"; then
  80       # Install a library built with a cross compiler in tooldir, not libdir.
  81       toolexecdir='$(exec_prefix)/$(target_alias)'
  82       toolexeclibdir='$(toolexecdir)/lib'
  83     else
  84       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  85       toolexeclibdir='$(libdir)'
  86     fi
  87     multi_os_directory=`$CC -print-multi-os-directory`
  88     case $multi_os_directory in
  89       .) ;; # Avoid trailing /.
  90       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  91     esac
  92     ;;
  93 esac
  94 AC_SUBST(toolexecdir)
  95 AC_SUBST(toolexeclibdir)
  96
  97 # Check the compiler.
  98 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  99 # We must force CC to /not/ be precious variables; otherwise
 100 # the wrong, non-multilib-adjusted value will be used in multilibs.
 101 # As a side effect, we have to subst CFLAGS ourselves.
 102
 103 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 104 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 105 AC_PROG_CC
 106 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107
 108 AC_SUBST(CFLAGS)
 109
 110 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 111 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 112 # in both places for now and restore CFLAGS at the end of config.
 113 save_CFLAGS="$CFLAGS"
 114
 115 # Add -Wall -Werror if we are using GCC.
 116 if test "x$GCC" = "xyes"; then
 117   XCFLAGS="$XCFLAGS -Wall -Werror"
 118 fi
 119
 120 # Find other programs we need.
 121 AC_CHECK_TOOL(AR, ar)
 122 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 123 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 124 AC_PROG_MAKE_SET
 125 AC_PROG_INSTALL
 126
 127 # See if makeinfo has been installed and is modern enough
 128 # that we can use it.
 129 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 130                    [GNU texinfo.* \([0-9][0-9.]*\)],
 131                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 132 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 133
 134
 135 # Configure libtool
 136 AM_PROG_LIBTOOL
 137 AC_SUBST(enable_shared)
 138 AC_SUBST(enable_static)
 139
 140 AM_MAINTAINER_MODE
 141
 142 # We need gfortran to compile parts of the library
 143 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 144 #AC_PROG_FC(gfortran)
 145 case `echo $GFORTRAN` in
 146   -* | no* )
 147     FC=no ;;
 148   *)
 149     set dummy $GFORTRAN; ac_word=$2
 150     if test -x "$ac_word"; then
 151       FC="$GFORTRAN"
 152     else
 153       FC=no
 154     fi ;;
 155 esac
 156 AC_PROG_FC(gfortran)
 157 FCFLAGS="$FCFLAGS -Wall"
 158
 159 # For libtool versioning info, format is CURRENT:REVISION:AGE
 160 libtool_VERSION=1:0:0
 161 AC_SUBST(libtool_VERSION)
 162
 163 # Check header files.
 164 AC_STDC_HEADERS
 165 AC_HEADER_TIME
 166 ACX_HEADER_STRING
 167 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h sys/time.h)
 168
 169 GCC_HEADER_STDINT(gstdint.h)
 170
 171 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 172 # In case the pthread.h system header is not found, this test will fail.
 173 XPCFLAGS=""
 174 CFLAGS="$CFLAGS -pthread"
 175 AC_LINK_IFELSE(
 176  [AC_LANG_PROGRAM(
 177   [#include <pthread.h>
 178    void *g(void *d) { return NULL; }],
 179   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 180  [XPCFLAGS=" -Wc,-pthread"],
 181  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 182   AC_LINK_IFELSE(
 183    [AC_LANG_PROGRAM(
 184     [#include <pthread.h>
 185      void *g(void *d) { return NULL; }],
 186     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 187    [],
 188    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 189
 190 # Check for functions needed.
 191 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 192
 193 # Check for broken semaphore implementation on darwin.
 194 # sem_init returns: sem_init error: Function not implemented.
 195 case "$host" in
 196   *-darwin*)
 197     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 198         Define if the POSIX Semaphores do not work on your system.)
 199     ;;
 200 esac
 201
 202 GCC_LINUX_FUTEX(:)
 203
 204 # Check for pthread_{,attr_}[sg]etaffinity_np.
 205 AC_LINK_IFELSE(
 206  [AC_LANG_PROGRAM(
 207   [#define _GNU_SOURCE
 208    #include <pthread.h>],
 209   [cpu_set_t cpuset;
 210    pthread_attr_t attr;
 211    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 212    if (CPU_ISSET (0, &cpuset))
 213      CPU_SET (1, &cpuset);
 214    else
 215      CPU_ZERO (&cpuset);
 216    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 217    pthread_attr_init (&attr);
 218    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 219    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 220   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 221 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 222
 223 # At least for glibc, clock_gettime is in librt.  But don't pull that
 224 # in if it still doesn't give us the function we want.
 225 if test $ac_cv_func_clock_gettime = no; then
 226   AC_CHECK_LIB(rt, clock_gettime,
 227     [LIBS="-lrt $LIBS"
 228      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 229                [Define to 1 if you have the `clock_gettime' function.])])
 230 fi
 231
 232 # See if we support thread-local storage.
 233 GCC_CHECK_TLS
 234
 235 # See what sort of export controls are availible.
 236 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 237 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 238 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 239 LIBGOMP_ENABLE_SYMVERS
 240
 241 if test $enable_symvers = gnu; then
 242   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 243             [Define to 1 if GNU symbol versioning is used for libgomp.])
 244 fi
 245
 246 # Get target configury.
 247 . ${srcdir}/configure.tgt
 248 CFLAGS="$save_CFLAGS $XCFLAGS"
 249
 250 # Check for __sync_val_compare_and_swap, but only after the target has
 251 # had a chance to set XCFLAGS.
 252 LIBGOMP_CHECK_SYNC_BUILTINS
 253
 254 XCFLAGS="$XCFLAGS$XPCFLAGS"
 255
 256 AC_SUBST(config_path)
 257 AC_SUBST(XCFLAGS)
 258 AC_SUBST(XLDFLAGS)
 259
 260 # Cleanup and exit.
 261 CFLAGS="$save_CFLAGS"
 262 AC_CACHE_SAVE
 263
 264 if test ${multilib} = yes; then
 265   multilib_arg="--enable-multilib"
 266 else
 267   multilib_arg=
 268 fi
 269
 270 # Set up the set of libraries that we need to link against for libgomp.
 271 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 272 # which will force linkage against -lpthread (or equivalent for the system).
 273 # That's not 100% ideal, but about the best we can do easily.
 274 if test $enable_shared = yes; then
 275   link_gomp="-lgomp %{static: $LIBS}"
 276 else
 277   link_gomp="-lgomp $LIBS"
 278 fi
 279 AC_SUBST(link_gomp)
 280
 281 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 282
 283 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 284 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 285 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 286 # need to copy this macro to our acinclude.m4.
 287 save_CFLAGS="$CFLAGS"
 288 for i in $config_path; do
 289   if test -f $srcdir/config/$i/omp-lock.h; then
 290     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 291     break
 292   fi
 293 done
 294
 295 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 296   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 297 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 298 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 299 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 300 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 301   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 302 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 303 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 304 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 305
 306 # If the lock fits in an integer, then arrange for Fortran to use that
 307 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 308 # Except that we don't have a way at present to multi-lib the installed
 309 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 310 # actual target.
 311 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 312 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 313 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 314   OMP_LOCK_KIND=8
 315 fi
 316 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 317   OMP_NEST_LOCK_KIND=8
 318 fi
 319 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 320 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 321 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 322   OMP_LOCK_25_KIND=8
 323 fi
 324 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 325   OMP_NEST_LOCK_25_KIND=8
 326 fi
 327
 328 AC_SUBST(OMP_LOCK_SIZE)
 329 AC_SUBST(OMP_LOCK_ALIGN)
 330 AC_SUBST(OMP_NEST_LOCK_SIZE)
 331 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 332 AC_SUBST(OMP_LOCK_KIND)
 333 AC_SUBST(OMP_NEST_LOCK_KIND)
 334 AC_SUBST(OMP_LOCK_25_SIZE)
 335 AC_SUBST(OMP_LOCK_25_ALIGN)
 336 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 337 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 338 AC_SUBST(OMP_LOCK_25_KIND)
 339 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 340 CFLAGS="$save_CFLAGS"
 341
 342 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 343 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 344 AC_OUTPUT