gcc/ada/sem_aux.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ A U X                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;          use Atree;
  27 with Einfo;          use Einfo;
  28 with Einfo.Entities; use Einfo.Entities;
  29 with Einfo.Utils;    use Einfo.Utils;
  30 with Nlists;         use Nlists;
  31 with Sinfo;          use Sinfo;
  32 with Sinfo.Nodes;    use Sinfo.Nodes;
  33 with Sinfo.Utils;    use Sinfo.Utils;
  34 with Snames;         use Snames;
  35 with Stand;          use Stand;
  36 with Uintp;          use Uintp;
  37
  38 package body Sem_Aux is
  39
  40    ----------------------
  41    -- Ancestor_Subtype --
  42    ----------------------
  43
  44    function Ancestor_Subtype (Typ : Entity_Id) return Entity_Id is
  45    begin
  46       --  If this is first subtype, or is a base type, then there is no
  47       --  ancestor subtype, so we return Empty to indicate this fact.
  48
  49       if Is_First_Subtype (Typ) or else Is_Base_Type (Typ) then
  50          return Empty;
  51       end if;
  52
  53       declare
  54          D : constant Node_Id := Declaration_Node (Typ);
  55
  56       begin
  57          --  If we have a subtype declaration, get the ancestor subtype
  58
  59          if Nkind (D) = N_Subtype_Declaration then
  60             if Nkind (Subtype_Indication (D)) = N_Subtype_Indication then
  61                return Entity (Subtype_Mark (Subtype_Indication (D)));
  62             else
  63                return Entity (Subtype_Indication (D));
  64             end if;
  65
  66          --  If not, then no subtype indication is available
  67
  68          else
  69             return Empty;
  70          end if;
  71       end;
  72    end Ancestor_Subtype;
  73
  74    --------------------
  75    -- Available_View --
  76    --------------------
  77
  78    function Available_View (Ent : Entity_Id) return Entity_Id is
  79    begin
  80       --  Obtain the non-limited view (if available)
  81
  82       if Has_Non_Limited_View (Ent) then
  83          return Get_Full_View (Non_Limited_View (Ent));
  84
  85       --  In all other cases, return entity unchanged
  86
  87       else
  88          return Ent;
  89       end if;
  90    end Available_View;
  91
  92    --------------------
  93    -- Constant_Value --
  94    --------------------
  95
  96    function Constant_Value (Ent : Entity_Id) return Node_Id is
  97       D      : constant Node_Id := Declaration_Node (Ent);
  98       Full_D : Node_Id;
  99
 100    begin
 101       --  If we have no declaration node, then return no constant value. Not
 102       --  clear how this can happen, but it does sometimes and this is the
 103       --  safest approach.
 104
 105       if No (D) then
 106          return Empty;
 107
 108       --  Normal case where a declaration node is present
 109
 110       elsif Nkind (D) = N_Object_Renaming_Declaration then
 111          return Renamed_Object (Ent);
 112
 113       --  If this is a component declaration whose entity is a constant, it is
 114       --  a prival within a protected function (and so has no constant value).
 115
 116       elsif Nkind (D) = N_Component_Declaration then
 117          return Empty;
 118
 119       --  If there is an expression, return it
 120
 121       elsif Present (Expression (D)) then
 122          return Expression (D);
 123
 124       --  For a constant, see if we have a full view
 125
 126       elsif Ekind (Ent) = E_Constant
 127         and then Present (Full_View (Ent))
 128       then
 129          Full_D := Parent (Full_View (Ent));
 130
 131          --  The full view may have been rewritten as an object renaming
 132
 133          if Nkind (Full_D) = N_Object_Renaming_Declaration then
 134             return Name (Full_D);
 135          else
 136             return Expression (Full_D);
 137          end if;
 138
 139       --  Otherwise we have no expression to return
 140
 141       else
 142          return Empty;
 143       end if;
 144    end Constant_Value;
 145
 146    ---------------------------------
 147    -- Corresponding_Unsigned_Type --
 148    ---------------------------------
 149
 150    function Corresponding_Unsigned_Type (Typ : Entity_Id) return Entity_Id is
 151       pragma Assert (Is_Signed_Integer_Type (Typ));
 152       Siz : constant Uint := Esize (Base_Type (Typ));
 153    begin
 154       if Siz = Esize (Standard_Short_Short_Integer) then
 155          return Standard_Short_Short_Unsigned;
 156       elsif Siz = Esize (Standard_Short_Integer) then
 157          return Standard_Short_Unsigned;
 158       elsif Siz = Esize (Standard_Unsigned) then
 159          return Standard_Unsigned;
 160       elsif Siz = Esize (Standard_Long_Integer) then
 161          return Standard_Long_Unsigned;
 162       elsif Siz = Esize (Standard_Long_Long_Integer) then
 163          return Standard_Long_Long_Unsigned;
 164       elsif Siz = Esize (Standard_Long_Long_Long_Integer) then
 165          return Standard_Long_Long_Long_Unsigned;
 166       else
 167          raise Program_Error;
 168       end if;
 169    end Corresponding_Unsigned_Type;
 170
 171    -----------------------------
 172    -- Enclosing_Dynamic_Scope --
 173    -----------------------------
 174
 175    function Enclosing_Dynamic_Scope (Ent : Entity_Id) return Entity_Id is
 176       S : Entity_Id;
 177
 178    begin
 179       --  The following test is an error defense against some syntax errors
 180       --  that can leave scopes very messed up.
 181
 182       if Ent = Standard_Standard then
 183          return Ent;
 184       end if;
 185
 186       --  Normal case, search enclosing scopes
 187
 188       --  Note: the test for Present (S) should not be required, it defends
 189       --  against an ill-formed tree.
 190
 191       S := Scope (Ent);
 192       loop
 193          --  If we somehow got an empty value for Scope, the tree must be
 194          --  malformed. Rather than blow up we return Standard in this case.
 195
 196          if No (S) then
 197             return Standard_Standard;
 198
 199          --  Quit if we get to standard or a dynamic scope. We must also
 200          --  handle enclosing scopes that have a full view; required to
 201          --  locate enclosing scopes that are synchronized private types
 202          --  whose full view is a task type.
 203
 204          elsif S = Standard_Standard
 205            or else Is_Dynamic_Scope (S)
 206            or else (Is_Private_Type (S)
 207                      and then Present (Full_View (S))
 208                      and then Is_Dynamic_Scope (Full_View (S)))
 209          then
 210             return S;
 211
 212          --  Otherwise keep climbing
 213
 214          else
 215             S := Scope (S);
 216          end if;
 217       end loop;
 218    end Enclosing_Dynamic_Scope;
 219
 220    ------------------------
 221    -- First_Discriminant --
 222    ------------------------
 223
 224    function First_Discriminant (Typ : Entity_Id) return Entity_Id is
 225       Ent : Entity_Id;
 226
 227    begin
 228       pragma Assert
 229         (Has_Discriminants (Typ) or else Has_Unknown_Discriminants (Typ));
 230
 231       Ent := First_Entity (Typ);
 232
 233       --  The discriminants are not necessarily contiguous, because access
 234       --  discriminants will generate itypes. They are not the first entities
 235       --  either because the tag must be ahead of them.
 236
 237       if Chars (Ent) = Name_uTag then
 238          Next_Entity (Ent);
 239       end if;
 240
 241       --  Skip all hidden stored discriminants if any
 242
 243       while Present (Ent) loop
 244          exit when Ekind (Ent) = E_Discriminant
 245            and then not Is_Completely_Hidden (Ent);
 246
 247          Next_Entity (Ent);
 248       end loop;
 249
 250       --  Call may be on a private type with unknown discriminants, in which
 251       --  case Ent is Empty, and as per the spec, we return Empty in this case.
 252
 253       --  Historical note: The assertion in previous versions that Ent is a
 254       --  discriminant was overly cautious and prevented convenient application
 255       --  of this function in the gnatprove context.
 256
 257       return Ent;
 258    end First_Discriminant;
 259
 260    -------------------------------
 261    -- First_Stored_Discriminant --
 262    -------------------------------
 263
 264    function First_Stored_Discriminant (Typ : Entity_Id) return Entity_Id is
 265       Ent : Entity_Id;
 266
 267       function Has_Completely_Hidden_Discriminant
 268         (Typ : Entity_Id) return Boolean;
 269       --  Scans the Discriminants to see whether any are Completely_Hidden
 270       --  (the mechanism for describing non-specified stored discriminants)
 271       --  Note that the entity list for the type may contain anonymous access
 272       --  types created by expressions that constrain access discriminants.
 273
 274       ----------------------------------------
 275       -- Has_Completely_Hidden_Discriminant --
 276       ----------------------------------------
 277
 278       function Has_Completely_Hidden_Discriminant
 279         (Typ : Entity_Id) return Boolean
 280       is
 281          Ent : Entity_Id;
 282
 283       begin
 284          pragma Assert (Ekind (Typ) = E_Discriminant);
 285
 286          Ent := Typ;
 287          while Present (Ent) loop
 288
 289             --  Skip anonymous types that may be created by expressions
 290             --  used as discriminant constraints on inherited discriminants.
 291
 292             if Is_Itype (Ent) then
 293                null;
 294
 295             elsif Ekind (Ent) = E_Discriminant
 296               and then Is_Completely_Hidden (Ent)
 297             then
 298                return True;
 299             end if;
 300
 301             Next_Entity (Ent);
 302          end loop;
 303
 304          return False;
 305       end Has_Completely_Hidden_Discriminant;
 306
 307    --  Start of processing for First_Stored_Discriminant
 308
 309    begin
 310       pragma Assert
 311         (Has_Discriminants (Typ)
 312           or else Has_Unknown_Discriminants (Typ));
 313
 314       Ent := First_Entity (Typ);
 315
 316       if Chars (Ent) = Name_uTag then
 317          Next_Entity (Ent);
 318       end if;
 319
 320       if Has_Completely_Hidden_Discriminant (Ent) then
 321          while Present (Ent) loop
 322             exit when Ekind (Ent) = E_Discriminant
 323               and then Is_Completely_Hidden (Ent);
 324             Next_Entity (Ent);
 325          end loop;
 326       end if;
 327
 328       pragma Assert (Ekind (Ent) = E_Discriminant);
 329
 330       return Ent;
 331    end First_Stored_Discriminant;
 332
 333    -------------------
 334    -- First_Subtype --
 335    -------------------
 336
 337    function First_Subtype (Typ : Entity_Id) return Entity_Id is
 338       B   : constant Entity_Id := Base_Type (Typ);
 339       F   : Node_Id := Freeze_Node (B);
 340       Ent : Entity_Id;
 341
 342    begin
 343       --  The freeze node of a ghost type might have been rewritten in a null
 344       --  statement by the time gigi calls First_Subtype on the corresponding
 345       --  type.
 346
 347       if Nkind (F) = N_Null_Statement then
 348          F := Original_Node (F);
 349       end if;
 350
 351       --  If the base type has no freeze node, it is a type in Standard, and
 352       --  always acts as its own first subtype, except where it is one of the
 353       --  predefined integer types. If the type is formal, it is also a first
 354       --  subtype, and its base type has no freeze node. On the other hand, a
 355       --  subtype of a generic formal is not its own first subtype. Its base
 356       --  type, if anonymous, is attached to the formal type declaration from
 357       --  which the first subtype is obtained.
 358
 359       if No (F) then
 360          if B = Base_Type (Standard_Integer) then
 361             return Standard_Integer;
 362
 363          elsif B = Base_Type (Standard_Long_Integer) then
 364             return Standard_Long_Integer;
 365
 366          elsif B = Base_Type (Standard_Short_Short_Integer) then
 367             return Standard_Short_Short_Integer;
 368
 369          elsif B = Base_Type (Standard_Short_Integer) then
 370             return Standard_Short_Integer;
 371
 372          elsif B = Base_Type (Standard_Long_Long_Integer) then
 373             return Standard_Long_Long_Integer;
 374
 375          elsif B = Base_Type (Standard_Long_Long_Long_Integer) then
 376             return Standard_Long_Long_Long_Integer;
 377
 378          elsif Is_Generic_Type (Typ) then
 379             if Present (Parent (B)) then
 380                return Defining_Identifier (Parent (B));
 381             else
 382                return Defining_Identifier (Associated_Node_For_Itype (B));
 383             end if;
 384
 385          else
 386             return B;
 387          end if;
 388
 389       --  Otherwise we check the freeze node, if it has a First_Subtype_Link
 390       --  then we use that link, otherwise (happens with some Itypes), we use
 391       --  the base type itself.
 392
 393       else
 394          Ent := First_Subtype_Link (F);
 395
 396          if Present (Ent) then
 397             return Ent;
 398          else
 399             return B;
 400          end if;
 401       end if;
 402    end First_Subtype;
 403
 404    -------------------------
 405    -- First_Tag_Component --
 406    -------------------------
 407
 408    function First_Tag_Component (Typ : Entity_Id) return Entity_Id is
 409       Comp : Entity_Id;
 410       Ctyp : Entity_Id;
 411
 412    begin
 413       pragma Assert (Is_Tagged_Type (Typ)
 414         or else Is_Class_Wide_Equivalent_Type (Typ));
 415
 416       Ctyp := Typ;
 417
 418       if Is_Class_Wide_Type (Ctyp) then
 419          Ctyp := Root_Type (Ctyp);
 420       end if;
 421
 422       if Is_Private_Type (Ctyp) then
 423          Ctyp := Underlying_Type (Ctyp);
 424
 425          --  If the underlying type is missing then the source program has
 426          --  errors and there is nothing else to do (the full-type declaration
 427          --  associated with the private type declaration is missing).
 428
 429          if No (Ctyp) then
 430             return Empty;
 431          end if;
 432       end if;
 433
 434       Comp := First_Entity (Ctyp);
 435       while Present (Comp) loop
 436          if Is_Tag (Comp) then
 437             return Comp;
 438          end if;
 439
 440          Next_Entity (Comp);
 441       end loop;
 442
 443       --  No tag component found
 444
 445       return Empty;
 446    end First_Tag_Component;
 447
 448    -----------------------
 449    -- Get_Called_Entity --
 450    -----------------------
 451
 452    function Get_Called_Entity (Call : Node_Id) return Entity_Id is
 453       Nam : constant Node_Id := Name (Call);
 454       Id  : Entity_Id;
 455
 456    begin
 457       if Nkind (Nam) = N_Explicit_Dereference then
 458          Id := Etype (Nam);
 459          pragma Assert (Ekind (Id) = E_Subprogram_Type);
 460
 461       elsif Nkind (Nam) = N_Selected_Component then
 462          Id := Entity (Selector_Name (Nam));
 463
 464       elsif Nkind (Nam) = N_Indexed_Component then
 465          Id := Entity (Selector_Name (Prefix (Nam)));
 466
 467       else
 468          Id := Entity (Nam);
 469       end if;
 470
 471       return Id;
 472    end Get_Called_Entity;
 473
 474    ------------------
 475    -- Get_Rep_Item --
 476    ------------------
 477
 478    function Get_Rep_Item
 479      (E             : Entity_Id;
 480       Nam           : Name_Id;
 481       Check_Parents : Boolean := True) return Node_Id
 482    is
 483       N : Node_Id;
 484
 485    begin
 486       N := First_Rep_Item (E);
 487       while Present (N) loop
 488
 489          --  Only one of Priority / Interrupt_Priority can be specified, so
 490          --  return whichever one is present to catch illegal duplication.
 491
 492          if Nkind (N) = N_Pragma
 493            and then
 494              (Pragma_Name_Unmapped (N) = Nam
 495                or else (Nam = Name_Priority
 496                          and then Pragma_Name (N) =
 497                            Name_Interrupt_Priority)
 498                or else (Nam = Name_Interrupt_Priority
 499                          and then Pragma_Name (N) = Name_Priority))
 500          then
 501             if Check_Parents then
 502                return N;
 503
 504             --  If Check_Parents is False, return N if the pragma doesn't
 505             --  appear in the Rep_Item chain of the parent.
 506
 507             else
 508                declare
 509                   Par : constant Entity_Id := Nearest_Ancestor (E);
 510                   --  This node represents the parent type of type E (if any)
 511
 512                begin
 513                   if No (Par) then
 514                      return N;
 515
 516                   elsif not Present_In_Rep_Item (Par, N) then
 517                      return N;
 518                   end if;
 519                end;
 520             end if;
 521
 522          elsif Nkind (N) = N_Attribute_Definition_Clause
 523            and then
 524              (Chars (N) = Nam
 525                or else (Nam = Name_Priority
 526                          and then Chars (N) = Name_Interrupt_Priority))
 527          then
 528             if Check_Parents or else Entity (N) = E then
 529                return N;
 530             end if;
 531
 532          elsif Nkind (N) = N_Aspect_Specification
 533            and then
 534              (Chars (Identifier (N)) = Nam
 535                or else
 536                  (Nam = Name_Priority
 537                    and then Chars (Identifier (N)) = Name_Interrupt_Priority))
 538          then
 539             if Check_Parents then
 540                return N;
 541
 542             elsif Entity (N) = E then
 543                return N;
 544             end if;
 545
 546          --  A Ghost-related aspect, if disabled, may have been replaced by a
 547          --  null statement.
 548
 549          elsif Nkind (N) = N_Null_Statement then
 550             N := Original_Node (N);
 551          end if;
 552
 553          Next_Rep_Item (N);
 554       end loop;
 555
 556       return Empty;
 557    end Get_Rep_Item;
 558
 559    function Get_Rep_Item
 560      (E             : Entity_Id;
 561       Nam1          : Name_Id;
 562       Nam2          : Name_Id;
 563       Check_Parents : Boolean := True) return Node_Id
 564    is
 565       Nam1_Item : constant Node_Id := Get_Rep_Item (E, Nam1, Check_Parents);
 566       Nam2_Item : constant Node_Id := Get_Rep_Item (E, Nam2, Check_Parents);
 567
 568       N : Node_Id;
 569
 570    begin
 571       --  Check both Nam1_Item and Nam2_Item are present
 572
 573       if No (Nam1_Item) then
 574          return Nam2_Item;
 575       elsif No (Nam2_Item) then
 576          return Nam1_Item;
 577       end if;
 578
 579       --  Return the first node encountered in the list
 580
 581       N := First_Rep_Item (E);
 582       while Present (N) loop
 583          if N = Nam1_Item or else N = Nam2_Item then
 584             return N;
 585          end if;
 586
 587          Next_Rep_Item (N);
 588       end loop;
 589
 590       return Empty;
 591    end Get_Rep_Item;
 592
 593    --------------------
 594    -- Get_Rep_Pragma --
 595    --------------------
 596
 597    function Get_Rep_Pragma
 598      (E             : Entity_Id;
 599       Nam           : Name_Id;
 600       Check_Parents : Boolean := True) return Node_Id
 601    is
 602       N : constant Node_Id := Get_Rep_Item (E, Nam, Check_Parents);
 603
 604    begin
 605       if Present (N) and then Nkind (N) = N_Pragma then
 606          return N;
 607       end if;
 608
 609       return Empty;
 610    end Get_Rep_Pragma;
 611
 612    function Get_Rep_Pragma
 613      (E             : Entity_Id;
 614       Nam1          : Name_Id;
 615       Nam2          : Name_Id;
 616       Check_Parents : Boolean := True) return Node_Id
 617    is
 618       Nam1_Item : constant Node_Id := Get_Rep_Pragma (E, Nam1, Check_Parents);
 619       Nam2_Item : constant Node_Id := Get_Rep_Pragma (E, Nam2, Check_Parents);
 620
 621       N : Node_Id;
 622
 623    begin
 624       --  Check both Nam1_Item and Nam2_Item are present
 625
 626       if No (Nam1_Item) then
 627          return Nam2_Item;
 628       elsif No (Nam2_Item) then
 629          return Nam1_Item;
 630       end if;
 631
 632       --  Return the first node encountered in the list
 633
 634       N := First_Rep_Item (E);
 635       while Present (N) loop
 636          if N = Nam1_Item or else N = Nam2_Item then
 637             return N;
 638          end if;
 639
 640          Next_Rep_Item (N);
 641       end loop;
 642
 643       return Empty;
 644    end Get_Rep_Pragma;
 645
 646    ---------------------------------
 647    -- Has_External_Tag_Rep_Clause --
 648    ---------------------------------
 649
 650    function Has_External_Tag_Rep_Clause (T : Entity_Id) return Boolean is
 651    begin
 652       pragma Assert (Is_Tagged_Type (T));
 653       return Has_Rep_Item (T, Name_External_Tag, Check_Parents => False);
 654    end Has_External_Tag_Rep_Clause;
 655
 656    ------------------
 657    -- Has_Rep_Item --
 658    ------------------
 659
 660    function Has_Rep_Item
 661      (E             : Entity_Id;
 662       Nam           : Name_Id;
 663       Check_Parents : Boolean := True) return Boolean
 664    is
 665    begin
 666       return Present (Get_Rep_Item (E, Nam, Check_Parents));
 667    end Has_Rep_Item;
 668
 669    function Has_Rep_Item
 670      (E             : Entity_Id;
 671       Nam1          : Name_Id;
 672       Nam2          : Name_Id;
 673       Check_Parents : Boolean := True) return Boolean
 674    is
 675    begin
 676       return Present (Get_Rep_Item (E, Nam1, Nam2, Check_Parents));
 677    end Has_Rep_Item;
 678
 679    --------------------
 680    -- Has_Rep_Pragma --
 681    --------------------
 682
 683    function Has_Rep_Pragma
 684      (E             : Entity_Id;
 685       Nam           : Name_Id;
 686       Check_Parents : Boolean := True) return Boolean
 687    is
 688    begin
 689       return Present (Get_Rep_Pragma (E, Nam, Check_Parents));
 690    end Has_Rep_Pragma;
 691
 692    function Has_Rep_Pragma
 693      (E             : Entity_Id;
 694       Nam1          : Name_Id;
 695       Nam2          : Name_Id;
 696       Check_Parents : Boolean := True) return Boolean
 697    is
 698    begin
 699       return Present (Get_Rep_Pragma (E, Nam1, Nam2, Check_Parents));
 700    end Has_Rep_Pragma;
 701
 702    --------------------------------
 703    -- Has_Unconstrained_Elements --
 704    --------------------------------
 705
 706    function Has_Unconstrained_Elements (T : Entity_Id) return Boolean is
 707       U_T : constant Entity_Id := Underlying_Type (T);
 708    begin
 709       if No (U_T) then
 710          return False;
 711       elsif Is_Record_Type (U_T) then
 712          return Has_Discriminants (U_T) and then not Is_Constrained (U_T);
 713       elsif Is_Array_Type (U_T) then
 714          return Has_Unconstrained_Elements (Component_Type (U_T));
 715       else
 716          return False;
 717       end if;
 718    end Has_Unconstrained_Elements;
 719
 720    ----------------------
 721    -- Has_Variant_Part --
 722    ----------------------
 723
 724    function Has_Variant_Part (Typ : Entity_Id) return Boolean is
 725       FSTyp : Entity_Id;
 726       Decl  : Node_Id;
 727       TDef  : Node_Id;
 728       CList : Node_Id;
 729
 730    begin
 731       FSTyp := First_Subtype (Typ);
 732
 733       if not Has_Discriminants (FSTyp) then
 734          return False;
 735       end if;
 736
 737       --  Proceed with cautious checks here, return False if tree is not
 738       --  as expected (may be caused by prior errors).
 739
 740       Decl := Declaration_Node (FSTyp);
 741
 742       if Nkind (Decl) /= N_Full_Type_Declaration then
 743          return False;
 744       end if;
 745
 746       TDef := Type_Definition (Decl);
 747
 748       if Nkind (TDef) /= N_Record_Definition then
 749          return False;
 750       end if;
 751
 752       CList := Component_List (TDef);
 753
 754       if Nkind (CList) /= N_Component_List then
 755          return False;
 756       else
 757          return Present (Variant_Part (CList));
 758       end if;
 759    end Has_Variant_Part;
 760
 761    ---------------------
 762    -- In_Generic_Body --
 763    ---------------------
 764
 765    function In_Generic_Body (Id : Entity_Id) return Boolean is
 766       S : Entity_Id;
 767
 768    begin
 769       --  Climb scopes looking for generic body
 770
 771       S := Id;
 772       while Present (S) and then S /= Standard_Standard loop
 773
 774          --  Generic package body
 775
 776          if Ekind (S) = E_Generic_Package
 777            and then In_Package_Body (S)
 778          then
 779             return True;
 780
 781          --  Generic subprogram body
 782
 783          elsif Is_Subprogram (S)
 784            and then Nkind (Unit_Declaration_Node (S)) =
 785                       N_Generic_Subprogram_Declaration
 786          then
 787             return True;
 788          end if;
 789
 790          S := Scope (S);
 791       end loop;
 792
 793       --  False if top of scope stack without finding a generic body
 794
 795       return False;
 796    end In_Generic_Body;
 797
 798    -------------------------------
 799    -- Initialization_Suppressed --
 800    -------------------------------
 801
 802    function Initialization_Suppressed (Typ : Entity_Id) return Boolean is
 803    begin
 804       return Suppress_Initialization (Typ)
 805         or else Suppress_Initialization (Base_Type (Typ));
 806    end Initialization_Suppressed;
 807
 808    ----------------
 809    -- Initialize --
 810    ----------------
 811
 812    procedure Initialize is
 813    begin
 814       Obsolescent_Warnings.Init;
 815    end Initialize;
 816
 817    -------------
 818    -- Is_Body --
 819    -------------
 820
 821    function Is_Body (N : Node_Id) return Boolean is
 822    begin
 823       return Nkind (N) in
 824         N_Body_Stub       | N_Entry_Body | N_Package_Body | N_Protected_Body |
 825         N_Subprogram_Body | N_Task_Body;
 826    end Is_Body;
 827
 828    ---------------------
 829    -- Is_By_Copy_Type --
 830    ---------------------
 831
 832    function Is_By_Copy_Type (Ent : Entity_Id) return Boolean is
 833    begin
 834       --  If Id is a private type whose full declaration has not been seen,
 835       --  we assume for now that it is not a By_Copy type. Clearly this
 836       --  attribute should not be used before the type is frozen, but it is
 837       --  needed to build the associated record of a protected type. Another
 838       --  place where some lookahead for a full view is needed ???
 839
 840       return
 841         Is_Elementary_Type (Ent)
 842           or else (Is_Private_Type (Ent)
 843                      and then Present (Underlying_Type (Ent))
 844                      and then Is_Elementary_Type (Underlying_Type (Ent)));
 845    end Is_By_Copy_Type;
 846
 847    --------------------------
 848    -- Is_By_Reference_Type --
 849    --------------------------
 850
 851    function Is_By_Reference_Type (Ent : Entity_Id) return Boolean is
 852       Btype : constant Entity_Id := Base_Type (Ent);
 853
 854    begin
 855       if Is_Private_Type (Btype) then
 856          declare
 857             Utyp : constant Entity_Id := Underlying_Type (Btype);
 858          begin
 859             if No (Utyp) then
 860                return False;
 861             else
 862                return Is_By_Reference_Type (Utyp);
 863             end if;
 864          end;
 865
 866       elsif Is_Incomplete_Type (Btype) then
 867          declare
 868             Ftyp : constant Entity_Id := Full_View (Btype);
 869          begin
 870             --  Return true for a tagged incomplete type built as a shadow
 871             --  entity in Build_Limited_Views. It can appear in the profile
 872             --  of a thunk and the back end needs to know how it is passed.
 873
 874             if No (Ftyp) then
 875                return Is_Tagged_Type (Btype);
 876             else
 877                return Is_By_Reference_Type (Ftyp);
 878             end if;
 879          end;
 880
 881       elsif Is_Concurrent_Type (Btype) then
 882          return True;
 883
 884       elsif Is_Record_Type (Btype) then
 885          if Is_Limited_Record (Btype)
 886            or else Is_Tagged_Type (Btype)
 887            or else Is_Volatile (Btype)
 888          then
 889             return True;
 890
 891          else
 892             declare
 893                C : Entity_Id;
 894
 895             begin
 896                C := First_Component (Btype);
 897                while Present (C) loop
 898
 899                   --  For each component, test if its type is a by reference
 900                   --  type and if its type is volatile. Also test the component
 901                   --  itself for being volatile. This happens for example when
 902                   --  a Volatile aspect is added to a component.
 903
 904                   if Is_By_Reference_Type (Etype (C))
 905                     or else Is_Volatile (Etype (C))
 906                     or else Is_Volatile (C)
 907                   then
 908                      return True;
 909                   end if;
 910
 911                   Next_Component (C);
 912                end loop;
 913             end;
 914
 915             return False;
 916          end if;
 917
 918       elsif Is_Array_Type (Btype) then
 919          return
 920            Is_Volatile (Btype)
 921              or else Is_By_Reference_Type (Component_Type (Btype))
 922              or else Is_Volatile (Component_Type (Btype))
 923              or else Has_Volatile_Components (Btype);
 924
 925       else
 926          return False;
 927       end if;
 928    end Is_By_Reference_Type;
 929
 930    -------------------------
 931    -- Is_Definite_Subtype --
 932    -------------------------
 933
 934    function Is_Definite_Subtype (T : Entity_Id) return Boolean is
 935       pragma Assert (Is_Type (T));
 936       K : constant Entity_Kind := Ekind (T);
 937
 938    begin
 939       if Is_Constrained (T) then
 940          return True;
 941
 942       elsif K in Array_Kind
 943         or else K in Class_Wide_Kind
 944         or else Has_Unknown_Discriminants (T)
 945       then
 946          return False;
 947
 948       --  Known discriminants: definite if there are default values. Note that
 949       --  if any discriminant has a default, they all do.
 950
 951       elsif Has_Discriminants (T) then
 952          return Present (Discriminant_Default_Value (First_Discriminant (T)));
 953
 954       else
 955          return True;
 956       end if;
 957    end Is_Definite_Subtype;
 958
 959    ---------------------
 960    -- Is_Derived_Type --
 961    ---------------------
 962
 963    function Is_Derived_Type (Ent : Entity_Id) return B is
 964       Par : Node_Id;
 965
 966    begin
 967       if Is_Type (Ent)
 968         and then Base_Type (Ent) /= Root_Type (Ent)
 969         and then not Is_Class_Wide_Type (Ent)
 970
 971         --  An access_to_subprogram whose result type is a limited view can
 972         --  appear in a return statement, without the full view of the result
 973         --  type being available. Do not interpret this as a derived type.
 974
 975         and then Ekind (Ent) /= E_Subprogram_Type
 976       then
 977          if not Is_Numeric_Type (Root_Type (Ent)) then
 978             return True;
 979
 980          else
 981             Par := Parent (First_Subtype (Ent));
 982
 983             return Present (Par)
 984               and then Nkind (Par) = N_Full_Type_Declaration
 985               and then Nkind (Type_Definition (Par)) =
 986                          N_Derived_Type_Definition;
 987          end if;
 988
 989       else
 990          return False;
 991       end if;
 992    end Is_Derived_Type;
 993
 994    -----------------------
 995    -- Is_Generic_Formal --
 996    -----------------------
 997
 998    function Is_Generic_Formal (E : Entity_Id) return Boolean is
 999       Kind : Node_Kind;
1000
1001    begin
1002       if No (E) then
1003          return False;
1004       else
1005          --  Formal derived types are rewritten as private extensions, so
1006          --  examine original node.
1007
1008          Kind := Nkind (Original_Node (Parent (E)));
1009
1010          return
1011            Kind in N_Formal_Object_Declaration | N_Formal_Type_Declaration
1012              or else Is_Formal_Subprogram (E)
1013              or else
1014                (Ekind (E) = E_Package
1015                  and then Nkind (Original_Node (Unit_Declaration_Node (E))) =
1016                             N_Formal_Package_Declaration);
1017       end if;
1018    end Is_Generic_Formal;
1019
1020    -------------------------------
1021    -- Is_Immutably_Limited_Type --
1022    -------------------------------
1023
1024    function Is_Immutably_Limited_Type (Ent : Entity_Id) return Boolean is
1025       Btype : constant Entity_Id := Available_View (Base_Type (Ent));
1026
1027    begin
1028       if Is_Limited_Record (Btype) then
1029          return True;
1030
1031       elsif Ekind (Btype) = E_Limited_Private_Type
1032         and then Nkind (Parent (Btype)) = N_Formal_Type_Declaration
1033       then
1034          return not In_Package_Body (Scope ((Btype)));
1035
1036       elsif Is_Private_Type (Btype) then
1037
1038          --  AI05-0063: A type derived from a limited private formal type is
1039          --  not immutably limited in a generic body.
1040
1041          if Is_Derived_Type (Btype)
1042            and then Is_Generic_Type (Etype (Btype))
1043          then
1044             if not Is_Limited_Type (Etype (Btype)) then
1045                return False;
1046
1047             --  A descendant of a limited formal type is not immutably limited
1048             --  in the generic body, or in the body of a generic child.
1049
1050             elsif Ekind (Scope (Etype (Btype))) = E_Generic_Package then
1051                return not In_Package_Body (Scope (Btype));
1052
1053             else
1054                return False;
1055             end if;
1056
1057          else
1058             return False;
1059          end if;
1060
1061       elsif Is_Concurrent_Type (Btype) then
1062          return True;
1063
1064       else
1065          return False;
1066       end if;
1067    end Is_Immutably_Limited_Type;
1068
1069    ---------------------
1070    -- Is_Limited_Type --
1071    ---------------------
1072
1073    function Is_Limited_Type (Ent : Entity_Id) return Boolean is
1074       Btype : Entity_Id;
1075       Rtype : Entity_Id;
1076
1077    begin
1078       if not Is_Type (Ent) then
1079          return False;
1080       end if;
1081
1082       Btype := Base_Type (Ent);
1083       Rtype := Root_Type (Btype);
1084
1085       if Ekind (Btype) = E_Limited_Private_Type
1086         or else Is_Limited_Composite (Btype)
1087       then
1088          return True;
1089
1090       elsif Is_Concurrent_Type (Btype) then
1091          return True;
1092
1093          --  The Is_Limited_Record flag normally indicates that the type is
1094          --  limited. The exception is that a type does not inherit limitedness
1095          --  from its interface ancestor. So the type may be derived from a
1096          --  limited interface, but is not limited.
1097
1098       elsif Is_Limited_Record (Ent)
1099         and then not Is_Interface (Ent)
1100       then
1101          return True;
1102
1103       --  Otherwise we will look around to see if there is some other reason
1104       --  for it to be limited, except that if an error was posted on the
1105       --  entity, then just assume it is non-limited, because it can cause
1106       --  trouble to recurse into a murky entity resulting from other errors.
1107
1108       elsif Error_Posted (Ent) then
1109          return False;
1110
1111       elsif Is_Record_Type (Btype) then
1112
1113          if Is_Limited_Interface (Ent) then
1114             return True;
1115
1116          --  AI-419: limitedness is not inherited from a limited interface
1117
1118          elsif Is_Limited_Record (Rtype) then
1119             return not Is_Interface (Rtype)
1120               or else Is_Protected_Interface (Rtype)
1121               or else Is_Synchronized_Interface (Rtype)
1122               or else Is_Task_Interface (Rtype);
1123
1124          elsif Is_Class_Wide_Type (Btype) then
1125             return Is_Limited_Type (Rtype);
1126
1127          else
1128             declare
1129                C : Entity_Id := First_Component (Btype);
1130             begin
1131                while Present (C) loop
1132                   if Is_Limited_Type (Etype (C)) then
1133                      return True;
1134                   end if;
1135
1136                   Next_Component (C);
1137                end loop;
1138             end;
1139
1140             return False;
1141          end if;
1142
1143       elsif Is_Array_Type (Btype) then
1144          return Is_Limited_Type (Component_Type (Btype));
1145
1146       else
1147          return False;
1148       end if;
1149    end Is_Limited_Type;
1150
1151    ---------------------
1152    -- Is_Limited_View --
1153    ---------------------
1154
1155    function Is_Limited_View (Ent : Entity_Id) return Boolean is
1156       Btype : constant Entity_Id := Available_View (Base_Type (Ent));
1157
1158    begin
1159       if Is_Limited_Record (Btype) then
1160          return True;
1161
1162       elsif Ekind (Btype) = E_Limited_Private_Type
1163         and then Nkind (Parent (Btype)) = N_Formal_Type_Declaration
1164       then
1165          return not In_Package_Body (Scope ((Btype)));
1166
1167       elsif Is_Private_Type (Btype) then
1168
1169          --  AI05-0063: A type derived from a limited private formal type is
1170          --  not immutably limited in a generic body.
1171
1172          if Is_Derived_Type (Btype)
1173            and then Is_Generic_Type (Etype (Btype))
1174          then
1175             if not Is_Limited_Type (Etype (Btype)) then
1176                return False;
1177
1178             --  A descendant of a limited formal type is not immutably limited
1179             --  in the generic body, or in the body of a generic child.
1180
1181             elsif Ekind (Scope (Etype (Btype))) = E_Generic_Package then
1182                return not In_Package_Body (Scope (Btype));
1183
1184             else
1185                return False;
1186             end if;
1187
1188          else
1189             declare
1190                Utyp : constant Entity_Id := Underlying_Type (Btype);
1191             begin
1192                if No (Utyp) then
1193                   return False;
1194                else
1195                   return Is_Limited_View (Utyp);
1196                end if;
1197             end;
1198          end if;
1199
1200       elsif Is_Concurrent_Type (Btype) then
1201          return True;
1202
1203       elsif Is_Record_Type (Btype) then
1204
1205          --  Note that we return True for all limited interfaces, even though
1206          --  (unsynchronized) limited interfaces can have descendants that are
1207          --  nonlimited, because this is a predicate on the type itself, and
1208          --  things like functions with limited interface results need to be
1209          --  handled as build in place even though they might return objects
1210          --  of a type that is not inherently limited.
1211
1212          if Is_Class_Wide_Type (Btype) then
1213             return Is_Limited_View (Root_Type (Btype));
1214
1215          else
1216             declare
1217                C : Entity_Id;
1218
1219             begin
1220                C := First_Component (Btype);
1221                while Present (C) loop
1222
1223                   --  Don't consider components with interface types (which can
1224                   --  only occur in the case of a _parent component anyway).
1225                   --  They don't have any components, plus it would cause this
1226                   --  function to return true for nonlimited types derived from
1227                   --  limited interfaces.
1228
1229                   if not Is_Interface (Etype (C))
1230                     and then Is_Limited_View (Etype (C))
1231                   then
1232                      return True;
1233                   end if;
1234
1235                   Next_Component (C);
1236                end loop;
1237             end;
1238
1239             return False;
1240          end if;
1241
1242       elsif Is_Array_Type (Btype) then
1243          return Is_Limited_View (Component_Type (Btype));
1244
1245       else
1246          return False;
1247       end if;
1248    end Is_Limited_View;
1249
1250    ----------------------
1251    -- Nearest_Ancestor --
1252    ----------------------
1253
1254    function Nearest_Ancestor (Typ : Entity_Id) return Entity_Id is
1255       D : constant Node_Id := Original_Node (Declaration_Node (Typ));
1256       --  We use the original node of the declaration, because derived
1257       --  types from record subtypes are rewritten as record declarations,
1258       --  and it is the original declaration that carries the ancestor.
1259
1260    begin
1261       --  If we have a subtype declaration, get the ancestor subtype
1262
1263       if Nkind (D) = N_Subtype_Declaration then
1264          if Nkind (Subtype_Indication (D)) = N_Subtype_Indication then
1265             return Entity (Subtype_Mark (Subtype_Indication (D)));
1266          else
1267             return Entity (Subtype_Indication (D));
1268          end if;
1269
1270       --  If derived type declaration, find who we are derived from
1271
1272       elsif Nkind (D) = N_Full_Type_Declaration
1273         and then Nkind (Type_Definition (D)) = N_Derived_Type_Definition
1274       then
1275          declare
1276             DTD : constant Entity_Id := Type_Definition (D);
1277             SI  : constant Entity_Id := Subtype_Indication (DTD);
1278          begin
1279             if Is_Entity_Name (SI) then
1280                return Entity (SI);
1281             else
1282                return Entity (Subtype_Mark (SI));
1283             end if;
1284          end;
1285
1286       --  If this is a concurrent declaration with a nonempty interface list,
1287       --  get the first progenitor. Account for case of a record type created
1288       --  for a concurrent type (which is the only case that seems to occur
1289       --  in practice).
1290
1291       elsif Nkind (D) = N_Full_Type_Declaration
1292         and then (Is_Concurrent_Type (Defining_Identifier (D))
1293                    or else Is_Concurrent_Record_Type (Defining_Identifier (D)))
1294         and then Is_Non_Empty_List (Interface_List (Type_Definition (D)))
1295       then
1296          return Entity (First (Interface_List (Type_Definition (D))));
1297
1298       --  If derived type and private type, get the full view to find who we
1299       --  are derived from.
1300
1301       elsif Is_Derived_Type (Typ)
1302         and then Is_Private_Type (Typ)
1303         and then Present (Full_View (Typ))
1304       then
1305          return Nearest_Ancestor (Full_View (Typ));
1306
1307       --  Otherwise, nothing useful to return, return Empty
1308
1309       else
1310          return Empty;
1311       end if;
1312    end Nearest_Ancestor;
1313
1314    ---------------------------
1315    -- Nearest_Dynamic_Scope --
1316    ---------------------------
1317
1318    function Nearest_Dynamic_Scope (Ent : Entity_Id) return Entity_Id is
1319    begin
1320       if Is_Dynamic_Scope (Ent) then
1321          return Ent;
1322       else
1323          return Enclosing_Dynamic_Scope (Ent);
1324       end if;
1325    end Nearest_Dynamic_Scope;
1326
1327    ------------------------
1328    -- Next_Tag_Component --
1329    ------------------------
1330
1331    function Next_Tag_Component (Tag : Entity_Id) return Entity_Id is
1332       Comp : Entity_Id;
1333
1334    begin
1335       pragma Assert (Is_Tag (Tag));
1336
1337       --  Loop to look for next tag component
1338
1339       Comp := Next_Entity (Tag);
1340       while Present (Comp) loop
1341          if Is_Tag (Comp) then
1342             pragma Assert (Chars (Comp) /= Name_uTag);
1343             return Comp;
1344          end if;
1345
1346          Next_Entity (Comp);
1347       end loop;
1348
1349       --  No tag component found
1350
1351       return Empty;
1352    end Next_Tag_Component;
1353
1354    --------------------------
1355    -- Number_Discriminants --
1356    --------------------------
1357
1358    function Number_Discriminants (Typ : Entity_Id) return Pos is
1359       N     : Nat       := 0;
1360       Discr : Entity_Id := First_Discriminant (Typ);
1361
1362    begin
1363       while Present (Discr) loop
1364          N := N + 1;
1365          Next_Discriminant (Discr);
1366       end loop;
1367
1368       return N;
1369    end Number_Discriminants;
1370
1371    ----------------------------------------------
1372    -- Object_Type_Has_Constrained_Partial_View --
1373    ----------------------------------------------
1374
1375    function Object_Type_Has_Constrained_Partial_View
1376      (Typ  : Entity_Id;
1377       Scop : Entity_Id) return Boolean
1378    is
1379    begin
1380       return Has_Constrained_Partial_View (Typ)
1381         or else (In_Generic_Body (Scop)
1382                   and then Is_Generic_Type (Base_Type (Typ))
1383                   and then (Is_Private_Type (Base_Type (Typ))
1384                              or else Is_Derived_Type (Base_Type (Typ)))
1385                   and then not Is_Tagged_Type (Typ)
1386                   and then not (Is_Array_Type (Typ)
1387                                  and then not Is_Constrained (Typ))
1388                   and then Has_Discriminants (Typ));
1389    end Object_Type_Has_Constrained_Partial_View;
1390
1391    ------------------
1392    -- Package_Body --
1393    ------------------
1394
1395    function Package_Body (E : Entity_Id) return Node_Id is
1396       Body_Decl : Node_Id;
1397       Body_Id   : constant Opt_E_Package_Body_Id :=
1398         Corresponding_Body (Package_Spec (E));
1399
1400    begin
1401       if Present (Body_Id) then
1402          Body_Decl := Parent (Body_Id);
1403
1404          if Nkind (Body_Decl) = N_Defining_Program_Unit_Name then
1405             Body_Decl := Parent (Body_Decl);
1406          end if;
1407
1408          pragma Assert (Nkind (Body_Decl) = N_Package_Body);
1409
1410          return Body_Decl;
1411       else
1412          return Empty;
1413       end if;
1414    end Package_Body;
1415
1416    ------------------
1417    -- Package_Spec --
1418    ------------------
1419
1420    function Package_Spec (E : Entity_Id) return Node_Id is
1421    begin
1422       return Parent (Package_Specification (E));
1423    end Package_Spec;
1424
1425    ---------------------------
1426    -- Package_Specification --
1427    ---------------------------
1428
1429    function Package_Specification (E : Entity_Id) return Node_Id is
1430       N : Node_Id;
1431
1432    begin
1433       pragma Assert (Is_Package_Or_Generic_Package (E));
1434
1435       N := Parent (E);
1436
1437       if Nkind (N) = N_Defining_Program_Unit_Name then
1438          N := Parent (N);
1439       end if;
1440
1441       pragma Assert (Nkind (N) = N_Package_Specification);
1442
1443       return N;
1444    end Package_Specification;
1445
1446    ---------------------
1447    -- Subprogram_Body --
1448    ---------------------
1449
1450    function Subprogram_Body (E : Entity_Id) return Node_Id is
1451       Body_E : constant Entity_Id := Subprogram_Body_Entity (E);
1452
1453    begin
1454       if No (Body_E) then
1455          return Empty;
1456       else
1457          return Parent (Subprogram_Specification (Body_E));
1458       end if;
1459    end Subprogram_Body;
1460
1461    ----------------------------
1462    -- Subprogram_Body_Entity --
1463    ----------------------------
1464
1465    function Subprogram_Body_Entity (E : Entity_Id) return Entity_Id is
1466       N : constant Node_Id := Parent (Subprogram_Specification (E));
1467       --  Declaration for E
1468
1469    begin
1470       --  If this declaration is not a subprogram body, then it must be a
1471       --  subprogram declaration or body stub, from which we can retrieve the
1472       --  entity for the corresponding subprogram body if any, or an abstract
1473       --  subprogram declaration, for which we return Empty.
1474
1475       case Nkind (N) is
1476          when N_Subprogram_Body =>
1477             return E;
1478
1479          when N_Subprogram_Body_Stub
1480             | N_Subprogram_Declaration
1481          =>
1482             return Corresponding_Body (N);
1483
1484          when others =>
1485             return Empty;
1486       end case;
1487    end Subprogram_Body_Entity;
1488
1489    ---------------------
1490    -- Subprogram_Spec --
1491    ---------------------
1492
1493    function Subprogram_Spec (E : Entity_Id) return Node_Id is
1494       N : constant Node_Id := Parent (Subprogram_Specification (E));
1495       --  Declaration for E
1496
1497    begin
1498       --  This declaration is either subprogram declaration or a subprogram
1499       --  body, in which case return Empty.
1500
1501       if Nkind (N) = N_Subprogram_Declaration then
1502          return N;
1503       else
1504          return Empty;
1505       end if;
1506    end Subprogram_Spec;
1507
1508    ------------------------------
1509    -- Subprogram_Specification --
1510    ------------------------------
1511
1512    function Subprogram_Specification (E : Entity_Id) return Node_Id is
1513       N : Node_Id;
1514
1515    begin
1516       N := Parent (E);
1517
1518       if Nkind (N) = N_Defining_Program_Unit_Name then
1519          N := Parent (N);
1520       end if;
1521
1522       --  If the Parent pointer of E is not a subprogram specification node
1523       --  (going through an intermediate N_Defining_Program_Unit_Name node
1524       --  for subprogram units), then E is an inherited operation. Its parent
1525       --  points to the type derivation that produces the inheritance: that's
1526       --  the node that generates the subprogram specification. Its alias
1527       --  is the parent subprogram, and that one points to a subprogram
1528       --  declaration, or to another type declaration if this is a hierarchy
1529       --  of derivations.
1530
1531       if Nkind (N) not in N_Subprogram_Specification then
1532          pragma Assert (Present (Alias (E)));
1533          N := Subprogram_Specification (Alias (E));
1534       end if;
1535
1536       return N;
1537    end Subprogram_Specification;
1538
1539    --------------------
1540    -- Ultimate_Alias --
1541    --------------------
1542
1543    function Ultimate_Alias (Prim : Entity_Id) return Entity_Id is
1544       E : Entity_Id := Prim;
1545
1546    begin
1547       while Present (Alias (E)) loop
1548          pragma Assert (Alias (E) /= E);
1549          E := Alias (E);
1550       end loop;
1551
1552       return E;
1553    end Ultimate_Alias;
1554
1555    --------------------------
1556    -- Unit_Declaration_Node --
1557    --------------------------
1558
1559    function Unit_Declaration_Node (Unit_Id : Entity_Id) return Node_Id is
1560       N : Node_Id := Parent (Unit_Id);
1561
1562    begin
1563       --  Predefined operators do not have a full function declaration
1564
1565       if Ekind (Unit_Id) = E_Operator then
1566          return N;
1567       end if;
1568
1569       --  Isn't there some better way to express the following ???
1570
1571       while Nkind (N) /= N_Abstract_Subprogram_Declaration
1572         and then Nkind (N) /= N_Entry_Body
1573         and then Nkind (N) /= N_Entry_Declaration
1574         and then Nkind (N) /= N_Formal_Package_Declaration
1575         and then Nkind (N) /= N_Function_Instantiation
1576         and then Nkind (N) /= N_Generic_Package_Declaration
1577         and then Nkind (N) /= N_Generic_Subprogram_Declaration
1578         and then Nkind (N) /= N_Package_Declaration
1579         and then Nkind (N) /= N_Package_Body
1580         and then Nkind (N) /= N_Package_Instantiation
1581         and then Nkind (N) /= N_Package_Renaming_Declaration
1582         and then Nkind (N) /= N_Procedure_Instantiation
1583         and then Nkind (N) /= N_Protected_Body
1584         and then Nkind (N) /= N_Protected_Type_Declaration
1585         and then Nkind (N) /= N_Subprogram_Declaration
1586         and then Nkind (N) /= N_Subprogram_Body
1587         and then Nkind (N) /= N_Subprogram_Body_Stub
1588         and then Nkind (N) /= N_Subprogram_Renaming_Declaration
1589         and then Nkind (N) /= N_Task_Body
1590         and then Nkind (N) /= N_Task_Type_Declaration
1591         and then Nkind (N) not in N_Formal_Subprogram_Declaration
1592         and then Nkind (N) not in N_Generic_Renaming_Declaration
1593       loop
1594          N := Parent (N);
1595
1596          --  We don't use Assert here, because that causes an infinite loop
1597          --  when assertions are turned off. Better to crash.
1598
1599          if No (N) then
1600             raise Program_Error;
1601          end if;
1602       end loop;
1603
1604       return N;
1605    end Unit_Declaration_Node;
1606
1607 end Sem_Aux;