libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 # We would like our source tree to be readonly. However when releases or
  19 # pre-releases are generated, the flex/bison generated files as well as the
  20 # various formats of manuals need to be included along with the rest of the
  21 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  22 # just that.
  23 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  24 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  25    [put copies of generated files in source dir intended for creating source
  26     tarballs for users without texinfo bison or flex.],
  27    permit yes|no)
  28 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  29 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  30
  31
  32 # -------
  33 # -------
  34
  35 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  36 #
  37 # You will slowly go insane if you do not grok the following fact:  when
  38 # building this library, the top-level /target/ becomes the library's /host/.
  39 #
  40 # configure then causes --target to default to --host, exactly like any
  41 # other package using autoconf.  Therefore, 'target' and 'host' will
  42 # always be the same.  This makes sense both for native and cross compilers
  43 # just think about it for a little while.  :-)
  44 #
  45 # Also, if this library is being configured as part of a cross compiler, the
  46 # top-level configure script will pass the "real" host as $with_cross_host.
  47 #
  48 # Do not delete or change the following two lines.  For why, see
  49 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  50 AC_CANONICAL_SYSTEM
  51 target_alias=${target_alias-$host_alias}
  52
  53 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  54 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  55 #  1.9.0:  minimum required version
  56 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  57 #              of other PACKAGE_* variables will, however, and there's nothing
  58 #              we can do about that; they come from AC_INIT).
  59 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  60 #            file in the top srcdir, etc, etc), so stop complaining.
  61 #  no-dist:  we don't want 'dist' and related rules.
  62 #  -Wall:  turns on all automake warnings...
  63 #  -Wno-portability:  ...except this one, since GNU make is required.
  64 #  -Wno-override: ... and this one, since we do want this in testsuite.
  65 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  66 AM_ENABLE_MULTILIB(, ..)
  67
  68 # Calculate toolexeclibdir
  69 # Also toolexecdir, though it's only used in toolexeclibdir
  70 case ${enable_version_specific_runtime_libs} in
  71   yes)
  72     # Need the gcc compiler version to know where to install libraries
  73     # and header files if --enable-version-specific-runtime-libs option
  74     # is selected.
  75     toolexecdir='$(libdir)/gcc/$(target_alias)'
  76     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  77     ;;
  78   no)
  79     if test -n "$with_cross_host" &&
  80        test x"$with_cross_host" != x"no"; then
  81       # Install a library built with a cross compiler in tooldir, not libdir.
  82       toolexecdir='$(exec_prefix)/$(target_alias)'
  83       toolexeclibdir='$(toolexecdir)/lib'
  84     else
  85       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  86       toolexeclibdir='$(libdir)'
  87     fi
  88     multi_os_directory=`$CC -print-multi-os-directory`
  89     case $multi_os_directory in
  90       .) ;; # Avoid trailing /.
  91       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  92     esac
  93     ;;
  94 esac
  95 AC_SUBST(toolexecdir)
  96 AC_SUBST(toolexeclibdir)
  97
  98 # Check the compiler.
  99 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 100 # We must force CC to /not/ be precious variables; otherwise
 101 # the wrong, non-multilib-adjusted value will be used in multilibs.
 102 # As a side effect, we have to subst CFLAGS ourselves.
 103
 104 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 105 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 106 AC_PROG_CC
 107 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108
 109 AC_SUBST(CFLAGS)
 110
 111 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 112 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 113 # in both places for now and restore CFLAGS at the end of config.
 114 save_CFLAGS="$CFLAGS"
 115
 116 # Add -Wall -Werror if we are using GCC.
 117 if test "x$GCC" = "xyes"; then
 118   XCFLAGS="$XCFLAGS -Wall -Werror"
 119 fi
 120
 121 # Find other programs we need.
 122 AC_CHECK_TOOL(AR, ar)
 123 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 124 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 125 AC_PROG_MAKE_SET
 126 AC_PROG_INSTALL
 127
 128 # See if makeinfo has been installed and is modern enough
 129 # that we can use it.
 130 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 131                    [GNU texinfo.* \([0-9][0-9.]*\)],
 132                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 133 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 134
 135
 136 # Configure libtool
 137 AM_PROG_LIBTOOL
 138 ACX_LT_HOST_FLAGS
 139 AC_SUBST(enable_shared)
 140 AC_SUBST(enable_static)
 141
 142 AM_MAINTAINER_MODE
 143
 144 # Create a spec file, so that compile/link tests don't fail
 145 test -f libgfortran.spec || touch libgfortran.spec
 146 FCFLAGS="$FCFLAGS -L."
 147
 148 # We need gfortran to compile parts of the library
 149 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 150 #AC_PROG_FC(gfortran)
 151 case `echo $GFORTRAN` in
 152   -* | no* )
 153     FC=no ;;
 154   *)
 155     set dummy $GFORTRAN; ac_word=$2
 156     if test -x "$ac_word"; then
 157       FC="$GFORTRAN"
 158     else
 159       FC=no
 160     fi ;;
 161 esac
 162 AC_PROG_FC(gfortran)
 163 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 164
 165 # For libtool versioning info, format is CURRENT:REVISION:AGE
 166 libtool_VERSION=1:0:0
 167 AC_SUBST(libtool_VERSION)
 168
 169 # Check header files.
 170 AC_STDC_HEADERS
 171 AC_HEADER_TIME
 172 ACX_HEADER_STRING
 173 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 174
 175 GCC_HEADER_STDINT(gstdint.h)
 176
 177 XPCFLAGS=""
 178 case "$host" in
 179   *-*-rtems*)
 180     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 181     ;;
 182   nvptx*-*-*)
 183     # NVPTX does not support Pthreads, has its own code replacement.
 184     ;;
 185   *)
 186     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 187     # In case the pthread.h system header is not found, this test will fail.
 188     CFLAGS="$CFLAGS -pthread"
 189     AC_LINK_IFELSE(
 190      [AC_LANG_PROGRAM(
 191       [#include <pthread.h>
 192        void *g(void *d) { return NULL; }],
 193       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 194      [XPCFLAGS=" -Wc,-pthread"],
 195      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 196       AC_LINK_IFELSE(
 197        [AC_LANG_PROGRAM(
 198         [#include <pthread.h>
 199          void *g(void *d) { return NULL; }],
 200         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 201        [],
 202        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 203 esac
 204
 205 m4_include([plugin/configfrag.ac])
 206
 207 # Check for functions needed.
 208 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 209
 210 # Check for broken semaphore implementation on darwin.
 211 # sem_init returns: sem_init error: Function not implemented.
 212 case "$host" in
 213   *-darwin*)
 214     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 215         Define if the POSIX Semaphores do not work on your system.)
 216     ;;
 217 esac
 218
 219 # RTEMS specific checks
 220 case "$host" in
 221   *-*-rtems*)
 222     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 223     ;;
 224 esac
 225
 226 GCC_LINUX_FUTEX(:)
 227
 228 # Check for pthread_{,attr_}[sg]etaffinity_np.
 229 AC_LINK_IFELSE(
 230  [AC_LANG_PROGRAM(
 231   [#define _GNU_SOURCE
 232    #include <pthread.h>],
 233   [cpu_set_t cpuset;
 234    pthread_attr_t attr;
 235    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 236    if (CPU_ISSET (0, &cpuset))
 237      CPU_SET (1, &cpuset);
 238    else
 239      CPU_ZERO (&cpuset);
 240    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 241    pthread_attr_init (&attr);
 242    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 243    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 244   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 245 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 246
 247 # At least for glibc, clock_gettime is in librt.  But don't pull that
 248 # in if it still doesn't give us the function we want.
 249 if test $ac_cv_func_clock_gettime = no; then
 250   AC_CHECK_LIB(rt, clock_gettime,
 251     [LIBS="-lrt $LIBS"
 252      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 253                [Define to 1 if you have the `clock_gettime' function.])])
 254 fi
 255
 256 # See if we support thread-local storage.
 257 GCC_CHECK_TLS
 258
 259 # See if we have emulated thread-local storage.
 260 GCC_CHECK_EMUTLS
 261
 262 # See what sort of export controls are available.
 263 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 264 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 265 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 266 LIBGOMP_ENABLE_SYMVERS
 267
 268 if test $enable_symvers = gnu; then
 269   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 270             [Define to 1 if GNU symbol versioning is used for libgomp.])
 271 fi
 272
 273 # Get target configury.
 274 . ${srcdir}/configure.tgt
 275 CFLAGS="$save_CFLAGS $XCFLAGS"
 276
 277 # Check for __sync_val_compare_and_swap, but only after the target has
 278 # had a chance to set XCFLAGS.
 279 LIBGOMP_CHECK_SYNC_BUILTINS
 280
 281 XCFLAGS="$XCFLAGS$XPCFLAGS"
 282
 283 AC_SUBST(config_path)
 284 AC_SUBST(XCFLAGS)
 285 AC_SUBST(XLDFLAGS)
 286
 287 # Cleanup and exit.
 288 CFLAGS="$save_CFLAGS"
 289 AC_CACHE_SAVE
 290
 291 if test ${multilib} = yes; then
 292   multilib_arg="--enable-multilib"
 293 else
 294   multilib_arg=
 295 fi
 296
 297 # Set up the set of libraries that we need to link against for libgomp.
 298 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 299 # which will force linkage against -lpthread (or equivalent for the system).
 300 # That's not 100% ideal, but about the best we can do easily.
 301 if test $enable_shared = yes; then
 302   link_gomp="-lgomp %{static: $LIBS}"
 303 else
 304   link_gomp="-lgomp $LIBS"
 305 fi
 306 AC_SUBST(link_gomp)
 307
 308 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 309
 310 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 311 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 312 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 313 # need to copy this macro to our acinclude.m4.
 314 save_CFLAGS="$CFLAGS"
 315 for i in $config_path; do
 316   if test -f $srcdir/config/$i/omp-lock.h; then
 317     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 318     break
 319   fi
 320 done
 321
 322 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 323   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 324 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 325 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 326 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 327 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 328   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 329 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 330 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 331 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 332
 333 # If the lock fits in an integer, then arrange for Fortran to use that
 334 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 335 # Except that we don't have a way at present to multi-lib the installed
 336 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 337 # actual target.
 338 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 339 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 340 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 341   OMP_LOCK_KIND=8
 342 fi
 343 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 344   OMP_NEST_LOCK_KIND=8
 345 fi
 346 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 347 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 348 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 349   OMP_LOCK_25_KIND=8
 350 fi
 351 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 352   OMP_NEST_LOCK_25_KIND=8
 353 fi
 354
 355 AC_SUBST(OMP_LOCK_SIZE)
 356 AC_SUBST(OMP_LOCK_ALIGN)
 357 AC_SUBST(OMP_NEST_LOCK_SIZE)
 358 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 359 AC_SUBST(OMP_LOCK_KIND)
 360 AC_SUBST(OMP_NEST_LOCK_KIND)
 361 AC_SUBST(OMP_LOCK_25_SIZE)
 362 AC_SUBST(OMP_LOCK_25_ALIGN)
 363 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 364 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 365 AC_SUBST(OMP_LOCK_25_KIND)
 366 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 367 CFLAGS="$save_CFLAGS"
 368
 369 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 370 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 371 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 372 AC_OUTPUT