libgfortran/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU Fortran Runtime Library], 0.3,,[libgfortran])
   6 AC_CONFIG_HEADER(config.h)
   7 GCC_TOPLEV_SUBDIRS
   8
   9 # -------
  10 # Options
  11 # -------
  12
  13 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  14 AC_ARG_ENABLE(version-specific-runtime-libs,
  15 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  16   [specify that runtime libraries should be installed in a compiler-specific directory]),
  17 [case "$enableval" in
  18  yes) version_specific_libs=yes ;;
  19  no)  version_specific_libs=no ;;
  20  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  21  esac],
  22 [version_specific_libs=no])
  23 AC_MSG_RESULT($version_specific_libs)
  24
  25 # Build with intermodule optimisations
  26 AC_MSG_CHECKING([for --enable-intermodule])
  27 AC_ARG_ENABLE(intermodule,
  28 AS_HELP_STRING([--enable-intermodule],[build the library in one step]),
  29 [case "$enable_intermodule" in
  30   yes) onestep="-onestep";;
  31     *) onestep="";;
  32 esac],
  33 [onestep=""])
  34 AC_MSG_RESULT($enable_intermodule)
  35 AM_CONDITIONAL(onestep,[test x$onestep = x-onestep])
  36 AC_SUBST(onestep)
  37
  38 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  39 #
  40 # You will slowly go insane if you do not grok the following fact:  when
  41 # building this library, the top-level /target/ becomes the library's /host/.
  42 #
  43 # configure then causes --target to default to --host, exactly like any
  44 # other package using autoconf.  Therefore, 'target' and 'host' will
  45 # always be the same.  This makes sense both for native and cross compilers
  46 # just think about it for a little while.  :-)
  47 #
  48 # Also, if this library is being configured as part of a cross compiler, the
  49 # top-level configure script will pass the "real" host as $with_cross_host.
  50 #
  51 # Do not delete or change the following two lines.  For why, see
  52 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  53 AC_CANONICAL_SYSTEM
  54 ACX_NONCANONICAL_TARGET
  55
  56 target_alias=${target_alias-$host_alias}
  57 AC_SUBST(target_alias)
  58
  59 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  60 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  61 #  1.9.6:  minimum required version
  62 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  63 #              of other PACKAGE_* variables will, however, and there's nothing
  64 #              we can do about that; they come from AC_INIT).
  65 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  66 #            file in the top srcdir, etc, etc), so stop complaining.
  67 #  no-dist:  we don't want 'dist' and related rules.
  68 #  -Wall:  turns on all automake warnings...
  69 #  -Wno-portability:  ...except this one, since GNU make is required.
  70 AM_INIT_AUTOMAKE([1.9.6 no-define foreign no-dist -Wall -Wno-portability])
  71
  72 AM_MAINTAINER_MODE
  73 AM_ENABLE_MULTILIB(, ..)
  74
  75 # Handy for debugging:
  76 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  77
  78 # Are we being configured with some form of cross compiler?
  79 # NB: We don't actually need to know this just now, but when, say, a test
  80 #     suite is included, we'll have to know.
  81 if test "$build" != "$host"; then
  82   LIBGFOR_IS_NATIVE=false
  83   GCC_NO_EXECUTABLES
  84 else
  85   LIBGFOR_IS_NATIVE=true
  86 fi
  87
  88 AC_USE_SYSTEM_EXTENSIONS
  89
  90 # Calculate toolexeclibdir
  91 # Also toolexecdir, though it's only used in toolexeclibdir
  92 case ${version_specific_libs} in
  93   yes)
  94     # Need the gcc compiler version to know where to install libraries
  95     # and header files if --enable-version-specific-runtime-libs option
  96     # is selected.
  97     toolexecdir='$(libdir)/gcc/$(target_alias)'
  98     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  99     ;;
 100   no)
 101     if test -n "$with_cross_host" &&
 102        test x"$with_cross_host" != x"no"; then
 103       # Install a library built with a cross compiler in tooldir, not libdir.
 104       toolexecdir='$(exec_prefix)/$(target_alias)'
 105       toolexeclibdir='$(toolexecdir)/lib'
 106     else
 107       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 108       toolexeclibdir='$(libdir)'
 109     fi
 110     multi_os_directory=`$CC -print-multi-os-directory`
 111     case $multi_os_directory in
 112       .) ;; # Avoid trailing /.
 113       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 114     esac
 115     ;;
 116 esac
 117 AC_SUBST(toolexecdir)
 118 AC_SUBST(toolexeclibdir)
 119
 120 # Create a spec file, so that compile/link tests don't fail
 121 test -f libgfortran.spec || touch libgfortran.spec
 122
 123 AC_LANG_C
 124 # Check the compiler.
 125 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 126 # We must force CC to /not/ be precious variables; otherwise
 127 # the wrong, non-multilib-adjusted value will be used in multilibs.
 128 # As a side effect, we have to subst CFLAGS ourselves.
 129
 130 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 131 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 132 AC_PROG_CC
 133 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 134
 135 AC_SUBST(CFLAGS)
 136
 137 AM_PROG_CC_C_O
 138
 139 # Add -Wall -fno-repack-arrays -fno-underscoring if we are using GCC.
 140 if test "x$GCC" = "xyes"; then
 141   AM_FCFLAGS="-I . -Wall -Werror -fimplicit-none -fno-repack-arrays -fno-underscoring"
 142   ## We like to use C11 and C99 routines when available.  This makes
 143   ## sure that
 144   ## __STDC_VERSION__ is set such that libc includes make them available.
 145   AM_CFLAGS="-std=gnu11 -Wall -Wstrict-prototypes -Wmissing-prototypes -Wold-style-definition -Wextra -Wwrite-strings -Werror=implicit-function-declaration -Werror=vla"
 146   ## Compile the following tests with the same system header contents
 147   ## that we'll encounter when compiling our own source files.
 148   CFLAGS="-std=gnu11 $CFLAGS"
 149 fi
 150 AC_SUBST(AM_FCFLAGS)
 151 AC_SUBST(AM_CFLAGS)
 152 AC_SUBST(CFLAGS)
 153
 154 # Check for symbol versioning (copied from libssp).
 155 AC_MSG_CHECKING([whether symbol versioning is supported])
 156 AC_ARG_ENABLE(symvers,
 157 AS_HELP_STRING([--disable-symvers],
 158   [disable symbol versioning for libgfortran]),
 159 gfortran_use_symver=$enableval,
 160 gfortran_use_symver=yes)
 161 if test "x$gfortran_use_symver" != xno; then
 162   save_LDFLAGS="$LDFLAGS"
 163   LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 164   cat > conftest.map <<EOF
 165 FOO_1.0 {
 166   global: *foo*; bar; local: *;
 167 };
 168 EOF
 169   AC_LINK_IFELSE([AC_LANG_PROGRAM([[int foo;]],[[]])],[gfortran_use_symver=gnu],[gfortran_use_symver=no])
 170   if test x$gfortran_use_symver = xno; then
 171     case "$target_os" in
 172       solaris2*)
 173         LDFLAGS="$save_LDFLAGS"
 174         LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 175         # Sun ld cannot handle wildcards and treats all entries as undefined.
 176         cat > conftest.map <<EOF
 177 FOO_1.0 {
 178   global: foo; local: *;
 179 };
 180 EOF
 181         AC_LINK_IFELSE([AC_LANG_PROGRAM([[int foo;]],[[]])],[gfortran_use_symver=sun],[gfortran_use_symver=no])
 182         ;;
 183     esac
 184   fi
 185   LDFLAGS="$save_LDFLAGS"
 186 fi
 187 AC_MSG_RESULT($gfortran_use_symver)
 188 AM_CONDITIONAL(LIBGFOR_USE_SYMVER, [test "x$gfortran_use_symver" != xno])
 189 AM_CONDITIONAL(LIBGFOR_USE_SYMVER_GNU, [test "x$gfortran_use_symver" = xgnu])
 190 AM_CONDITIONAL(LIBGFOR_USE_SYMVER_SUN, [test "x$gfortran_use_symver" = xsun])
 191
 192 # For GPU offloading, not everything in libfortran can be supported.
 193 # Currently, the only target that has this problem is nvptx.  The
 194 # following is a (partial) list of features that are unsupportable on
 195 # this particular target:
 196 # * Constructors
 197 # * alloca
 198 # * C library support for I/O, with printf as the one notable exception
 199 # * C library support for other features such as signal, environment
 200 #   variables, time functions
 201
 202 AM_CONDITIONAL(LIBGFOR_MINIMAL, [test "x${target_cpu}" = xnvptx])
 203
 204 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
 205 # similarly to how libstdc++ does it
 206 ac_test_CFLAGS="${CFLAGS+set}"
 207 ac_save_CFLAGS="$CFLAGS"
 208
 209 # Check for -ffunction-sections -fdata-sections
 210 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
 211 CFLAGS='-Werror -ffunction-sections -fdata-sections'
 212 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int foo;]])], [ac_fdsections=yes], [ac_fdsections=no])
 213 if test "$ac_test_CFLAGS" = set; then
 214   CFLAGS="$ac_save_CFLAGS"
 215 else
 216   # this is the suspicious part
 217   CFLAGS=""
 218 fi
 219 if test x"$ac_fdsections" = x"yes"; then
 220   SECTION_FLAGS='-ffunction-sections -fdata-sections'
 221 fi
 222 AC_MSG_RESULT($ac_fdsections)
 223 AC_SUBST(SECTION_FLAGS)
 224
 225 # Check linker hardware capability support.
 226 GCC_CHECK_LINKER_HWCAP
 227
 228 # Find other programs we need.
 229 AC_CHECK_TOOL(AS, as)
 230 AC_CHECK_TOOL(AR, ar)
 231 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 232 AC_PROG_MAKE_SET
 233 AC_PROG_INSTALL
 234
 235 # Configure libtool
 236 #AC_MSG_NOTICE([====== Starting libtool configuration])
 237 AC_LIBTOOL_DLOPEN
 238 AM_PROG_LIBTOOL
 239 ACX_LT_HOST_FLAGS
 240 AC_SUBST(enable_shared)
 241 AC_SUBST(enable_static)
 242 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
 243
 244 # We need gfortran to compile parts of the library
 245 #AC_PROG_FC(gfortran)
 246 FC="$GFORTRAN"
 247 AC_PROG_FC(gfortran)
 248
 249 # extra LD Flags which are required for targets
 250 case "${host}" in
 251   *-darwin*)
 252     # Darwin needs -single_module when linking libgfortran
 253     extra_ldflags_libgfortran=-Wl,-single_module
 254     ;;
 255 esac
 256 AC_SUBST(extra_ldflags_libgfortran)
 257
 258 # We need a working compiler at that point, otherwise give a clear
 259 # error message and bail out.
 260 LIBGFOR_WORKING_GFORTRAN
 261
 262 AC_SYS_LARGEFILE
 263
 264 # Types
 265 AC_TYPE_OFF_T
 266 AC_TYPE_INTPTR_T
 267 AC_TYPE_UINTPTR_T
 268 AC_CHECK_TYPES([ptrdiff_t])
 269
 270 # check header files (we assume C89 is available, so don't check for that)
 271 AC_CHECK_HEADERS_ONCE(unistd.h sys/time.h sys/times.h sys/resource.h \
 272 sys/types.h sys/stat.h sys/wait.h floatingpoint.h ieeefp.h fenv.h fptrap.h \
 273 fpxcp.h pwd.h complex.h xlocale.h)
 274
 275 GCC_HEADER_STDINT(gstdint.h)
 276
 277 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct stat.st_rdev])
 278
 279 case "${host}--x${with_newlib}" in
 280   mips*--xyes)
 281     hardwire_newlib=1;;
 282   nvptx*--xyes)
 283     hardwire_newlib=1;;
 284 esac
 285
 286 # Check for library functions.
 287 if test "${hardwire_newlib:-0}" -eq 1; then
 288    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 289    # may not work correctly, because the compiler may not be able to
 290    # link executables.
 291    AC_DEFINE(HAVE_MKSTEMP, 1, [Define if you have mkstemp.])
 292    AC_DEFINE(HAVE_STRTOF, 1, [Define if you have strtof.])
 293    AC_DEFINE(HAVE_SNPRINTF, 1, [Define if you have snprintf.])
 294    AC_DEFINE(HAVE_VSNPRINTF, 1, [Define if you have vsnprintf.])
 295    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have localtime_r.])
 296    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have gmtime_r.])
 297    AC_DEFINE(HAVE_STRNLEN, 1, [Define if you have strnlen.])
 298    AC_DEFINE(HAVE_STRNDUP, 1, [Define if you have strndup.])
 299
 300    # At some point, we should differentiate between architectures
 301    # like x86, which have long double versions, and alpha/powerpc/etc.,
 302    # which don't. For the time being, punt.
 303    if test x"long_double_math_on_this_cpu" = x"yes"; then
 304      AC_DEFINE(HAVE_STRTOLD, 1, [Define if you have strtold.])
 305    fi
 306 else
 307    AC_CHECK_FUNCS_ONCE(getrusage times mkstemp strtof strtold snprintf \
 308    ftruncate chsize chdir getlogin gethostname kill link symlink sleep ttyname \
 309    alarm access fork setmode fcntl \
 310    gettimeofday stat fstat lstat getpwuid vsnprintf dup \
 311    getcwd localtime_r gmtime_r getpwuid_r ttyname_r clock_gettime \
 312    getgid getpid getuid geteuid umask getegid \
 313    secure_getenv __secure_getenv mkostemp strnlen strndup newlocale \
 314    freelocale uselocale strerror_l)
 315 fi
 316
 317 # Check strerror_r, cannot be above as versions with two and three arguments exist
 318 LIBGFOR_CHECK_STRERROR_R
 319
 320 # Check for C99 (and other IEEE) math functions
 321 GCC_CHECK_MATH_FUNC([acosf])
 322 GCC_CHECK_MATH_FUNC([acos])
 323 GCC_CHECK_MATH_FUNC([acosl])
 324 GCC_CHECK_MATH_FUNC([acoshf])
 325 GCC_CHECK_MATH_FUNC([acosh])
 326 GCC_CHECK_MATH_FUNC([acoshl])
 327 GCC_CHECK_MATH_FUNC([asinf])
 328 GCC_CHECK_MATH_FUNC([asin])
 329 GCC_CHECK_MATH_FUNC([asinl])
 330 GCC_CHECK_MATH_FUNC([asinhf])
 331 GCC_CHECK_MATH_FUNC([asinh])
 332 GCC_CHECK_MATH_FUNC([asinhl])
 333 GCC_CHECK_MATH_FUNC([atan2f])
 334 GCC_CHECK_MATH_FUNC([atan2])
 335 GCC_CHECK_MATH_FUNC([atan2l])
 336 GCC_CHECK_MATH_FUNC([atanf])
 337 GCC_CHECK_MATH_FUNC([atan])
 338 GCC_CHECK_MATH_FUNC([atanl])
 339 GCC_CHECK_MATH_FUNC([atanhf])
 340 GCC_CHECK_MATH_FUNC([atanh])
 341 GCC_CHECK_MATH_FUNC([atanhl])
 342 GCC_CHECK_MATH_FUNC([cargf])
 343 GCC_CHECK_MATH_FUNC([carg])
 344 GCC_CHECK_MATH_FUNC([cargl])
 345 GCC_CHECK_MATH_FUNC([ceilf])
 346 GCC_CHECK_MATH_FUNC([ceil])
 347 GCC_CHECK_MATH_FUNC([ceill])
 348 GCC_CHECK_MATH_FUNC([copysignf])
 349 GCC_CHECK_MATH_FUNC([copysign])
 350 GCC_CHECK_MATH_FUNC([copysignl])
 351 GCC_CHECK_MATH_FUNC([cosf])
 352 GCC_CHECK_MATH_FUNC([cos])
 353 GCC_CHECK_MATH_FUNC([cosl])
 354 GCC_CHECK_MATH_FUNC([ccosf])
 355 GCC_CHECK_MATH_FUNC([ccos])
 356 GCC_CHECK_MATH_FUNC([ccosl])
 357 GCC_CHECK_MATH_FUNC([coshf])
 358 GCC_CHECK_MATH_FUNC([cosh])
 359 GCC_CHECK_MATH_FUNC([coshl])
 360 GCC_CHECK_MATH_FUNC([ccoshf])
 361 GCC_CHECK_MATH_FUNC([ccosh])
 362 GCC_CHECK_MATH_FUNC([ccoshl])
 363 GCC_CHECK_MATH_FUNC([expf])
 364 GCC_CHECK_MATH_FUNC([exp])
 365 GCC_CHECK_MATH_FUNC([expl])
 366 GCC_CHECK_MATH_FUNC([cexpf])
 367 GCC_CHECK_MATH_FUNC([cexp])
 368 GCC_CHECK_MATH_FUNC([cexpl])
 369 GCC_CHECK_MATH_FUNC([fabsf])
 370 GCC_CHECK_MATH_FUNC([fabs])
 371 GCC_CHECK_MATH_FUNC([fabsl])
 372 GCC_CHECK_MATH_FUNC([cabsf])
 373 GCC_CHECK_MATH_FUNC([cabs])
 374 GCC_CHECK_MATH_FUNC([cabsl])
 375 GCC_CHECK_MATH_FUNC([floorf])
 376 GCC_CHECK_MATH_FUNC([floor])
 377 GCC_CHECK_MATH_FUNC([floorl])
 378 GCC_CHECK_MATH_FUNC([fmodf])
 379 GCC_CHECK_MATH_FUNC([fmod])
 380 GCC_CHECK_MATH_FUNC([fmodl])
 381 GCC_CHECK_MATH_FUNC([frexpf])
 382 GCC_CHECK_MATH_FUNC([frexp])
 383 GCC_CHECK_MATH_FUNC([frexpl])
 384 GCC_CHECK_MATH_FUNC([hypotf])
 385 GCC_CHECK_MATH_FUNC([hypot])
 386 GCC_CHECK_MATH_FUNC([hypotl])
 387 GCC_CHECK_MATH_FUNC([ldexpf])
 388 GCC_CHECK_MATH_FUNC([ldexp])
 389 GCC_CHECK_MATH_FUNC([ldexpl])
 390 GCC_CHECK_MATH_FUNC([logf])
 391 GCC_CHECK_MATH_FUNC([log])
 392 GCC_CHECK_MATH_FUNC([logl])
 393 GCC_CHECK_MATH_FUNC([clogf])
 394 GCC_CHECK_MATH_FUNC([clog])
 395 GCC_CHECK_MATH_FUNC([clogl])
 396 GCC_CHECK_MATH_FUNC([log10f])
 397 GCC_CHECK_MATH_FUNC([log10])
 398 GCC_CHECK_MATH_FUNC([log10l])
 399 GCC_CHECK_MATH_FUNC([clog10f])
 400 GCC_CHECK_MATH_FUNC([clog10])
 401 GCC_CHECK_MATH_FUNC([clog10l])
 402 GCC_CHECK_MATH_FUNC([nextafterf])
 403 GCC_CHECK_MATH_FUNC([nextafter])
 404 GCC_CHECK_MATH_FUNC([nextafterl])
 405 GCC_CHECK_MATH_FUNC([powf])
 406 GCC_CHECK_MATH_FUNC([pow])
 407 GCC_CHECK_MATH_FUNC([cpowf])
 408 GCC_CHECK_MATH_FUNC([cpow])
 409 GCC_CHECK_MATH_FUNC([cpowl])
 410 GCC_CHECK_MATH_FUNC([roundf])
 411 GCC_CHECK_MATH_FUNC([round])
 412 GCC_CHECK_MATH_FUNC([roundl])
 413 GCC_CHECK_MATH_FUNC([lroundf])
 414 GCC_CHECK_MATH_FUNC([lround])
 415 GCC_CHECK_MATH_FUNC([lroundl])
 416 GCC_CHECK_MATH_FUNC([llroundf])
 417 GCC_CHECK_MATH_FUNC([llround])
 418 GCC_CHECK_MATH_FUNC([llroundl])
 419 GCC_CHECK_MATH_FUNC([scalbnf])
 420 GCC_CHECK_MATH_FUNC([scalbn])
 421 GCC_CHECK_MATH_FUNC([scalbnl])
 422 GCC_CHECK_MATH_FUNC([sinf])
 423 GCC_CHECK_MATH_FUNC([sin])
 424 GCC_CHECK_MATH_FUNC([sinl])
 425 GCC_CHECK_MATH_FUNC([csinf])
 426 GCC_CHECK_MATH_FUNC([csin])
 427 GCC_CHECK_MATH_FUNC([csinl])
 428 GCC_CHECK_MATH_FUNC([sinhf])
 429 GCC_CHECK_MATH_FUNC([sinh])
 430 GCC_CHECK_MATH_FUNC([sinhl])
 431 GCC_CHECK_MATH_FUNC([csinhf])
 432 GCC_CHECK_MATH_FUNC([csinh])
 433 GCC_CHECK_MATH_FUNC([csinhl])
 434 GCC_CHECK_MATH_FUNC([sqrtf])
 435 GCC_CHECK_MATH_FUNC([sqrt])
 436 GCC_CHECK_MATH_FUNC([sqrtl])
 437 GCC_CHECK_MATH_FUNC([csqrtf])
 438 GCC_CHECK_MATH_FUNC([csqrt])
 439 GCC_CHECK_MATH_FUNC([csqrtl])
 440 GCC_CHECK_MATH_FUNC([tanf])
 441 GCC_CHECK_MATH_FUNC([tan])
 442 GCC_CHECK_MATH_FUNC([tanl])
 443 GCC_CHECK_MATH_FUNC([ctanf])
 444 GCC_CHECK_MATH_FUNC([ctan])
 445 GCC_CHECK_MATH_FUNC([ctanl])
 446 GCC_CHECK_MATH_FUNC([tanhf])
 447 GCC_CHECK_MATH_FUNC([tanh])
 448 GCC_CHECK_MATH_FUNC([tanhl])
 449 GCC_CHECK_MATH_FUNC([ctanhf])
 450 GCC_CHECK_MATH_FUNC([ctanh])
 451 GCC_CHECK_MATH_FUNC([ctanhl])
 452 GCC_CHECK_MATH_FUNC([truncf])
 453 GCC_CHECK_MATH_FUNC([trunc])
 454 GCC_CHECK_MATH_FUNC([truncl])
 455 GCC_CHECK_MATH_FUNC([erff])
 456 GCC_CHECK_MATH_FUNC([erf])
 457 GCC_CHECK_MATH_FUNC([erfcf])
 458 GCC_CHECK_MATH_FUNC([erfc])
 459 GCC_CHECK_MATH_FUNC([erfcl])
 460 GCC_CHECK_MATH_FUNC([j0f])
 461 GCC_CHECK_MATH_FUNC([j0])
 462 GCC_CHECK_MATH_FUNC([j1f])
 463 GCC_CHECK_MATH_FUNC([j1])
 464 GCC_CHECK_MATH_FUNC([jnf])
 465 GCC_CHECK_MATH_FUNC([jn])
 466 GCC_CHECK_MATH_FUNC([jnl])
 467 GCC_CHECK_MATH_FUNC([y0f])
 468 GCC_CHECK_MATH_FUNC([y0])
 469 GCC_CHECK_MATH_FUNC([y1f])
 470 GCC_CHECK_MATH_FUNC([y1])
 471 GCC_CHECK_MATH_FUNC([ynf])
 472 GCC_CHECK_MATH_FUNC([yn])
 473 GCC_CHECK_MATH_FUNC([ynl])
 474 GCC_CHECK_MATH_FUNC([tgamma])
 475 GCC_CHECK_MATH_FUNC([tgammaf])
 476 GCC_CHECK_MATH_FUNC([lgamma])
 477 GCC_CHECK_MATH_FUNC([lgammaf])
 478
 479 # Check for GFORTRAN_C99_1.1 funcs
 480 GCC_CHECK_MATH_FUNC([cacos])
 481 GCC_CHECK_MATH_FUNC([cacosf])
 482 GCC_CHECK_MATH_FUNC([cacosh])
 483 GCC_CHECK_MATH_FUNC([cacoshf])
 484 GCC_CHECK_MATH_FUNC([cacoshl])
 485 GCC_CHECK_MATH_FUNC([cacosl])
 486 GCC_CHECK_MATH_FUNC([casin])
 487 GCC_CHECK_MATH_FUNC([casinf])
 488 GCC_CHECK_MATH_FUNC([casinh])
 489 GCC_CHECK_MATH_FUNC([casinhf])
 490 GCC_CHECK_MATH_FUNC([casinhl])
 491 GCC_CHECK_MATH_FUNC([casinl])
 492 GCC_CHECK_MATH_FUNC([catan])
 493 GCC_CHECK_MATH_FUNC([catanf])
 494 GCC_CHECK_MATH_FUNC([catanh])
 495 GCC_CHECK_MATH_FUNC([catanhf])
 496 GCC_CHECK_MATH_FUNC([catanhl])
 497 GCC_CHECK_MATH_FUNC([catanl])
 498
 499 # On AIX, clog is present in libm as __clog
 500 AC_CHECK_LIB([m],[__clog],[AC_DEFINE([HAVE_CLOG],[1],[libm includes clog])])
 501
 502 # Check whether the system has a working stat()
 503 LIBGFOR_CHECK_WORKING_STAT
 504
 505 # Check whether __mingw_snprintf() is present
 506 LIBGFOR_CHECK_MINGW_SNPRINTF
 507
 508 # Check whether libquadmath should be used
 509 AC_ARG_ENABLE(libquadmath-support,
 510 AS_HELP_STRING([--disable-libquadmath-support],
 511   [disable libquadmath support for Fortran]),
 512 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 513 ENABLE_LIBQUADMATH_SUPPORT=yes)
 514 enable_libquadmath_support=
 515 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 516   enable_libquadmath_support=no
 517 fi
 518
 519 # Check whether we have a __float128 type, depends on enable_libquadmath_support
 520 LIBGFOR_CHECK_FLOAT128
 521
 522 # Check for GNU libc feenableexcept
 523 AC_CHECK_LIB([m],[feenableexcept],[have_feenableexcept=yes AC_DEFINE([HAVE_FEENABLEEXCEPT],[1],[libm includes feenableexcept])])
 524
 525 # At least for glibc, clock_gettime is in librt.  But don't
 526 # pull that in if it still doesn't give us the function we want.  This
 527 # test is copied from libgomp, and modified to not link in -lrt as
 528 # libgfortran calls clock_gettime via a weak reference if it's found
 529 # in librt.
 530 if test "$ac_cv_func_clock_gettime" = no; then
 531   AC_CHECK_LIB(rt, clock_gettime,
 532     [AC_DEFINE(HAVE_CLOCK_GETTIME_LIBRT, 1,
 533                [Define to 1 if you have the `clock_gettime' function in librt.])])
 534 fi
 535
 536 # Check for SysV fpsetmask
 537 LIBGFOR_CHECK_FPSETMASK
 538 AC_CHECK_TYPES([fp_except,fp_except_t], [], [], [[
 539 #ifdef HAVE_IEEEFP_H
 540 #include <ieeefp.h>
 541 #endif
 542 #include <math.h>
 543 ]])
 544 AC_CHECK_TYPES([fp_rnd,fp_rnd_t], [], [], [[
 545 #ifdef HAVE_IEEEFP_H
 546 #include <ieeefp.h>
 547 #endif
 548 #include <math.h>
 549 ]])
 550
 551 # Check whether we have fpsetsticky or fpresetsticky
 552 AC_CHECK_FUNC([fpsetsticky],[have_fpsetsticky=yes AC_DEFINE([HAVE_FPSETSTICKY],[1],[fpsetsticky is present])])
 553 AC_CHECK_FUNC([fpresetsticky],[have_fpresetsticky=yes AC_DEFINE([HAVE_FPRESETSTICKY],[1],[fpresetsticky is present])])
 554
 555 # Check for AIX fp_trap and fp_enable
 556 AC_CHECK_FUNC([fp_trap],[have_fp_trap=yes AC_DEFINE([HAVE_FP_TRAP],[1],[fp_trap is present])])
 557 AC_CHECK_FUNC([fp_enable],[have_fp_enable=yes AC_DEFINE([HAVE_FP_ENABLE],[1],[fp_enable is present])])
 558
 559 # Check if _SOFT_FLOAT is defined
 560 AC_CHECK_DEFINE([_SOFT_FLOAT],[have_soft_float=yes])
 561
 562 # Runs configure.host to set up necessary host-dependent shell variables.
 563 # We then display a message about it, and propagate them through the
 564 # build chain.
 565 . ${srcdir}/configure.host
 566 AC_MSG_NOTICE([FPU dependent file will be ${fpu_host}.h])
 567 AC_MSG_NOTICE([Support for IEEE modules: ${ieee_support}])
 568 FPU_HOST_HEADER=config/${fpu_host}.h
 569 AC_SUBST(FPU_HOST_HEADER)
 570
 571 # Whether we will build the IEEE modules
 572 AM_CONDITIONAL(IEEE_SUPPORT,[test x${ieee_support} = xyes])
 573 AC_SUBST(IEEE_SUPPORT)
 574
 575 # Some targets require additional compiler options for IEEE compatibility.
 576 IEEE_FLAGS="${ieee_flags}"
 577 AC_SUBST(IEEE_FLAGS)
 578
 579
 580 # Check for POSIX getpwuid_r
 581 #
 582 # There are two versions of getpwuid_r, the POSIX one with 5
 583 # arguments, and another one with 4 arguments used by at least HP-UX
 584 # 10.2.
 585 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 586    AC_CACHE_CHECK([POSIX version of getpwuid_r with 5 arguments], libgfor_cv_posix_getpwuid_r, [
 587    AC_LINK_IFELSE([AC_LANG_PROGRAM([
 588 #include <stdio.h>
 589 #include <sys/types.h>
 590 #include <pwd.h>], [
 591     getpwuid_r(0, NULL, NULL, 0, NULL);
 592     ])],  [libgfor_cv_posix_getpwuid_r="yes"], [libgfor_cv_posix_getpwuid_r="no"])])
 593 fi
 594 if test "$libgfor_cv_posix_getpwuid_r" = "yes"; then
 595     AC_DEFINE([HAVE_POSIX_GETPWUID_R], [1], [Define to 1 if we have POSIX getpwuid_r which takes 5 arguments.])
 596 fi
 597
 598
 599 # Check out attribute support.
 600 LIBGFOR_CHECK_ATTRIBUTE_VISIBILITY
 601 LIBGFOR_CHECK_ATTRIBUTE_ALIAS
 602
 603 # Check out sync builtins support.
 604 LIBGFOR_CHECK_SYNC_FETCH_AND_ADD
 605
 606 # Check out #pragma weak.
 607 LIBGFOR_GTHREAD_WEAK
 608
 609 # Check out weakref support.
 610 LIBGFOR_CHECK_WEAKREF
 611
 612 # Various other checks on target
 613 LIBGFOR_CHECK_UNLINK_OPEN_FILE
 614
 615 # Check whether line terminator is LF or CRLF
 616 LIBGFOR_CHECK_CRLF
 617
 618 # Check whether we support AVX extensions
 619 LIBGFOR_CHECK_AVX
 620
 621 # Check wether we support AVX2 extensions
 622 LIBGFOR_CHECK_AVX2
 623
 624 # Check wether we support AVX512f extensions
 625 LIBGFOR_CHECK_AVX512F
 626
 627 # Check for FMA3 extensions
 628 LIBGFOR_CHECK_FMA3
 629
 630 # Check for FMA4 extensions
 631 LIBGFOR_CHECK_FMA4
 632
 633 # Check if AVX128 works
 634 LIBGFOR_CHECK_AVX128
 635
 636 # Determine what GCC version number to use in filesystem paths.
 637 GCC_BASE_VER
 638
 639 AC_CACHE_SAVE
 640
 641 if test ${multilib} = yes; then
 642   multilib_arg="--enable-multilib"
 643 else
 644   multilib_arg=
 645 fi
 646
 647 # Write our Makefile and spec file.
 648 AC_CONFIG_FILES([
 649 Makefile
 650 libgfortran.spec
 651 ])
 652 AC_OUTPUT