libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012-2013 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.64)
  33 AC_INIT(package-unused, version-unused,, libbacktrace)
  34 AC_CONFIG_SRCDIR(backtrace.h)
  35 AC_CONFIG_HEADER(config.h)
  36
  37 AC_CANONICAL_SYSTEM
  38 target_alias=${target_alias-$host_alias}
  39
  40 AC_USE_SYSTEM_EXTENSIONS
  41
  42 libtool_VERSION=1:0:0
  43 AC_SUBST(libtool_VERSION)
  44
  45 # 1.11.1: Require that version of automake.
  46 # foreign: Don't require README, INSTALL, NEWS, etc.
  47 # no-define: Don't define PACKAGE and VERSION.
  48 # no-dependencies: Don't generate automatic dependencies.
  49 #    (because it breaks when using bootstrap-lean, since some of the
  50 #    headers are gone at "make install" time).
  51 # -Wall: Issue all automake warnings.
  52 # -Wno-portability: Don't warn about constructs supported by GNU make.
  53 #    (because GCC requires GNU make anyhow).
  54 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  55
  56 AM_MAINTAINER_MODE
  57
  58 AC_ARG_WITH(target-subdir,
  59 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  60
  61 # We must force CC to /not/ be precious variables; otherwise
  62 # the wrong, non-multilib-adjusted value will be used in multilibs.
  63 # As a side effect, we have to subst CFLAGS ourselves.
  64 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  65 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  66 AC_PROG_CC
  67 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  68
  69 AC_SUBST(CFLAGS)
  70
  71 AC_PROG_RANLIB
  72
  73 AC_PROG_AWK
  74 case "$AWK" in
  75 "") AC_MSG_ERROR([can't build without awk]) ;;
  76 esac
  77
  78 LT_INIT([disable-shared])
  79 AM_PROG_LIBTOOL
  80
  81 backtrace_supported=yes
  82
  83 if test -n "${with_target_subdir}"; then
  84   # We are compiling a GCC library.  We can assume that the unwind
  85   # library exists.
  86   AM_ENABLE_MULTILIB(, ..)
  87   BACKTRACE_FILE="backtrace.lo simple.lo"
  88 else
  89   AC_CHECK_HEADER([unwind.h],
  90     [AC_CHECK_FUNC([_Unwind_Backtrace],
  91                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  92                    [BACKTRACE_FILE="nounwind.lo"
  93                     backtrace_supported=no])],
  94     [BACKTRACE_FILE="nounwind.lo"
  95      backtrace_supported=no])
  96 fi
  97 AC_SUBST(BACKTRACE_FILE)
  98
  99 EXTRA_FLAGS=
 100 if test -n "${with_target_subdir}"; then
 101   EXTRA_FLAGS="-funwind-tables -frandom-seed=\$@"
 102 else
 103   AC_CACHE_CHECK([for -funwind-tables option],
 104     [libbacktrace_cv_c_unwind_tables],
 105     [CFLAGS_hold="$CFLAGS"
 106      CFLAGS="$CFLAGS -funwind-tables"
 107      AC_COMPILE_IFELSE(
 108        [AC_LANG_PROGRAM([static int f() { return 0; }], [return f();])],
 109        [libbacktrace_cv_c_unwind_tables=yes],
 110        [libbacktrace_cv_c_unwind_tables=no])
 111      CFLAGS="$CFLAGS_hold"])
 112   if test "$libbacktrace_cv_c_unwind_tables" = "yes"; then
 113     EXTRA_FLAGS=-funwind-tables
 114   fi
 115   AC_CACHE_CHECK([for -frandom-seed=string option],
 116     [libbacktrace_cv_c_random_seed_string],
 117     [CFLAGS_hold="$CFLAGS"
 118      CFLAGS="$CFLAGS -frandom-seed=conftest.lo"
 119      AC_COMPILE_IFELSE(
 120        [AC_LANG_PROGRAM([], [return 0;])],
 121        [libbacktrace_cv_c_random_seed_string=yes],
 122        [libbacktrace_cv_c_random_seed_string=no])
 123      CFLAGS="$CFLAGS_hold"])
 124   if test "$libbacktrace_cv_c_random_seed_string" = "yes"; then
 125     EXTRA_FLAGS="$EXTRA_FLAGS -frandom-seed=\$@"
 126   fi
 127 fi
 128 AC_SUBST(EXTRA_FLAGS)
 129
 130 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 131                           -Wmissing-prototypes -Wold-style-definition \
 132                           -Wmissing-format-attribute -Wcast-qual],
 133                           [WARN_FLAGS])
 134
 135 if test -n "${with_target_subdir}"; then
 136   WARN_FLAGS="$WARN_FLAGS -Werror"
 137 fi
 138
 139 AC_SUBST(WARN_FLAGS)
 140
 141 if test -n "${with_target_subdir}"; then
 142   GCC_CHECK_UNWIND_GETIPINFO
 143 else
 144   ac_save_CFFLAGS="$CFLAGS"
 145   CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 146   AC_MSG_CHECKING([for _Unwind_GetIPInfo])
 147   AC_COMPILE_IFELSE(
 148     [AC_LANG_PROGRAM(
 149        [#include "unwind.h"
 150         struct _Unwind_Context *context;
 151         int ip_before_insn = 0;],
 152         [return _Unwind_GetIPInfo (context, &ip_before_insn);])],
 153         [have_unwind_getipinfo=yes], [have_unwind_getipinfo=no])
 154   CFLAGS="$ac_save_CFLAGS"
 155   AC_MSG_RESULT([$have_unwind_getipinfo])
 156   if test "$have_unwind_getipinfo" = "yes"; then
 157     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 158   fi
 159 fi
 160
 161 # When building as a target library, shared libraries may want to link
 162 # this in.  We don't want to provide another shared library to
 163 # complicate dependencies.  Instead, we just compile with -fPIC.
 164 PIC_FLAG=
 165 if test -n "${with_target_subdir}"; then
 166   PIC_FLAG=-fPIC
 167 fi
 168 # Similarly, use -fPIC with --enable-host-shared:
 169 AC_ARG_ENABLE(host-shared,
 170 [AS_HELP_STRING([--enable-host-shared],
 171                 [build host code as shared libraries])],
 172 [PIC_FLAG=-fPIC], [])
 173 AC_SUBST(PIC_FLAG)
 174
 175 # Test for __sync support.
 176 AC_CACHE_CHECK([__sync extensions],
 177 [libbacktrace_cv_sys_sync],
 178 [if test -n "${with_target_subdir}"; then
 179    libbacktrace_cv_sys_sync=yes
 180  else
 181    AC_LINK_IFELSE(
 182      [AC_LANG_PROGRAM([int i;],
 183                       [__sync_bool_compare_and_swap (&i, i, i);
 184                        __sync_lock_test_and_set (&i, 1);
 185                        __sync_lock_release (&i);])],
 186      [libbacktrace_cv_sys_sync=yes],
 187      [libbacktrace_cv_sys_sync=no])
 188  fi])
 189 BACKTRACE_SUPPORTS_THREADS=0
 190 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 191   BACKTRACE_SUPPORTS_THREADS=1
 192   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 193             [Define to 1 if you have the __sync functions])
 194 fi
 195 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 196
 197 # The library needs to be able to read the executable itself.  Compile
 198 # a file to determine the executable format.  The awk script
 199 # filetype.awk prints out the file type.
 200 AC_CACHE_CHECK([output filetype],
 201 [libbacktrace_cv_sys_filetype],
 202 [filetype=
 203 AC_COMPILE_IFELSE(
 204   [AC_LANG_PROGRAM([int i;], [int j;])],
 205   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 206   [AC_MSG_FAILURE([compiler failed])])
 207 libbacktrace_cv_sys_filetype=$filetype])
 208
 209 # Match the file type to decide what files to compile.
 210 FORMAT_FILE=
 211 case "$libbacktrace_cv_sys_filetype" in
 212 elf*) FORMAT_FILE="elf.lo" ;;
 213 *) AC_MSG_WARN([could not determine output file type])
 214    FORMAT_FILE="unknown.lo"
 215    backtrace_supported=no
 216    ;;
 217 esac
 218 AC_SUBST(FORMAT_FILE)
 219
 220 # ELF defines.
 221 elfsize=
 222 case "$libbacktrace_cv_sys_filetype" in
 223 elf32) elfsize=32 ;;
 224 elf64) elfsize=64 ;;
 225 esac
 226 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 227
 228 BACKTRACE_SUPPORTED=0
 229 if test "$backtrace_supported" = "yes"; then
 230   BACKTRACE_SUPPORTED=1
 231 fi
 232 AC_SUBST(BACKTRACE_SUPPORTED)
 233
 234 GCC_HEADER_STDINT(gstdint.h)
 235
 236 AC_CHECK_HEADERS(sys/mman.h)
 237 if test "$ac_cv_header_sys_mman_h" = "no"; then
 238   have_mmap=no
 239 else
 240   if test -n "${with_target_subdir}"; then
 241     # When built as a GCC target library, we can't do a link test.  We
 242     # simply assume that if we have mman.h, we have mmap.
 243     have_mmap=yes
 244   else
 245     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 246   fi
 247 fi
 248 if test "$have_mmap" = "no"; then
 249   VIEW_FILE=read.lo
 250   ALLOC_FILE=alloc.lo
 251 else
 252   VIEW_FILE=mmapio.lo
 253   AC_PREPROC_IFELSE([
 254 #include <sys/mman.h>
 255 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 256   #error no MAP_ANONYMOUS
 257 #endif
 258 ], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 259 fi
 260 AC_SUBST(VIEW_FILE)
 261 AC_SUBST(ALLOC_FILE)
 262
 263 BACKTRACE_USES_MALLOC=0
 264 if test "$ALLOC_FILE" = "alloc.lo"; then
 265   BACKTRACE_USES_MALLOC=1
 266 fi
 267 AC_SUBST(BACKTRACE_USES_MALLOC)
 268
 269 # Check for dl_iterate_phdr.
 270 AC_CHECK_HEADERS(link.h)
 271 if test "$ac_cv_header_link_h" = "no"; then
 272   have_dl_iterate_phdr=no
 273 else
 274   if test -n "${with_target_subdir}"; then
 275     # When built as a GCC target library, we can't do a link test.
 276     AC_EGREP_HEADER([dl_iterate_phdr], [link.h], [have_dl_iterate_phdr=yes],
 277                     [have_dl_iterate_phdr=no])
 278     case "${host}" in
 279     *-*-solaris2.10*)
 280         # Avoid dl_iterate_phdr on Solaris 10, where it is in the
 281         # header file but is only in -ldl.
 282         have_dl_iterate_phdr=no ;;
 283     esac
 284   else
 285     AC_CHECK_FUNC([dl_iterate_phdr], [have_dl_iterate_phdr=yes],
 286                   [have_dl_iterate_phdr=no])
 287   fi
 288 fi
 289 if test "$have_dl_iterate_phdr" = "yes"; then
 290   AC_DEFINE(HAVE_DL_ITERATE_PHDR, 1, [Define if dl_iterate_phdr is available.])
 291 fi
 292
 293 # Check for the fcntl function.
 294 if test -n "${with_target_subdir}"; then
 295    case "${host}" in
 296    *-*-mingw*) have_fcntl=no ;;
 297    *) have_fcntl=yes ;;
 298    esac
 299 else
 300   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 301 fi
 302 if test "$have_fcntl" = "yes"; then
 303   AC_DEFINE([HAVE_FCNTL], 1,
 304             [Define to 1 if you have the fcntl function])
 305 fi
 306
 307 AC_CHECK_DECLS(strnlen)
 308
 309 # Check for getexecname function.
 310 if test -n "${with_target_subdir}"; then
 311    case "${host}" in
 312    *-*-solaris2*) have_getexecname=yes ;;
 313    *) have_getexecname=no ;;
 314    esac
 315 else
 316   AC_CHECK_FUNC(getexecname, [have_getexecname=yes], [have_getexecname=no])
 317 fi
 318 if test "$have_getexecname" = "yes"; then
 319   AC_DEFINE(HAVE_GETEXECNAME, 1, [Define if getexecname is available.])
 320 fi
 321
 322 AC_CACHE_CHECK([whether tests can run],
 323   [libbacktrace_cv_sys_native],
 324   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 325      [libbacktrace_cv_sys_native=yes],
 326      [libbacktrace_cv_sys_native=no],
 327      [libbacktrace_cv_sys_native=no])])
 328 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 329
 330 if test "${multilib}" = "yes"; then
 331   multilib_arg="--enable-multilib"
 332 else
 333   multilib_arg=
 334 fi
 335
 336 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 337
 338 # We need multilib support, but only if configuring for the target.
 339 AC_CONFIG_COMMANDS([default],
 340 [if test -n "$CONFIG_FILES"; then
 341    if test -n "${with_target_subdir}"; then
 342      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 343      # that multilib installs will end up installed in the correct place.
 344      # The testsuite needs it for multilib-aware ABI baseline files.
 345      # To work around this not being passed down from config-ml.in ->
 346      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 347      # append it here.  Only modify Makefiles that have just been created.
 348      #
 349      # Also, get rid of this simulated-VPATH thing that automake does.
 350      cat > vpsed << \_EOF
 351   s!`test -f '$<' || echo '$(srcdir)/'`!!
 352 _EOF
 353      for i in $SUBDIRS; do
 354       case $CONFIG_FILES in
 355        *${i}/Makefile*)
 356          #echo "Adding MULTISUBDIR to $i/Makefile"
 357          sed -f vpsed $i/Makefile > tmp
 358          grep '^MULTISUBDIR =' Makefile >> tmp
 359          mv tmp $i/Makefile
 360          ;;
 361       esac
 362      done
 363      rm vpsed
 364    fi
 365  fi
 366 ],
 367 [
 368 # Variables needed in config.status (file generation) which aren't already
 369 # passed by autoconf.
 370 SUBDIRS="$SUBDIRS"
 371 ])
 372
 373 AC_OUTPUT