gcc/optc-gen.awk

   1 #  Copyright (C) 2003, 2004, 2007, 2008, 2009 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicate options and generates a
  21 # C file.
  22 #
  23 # This program uses functions from opt-functions.awk
  24 #
  25 # Usage: awk -f opt-functions.awk -f optc-gen.awk \
  26 #            [-v header_name=header.h] < inputfile > options.c
  27
  28 BEGIN {
  29         n_opts = 0
  30         n_langs = 0
  31         n_target_save = 0
  32         quote = "\042"
  33         comma = ","
  34         FS=SUBSEP
  35         # Default the name of header created from opth-gen.awk to options.h
  36         if (header_name == "") header_name="options.h"
  37 }
  38
  39 # Collect the text and flags of each option into an array
  40         {
  41                 if ($1 == "Language") {
  42                         langs[n_langs] = $2
  43                         n_langs++;
  44                 }
  45                 else if ($1 == "TargetSave") {
  46                         # Make sure the declarations are put in source order
  47                         target_save_decl[n_target_save] = $2
  48                         n_target_save++
  49                 }
  50                 else {
  51                         name = opt_args("Mask", $1)
  52                         if (name == "") {
  53                                 opts[n_opts]  = $1
  54                                 flags[n_opts] = $2
  55                                 help[n_opts]  = $3
  56                                 for (i = 4; i <= NF; i++)
  57                                         help[n_opts] = help[n_opts] " " $i
  58                                 n_opts++;
  59                         }
  60                 }
  61         }
  62
  63 # Dump that array of options into a C file.
  64 END {
  65 print "/* This file is auto-generated by optc-gen.awk.  */"
  66 print ""
  67 n_headers = split(header_name, headers, " ")
  68 for (i = 1; i <= n_headers; i++)
  69         print "#include " quote headers[i] quote
  70 print "#include " quote "opts.h" quote
  71 print "#include " quote "intl.h" quote
  72 print ""
  73 print "#ifdef GCC_DRIVER"
  74 print "int target_flags;"
  75 print "#else"
  76 print "#include " quote "flags.h" quote
  77 print "#include " quote "target.h" quote
  78 print "#endif /* GCC_DRIVER */"
  79 print ""
  80
  81 have_save = 0;
  82 for (i = 0; i < n_opts; i++) {
  83         if (flag_set_p("Save", flags[i]))
  84                 have_save = 1;
  85
  86         name = var_name(flags[i]);
  87         if (name == "")
  88                 continue;
  89
  90         if (flag_set_p("VarExists", flags[i])) {
  91                 # Need it for the gcc driver.
  92                 if (name in var_seen)
  93                         continue;
  94                 init = ""
  95                 gcc_driver = 1
  96         }
  97         else {
  98                 init = opt_args("Init", flags[i])
  99                 if (init != "")
 100                         init = " = " init;
 101                 else if (name in var_seen)
 102                         continue;
 103                 gcc_driver = 0
 104         }
 105
 106         if (gcc_driver == 1)
 107                 print "#ifdef GCC_DRIVER"
 108         print "/* Set by -" opts[i] "."
 109         print "   " help[i] "  */"
 110         print var_type(flags[i]) name init ";"
 111         if (gcc_driver == 1)
 112                 print "#endif /* GCC_DRIVER */"
 113         print ""
 114
 115         var_seen[name] = 1;
 116 }
 117
 118 print ""
 119 print "/* Local state variables.  */"
 120 for (i = 0; i < n_opts; i++) {
 121         name = static_var(opts[i], flags[i]);
 122         if (name != "")
 123                 print "static " var_type(flags[i]) name ";"
 124 }
 125 print ""
 126
 127 print "const char * const lang_names[] =\n{"
 128 for (i = 0; i < n_langs; i++) {
 129         macros[i] = "CL_" langs[i]
 130         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
 131         s = substr("         ", length (macros[i]))
 132         print "  " quote langs[i] quote ","
 133     }
 134
 135 print "  0\n};\n"
 136 print "const unsigned int cl_options_count = N_OPTS;\n"
 137 print "const unsigned int cl_lang_count = " n_langs ";\n"
 138
 139 print "const struct cl_option cl_options[] =\n{"
 140
 141 j = 0
 142 for (i = 0; i < n_opts; i++) {
 143         back_chain[i] = "N_OPTS";
 144         indices[opts[i]] = j;
 145         # Combine the flags of identical switches.  Switches
 146         # appear many times if they are handled by many front
 147         # ends, for example.
 148         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 149                 flags[i + 1] = flags[i] " " flags[i + 1];
 150                 if (help[i + 1] == "")
 151                         help[i + 1] = help[i]
 152                 else if (help[i] != "" && help[i + 1] != help[i])
 153                         print "warning: multiple different help strings for " \
 154                                 opts[i] ":\n\t" help[i] "\n\t" help[i + 1] \
 155                                 | "cat 1>&2"
 156                 i++;
 157                 back_chain[i] = "N_OPTS";
 158                 indices[opts[i]] = j;
 159         }
 160         j++;
 161 }
 162
 163 for (i = 0; i < n_opts; i++) {
 164         # With identical flags, pick only the last one.  The
 165         # earlier loop ensured that it has all flags merged,
 166         # and a nonempty help text if one of the texts was nonempty.
 167         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 168                 i++;
 169         }
 170
 171         len = length (opts[i]);
 172         enum = "OPT_" opts[i]
 173         if (opts[i] == "finline-limit=" || opts[i] == "Wlarger-than=")
 174                 enum = enum "eq"
 175         gsub ("[^A-Za-z0-9]", "_", enum)
 176
 177         # If this switch takes joined arguments, back-chain all
 178         # subsequent switches to it for which it is a prefix.  If
 179         # a later switch S is a longer prefix of a switch T, T
 180         # will be back-chained to S in a later iteration of this
 181         # for() loop, which is what we want.
 182         if (flag_set_p("Joined.*", flags[i])) {
 183                 for (j = i + 1; j < n_opts; j++) {
 184                         if (substr (opts[j], 1, len) != opts[i])
 185                                 break;
 186                         back_chain[j] = enum;
 187                 }
 188         }
 189
 190         s = substr("                                  ", length (opts[i]))
 191         if (i + 1 == n_opts)
 192                 comma = ""
 193
 194         if (help[i] == "")
 195                 hlp = "0"
 196         else
 197                 hlp = quote help[i] quote;
 198
 199         neg = opt_args("Negative", flags[i]);
 200         if (neg != "")
 201                 idx = indices[neg]
 202         else {
 203                 if (flag_set_p("RejectNegative", flags[i]))
 204                         idx = -1;
 205                 else {
 206                         if (opts[i] ~ "^[Wfm]")
 207                                 idx = indices[opts[i]];
 208                         else
 209                                 idx = -1;
 210                 }
 211         }
 212         # Split the printf after %u to work around an ia64-hp-hpux11.23
 213         # awk bug.
 214         printf("  { %c-%s%c,\n    %s,\n    %s, %u,",
 215                quote, opts[i], quote, hlp, back_chain[i], len)
 216         printf(" %d,\n", idx)
 217         condition = opt_args("Condition", flags[i])
 218         cl_flags = switch_flags(flags[i])
 219         if (condition != "")
 220                 printf("#if %s\n" \
 221                        "    %s,\n" \
 222                        "#else\n" \
 223                        "    CL_DISABLED,\n" \
 224                        "#endif\n",
 225                        condition, cl_flags, cl_flags)
 226         else
 227                 printf("    %s,\n", cl_flags)
 228         printf("    %s, %s }%s\n", var_ref(opts[i], flags[i]),
 229                var_set(flags[i]), comma)
 230 }
 231
 232 print "};"
 233
 234 print "";
 235 print "#if !defined(GCC_DRIVER) && !defined(IN_LIBGCC2) && !defined(IN_TARGET_LIBS)"
 236 print "";
 237 print "/* Save optimization variables into a structure.  */"
 238 print "void";
 239 print "cl_optimization_save (struct cl_optimization *ptr)";
 240 print "{";
 241
 242 n_opt_char = 2;
 243 n_opt_short = 0;
 244 n_opt_int = 0;
 245 n_opt_other = 0;
 246 var_opt_char[0] = "optimize";
 247 var_opt_char[1] = "optimize_size";
 248 var_opt_range["optimize"] = "0, 255";
 249 var_opt_range["optimize_size"] = "0, 255";
 250
 251 # Sort by size to mimic how the structure is laid out to be friendlier to the
 252 # cache.
 253
 254 for (i = 0; i < n_opts; i++) {
 255         if (flag_set_p("Optimization", flags[i])) {
 256                 name = var_name(flags[i])
 257                 if(name == "")
 258                         continue;
 259
 260                 if(name in var_opt_seen)
 261                         continue;
 262
 263                 var_opt_seen[name]++;
 264                 otype = var_type_struct(flags[i]);
 265                 if (otype ~ "^((un)?signed +)?int *$")
 266                         var_opt_int[n_opt_int++] = name;
 267
 268                 else if (otype ~ "^((un)?signed +)?short *$")
 269                         var_opt_short[n_opt_short++] = name;
 270
 271                 else if (otype ~ "^((un)?signed +)?char *$") {
 272                         var_opt_char[n_opt_char++] = name;
 273                         if (otype ~ "^unsigned +char *$")
 274                                 var_opt_range[name] = "0, 255"
 275                         else if (otype ~ "^signed +char *$")
 276                                 var_opt_range[name] = "-128, 127"
 277                 }
 278                 else
 279                         var_opt_other[n_opt_other++] = name;
 280         }
 281 }
 282
 283 for (i = 0; i < n_opt_char; i++) {
 284         name = var_opt_char[i];
 285         if (var_opt_range[name] != "")
 286                 print "  gcc_assert (IN_RANGE (" name ", " var_opt_range[name] "));";
 287 }
 288
 289 print "";
 290 for (i = 0; i < n_opt_other; i++) {
 291         print "  ptr->" var_opt_other[i] " = " var_opt_other[i] ";";
 292 }
 293
 294 for (i = 0; i < n_opt_int; i++) {
 295         print "  ptr->" var_opt_int[i] " = " var_opt_int[i] ";";
 296 }
 297
 298 for (i = 0; i < n_opt_short; i++) {
 299         print "  ptr->" var_opt_short[i] " = " var_opt_short[i] ";";
 300 }
 301
 302 for (i = 0; i < n_opt_char; i++) {
 303         print "  ptr->" var_opt_char[i] " = " var_opt_char[i] ";";
 304 }
 305
 306 print "}";
 307
 308 print "";
 309 print "/* Restore optimization options from a structure.  */";
 310 print "void";
 311 print "cl_optimization_restore (struct cl_optimization *ptr)";
 312 print "{";
 313
 314 for (i = 0; i < n_opt_other; i++) {
 315         print "  " var_opt_other[i] " = ptr->" var_opt_other[i] ";";
 316 }
 317
 318 for (i = 0; i < n_opt_int; i++) {
 319         print "  " var_opt_int[i] " = ptr->" var_opt_int[i] ";";
 320 }
 321
 322 for (i = 0; i < n_opt_short; i++) {
 323         print "  " var_opt_short[i] " = ptr->" var_opt_short[i] ";";
 324 }
 325
 326 for (i = 0; i < n_opt_char; i++) {
 327         print "  " var_opt_char[i] " = ptr->" var_opt_char[i] ";";
 328 }
 329
 330 print "  targetm.override_options_after_change ();";
 331 print "}";
 332
 333 print "";
 334 print "/* Print optimization options from a structure.  */";
 335 print "void";
 336 print "cl_optimization_print (FILE *file,";
 337 print "                       int indent_to,";
 338 print "                       struct cl_optimization *ptr)";
 339 print "{";
 340
 341 print "  fputs (\"\\n\", file);";
 342 for (i = 0; i < n_opt_other; i++) {
 343         print "  if (ptr->" var_opt_other[i] ")";
 344         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 345         print "             indent_to, \"\",";
 346         print "             \"" var_opt_other[i] "\",";
 347         print "             (unsigned long)ptr->" var_opt_other[i] ");";
 348         print "";
 349 }
 350
 351 for (i = 0; i < n_opt_int; i++) {
 352         print "  if (ptr->" var_opt_int[i] ")";
 353         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 354         print "             indent_to, \"\",";
 355         print "             \"" var_opt_int[i] "\",";
 356         print "             ptr->" var_opt_int[i] ");";
 357         print "";
 358 }
 359
 360 for (i = 0; i < n_opt_short; i++) {
 361         print "  if (ptr->" var_opt_short[i] ")";
 362         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 363         print "             indent_to, \"\",";
 364         print "             \"" var_opt_short[i] "\",";
 365         print "             ptr->" var_opt_short[i] ");";
 366         print "";
 367 }
 368
 369 for (i = 0; i < n_opt_char; i++) {
 370         print "  if (ptr->" var_opt_char[i] ")";
 371         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 372         print "             indent_to, \"\",";
 373         print "             \"" var_opt_char[i] "\",";
 374         print "             ptr->" var_opt_char[i] ");";
 375         print "";
 376 }
 377
 378 print "}";
 379
 380 print "";
 381 print "/* Save selected option variables into a structure.  */"
 382 print "void";
 383 print "cl_target_option_save (struct cl_target_option *ptr)";
 384 print "{";
 385
 386 n_target_char = 0;
 387 n_target_short = 0;
 388 n_target_int = 0;
 389 n_target_other = 0;
 390
 391 if (have_save) {
 392         for (i = 0; i < n_opts; i++) {
 393                 if (flag_set_p("Save", flags[i])) {
 394                         name = var_name(flags[i])
 395                         if(name == "")
 396                                 name = "target_flags";
 397
 398                         if(name in var_save_seen)
 399                                 continue;
 400
 401                         var_save_seen[name]++;
 402                         otype = var_type_struct(flags[i])
 403                         if (otype ~ "^((un)?signed +)?int *$")
 404                                 var_target_int[n_target_int++] = name;
 405
 406                         else if (otype ~ "^((un)?signed +)?short *$")
 407                                 var_target_short[n_target_short++] = name;
 408
 409                         else if (otype ~ "^((un)?signed +)?char *$") {
 410                                 var_target_char[n_target_char++] = name;
 411                                 if (otype ~ "^unsigned +char *$")
 412                                         var_target_range[name] = "0, 255"
 413                                 else if (otype ~ "^signed +char *$")
 414                                         var_target_range[name] = "-128, 127"
 415                         }
 416                         else
 417                                 var_target_other[n_target_other++] = name;
 418                 }
 419         }
 420 } else {
 421         var_target_int[n_target_int++] = "target_flags";
 422 }
 423
 424 have_assert = 0;
 425 for (i = 0; i < n_target_char; i++) {
 426         name = var_target_char[i];
 427         if (var_target_range[name] != "") {
 428                 have_assert = 1;
 429                 print "  gcc_assert (IN_RANGE (" name ", " var_target_range[name] "));";
 430         }
 431 }
 432
 433 if (have_assert)
 434         print "";
 435
 436 print "  if (targetm.target_option.save)";
 437 print "    targetm.target_option.save (ptr);";
 438 print "";
 439
 440 for (i = 0; i < n_target_other; i++) {
 441         print "  ptr->" var_target_other[i] " = " var_target_other[i] ";";
 442 }
 443
 444 for (i = 0; i < n_target_int; i++) {
 445         print "  ptr->" var_target_int[i] " = " var_target_int[i] ";";
 446 }
 447
 448 for (i = 0; i < n_target_short; i++) {
 449         print "  ptr->" var_target_short[i] " = " var_target_short[i] ";";
 450 }
 451
 452 for (i = 0; i < n_target_char; i++) {
 453         print "  ptr->" var_target_char[i] " = " var_target_char[i] ";";
 454 }
 455
 456 print "}";
 457
 458 print "";
 459 print "/* Restore selected current options from a structure.  */";
 460 print "void";
 461 print "cl_target_option_restore (struct cl_target_option *ptr)";
 462 print "{";
 463
 464 for (i = 0; i < n_target_other; i++) {
 465         print "  " var_target_other[i] " = ptr->" var_target_other[i] ";";
 466 }
 467
 468 for (i = 0; i < n_target_int; i++) {
 469         print "  " var_target_int[i] " = ptr->" var_target_int[i] ";";
 470 }
 471
 472 for (i = 0; i < n_target_short; i++) {
 473         print "  " var_target_short[i] " = ptr->" var_target_short[i] ";";
 474 }
 475
 476 for (i = 0; i < n_target_char; i++) {
 477         print "  " var_target_char[i] " = ptr->" var_target_char[i] ";";
 478 }
 479
 480 # This must occur after the normal variables in case the code depends on those
 481 # variables.
 482 print "";
 483 print "  if (targetm.target_option.restore)";
 484 print "    targetm.target_option.restore (ptr);";
 485
 486 print "}";
 487
 488 print "";
 489 print "/* Print optimization options from a structure.  */";
 490 print "void";
 491 print "cl_target_option_print (FILE *file,";
 492 print "                        int indent,";
 493 print "                        struct cl_target_option *ptr)";
 494 print "{";
 495
 496 print "  fputs (\"\\n\", file);";
 497 for (i = 0; i < n_target_other; i++) {
 498         print "  if (ptr->" var_target_other[i] ")";
 499         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 500         print "             indent, \"\",";
 501         print "             \"" var_target_other[i] "\",";
 502         print "             (unsigned long)ptr->" var_target_other[i] ");";
 503         print "";
 504 }
 505
 506 for (i = 0; i < n_target_int; i++) {
 507         print "  if (ptr->" var_target_int[i] ")";
 508         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 509         print "             indent, \"\",";
 510         print "             \"" var_target_int[i] "\",";
 511         print "             ptr->" var_target_int[i] ");";
 512         print "";
 513 }
 514
 515 for (i = 0; i < n_target_short; i++) {
 516         print "  if (ptr->" var_target_short[i] ")";
 517         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 518         print "             indent, \"\",";
 519         print "             \"" var_target_short[i] "\",";
 520         print "             ptr->" var_target_short[i] ");";
 521         print "";
 522 }
 523
 524 for (i = 0; i < n_target_char; i++) {
 525         print "  if (ptr->" var_target_char[i] ")";
 526         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 527         print "             indent, \"\",";
 528         print "             \"" var_target_char[i] "\",";
 529         print "             ptr->" var_target_char[i] ");";
 530         print "";
 531 }
 532
 533 print "";
 534 print "  if (targetm.target_option.print)";
 535 print "    targetm.target_option.print (file, indent, ptr);";
 536
 537 print "}";
 538 print "#endif";
 539
 540 }