gcc/ada/mlib-tgt-irix.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             M L I B . T G T                              --
   6 --                              (IRIX Version)                              --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --           Copyright (C) 2003-2004, Ada Core Technologies, Inc.           --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 --  This package provides a set of target dependent routines to build
  29 --  static, dynamic and shared libraries.
  30
  31 --  This is the IRIX version of the body.
  32
  33 with MLib.Fil;
  34 with MLib.Utl;
  35 with Namet;  use Namet;
  36 with Opt;
  37 with Output; use Output;
  38 with Prj.Com;
  39 with System;
  40
  41 package body MLib.Tgt is
  42
  43    No_Arguments        : aliased Argument_List         := (1 .. 0 => null);
  44    Empty_Argument_List : constant Argument_List_Access := No_Arguments'Access;
  45
  46    Wl_Init_String : aliased String         := "-Wl,-init";
  47    Wl_Init        : constant String_Access := Wl_Init_String'Access;
  48    Wl_Fini_String : aliased String         := "-Wl,-fini";
  49    Wl_Fini        : constant String_Access := Wl_Fini_String'Access;
  50
  51    Init_Fini_List :  constant Argument_List_Access :=
  52                        new Argument_List'(1 => Wl_Init,
  53                                           2 => null,
  54                                           3 => Wl_Fini,
  55                                           4 => null);
  56    --  Used to put switches for automatic elaboration/finalization
  57
  58    ---------------------
  59    -- Archive_Builder --
  60    ---------------------
  61
  62    function Archive_Builder return String is
  63    begin
  64       return "ar";
  65    end Archive_Builder;
  66
  67    -----------------------------
  68    -- Archive_Builder_Options --
  69    -----------------------------
  70
  71    function Archive_Builder_Options return String_List_Access is
  72    begin
  73       return new String_List'(1 => new String'("cr"));
  74    end Archive_Builder_Options;
  75
  76    -----------------
  77    -- Archive_Ext --
  78    -----------------
  79
  80    function Archive_Ext return String is
  81    begin
  82       return "a";
  83    end Archive_Ext;
  84
  85    ---------------------
  86    -- Archive_Indexer --
  87    ---------------------
  88
  89    function Archive_Indexer return String is
  90    begin
  91       return "ranlib";
  92    end Archive_Indexer;
  93
  94    ---------------------------
  95    -- Build_Dynamic_Library --
  96    ---------------------------
  97
  98    procedure Build_Dynamic_Library
  99      (Ofiles       : Argument_List;
 100       Foreign      : Argument_List;
 101       Afiles       : Argument_List;
 102       Options      : Argument_List;
 103       Options_2    : Argument_List;
 104       Interfaces   : Argument_List;
 105       Lib_Filename : String;
 106       Lib_Dir      : String;
 107       Symbol_Data  : Symbol_Record;
 108       Driver_Name  : Name_Id := No_Name;
 109       Lib_Version  : String  := "";
 110       Auto_Init    : Boolean := False)
 111    is
 112       pragma Unreferenced (Foreign);
 113       pragma Unreferenced (Afiles);
 114       pragma Unreferenced (Interfaces);
 115       pragma Unreferenced (Symbol_Data);
 116
 117       Lib_File : constant String :=
 118                    Lib_Dir & Directory_Separator & "lib" &
 119                    MLib.Fil.Ext_To (Lib_Filename, DLL_Ext);
 120
 121       Version_Arg          : String_Access;
 122       Symbolic_Link_Needed : Boolean := False;
 123
 124       Init_Fini : Argument_List_Access := Empty_Argument_List;
 125
 126       N_Options    : Argument_List := Options;
 127       Options_Last : Natural := N_Options'Last;
 128       --  After moving -lxxx to Options_2, N_Options up to index Options_Last
 129       --  will contain the Options to pass to MLib.Utl.Gcc.
 130
 131       Real_Options_2 : Argument_List (1 .. Options'Length + Options_2'Length);
 132       Real_Options_2_Last : Natural := 0;
 133       --  Real_Options_2 up to index Real_Options_2_Last will contain the
 134       --  Options_2 to pass to MLib.Utl.Gcc.
 135
 136    begin
 137       if Opt.Verbose_Mode then
 138          Write_Str ("building relocatable shared library ");
 139          Write_Line (Lib_File);
 140       end if;
 141
 142       --  If specified, add automatic elaboration/finalization
 143
 144       if Auto_Init then
 145          Init_Fini := Init_Fini_List;
 146          Init_Fini (2) := new String'("-Wl," & Lib_Filename & "init");
 147          Init_Fini (4) := new String'("-Wl," & Lib_Filename & "final");
 148       end if;
 149
 150       --  Move all -lxxx to Options_2
 151
 152       declare
 153          Index : Natural := N_Options'First;
 154          Arg   : String_Access;
 155
 156       begin
 157          while Index <= Options_Last loop
 158             Arg := N_Options (Index);
 159
 160             if Arg'Length > 2
 161               and then Arg (Arg'First .. Arg'First + 1) = "-l"
 162             then
 163                Real_Options_2_Last := Real_Options_2_Last + 1;
 164                Real_Options_2 (Real_Options_2_Last) := Arg;
 165                N_Options (Index .. Options_Last - 1) :=
 166                  N_Options (Index + 1 .. Options_Last);
 167                Options_Last := Options_Last - 1;
 168
 169             else
 170                Index := Index + 1;
 171             end if;
 172          end loop;
 173       end;
 174
 175       --  Add to Real_Options_2 the argument Options_2
 176
 177       Real_Options_2
 178         (Real_Options_2_Last + 1 .. Real_Options_2_Last + Options_2'Length) :=
 179         Options_2;
 180       Real_Options_2_Last := Real_Options_2_Last + Options_2'Length;
 181
 182       if Lib_Version = "" then
 183          MLib.Utl.Gcc
 184            (Output_File => Lib_File,
 185             Objects     => Ofiles,
 186             Options     => N_Options (N_Options'First .. Options_Last) &
 187                            Init_Fini.all,
 188             Driver_Name => Driver_Name,
 189             Options_2   => Real_Options_2 (1 .. Real_Options_2_Last));
 190
 191       else
 192          Version_Arg := new String'("-Wl,-soname," & Lib_Version);
 193
 194          if Is_Absolute_Path (Lib_Version) then
 195             MLib.Utl.Gcc
 196               (Output_File => Lib_Version,
 197                Objects     => Ofiles,
 198                Options     => N_Options (N_Options'First .. Options_Last) &
 199                               Version_Arg & Init_Fini.all,
 200                Driver_Name => Driver_Name,
 201                Options_2   => Real_Options_2 (1 .. Real_Options_2_Last));
 202             Symbolic_Link_Needed := Lib_Version /= Lib_File;
 203
 204          else
 205             MLib.Utl.Gcc
 206               (Output_File => Lib_Dir & Directory_Separator & Lib_Version,
 207                Objects     => Ofiles,
 208                Options     => N_Options (N_Options'First .. Options_Last) &
 209                               Version_Arg & Init_Fini.all,
 210                Driver_Name => Driver_Name,
 211                Options_2   => Real_Options_2 (1 .. Real_Options_2_Last));
 212             Symbolic_Link_Needed :=
 213               Lib_Dir & Directory_Separator & Lib_Version /= Lib_File;
 214          end if;
 215
 216          if Symbolic_Link_Needed then
 217             declare
 218                Success : Boolean;
 219                Oldpath : String (1 .. Lib_Version'Length + 1);
 220                Newpath : String (1 .. Lib_File'Length + 1);
 221
 222                Result : Integer;
 223                pragma Unreferenced (Result);
 224
 225                function Symlink
 226                  (Oldpath : System.Address;
 227                   Newpath : System.Address)
 228                   return    Integer;
 229                pragma Import (C, Symlink, "__gnat_symlink");
 230
 231             begin
 232                Oldpath (1 .. Lib_Version'Length) := Lib_Version;
 233                Oldpath (Oldpath'Last)            := ASCII.NUL;
 234                Newpath (1 .. Lib_File'Length)    := Lib_File;
 235                Newpath (Newpath'Last)            := ASCII.NUL;
 236
 237                Delete_File (Lib_File, Success);
 238
 239                Result := Symlink (Oldpath'Address, Newpath'Address);
 240             end;
 241          end if;
 242       end if;
 243    end Build_Dynamic_Library;
 244
 245    -------------
 246    -- DLL_Ext --
 247    -------------
 248
 249    function DLL_Ext return String is
 250    begin
 251       return "so";
 252    end DLL_Ext;
 253
 254    --------------------
 255    -- Dynamic_Option --
 256    --------------------
 257
 258    function Dynamic_Option return String is
 259    begin
 260       return "-shared";
 261    end Dynamic_Option;
 262
 263    -------------------
 264    -- Is_Object_Ext --
 265    -------------------
 266
 267    function Is_Object_Ext (Ext : String) return Boolean is
 268    begin
 269       return Ext = ".o";
 270    end Is_Object_Ext;
 271
 272    --------------
 273    -- Is_C_Ext --
 274    --------------
 275
 276    function Is_C_Ext (Ext : String) return Boolean is
 277    begin
 278       return Ext = ".c";
 279    end Is_C_Ext;
 280
 281    --------------------
 282    -- Is_Archive_Ext --
 283    --------------------
 284
 285    function Is_Archive_Ext (Ext : String) return Boolean is
 286    begin
 287       return Ext = ".a" or else Ext = ".so";
 288    end Is_Archive_Ext;
 289
 290    -------------
 291    -- Libgnat --
 292    -------------
 293
 294    function Libgnat return String is
 295    begin
 296       return "libgnat.a";
 297    end Libgnat;
 298
 299    ------------------------
 300    -- Library_Exists_For --
 301    ------------------------
 302
 303    function Library_Exists_For (Project : Project_Id) return Boolean is
 304    begin
 305       if not Projects.Table (Project).Library then
 306          Prj.Com.Fail ("INTERNAL ERROR: Library_Exists_For called " &
 307                        "for non library project");
 308          return False;
 309
 310       else
 311          declare
 312             Lib_Dir : constant String :=
 313               Get_Name_String (Projects.Table (Project).Library_Dir);
 314             Lib_Name : constant String :=
 315               Get_Name_String (Projects.Table (Project).Library_Name);
 316
 317          begin
 318             if Projects.Table (Project).Library_Kind = Static then
 319                return Is_Regular_File
 320                  (Lib_Dir & Directory_Separator & "lib" &
 321                   Fil.Ext_To (Lib_Name, Archive_Ext));
 322
 323             else
 324                return Is_Regular_File
 325                  (Lib_Dir & Directory_Separator & "lib" &
 326                   Fil.Ext_To (Lib_Name, DLL_Ext));
 327             end if;
 328          end;
 329       end if;
 330    end Library_Exists_For;
 331
 332    ---------------------------
 333    -- Library_File_Name_For --
 334    ---------------------------
 335
 336    function Library_File_Name_For (Project : Project_Id) return Name_Id is
 337    begin
 338       if not Projects.Table (Project).Library then
 339          Prj.Com.Fail ("INTERNAL ERROR: Library_File_Name_For called " &
 340                        "for non library project");
 341          return No_Name;
 342
 343       else
 344          declare
 345             Lib_Name : constant String :=
 346               Get_Name_String (Projects.Table (Project).Library_Name);
 347
 348          begin
 349             Name_Len := 3;
 350             Name_Buffer (1 .. Name_Len) := "lib";
 351
 352             if Projects.Table (Project).Library_Kind = Static then
 353                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, Archive_Ext));
 354
 355             else
 356                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, DLL_Ext));
 357             end if;
 358
 359             return Name_Find;
 360          end;
 361       end if;
 362    end Library_File_Name_For;
 363
 364    ----------------
 365    -- Object_Ext --
 366    ----------------
 367
 368    function Object_Ext return String is
 369    begin
 370       return "o";
 371    end Object_Ext;
 372
 373    ----------------
 374    -- PIC_Option --
 375    ----------------
 376
 377    function PIC_Option return String is
 378    begin
 379       return "-fPIC";
 380    end PIC_Option;
 381
 382    -----------------------------------------------
 383    -- Standalone_Library_Auto_Init_Is_Supported --
 384    -----------------------------------------------
 385
 386    function Standalone_Library_Auto_Init_Is_Supported return Boolean is
 387    begin
 388       return True;
 389    end Standalone_Library_Auto_Init_Is_Supported;
 390
 391    ---------------------------
 392    -- Support_For_Libraries --
 393    ---------------------------
 394
 395    function Support_For_Libraries return Library_Support is
 396    begin
 397       return Full;
 398    end Support_For_Libraries;
 399
 400 end MLib.Tgt;