libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/dfp.m4)
  10 sinclude(../config/unwind_ipinfo.m4)
  11
  12 AC_PREREQ(2.64)
  13 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  14 AC_CONFIG_SRCDIR([static-object.mk])
  15
  16 AC_ARG_WITH(target-subdir,
  17 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(ld,
  21 [  --with-ld               arrange to use the specified ld (full pathname)])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libgcc_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libgcc_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libgcc_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libgcc_topdir)
  40 AC_CONFIG_AUX_DIR($libgcc_topdir)
  41
  42 AC_ARG_ENABLE(shared,
  43 [  --disable-shared        don't provide a shared libgcc],
  44 [
  45   case $enable_shared in
  46   yes | no) ;;
  47   *)
  48     enable_shared=no
  49     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  50     for pkg in $enableval; do
  51       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  52         enable_shared=yes
  53       fi
  54     done
  55     IFS="$ac_save_ifs"
  56     ;;
  57   esac
  58 ], [enable_shared=yes])
  59 AC_SUBST(enable_shared)
  60
  61 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  62 AC_ARG_ENABLE(version-specific-runtime-libs,
  63 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  64 [case "$enableval" in
  65  yes) version_specific_libs=yes ;;
  66  no)  version_specific_libs=no ;;
  67  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  68  esac],
  69 [version_specific_libs=no])
  70 AC_MSG_RESULT($version_specific_libs)
  71
  72 AC_ARG_WITH(slibdir,
  73 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  74 slibdir="$with_slibdir",
  75 if test "${version_specific_libs}" = yes; then
  76   slibdir='$(libsubdir)'
  77 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  78   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
  79 else
  80   slibdir='$(libdir)'
  81 fi)
  82 AC_SUBST(slibdir)
  83
  84 # Command-line options.
  85 # Very limited version of AC_MAINTAINER_MODE.
  86 AC_ARG_ENABLE([maintainer-mode],
  87   [AC_HELP_STRING([--enable-maintainer-mode],
  88                  [enable make rules and dependencies not useful (and
  89                   sometimes confusing) to the casual installer])],
  90   [case ${enable_maintainer_mode} in
  91      yes) MAINT='' ;;
  92      no) MAINT='#' ;;
  93      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
  94    esac
  95    maintainer_mode=${enableval}],
  96   [MAINT='#'])
  97 AC_SUBST([MAINT])dnl
  98
  99 AC_PROG_INSTALL
 100
 101 AC_PROG_AWK
 102 # We need awk; bail out if it's missing.
 103 case ${AWK} in
 104   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 105 esac
 106
 107 AC_CANONICAL_HOST
 108 ACX_NONCANONICAL_HOST
 109 ACX_NONCANONICAL_TARGET
 110 GCC_TOPLEV_SUBDIRS
 111
 112 # Calculate toolexeclibdir
 113 # Also toolexecdir, though it's only used in toolexeclibdir
 114 case ${version_specific_libs} in
 115   yes)
 116     # Need the gcc compiler version to know where to install libraries
 117     # and header files if --enable-version-specific-runtime-libs option
 118     # is selected.
 119     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 120     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 121     ;;
 122   no)
 123     if test -n "$with_cross_host" &&
 124        test x"$with_cross_host" != x"no"; then
 125       # Install a library built with a cross compiler in tooldir, not libdir.
 126       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 127       toolexeclibdir='$(toolexecdir)/lib'
 128     else
 129       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 130       toolexeclibdir='$(libdir)'
 131     fi
 132     multi_os_directory=`$CC -print-multi-os-directory`
 133     case $multi_os_directory in
 134       .) ;; # Avoid trailing /.
 135       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 136     esac
 137     ;;
 138 esac
 139 AC_SUBST(toolexecdir)
 140 AC_SUBST(toolexeclibdir)
 141
 142 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 143 dnl to call AC_CHECK_PROG.
 144 AC_CHECK_TOOL(AR, ar)
 145 AC_CHECK_TOOL(LIPO, lipo, :)
 146 AC_CHECK_TOOL(NM, nm)
 147 AC_CHECK_TOOL(RANLIB, ranlib, :)
 148 AC_CHECK_TOOL(STRIP, strip, :)
 149 AC_PROG_LN_S
 150
 151 GCC_NO_EXECUTABLES
 152 AC_PROG_CC
 153 AC_PROG_CPP_WERROR
 154
 155 AC_CHECK_SIZEOF([double])
 156 AC_CHECK_SIZEOF([long double])
 157 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 158 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 159 AC_SUBST(double_type_size)
 160 AC_SUBST(long_double_type_size)
 161
 162 # Check for decimal float support.
 163 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 164                [AC_COMPILE_IFELSE([_Decimal32 x;], [libgcc_cv_dfp=yes],
 165                                   [libgcc_cv_dfp=no])])
 166 decimal_float=$libgcc_cv_dfp
 167 AC_SUBST(decimal_float)
 168
 169 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 170
 171 # Check for fixed-point support.
 172 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 173                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 174                                   [libgcc_cv_fixed_point=no])])
 175 fixed_point=$libgcc_cv_fixed_point
 176 AC_SUBST(fixed_point)
 177
 178 # For platforms with the unwind ABI which includes an unwind library,
 179 # libunwind, we can choose to use the system libunwind.
 180 # config.gcc also contains tests of with_system_libunwind.
 181 GCC_CHECK_UNWIND_GETIPINFO
 182
 183 AC_LIB_PROG_LD_GNU
 184
 185 AC_MSG_CHECKING([for thread model used by GCC])
 186 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 187 AC_MSG_RESULT([$target_thread_file])
 188
 189 # Check for assembler CFI support.
 190 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 191                [AC_COMPILE_IFELSE(
 192 [asm("\n\
 193         .text\n\
 194         .cfi_startproc\n\
 195         .cfi_personality 0, symbol\n\
 196         .cfi_endproc");],
 197   [libgcc_cv_cfi=yes],
 198   [libgcc_cv_cfi=no])])
 199
 200 # Check 32bit or 64bit for x86.
 201 case ${host} in
 202 i?86*-*-* | x86_64*-*-*)
 203   cat > conftest.c <<EOF
 204 #ifdef __x86_64__
 205 host_address=64
 206 #else
 207 host_address=32
 208 #endif
 209 EOF
 210     eval `${CC-cc} -E conftest.c | grep host_address=`
 211     rm -f conftest.c
 212     ;;
 213 esac
 214
 215 # Collect host-machine-specific information.
 216 . ${srcdir}/config.host
 217
 218 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 219 # This is after config.host so we can augment tmake_file.
 220 # Link with -nostartfiles -nodefaultlibs since neither are present while
 221 # building libgcc.
 222 case ${host} in
 223 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 224   cat > conftest.s <<EOF
 225         .section        .eh_frame,"a",@unwind
 226         .zero   4
 227         .section        .jcr,"aw",@progbits
 228         .zero   8
 229 EOF
 230   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 231       tmake_file="${tmake_file} i386/t-crtstuff"
 232   fi
 233   ;;
 234 esac
 235
 236 # Check for visibility support.  This is after config.host so that
 237 # we can check for asm_hidden_op.
 238 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 239     libgcc_cv_hidden_visibility_attribute, [
 240         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 241         libgcc_cv_hidden_visibility_attribute=no
 242         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 243             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 244                 libgcc_cv_hidden_visibility_attribute=yes
 245             fi
 246         fi
 247         rm -f conftest.*
 248     ])
 249
 250 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 251     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 252 else
 253     vis_hide=
 254 fi
 255 AC_SUBST(vis_hide)
 256
 257 # See if we have thread-local storage.  We can only test assembler
 258 # sicne link-time and run-time tests require the newly built
 259 # gcc, which can't be used to build executable due to that libgcc
 260 # is yet to be built here.
 261 GCC_CHECK_CC_TLS
 262 set_have_cc_tls=
 263 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 264   set_have_cc_tls="-DHAVE_CC_TLS"
 265 fi
 266 AC_SUBST(set_have_cc_tls)
 267
 268 # See if we have emulated thread-local storage.
 269 GCC_CHECK_EMUTLS
 270 set_use_emutls=
 271 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 272   set_use_emutls="-DUSE_EMUTLS"
 273 fi
 274 AC_SUBST(set_use_emutls)
 275
 276 # Conditionalize the sfp-machine.h header for this target machine.
 277 if test -z "${sfp_machine_header}"; then
 278         sfp_machine_header=$cpu_type/sfp-machine.h
 279         if test -f ${srcdir}/config/${sfp_machine_header}; then
 280                 :
 281         else
 282                 sfp_machine_header=no-sfp-machine.h
 283         fi
 284 fi
 285 AC_SUBST(sfp_machine_header)
 286
 287 # Conditionalize the makefile for this target machine.
 288 tmake_file_=
 289 for f in ${tmake_file}
 290 do
 291         if test -f ${srcdir}/config/$f
 292         then
 293                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 294         fi
 295 done
 296 tmake_file="${tmake_file_}"
 297 AC_SUBST(tmake_file)
 298
 299 # Substitute configuration variables
 300 AC_SUBST(cpu_type)
 301 AC_SUBST(extra_parts)
 302 AC_SUBST(asm_hidden_op)
 303 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 304 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 305 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 306 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 307
 308 # We need multilib support.
 309 AC_CONFIG_FILES([Makefile])
 310 AC_CONFIG_COMMANDS([default],
 311   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 312 if test -n "$CONFIG_FILES"; then
 313   # FIXME: We shouldn't need to set ac_file
 314   ac_file=Makefile
 315   . ${libgcc_topdir}/config-ml.in
 316 fi]],
 317 [[srcdir=${srcdir}
 318 host=${host}
 319 with_target_subdir=${with_target_subdir}
 320 with_multisubdir=${with_multisubdir}
 321 ac_configure_args="--enable-multilib ${ac_configure_args}"
 322 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 323 libgcc_topdir=${libgcc_topdir}
 324 CC="${CC}"
 325 ]])
 326 AC_OUTPUT