libdecnumber/configure.ac

   1 # configure.ac for libdecnumber                 -*- Autoconf -*-
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 2005-2018 Free Software Foundation, Inc.
   5
   6 # This file is part of GCC.
   7
   8 # GCC is free software; you can redistribute it and/or modify it under
   9 # the terms of the GNU General Public License as published by the Free
  10 # Software Foundation; either version 3, or (at your option) any
  11 # later #version.
  12
  13 # GCC is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public
  16 # License #for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with GCC; see the file COPYING3.  If not see
  20 # <http://www.gnu.org/licenses/>.
  21
  22 AC_INIT(libdecnumber, [ ], gcc-bugs@gcc.gnu.org, libdecnumber)
  23 AC_CONFIG_SRCDIR(decNumber.h)
  24 AC_CONFIG_MACRO_DIR(../config)
  25 AC_CONFIG_AUX_DIR(..)
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 AC_PROG_CC
  30 AC_PROG_RANLIB
  31
  32 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  33 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  34 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  35 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  36
  37 # Figure out what compiler warnings we can enable.
  38 # See config/warnings.m4 for details.
  39
  40 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
  41                           -Wmissing-prototypes -Wold-style-definition \
  42                           -Wmissing-format-attribute -Wcast-qual])
  43 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  44
  45 ACX_PROG_CC_WARNING_OPTS([-fno-lto], [nolto_flags])
  46
  47 # Only enable with --enable-werror-always until existing warnings are
  48 # corrected.
  49 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  50
  51 # Checks for header files.
  52 AC_CHECK_HEADERS(ctype.h stddef.h string.h stdio.h)
  53 GCC_HEADER_STDINT(gstdint.h)
  54
  55 # Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_CONST
  57 AC_TYPE_OFF_T
  58 AC_CHECK_SIZEOF(int)
  59 AC_CHECK_SIZEOF(long)
  60
  61 # Checks for library functions.
  62 AC_HEADER_STDC
  63
  64 AC_ARG_ENABLE(maintainer-mode,
  65 [  --enable-maintainer-mode enable rules only needed by maintainers],,
  66 enable_maintainer_mode=no)
  67
  68 if test "x$enable_maintainer_mode" = xno; then
  69   MAINT='#'
  70 else
  71   MAINT=
  72 fi
  73 AC_SUBST(MAINT)
  74
  75 AC_CANONICAL_TARGET
  76
  77 # Default decimal format
  78 # If you change the defaults here, be sure to change them in the GCC directory also
  79 AC_MSG_CHECKING([for decimal floating point])
  80
  81 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
  82
  83 # Use default_decimal_float for dependency.
  84 enable_decimal_float=$default_decimal_float
  85
  86 # If BID is being used, additional objects should be linked in.
  87 if test x$enable_decimal_float = xbid; then
  88   ADDITIONAL_OBJS="$ADDITIONAL_OBJS \$(bid_OBJS)"
  89 else
  90   ADDITIONAL_OBJS=
  91 fi
  92
  93 AC_MSG_RESULT($enable_decimal_float)
  94 AC_SUBST(enable_decimal_float)
  95 AC_SUBST(ADDITIONAL_OBJS)
  96
  97 AC_C_BIGENDIAN
  98
  99 # Enable --enable-host-shared.
 100 AC_ARG_ENABLE(host-shared,
 101 [AS_HELP_STRING([--enable-host-shared],
 102                 [build host code as shared libraries])],
 103 [PICFLAG=-fPIC], [PICFLAG=])
 104 AC_SUBST(PICFLAG)
 105
 106 # Output.
 107
 108 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 109 AC_CONFIG_FILES(Makefile)
 110 AC_OUTPUT