gcc/ada/sinput.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               S I N P U T                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2002 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package contains the input routines used for reading the
  35 --  input source file. The actual I/O routines are in OS_Interface,
  36 --  with this module containing only the system independent processing.
  37
  38 --  General Note: throughout the compiler, we use the term line or source
  39 --  line to refer to a physical line in the source, terminated by the end of
  40 --  physical line sequence. See Skip_Line_Terminators procedure for a full
  41 --  description of the difference between logical and physical lines.
  42
  43 with Alloc;
  44 with Casing; use Casing;
  45 with Table;
  46 with Types;  use Types;
  47
  48 package Sinput is
  49
  50    ----------------------------
  51    -- Source License Control --
  52    ----------------------------
  53
  54    --  The following type indicates the license state of a source if it
  55    --  is known.
  56
  57    type License_Type is
  58      (Unknown,
  59       --  Licensing status of this source unit is unknown
  60
  61       Restricted,
  62       --  This is a non-GPL'ed unit that is restricted from depending
  63       --  on GPL'ed units (e.g. proprietary code is in this category)
  64
  65       GPL,
  66       --  This file is licensed under the unmodified GPL. It is not allowed
  67       --  to depend on Non_GPL units, and Non_GPL units may not depend on
  68       --  this source unit.
  69
  70       Modified_GPL,
  71       --  This file is licensed under the GNAT modified GPL (see header of
  72       --  This file for wording of the modification). It may depend on other
  73       --  Modified_GPL units or on unrestricted units.
  74
  75       Unrestricted);
  76       --  The license on this file is permitted to depend on any other
  77       --  units, or have other units depend on it, without violating the
  78       --  license of this unit. Examples are public domain units, and
  79       --  units defined in the RM).
  80
  81    --  The above license status is checked when the appropriate check is
  82    --  activated and one source depends on another, and the licensing state
  83    --  of both files is known:
  84
  85    --  The prohibited combinations are:
  86
  87    --    Restricted file may not depend on GPL file
  88
  89    --    GPL file may not depend on Restricted file
  90
  91    --    Modified GPL file may not depend on Restricted file
  92    --    Modified_GPL file may not depend on GPL file
  93
  94    --  The reason for the last restriction here is that a client depending
  95    --  on a modified GPL file must be sure that the license condition is
  96    --  correct considered transitively.
  97
  98    --  The licensing status is determined either by the presence of a
  99    --  specific pragma License, or by scanning the header for a predefined
 100    --  file, or any file if compiling in -gnatg mode.
 101
 102    -----------------------
 103    -- Source File Table --
 104    -----------------------
 105
 106    --  The source file table has an entry for each source file read in for
 107    --  this run of the compiler. This table is (default) initialized when
 108    --  the compiler is loaded, and simply accumulates entries as compilation
 109    --  proceeds and the Sinput.L.Load_Source_File procedure is called to load
 110    --  required source files.
 111
 112    --  Virtual entries are also created for generic templates when they are
 113    --  instantiated, as described in a separate section later on.
 114
 115    --  In the case where there are multiple main units (e.g. in the case of
 116    --  the cross-reference tool), this table is not reset between these units,
 117    --  so that a given source file is only read once if it is used by two
 118    --  separate main units.
 119
 120    --  The entries in the table are accessed using a Source_File_Index that
 121    --  ranges from 1 to Last_Source_File. Each entry has the following fields
 122
 123    --  Note that entry 1 is always for system.ads (see Targparm for details
 124    --  of why we always read this source file first), and we have defined a
 125    --  constant Types.System_Source_File_Index as 1 to reflect this fact.
 126
 127    --  File_Name : File_Name_Type
 128    --    Name of the source file (simple name with no directory information).
 129    --    Set by Sinput.L.Load_Source_File and cannot be subequently changed.
 130
 131    --  Full_File_Name : File_Name_Type
 132    --    Full file name (full name with directory info), used for generation
 133    --    of error messages, etc. Set by Sinput.L.Load_Source_File and cannot
 134    --    be subsequently changed.
 135
 136    --  Reference_Name : File_Name_Type
 137    --    Name to be used for source file references in error messages where
 138    --    only the simple name of the file is required. Identical to File_Name
 139    --    unless pragma Source_Reference is used to change it. Only processing
 140    --    for the Source_Reference pragma circuit may set this field.
 141
 142    --  Full_Ref_Name : File_Name_Type
 143    --    Name to be used for source file references in error messages where
 144    --    the full name of the file is required. Identical to Full_File_Name
 145    --    unless pragma Source_Reference is used to change it. Only processing
 146    --    for the Source_Reference pragma may set this field.
 147
 148    --  Debug_Source_Name : File_Name_Type
 149    --    Name to be used for source file references in debugging information
 150    --    where only the simple name of the file is required. Identical to
 151    --    Full_Ref_Name unless the -gnatD (debug source file) switch is used.
 152    --    Only processing in Sprint that generates this file is permitted to
 153    --    set this field.
 154
 155    --  License : License_Type;
 156    --    License status of source file
 157
 158    --  Num_SRef_Pragmas : Nat;
 159    --    Number of source reference pragmas present in source file
 160
 161    --  First_Mapped_Line : Logical_Line_Number;
 162    --    This field stores logical line number of the first line in the
 163    --    file that is not a Source_Reference pragma. If no source reference
 164    --    pragmas are used, then the value is set to No_Line_Number.
 165
 166    --  Source_Text : Source_Buffer_Ptr
 167    --    Text of source file. Note that every source file has a distinct set
 168    --    of non-overlapping logical bounds, so it is possible to determine
 169    --    which file is referenced from a given subscript (Source_Ptr) value.
 170    --    Set by Sinput.L.Load_Source_File and cannot be subsequently changed.
 171
 172    --  Source_First : Source_Ptr;
 173    --    Subscript of first character in Source_Text. Note that this cannot
 174    --    be obtained as Source_Text'First, because we use virtual origin
 175    --    addressing. Set by Sinput.L procedures when the entry is first
 176    --    created and never subsequently changed.
 177
 178    --  Source_Last : Source_Ptr;
 179    --    Subscript of last character in Source_Text. Note that this cannot
 180    --    be obtained as Source_Text'Last, because we use virtual origin
 181    --    addressing, so this value is always Source_Ptr'Last. Set by
 182    --    Sinput.L procedures when the entry is first created and never
 183    --    subsequently changed.
 184
 185    --  Time_Stamp : Time_Stamp_Type;
 186    --    Time stamp of the source file. Set by Sinput.L.Load_Source_File,
 187    --    and cannot be subsequently changed.
 188
 189    --  Source_Checksum : Word;
 190    --    Computed checksum for contents of source file. See separate section
 191    --    later on in this spec for a description of the checksum algorithm.
 192
 193    --  Last_Source_Line : Physical_Line_Number;
 194    --    Physical line number of last source line. Whlie a file is being
 195    --    read, this refers to the last line scanned. Once a file has been
 196    --    completely scanned, it is the number of the last line in the file,
 197    --    and hence also gives the number of source lines in the file.
 198
 199    --  Keyword_Casing : Casing_Type;
 200    --    Casing style used in file for keyword casing. This is initialized
 201    --    to Unknown, and then set from the first occurrence of a keyword.
 202    --    This value is used only for formatting of error messages.
 203
 204    --  Identifier_Casing : Casing_Type;
 205    --    Casing style used in file for identifier casing. This is initialized
 206    --    to Unknown, and then set from an identifier in the program as soon as
 207    --    one is found whose casing is sufficiently clear to make a decision.
 208    --    This value is used for formatting of error messages, and also is used
 209    --    in the detection of keywords misused as identifiers.
 210
 211    --  Instantiation : Source_Ptr;
 212    --    Source file location of the instantiation if this source file entry
 213    --    represents a generic instantiation. Set to No_Location for the case
 214    --    of a normal non-instantiation entry. See section below for details.
 215    --    This field is read-only for clients.
 216
 217    --  Template : Source_File_Index;
 218    --    Source file index of the source file containing the template if this
 219    --    is a generic instantiation. Set to No_Source_File for the normal case
 220    --    of a non-instantiation entry. See Sinput-L for details. This field is
 221    --    read-only for clients.
 222
 223    --  The source file table is accessed by clients using the following
 224    --  subprogram interface:
 225
 226    subtype SFI is Source_File_Index;
 227
 228    function Debug_Source_Name (S : SFI) return File_Name_Type;
 229    function File_Name         (S : SFI) return File_Name_Type;
 230    function First_Mapped_Line (S : SFI) return Logical_Line_Number;
 231    function Full_File_Name    (S : SFI) return File_Name_Type;
 232    function Full_Ref_Name     (S : SFI) return File_Name_Type;
 233    function Identifier_Casing (S : SFI) return Casing_Type;
 234    function Instantiation     (S : SFI) return Source_Ptr;
 235    function Keyword_Casing    (S : SFI) return Casing_Type;
 236    function Last_Source_Line  (S : SFI) return Physical_Line_Number;
 237    function License           (S : SFI) return License_Type;
 238    function Num_SRef_Pragmas  (S : SFI) return Nat;
 239    function Reference_Name    (S : SFI) return File_Name_Type;
 240    function Source_Checksum   (S : SFI) return Word;
 241    function Source_First      (S : SFI) return Source_Ptr;
 242    function Source_Last       (S : SFI) return Source_Ptr;
 243    function Source_Text       (S : SFI) return Source_Buffer_Ptr;
 244    function Template          (S : SFI) return Source_File_Index;
 245    function Time_Stamp        (S : SFI) return Time_Stamp_Type;
 246
 247    procedure Set_Keyword_Casing    (S : SFI; C : Casing_Type);
 248    procedure Set_Identifier_Casing (S : SFI; C : Casing_Type);
 249    procedure Set_License           (S : SFI; L : License_Type);
 250
 251    function Last_Source_File return Source_File_Index;
 252    --  Index of last source file table entry
 253
 254    function Num_Source_Files return Nat;
 255    --  Number of source file table entries
 256
 257    procedure Initialize;
 258    --  Initialize internal tables
 259
 260    procedure Lock;
 261    --  Lock internal tables
 262
 263    Main_Source_File : Source_File_Index;
 264    --  This is set to the source file index of the main unit
 265
 266    -----------------------
 267    -- Checksum Handling --
 268    -----------------------
 269
 270    --  As a source file is scanned, a checksum is computed by taking all the
 271    --  non-blank characters in the file, excluding comment characters, the
 272    --  minus-minus sequence starting a comment, and all control characters
 273    --  except ESC.
 274
 275    --  The checksum algorithm used is the standard CRC-32 algorithm, as
 276    --  implemented by System.CRC32, except that we do not bother with the
 277    --  final XOR with all 1 bits.
 278
 279    --  This algorithm ensures that the checksum includes all semantically
 280    --  significant aspects of the program represented by the source file,
 281    --  but is insensitive to layout, presence or contents of comments, wide
 282    --  character representation method, or casing conventions outside strings.
 283
 284    --  Scans.Checksum is initialized appropriately at the start of scanning
 285    --  a file, and copied into the Source_Checksum field of the file table
 286    --  entry when the end of file is encountered.
 287
 288    -------------------------------------
 289    -- Handling Generic Instantiations --
 290    -------------------------------------
 291
 292    --  As described in Sem_Ch12, a generic instantiation involves making a
 293    --  copy of the tree of the generic template. The source locations in
 294    --  this tree directly reference the source of the template. However it
 295    --  is also possible to find the location of the instantiation.
 296
 297    --  This is achieved as follows. When an instantiation occurs, a new entry
 298    --  is made in the source file table. This entry points to the same source
 299    --  text, i.e. the file that contains the instantiation, but has a distinct
 300    --  set of Source_Ptr index values. The separate range of Sloc values avoids
 301    --  confusion, and means that the Sloc values can still be used to uniquely
 302    --  identify the source file table entry. It is possible for both entries
 303    --  to point to the same text, because of the virtual origin pointers used
 304    --  in the source table.
 305
 306    --  The Instantiation field of this source file index entry, usually set
 307    --  to No_Source_File, instead contains the Sloc of the instantiation. In
 308    --  the case of nested instantiations, this Sloc may itself refer to an
 309    --  instantiation, so the complete chain can be traced.
 310
 311    --  Two routines are used to build these special entries in the source
 312    --  file table. Create_Instantiation_Source is first called to build
 313    --  the virtual source table entry for the instantiation, and then the
 314    --  Sloc values in the copy are adjusted using Adjust_Instantiation_Sloc.
 315    --  See child unit Sinput.L for details on these two routines.
 316
 317    -----------------
 318    -- Global Data --
 319    -----------------
 320
 321    Current_Source_File : Source_File_Index;
 322    --  Source_File table index of source file currently being scanned
 323
 324    Current_Source_Unit : Unit_Number_Type;
 325    --  Unit number of source file currently being scanned. The special value
 326    --  of No_Unit indicates that the configuration pragma file is currently
 327    --  being scanned (this has no entry in the unit table).
 328
 329    Source_gnat_adc : Source_File_Index := No_Source_File;
 330    --  This is set if a gnat.adc file is present to reference this file
 331
 332    Source : Source_Buffer_Ptr;
 333    --  Current source (copy of Source_File.Table (Current_Source_Unit).Source)
 334
 335    Internal_Source : aliased Source_Buffer (1 .. 81);
 336    --  This buffer is used internally in the compiler when the lexical analyzer
 337    --  is used to scan a string from within the compiler. The procedure is to
 338    --  establish Internal_Source_Ptr as the value of Source, set the string to
 339    --  be scanned, appropriately terminated, in this buffer, and set Scan_Ptr
 340    --  to point to the start of the buffer. It is a fatal error if the scanner
 341    --  signals an error while scanning a token in this internal buffer.
 342
 343    Internal_Source_Ptr : constant Source_Buffer_Ptr :=
 344                            Internal_Source'Unrestricted_Access;
 345    --  Pointer to internal source buffer
 346
 347    -----------------
 348    -- Subprograms --
 349    -----------------
 350
 351    procedure Backup_Line (P : in out Source_Ptr);
 352    --  Back up the argument pointer to the start of the previous line. On
 353    --  entry, P points to the start of a physical line in the source buffer.
 354    --  On return, P is updated to point to the start of the previous line.
 355    --  The caller has checked that a Line_Terminator character precedes P so
 356    --  that there definitely is a previous line in the source buffer.
 357
 358    procedure Build_Location_String (Loc : Source_Ptr);
 359    --  This function builds a string literal of the form "name:line",
 360    --  where name is the file name corresponding to Loc, and line is
 361    --  the line number. In the event that instantiations are involved,
 362    --  additional suffixes of the same form are appended after the
 363    --  separating string " instantiated at ". The returned string is
 364    --  stored in Name_Buffer, terminated by ASCII.Nul, with Name_Length
 365    --  indicating the length not including the terminating Nul.
 366
 367    function Get_Column_Number (P : Source_Ptr) return Column_Number;
 368    --  The ones-origin column number of the specified Source_Ptr value is
 369    --  determined and returned. Tab characters if present are assumed to
 370    --  represent the standard 1,9,17.. spacing pattern.
 371
 372    function Get_Logical_Line_Number
 373      (P    : Source_Ptr)
 374       return Logical_Line_Number;
 375    --  The line number of the specified source position is obtained by
 376    --  doing a binary search on the source positions in the lines table
 377    --  for the unit containing the given source position. The returned
 378    --  value is the logical line number, already adjusted for the effect
 379    --  of source reference pragmas. If P refers to the line of a source
 380    --  reference pragma itself, then No_Line is returned. If no source
 381    --  reference pragmas have been encountered, the value returned is
 382    --  the same as the physical line number.
 383
 384    function Get_Physical_Line_Number
 385      (P    : Source_Ptr)
 386       return Physical_Line_Number;
 387    --  The line number of the specified source position is obtained by
 388    --  doing a binary search on the source positions in the lines table
 389    --  for the unit containing the given source position. The returned
 390    --  value is the physical line number in the source being compiled.
 391
 392    function Get_Source_File_Index (S : Source_Ptr) return Source_File_Index;
 393    --  Return file table index of file identified by given source pointer
 394    --  value. This call must always succeed, since any valid source pointer
 395    --  value belongs to some previously loaded source file.
 396
 397    function Instantiation_Depth (S : Source_Ptr) return Nat;
 398    --  Determine instantiation depth for given Sloc value. A value of
 399    --  zero means that the given Sloc is not in an instantiation.
 400
 401    function Line_Start (P : Source_Ptr) return Source_Ptr;
 402    --  Finds the source position of the start of the line containing the
 403    --  given source location.
 404
 405    function Line_Start
 406      (L    : Physical_Line_Number;
 407       S    : Source_File_Index)
 408       return Source_Ptr;
 409    --  Finds the source position of the start of the given line in the
 410    --  given source file, using a physical line number to identify the line.
 411
 412    function Num_Source_Lines (S : Source_File_Index) return Nat;
 413    --  Returns the number of source lines (this is equivalent to reading
 414    --  the value of Last_Source_Line, but returns Nat rathern than a
 415    --  physical line number.
 416
 417    procedure Register_Source_Ref_Pragma
 418      (File_Name          : Name_Id;
 419       Stripped_File_Name : Name_Id;
 420       Mapped_Line        : Nat;
 421       Line_After_Pragma  : Physical_Line_Number);
 422    --  Register a source reference pragma, the parameter File_Name is the
 423    --  file name from the pragma, and Stripped_File_Name is this name with
 424    --  the directory information stripped. Both these parameters are set
 425    --  to No_Name if no file name parameter was given in the pragma.
 426    --  (which can only happen for the second and subsequent pragmas).
 427    --  Mapped_Line is the line number parameter from the pragma, and
 428    --  Line_After_Pragma is the physical line number of the line that
 429    --  follows the line containing the Source_Reference pragma.
 430
 431    function Original_Location (S : Source_Ptr) return Source_Ptr;
 432    --  Given a source pointer S, returns the corresponding source pointer
 433    --  value ignoring instantiation copies. For locations that do not
 434    --  correspond to instantiation copies of templates, the argument is
 435    --  returned unchanged. For locations that do correspond to copies of
 436    --  templates from instantiations, the location within the original
 437    --  template is returned. This is useful in canonicalizing locations.
 438
 439    function Instantiation_Location (S : Source_Ptr) return Source_Ptr;
 440    pragma Inline (Instantiation_Location);
 441    --  Given a source pointer S, returns the corresponding source pointer
 442    --  value of the instantiation if this location is within an instance.
 443    --  If S is not within an instance, then this returns No_Location.
 444
 445    function Top_Level_Location (S : Source_Ptr) return Source_Ptr;
 446    --  Given a source pointer S, returns the argument unchanged if it is
 447    --  not in an instantiation. If S is in an instantiation, then it returns
 448    --  the location of the top level instantiation, i.e. the outer level
 449    --  instantiation in the nested case.
 450
 451    function Physical_To_Logical
 452      (Line : Physical_Line_Number;
 453       S    : Source_File_Index)
 454       return Logical_Line_Number;
 455    --  Given a physical line number in source file whose source index is S,
 456    --  return the corresponding logical line number. If the physical line
 457    --  number is one containing a Source_Reference pragma, the result will
 458    --  be No_Line_Number.
 459
 460    procedure Skip_Line_Terminators
 461      (P        : in out Source_Ptr;
 462       Physical : out Boolean);
 463    --  On entry, Source (P) points to the line terminator character that
 464    --  terminates a line. The result set in P is the location of the first
 465    --  character of the following line (after skipping the sequence of line
 466    --  terminator characters terminating the current line). In addition, if
 467    --  the terminator sequence ends a physical line (the definition of what
 468    --  constitutes a physical line is embodied in the implementation of this
 469    --  function), and it is the first time this sequence is encountered, then
 470    --  an entry is made in the lines table to record the location for further
 471    --  use by functions such as Get_Line_Number. Physical is set to True if
 472    --  the line terminator was the end of a physical line.
 473
 474    function Source_Offset (S : Source_Ptr) return Nat;
 475    --  Returns the zero-origin offset of the given source location from the
 476    --  start of its corresponding unit. This is used for creating canonical
 477    --  names in some situations.
 478
 479    procedure Write_Location (P : Source_Ptr);
 480    --  Writes out a string of the form fff:nn:cc, where fff, nn, cc are the
 481    --  file name, line number and column corresponding to the given source
 482    --  location. No_Location and Standard_Location appear as the strings
 483    --  <no location> and <standard location>. If the location is within an
 484    --  instantiation, then the instance location is appended, enclosed in
 485    --  square brackets (which can nest if necessary). Note that this routine
 486    --  is used only for internal compiler debugging output purposes (which
 487    --  is why the somewhat cryptic use of brackets is acceptable).
 488
 489    procedure wl (P : Source_Ptr);
 490    pragma Export (Ada, wl);
 491    --  Equivalent to Write_Location (P); Write_Eol; for calls from GDB
 492
 493    procedure Write_Time_Stamp (S : Source_File_Index);
 494    --  Writes time stamp of specified file in YY-MM-DD HH:MM.SS format
 495
 496    procedure Tree_Write;
 497    --  Writes out internal tables to current tree file using Tree_Write
 498
 499    procedure Tree_Read;
 500    --  Initializes internal tables from current tree file using Tree_Read
 501
 502 private
 503    pragma Inline (File_Name);
 504    pragma Inline (First_Mapped_Line);
 505    pragma Inline (Full_File_Name);
 506    pragma Inline (Identifier_Casing);
 507    pragma Inline (Instantiation);
 508    pragma Inline (Keyword_Casing);
 509    pragma Inline (Last_Source_Line);
 510    pragma Inline (Last_Source_File);
 511    pragma Inline (License);
 512    pragma Inline (Num_SRef_Pragmas);
 513    pragma Inline (Num_Source_Files);
 514    pragma Inline (Num_Source_Lines);
 515    pragma Inline (Reference_Name);
 516    pragma Inline (Set_Keyword_Casing);
 517    pragma Inline (Set_Identifier_Casing);
 518    pragma Inline (Source_First);
 519    pragma Inline (Source_Last);
 520    pragma Inline (Source_Text);
 521    pragma Inline (Template);
 522    pragma Inline (Time_Stamp);
 523
 524    -------------------------
 525    -- Source_Lines Tables --
 526    -------------------------
 527
 528    type Lines_Table_Type is
 529      array (Physical_Line_Number) of Source_Ptr;
 530    --  Type used for lines table. The entries are indexed by physical line
 531    --  numbers. The values are the starting Source_Ptr values for the start
 532    --  of the corresponding physical line. Note that we make this a bogus
 533    --  big array, sized as required, so that we avoid the use of fat pointers.
 534
 535    type Lines_Table_Ptr is access all Lines_Table_Type;
 536    --  Type used for pointers to line tables
 537
 538    type Logical_Lines_Table_Type is
 539      array (Physical_Line_Number) of Logical_Line_Number;
 540    --  Type used for logical lines table. This table is used if a source
 541    --  reference pragma is present. It is indexed by physical line numbers,
 542    --  and contains the corresponding logical line numbers. An entry that
 543    --  corresponds to a source reference pragma is set to No_Line_Number.
 544    --  Note that we make this a bogus big array, sized as required, so that
 545    --  we avoid the use of fat pointers.
 546
 547    type Logical_Lines_Table_Ptr is access all Logical_Lines_Table_Type;
 548    --  Type used for pointers to logical line tables.
 549
 550    -----------------------
 551    -- Source_File Table --
 552    -----------------------
 553
 554    --  See earlier descriptions for meanings of public fields
 555
 556    type Source_File_Record is record
 557
 558       File_Name         : File_Name_Type;
 559       Reference_Name    : File_Name_Type;
 560       Debug_Source_Name : File_Name_Type;
 561       Full_File_Name    : File_Name_Type;
 562       Full_Ref_Name     : File_Name_Type;
 563       License           : License_Type;
 564       Num_SRef_Pragmas  : Nat;
 565       First_Mapped_Line : Logical_Line_Number;
 566       Source_Text       : Source_Buffer_Ptr;
 567       Source_First      : Source_Ptr;
 568       Source_Last       : Source_Ptr;
 569       Time_Stamp        : Time_Stamp_Type;
 570       Source_Checksum   : Word;
 571       Last_Source_Line  : Physical_Line_Number;
 572       Keyword_Casing    : Casing_Type;
 573       Identifier_Casing : Casing_Type;
 574       Instantiation     : Source_Ptr;
 575       Template          : Source_File_Index;
 576
 577       --  The following fields are for internal use only (i.e. only in the
 578       --  body of Sinput or its children, with no direct access by clients).
 579
 580       Sloc_Adjust : Source_Ptr;
 581       --  A value to be added to Sloc values for this file to reference the
 582       --  corresponding lines table. This is zero for the non-instantiation
 583       --  case, and set so that the adition references the ultimate template
 584       --  for the instantiation case. See Sinput-L for further details.
 585
 586       Lines_Table : Lines_Table_Ptr;
 587       --  Pointer to lines table for this source. Updated as additional
 588       --  lines are accessed using the Skip_Line_Terminators procedure.
 589       --  Note: the lines table for an instantiation entry refers to the
 590       --  original line numbers of the template see Sinput-L for details.
 591
 592       Logical_Lines_Table : Logical_Lines_Table_Ptr;
 593       --  Pointer to logical lines table for this source. Non-null only if
 594       --  a source reference pragma has been processed. Updated as lines
 595       --  are accessed using the Skip_Line_Terminators procedure.
 596
 597       Lines_Table_Max : Physical_Line_Number;
 598       --  Maximum subscript values for currently allocated Lines_Table
 599       --  and (if present) the allocated Logical_Lines_Table. The value
 600       --  Max_Source_Line gives the maximum used value, this gives the
 601       --  maximum allocated value.
 602
 603    end record;
 604
 605    package Source_File is new Table.Table (
 606      Table_Component_Type => Source_File_Record,
 607      Table_Index_Type     => Source_File_Index,
 608      Table_Low_Bound      => 1,
 609      Table_Initial        => Alloc.Source_File_Initial,
 610      Table_Increment      => Alloc.Source_File_Increment,
 611      Table_Name           => "Source_File");
 612
 613    -----------------
 614    -- Subprograms --
 615    -----------------
 616
 617    procedure Alloc_Line_Tables
 618      (S       : in out Source_File_Record;
 619       New_Max : Nat);
 620    --  Allocate or reallocate the lines table for the given source file so
 621    --  that it can accommodate at least New_Max lines. Also allocates or
 622    --  reallocates logical lines table if source ref pragmas are present.
 623
 624    procedure Add_Line_Tables_Entry
 625      (S : in out Source_File_Record;
 626       P : Source_Ptr);
 627    --  Increment line table size by one (reallocating the lines table if
 628    --  needed) and set the new entry to contain the value P. Also bumps
 629    --  the Source_Line_Count field. If source reference pragmas are
 630    --  present, also increments logical lines table size by one, and
 631    --  sets new entry.
 632
 633    procedure Trim_Lines_Table (S : Source_File_Index);
 634    --  Set lines table size for entry S in the source file table to
 635    --  correspond to the current value of Num_Source_Lines, releasing
 636    --  any unused storage. This is used by Sinput.L and Sinput.D.
 637
 638 end Sinput;