gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997-2013 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 3, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 # --------------------------------
  23 # Initialization and sanity checks
  24 # --------------------------------
  25
  26 AC_PREREQ(2.64)
  27 AC_INIT
  28 AC_CONFIG_SRCDIR(tree.c)
  29 AC_CONFIG_HEADER(auto-host.h:config.in)
  30
  31 gcc_version=`cat $srcdir/BASE-VER`
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 ACX_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [AS_HELP_STRING([--with-local-prefix=DIR],
 108                 [specifies directory to put local include])],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 127                 [specifies directory to put g++ header files])],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 gcc_gxx_include_dir_add_sysroot=0
 148 if test "${with_sysroot+set}" = set; then
 149   gcc_gxx_without_sysroot=`expr "${gcc_gxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 150   if test "${gcc_gxx_without_sysroot}"; then
 151     gcc_gxx_include_dir="${gcc_gxx_without_sysroot}"
 152     gcc_gxx_include_dir_add_sysroot=1
 153   fi
 154 fi
 155
 156 AC_ARG_WITH(cpp_install_dir,
 157 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 158                 [install the user visible C preprocessor in DIR
 159                  (relative to PREFIX) as well as PREFIX/bin])],
 160 [if test x$withval = xyes; then
 161   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 162 elif test x$withval != xno; then
 163   cpp_install_dir=$withval
 164 fi])
 165
 166 # We would like to our source tree to be readonly.  However when releases or
 167 # pre-releases are generated, the flex/bison generated files as well as the
 168 # various formats of manuals need to be included along with the rest of the
 169 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 170 # just that.
 171
 172 AC_MSG_CHECKING([whether to place generated files in the source directory])
 173   dnl generated-files-in-srcdir is disabled by default
 174   AC_ARG_ENABLE(generated-files-in-srcdir,
 175     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 176                     [put copies of generated files in source dir
 177                      intended for creating source tarballs for users
 178                      without texinfo bison or flex])],
 179       generated_files_in_srcdir=$enableval,
 180       generated_files_in_srcdir=no)
 181
 182 AC_MSG_RESULT($generated_files_in_srcdir)
 183
 184 if test "$generated_files_in_srcdir" = "yes"; then
 185   GENINSRC=''
 186 else
 187   GENINSRC='#'
 188 fi
 189 AC_SUBST(GENINSRC)
 190
 191 # -------------------
 192 # Find default linker
 193 # -------------------
 194
 195 # With GNU ld
 196 AC_ARG_WITH(gnu-ld,
 197 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 198 gnu_ld_flag="$with_gnu_ld",
 199 gnu_ld_flag=no)
 200
 201 # With pre-defined ld
 202 AC_ARG_WITH(ld,
 203 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 204 DEFAULT_LINKER="$with_ld")
 205 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 206   if test ! -x "$DEFAULT_LINKER"; then
 207     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 208   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 209     gnu_ld_flag=yes
 210   fi
 211   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 212         [Define to enable the use of a default linker.])
 213 fi
 214
 215 AC_MSG_CHECKING([whether a default linker was specified])
 216 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 217   if test x"$gnu_ld_flag" = x"no"; then
 218     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 219   else
 220     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 221   fi
 222 else
 223   AC_MSG_RESULT(no)
 224 fi
 225
 226 # With demangler in GNU ld
 227 AC_ARG_WITH(demangler-in-ld,
 228 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 229 demangler_in_ld="$with_demangler_in_ld",
 230 demangler_in_ld=yes)
 231
 232 # ----------------------
 233 # Find default assembler
 234 # ----------------------
 235
 236 # With GNU as
 237 AC_ARG_WITH(gnu-as,
 238 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 239 gas_flag="$with_gnu_as",
 240 gas_flag=no)
 241
 242 AC_ARG_WITH(as,
 243 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 244 DEFAULT_ASSEMBLER="$with_as")
 245 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 246   if test ! -x "$DEFAULT_ASSEMBLER"; then
 247     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 248   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 249     gas_flag=yes
 250   fi
 251   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 252         [Define to enable the use of a default assembler.])
 253 fi
 254
 255 AC_MSG_CHECKING([whether a default assembler was specified])
 256 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 257   if test x"$gas_flag" = x"no"; then
 258     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 259   else
 260     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 261   fi
 262 else
 263   AC_MSG_RESULT(no)
 264 fi
 265
 266 # ---------------
 267 # Find C compiler
 268 # ---------------
 269
 270 # If a non-executable a.out is present (e.g. created by GNU as above even if
 271 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 272 # file, even when creating an executable, so an execution test fails.
 273 # Remove possible default executable files to avoid this.
 274 #
 275 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 276 # Autoconf includes it.
 277 rm -f a.out a.exe b.out
 278
 279 # Find the native compiler
 280 AC_PROG_CC
 281 AC_PROG_CXX
 282 ACX_PROG_GNAT([-I"$srcdir"/ada])
 283
 284 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 285 # optimizations to be activated explicitly by the toplevel.
 286 case "$CC" in
 287   */prev-gcc/xgcc*) ;;
 288   *) CFLAGS=`echo "$CFLAGS " | sed -e "s/-Ofast[[       ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" `
 289      CXXFLAGS=`echo "$CXXFLAGS " | sed -e "s/-Ofast[[   ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" ` ;;
 290 esac
 291 AC_SUBST(CFLAGS)
 292 AC_SUBST(CXXFLAGS)
 293
 294 # Determine PICFLAG for target gnatlib.
 295 GCC_PICFLAG_FOR_TARGET
 296 AC_SUBST(PICFLAG_FOR_TARGET)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 AC_SYS_LARGEFILE
 307
 308 # sizeof(char) is 1 by definition.
 309 AC_CHECK_SIZEOF(void *)
 310 AC_CHECK_SIZEOF(short)
 311 AC_CHECK_SIZEOF(int)
 312 AC_CHECK_SIZEOF(long)
 313 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 314 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 315 GCC_STDINT_TYPES
 316
 317 # ---------------------
 318 # Warnings and checking
 319 # ---------------------
 320
 321 # Check $CC warning features (if it's GCC).
 322 # We want to use -pedantic, but we don't want warnings about
 323 # * 'long long'
 324 # * variadic macros
 325 # * overlong strings
 326 # * C++11 narrowing conversions in { }
 327 # So, we only use -pedantic if we can disable those warnings.
 328
 329 # In stage 1, disable -Wformat warnings from old GCCs about new % codes
 330 AC_ARG_ENABLE(build-format-warnings,
 331   AS_HELP_STRING([--disable-build-format-warnings],[don't use -Wformat while building GCC]),
 332   [],[enable_build_format_warnings=yes])
 333 AS_IF([test $enable_build_format_warnings = no],
 334       [wf_opt=-Wno-format],[wf_opt=])
 335 ACX_PROG_CC_WARNING_OPTS(
 336         m4_quote(m4_do([-W -Wall -Wno-narrowing -Wwrite-strings -Wcast-qual $wf_opt])), [loose_warn])
 337 ACX_PROG_CC_WARNING_OPTS(
 338         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 339         [c_loose_warn])
 340 ACX_PROG_CC_WARNING_OPTS(
 341         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 342 ACX_PROG_CC_WARNING_OPTS(
 343         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 344 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 345         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 346                        [-Wno-overlength-strings])), [strict_warn])
 347 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 348
 349 # The above macros do nothing if the compiler is not GCC.  However, the
 350 # Makefile has more goo to add other flags, so these variables are used
 351 # to enable warnings only for GCC.
 352 warn_cflags=
 353 warn_cxxflags=
 354 if test "x$GCC" = "xyes"; then
 355   warn_cflags='$(GCC_WARN_CFLAGS)'
 356   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 357 fi
 358 AC_SUBST(warn_cflags)
 359 AC_SUBST(warn_cxxflags)
 360
 361 # Disable exceptions and RTTI if building with g++
 362 ACX_PROG_CC_WARNING_OPTS(
 363         m4_quote(m4_do([-fno-exceptions -fno-rtti -fasynchronous-unwind-tables])),
 364                        [noexception_flags])
 365
 366 # Enable expensive internal checks
 367 is_release=
 368 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 369   is_release=yes
 370 fi
 371
 372 AC_ARG_ENABLE(checking,
 373 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 374                 [enable expensive run-time checks.  With LIST,
 375                  enable only specific categories of checks.
 376                  Categories are: yes,no,all,none,release.
 377                  Flags are: assert,df,fold,gc,gcac,gimple,misc,
 378                  rtlflag,rtl,runtime,tree,valgrind,types])],
 379 [ac_checking_flags="${enableval}"],[
 380 # Determine the default checks.
 381 if test x$is_release = x ; then
 382   ac_checking_flags=yes
 383 else
 384   ac_checking_flags=release
 385 fi])
 386 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 387 for check in release $ac_checking_flags
 388 do
 389         case $check in
 390         # these set all the flags to specific states
 391         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 392                         ac_fold_checking= ; ac_gc_checking=1 ;
 393                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 394                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 395                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 396                         ac_types_checking=1 ;;
 397         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 398                         ac_fold_checking= ; ac_gc_checking= ;
 399                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 400                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 401                         ac_tree_checking= ; ac_valgrind_checking= ;
 402                         ac_types_checking= ;;
 403         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 404                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 405                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 406                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 407                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 408                         ac_types_checking=1 ;;
 409         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 410                         ac_fold_checking= ; ac_gc_checking= ;
 411                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 412                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 413                         ac_tree_checking= ; ac_valgrind_checking= ;
 414                         ac_types_checking= ;;
 415         # these enable particular checks
 416         assert)         ac_assert_checking=1 ;;
 417         df)             ac_df_checking=1 ;;
 418         fold)           ac_fold_checking=1 ;;
 419         gc)             ac_gc_checking=1 ;;
 420         gcac)           ac_gc_always_collect=1 ;;
 421         gimple)         ac_gimple_checking=1 ;;
 422         misc)           ac_checking=1 ;;
 423         rtl)            ac_rtl_checking=1 ;;
 424         rtlflag)        ac_rtlflag_checking=1 ;;
 425         runtime)        ac_runtime_checking=1 ;;
 426         tree)           ac_tree_checking=1 ;;
 427         types)          ac_types_checking=1 ;;
 428         valgrind)       ac_valgrind_checking=1 ;;
 429         *)      AC_MSG_ERROR(unknown check category $check) ;;
 430         esac
 431 done
 432 IFS="$ac_save_IFS"
 433
 434 nocommon_flag=""
 435 if test x$ac_checking != x ; then
 436   AC_DEFINE(ENABLE_CHECKING, 1,
 437 [Define if you want more run-time sanity checks.  This one gets a grab
 438    bag of miscellaneous but relatively cheap checks.])
 439   nocommon_flag=-fno-common
 440 fi
 441 AC_SUBST(nocommon_flag)
 442 if test x$ac_df_checking != x ; then
 443   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 444 [Define if you want more run-time sanity checks for dataflow.])
 445 fi
 446 if test x$ac_assert_checking != x ; then
 447   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 448 [Define if you want assertions enabled.  This is a cheap check.])
 449 fi
 450 if test x$ac_gimple_checking != x ; then
 451   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 452 [Define if you want operations on GIMPLE (the basic data structure of
 453 the high-level optimizers) to be checked for dynamic type safety at
 454 runtime.  This is moderately expensive.])
 455 fi
 456 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 457 if test x$ac_runtime_checking != x ; then
 458   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 459 [Define if you want runtime assertions enabled.  This is a cheap check.])
 460 fi
 461 if test x$ac_tree_checking != x ; then
 462   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 463 [Define if you want all operations on trees (the basic data
 464    structure of the front ends) to be checked for dynamic type safety
 465    at runtime.  This is moderately expensive.  The tree browser debugging
 466    routines will also be enabled by this option.
 467    ])
 468   TREEBROWSER=tree-browser.o
 469   TREECHECKING=yes
 470 fi
 471 if test x$ac_types_checking != x ; then
 472   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 473 [Define if you want all gimple types to be verified after gimplifiation.
 474    This is cheap.
 475    ])
 476 fi
 477 AC_SUBST(TREEBROWSER)
 478 AC_SUBST(TREECHECKING)
 479 if test x$ac_rtl_checking != x ; then
 480   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 481 [Define if you want all operations on RTL (the basic data structure
 482    of the optimizer and back end) to be checked for dynamic type safety
 483    at runtime.  This is quite expensive.])
 484 fi
 485 if test x$ac_rtlflag_checking != x ; then
 486   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 487 [Define if you want RTL flag accesses to be checked against the RTL
 488    codes that are supported for each access macro.  This is relatively
 489    cheap.])
 490 fi
 491 if test x$ac_gc_checking != x ; then
 492   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 493 [Define if you want the garbage collector to do object poisoning and
 494    other memory allocation checks.  This is quite expensive.])
 495 fi
 496 if test x$ac_gc_always_collect != x ; then
 497   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 498 [Define if you want the garbage collector to operate in maximally
 499    paranoid mode, validating the entire heap and collecting garbage at
 500    every opportunity.  This is extremely expensive.])
 501 fi
 502 if test x$ac_fold_checking != x ; then
 503   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 504 [Define if you want fold checked that it never destructs its argument.
 505    This is quite expensive.])
 506 fi
 507 valgrind_path_defines=
 508 valgrind_command=
 509
 510 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 511 dnl # an if statement.  This was the source of very frustrating bugs
 512 dnl # in converting to autoconf 2.5x!
 513 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 514
 515 if test x$ac_valgrind_checking != x ; then
 516   # It is certainly possible that there's valgrind but no valgrind.h.
 517   # GCC relies on making annotations so we must have both.
 518   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 519   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 520     [[#include <valgrind/memcheck.h>
 521 #ifndef VALGRIND_DISCARD
 522 #error VALGRIND_DISCARD not defined
 523 #endif]])],
 524   [gcc_cv_header_valgrind_memcheck_h=yes],
 525   [gcc_cv_header_valgrind_memcheck_h=no])
 526   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 527   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 528   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 529     [[#include <memcheck.h>
 530 #ifndef VALGRIND_DISCARD
 531 #error VALGRIND_DISCARD not defined
 532 #endif]])],
 533   [gcc_cv_header_memcheck_h=yes],
 534   [gcc_cv_header_memcheck_h=no])
 535   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 536   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 537         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 538   if test "x$valgrind_path" = "x" \
 539     || (test $have_valgrind_h = no \
 540         && test $gcc_cv_header_memcheck_h = no \
 541         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 542         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 543   fi
 544   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 545   valgrind_command="$valgrind_path -q"
 546   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 547 [Define if you want to run subprograms and generated programs
 548    through valgrind (a memory checker).  This is extremely expensive.])
 549   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 550     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 551         [Define if valgrind's valgrind/memcheck.h header is installed.])
 552   fi
 553   if test $gcc_cv_header_memcheck_h = yes; then
 554     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 555         [Define if valgrind's memcheck.h header is installed.])
 556   fi
 557 fi
 558 AC_SUBST(valgrind_path_defines)
 559 AC_SUBST(valgrind_command)
 560
 561 # Enable code coverage collection
 562 AC_ARG_ENABLE(coverage,
 563 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 564                 [enable compiler's code coverage collection.
 565                  Use to measure compiler performance and locate
 566                  unused parts of the compiler. With LEVEL, specify
 567                  optimization. Values are opt, noopt,
 568                  default is noopt])],
 569 [case "${enableval}" in
 570   yes|noopt)
 571     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 572     ;;
 573   opt)
 574     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 575     ;;
 576   no)
 577     # a.k.a. --disable-coverage
 578     coverage_flags=""
 579     ;;
 580   *)
 581     AC_MSG_ERROR(unknown coverage setting $enableval)
 582     ;;
 583 esac],
 584 [coverage_flags=""])
 585 AC_SUBST(coverage_flags)
 586
 587 AC_ARG_ENABLE(gather-detailed-mem-stats,
 588 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 589                 [enable detailed memory allocation stats gathering])], [],
 590 [enable_gather_detailed_mem_stats=no])
 591 gather_stats=`if test $enable_gather_detailed_mem_stats != no; then echo 1; else echo 0; fi`
 592 AC_DEFINE_UNQUOTED(GATHER_STATISTICS, $gather_stats,
 593 [Define to enable detailed memory allocation stats gathering.])
 594
 595 # -------------------------------
 596 # Miscenalleous configure options
 597 # -------------------------------
 598
 599 # With stabs
 600 AC_ARG_WITH(stabs,
 601 [AS_HELP_STRING([--with-stabs],
 602                 [arrange to use stabs instead of host debug format])],
 603 stabs="$with_stabs",
 604 stabs=no)
 605
 606 # Determine whether or not multilibs are enabled.
 607 AC_ARG_ENABLE(multilib,
 608 [AS_HELP_STRING([--enable-multilib],
 609                 [enable library support for multiple ABIs])],
 610 [], [enable_multilib=yes])
 611 AC_SUBST(enable_multilib)
 612
 613 # Determine whether or not multiarch is enabled.
 614 AC_ARG_ENABLE(multiarch,
 615 [AS_HELP_STRING([--enable-multiarch],
 616                 [enable support for multiarch paths])],
 617 [case "${enableval}" in
 618 yes|no|auto) enable_multiarch=$enableval;;
 619 *) AC_MSG_ERROR(bad value ${enableval} given for --enable-multiarch option) ;;
 620 esac], [enable_multiarch=auto])
 621 if test x${enable_multiarch} = xauto; then
 622   if test x${with_native_system_header_dir} != x; then
 623     ma_msg_suffix=", disabled auto check (configured with --native-system-header-dir)"
 624     enable_multiarch=no
 625   fi
 626   if test x$host != x$target && test "x$with_sysroot" = x; then
 627     ma_msg_suffix=", disabled auto check (cross build configured without --with-sysroot)"
 628     enable_multiarch=no
 629   fi
 630 fi
 631 AC_MSG_CHECKING(for multiarch configuration)
 632 AC_SUBST(enable_multiarch)
 633 AC_MSG_RESULT($enable_multiarch$ma_msg_suffix)
 634
 635 # needed for setting the multiarch name for soft-float/hard-float ABIs
 636 AC_SUBST(with_cpu)
 637 AC_SUBST(with_float)
 638
 639 # Enable __cxa_atexit for C++.
 640 AC_ARG_ENABLE(__cxa_atexit,
 641 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 642 [], [])
 643
 644 # Enable C extension for decimal float if target supports it.
 645 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 646
 647 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 648 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 649 [Define to 1 to enable decimal float extension to C.])
 650
 651 # Use default_decimal_float for dependency.
 652 enable_decimal_float=$default_decimal_float
 653
 654 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 655 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 656 [Define to 1 to specify that we are using the BID decimal floating
 657 point format instead of DPD])
 658
 659 # Enable C extension for fixed-point arithmetic.
 660 AC_ARG_ENABLE(fixed-point,
 661 [AS_HELP_STRING([--enable-fixed-point],
 662                 [enable fixed-point arithmetic extension to C])],
 663 [],
 664 [
 665   case $target in
 666     arm*)
 667       enable_fixed_point=yes
 668       ;;
 669
 670     mips*-*-*)
 671       enable_fixed_point=yes
 672       ;;
 673     *)
 674       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 675       enable_fixed_point=no
 676       ;;
 677   esac
 678 ])
 679 AC_SUBST(enable_fixed_point)
 680
 681 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 682 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 683 [Define to 1 to enable fixed-point arithmetic extension to C.])
 684
 685 # Enable threads
 686 # Pass with no value to take the default
 687 # Pass with a value to specify a thread package
 688 AC_ARG_ENABLE(threads,
 689 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 690                 [enable thread usage for target GCC,
 691                  using LIB thread package])],,
 692 [enable_threads=''])
 693
 694 AC_ARG_ENABLE(tls,
 695 [AS_HELP_STRING([--enable-tls],
 696                 [enable or disable generation of tls code
 697                  overriding the assembler check for tls support])],
 698 [
 699   case $enable_tls in
 700     yes | no) ;;
 701     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 702 Valid choices are 'yes' and 'no'.]) ;;
 703   esac
 704 ], [enable_tls=''])
 705
 706 AC_ARG_ENABLE(objc-gc,
 707 [AS_HELP_STRING([--enable-objc-gc],
 708                 [enable the use of Boehm's garbage collector with
 709                  the GNU Objective-C runtime])],
 710 if test x$enable_objc_gc = xno; then
 711         objc_boehm_gc=''
 712 else
 713         objc_boehm_gc=1
 714 fi,
 715 objc_boehm_gc='')
 716
 717 AC_ARG_WITH(dwarf2,
 718 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 719 dwarf2="$with_dwarf2",
 720 dwarf2=no)
 721
 722 AC_ARG_ENABLE(shared,
 723 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 724 [
 725   case $enable_shared in
 726   yes | no) ;;
 727   *)
 728     enable_shared=no
 729     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 730     for pkg in $enableval; do
 731       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 732         enable_shared=yes
 733       fi
 734     done
 735     IFS="$ac_save_ifs"
 736     ;;
 737   esac
 738 ], [enable_shared=yes])
 739 AC_SUBST(enable_shared)
 740
 741 AC_ARG_WITH([native-system-header-dir],
 742   [  --with-native-system-header-dir=dir
 743                           use dir as the directory to look for standard
 744                           system header files in.  Defaults to /usr/include.],
 745 [
 746  case ${with_native_system_header_dir} in
 747  yes|no) AC_MSG_ERROR([bad value ${withval} given for --with-native-system-header-dir]) ;;
 748  /* | [[A-Za-z]]:[[\\/]]*) ;;
 749  *) AC_MSG_ERROR([--with-native-system-header-dir argument ${withval} must be an absolute directory]) ;;
 750  esac
 751  configured_native_system_header_dir="${withval}"
 752 ], [configured_native_system_header_dir=])
 753
 754 AC_ARG_WITH(build-sysroot,
 755   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 756                   [use sysroot as the system root during the build])],
 757   [if test x"$withval" != x ; then
 758      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
 759    fi],
 760   [SYSROOT_CFLAGS_FOR_TARGET=])
 761 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 762
 763 if test "x$prefix" = xNONE; then
 764  test_prefix=/usr/local
 765 else
 766  test_prefix=$prefix
 767 fi
 768 if test "x$exec_prefix" = xNONE; then
 769  test_exec_prefix=$test_prefix
 770 else
 771  test_exec_prefix=$exec_prefix
 772 fi
 773
 774 AC_ARG_WITH(sysroot,
 775 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 776                 [search for usr/lib, usr/include, et al, within DIR])],
 777 [
 778  case ${with_sysroot} in
 779  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 780  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 781  esac
 782
 783  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 784  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 785
 786  case ${TARGET_SYSTEM_ROOT} in
 787  "${test_prefix}"|"${test_prefix}/"*|\
 788  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 789  '${prefix}'|'${prefix}/'*|\
 790  '${exec_prefix}'|'${exec_prefix}/'*)
 791    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 792    TARGET_SYSTEM_ROOT_DEFINE="$t"
 793    ;;
 794  esac
 795 ], [
 796  TARGET_SYSTEM_ROOT=
 797  TARGET_SYSTEM_ROOT_DEFINE=
 798  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 799 ])
 800 AC_SUBST(TARGET_SYSTEM_ROOT)
 801 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 802 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 803
 804 AC_ARG_WITH(specs,
 805   [AS_HELP_STRING([--with-specs=SPECS],
 806                   [add SPECS to driver command-line processing])],
 807   [CONFIGURE_SPECS=$withval],
 808   [CONFIGURE_SPECS=]
 809 )
 810 AC_SUBST(CONFIGURE_SPECS)
 811
 812 ACX_PKGVERSION([GCC])
 813 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 814
 815 # Sanity check enable_languages in case someone does not run the toplevel
 816 # configure # script.
 817 AC_ARG_ENABLE(languages,
 818 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 819 [case ,${enable_languages}, in
 820        ,,|,yes,)
 821                 # go safe -- we cannot be much sure without the toplevel
 822                 # configure's
 823                 # analysis of which target libs are present and usable
 824                 enable_languages=c
 825                 ;;
 826          *,all,*)
 827                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 828                 ;;
 829         *,c,*)
 830                 ;;
 831         *)
 832                 enable_languages=c,${enable_languages}
 833                 ;;
 834 esac],
 835 [enable_languages=c])
 836
 837 AC_ARG_WITH(multilib-list,
 838 [AS_HELP_STRING([--with-multilib-list], [select multilibs (AArch64, SH and x86-64 only)])],
 839 :,
 840 with_multilib_list=default)
 841
 842 # -------------------------
 843 # Checks for other programs
 844 # -------------------------
 845
 846 AC_PROG_MAKE_SET
 847
 848 # Find some useful tools
 849 AC_PROG_AWK
 850 # We need awk to create options.c and options.h.
 851 # Bail out if it's missing.
 852 case ${AWK} in
 853   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 854 esac
 855
 856 gcc_AC_PROG_LN_S
 857 ACX_PROG_LN($LN_S)
 858 AC_PROG_RANLIB
 859 ranlib_flags=""
 860 AC_SUBST(ranlib_flags)
 861
 862 gcc_AC_PROG_INSTALL
 863
 864 # See if cmp has --ignore-initial.
 865 gcc_AC_PROG_CMP_IGNORE_INITIAL
 866
 867 # See if we have the mktemp command.
 868 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 869
 870 # See if makeinfo has been installed and is modern enough
 871 # that we can use it.
 872 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 873   [GNU texinfo.* \([0-9][0-9.]*\)],
 874   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 875 if test $gcc_cv_prog_makeinfo_modern = no; then
 876   AC_MSG_WARN([
 877 *** Makeinfo is missing or too old.
 878 *** Info documentation will not be built.])
 879   BUILD_INFO=
 880 else
 881   BUILD_INFO=info
 882 fi
 883 AC_SUBST(BUILD_INFO)
 884
 885 # Is pod2man recent enough to regenerate manpages?
 886 AC_MSG_CHECKING([for recent Pod::Man])
 887 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 888   AC_MSG_RESULT(yes)
 889   GENERATED_MANPAGES=generated-manpages
 890 else
 891   AC_MSG_RESULT(no)
 892   GENERATED_MANPAGES=
 893 fi
 894 AC_SUBST(GENERATED_MANPAGES)
 895
 896 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 897
 898 # How about lex?
 899 dnl Don't use AC_PROG_LEX; we insist on flex.
 900 dnl LEXLIB is not useful in gcc.
 901 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 902
 903 # Bison?
 904 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 905
 906 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 907 # check for build == host before using them.
 908
 909 # NM
 910 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 911   && test -d ../binutils ; then
 912   NM='${objdir}/../binutils/nm-new'
 913 else
 914   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 915 fi
 916
 917 # AR
 918 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 919   && test -d ../binutils ; then
 920   AR='${objdir}/../binutils/ar'
 921 else
 922   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 923 fi
 924
 925
 926 # --------------------
 927 # Checks for C headers
 928 # --------------------
 929
 930 # Need to reject headers which give warnings, so that the -Werror bootstrap
 931 # works later. *sigh*  This needs to come before all header checks.
 932 AC_PROG_CPP_WERROR
 933
 934 AC_HEADER_STDC
 935 AC_HEADER_TIME
 936 ACX_HEADER_STRING
 937 AC_HEADER_SYS_WAIT
 938 AC_HEADER_TIOCGWINSZ
 939 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 940                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 941                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 942                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 943
 944 # Check for thread headers.
 945 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 946 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 947
 948 # These tests can't be done till we know if we have limits.h.
 949 gcc_AC_C_CHAR_BIT
 950 AC_C_BIGENDIAN
 951
 952 # ----------------------
 953 # Checks for C++ headers
 954 # ----------------------
 955
 956 dnl Autoconf will give an error in the configure script if there is no
 957 dnl C++ preprocessor.  Hack to prevent that.
 958 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
 959 AC_PROG_CXXCPP
 960 m4_popdef([AC_MSG_ERROR])[]dnl
 961
 962 AC_LANG_PUSH(C++)
 963
 964 AC_CHECK_HEADERS(unordered_map)
 965 AC_CHECK_HEADERS(tr1/unordered_map)
 966 AC_CHECK_HEADERS(ext/hash_map)
 967
 968 AC_LANG_POP(C++)
 969
 970 # --------
 971 # Dependency checking.
 972 # --------
 973
 974 AC_LANG_PUSH(C++)
 975 ZW_CREATE_DEPDIR
 976 AC_CONFIG_COMMANDS([gccdepdir],[
 977   ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs build/$DEPDIR
 978   for lang in $subdirs c-family common
 979   do
 980       ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs $lang/$DEPDIR
 981   done], [subdirs="$subdirs" ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR])
 982
 983 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
 984 AC_LANG_POP(C++)
 985
 986 # --------
 987 # UNSORTED
 988 # --------
 989
 990
 991 # These libraries may be used by collect2.
 992 # We may need a special search path to get them linked.
 993 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 994 [save_LIBS="$LIBS"
 995 for libs in '' -lld -lmld \
 996                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 997                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 998 do
 999         LIBS="$libs"
1000         AC_TRY_LINK_FUNC(ldopen,
1001                 [gcc_cv_collect2_libs="$libs"; break])
1002 done
1003 LIBS="$save_LIBS"
1004 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1005 case $gcc_cv_collect2_libs in
1006         "none required")        ;;
1007         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1008 esac
1009 AC_SUBST(COLLECT2_LIBS)
1010
1011 # When building Ada code on Alpha, we need exc_resume which is usually in
1012 # -lexc.  So test for it.
1013 save_LIBS="$LIBS"
1014 LIBS=
1015 AC_SEARCH_LIBS(exc_resume, exc)
1016 GNAT_LIBEXC="$LIBS"
1017 LIBS="$save_LIBS"
1018 AC_SUBST(GNAT_LIBEXC)
1019
1020 # To support -mcpu=native on Solaris/SPARC, we need libkstat.
1021 save_LIBS="$LIBS"
1022 LIBS=
1023 AC_SEARCH_LIBS(kstat_open, kstat)
1024 EXTRA_GCC_LIBS="$LIBS"
1025 LIBS="$save_LIBS"
1026 AC_SUBST(EXTRA_GCC_LIBS)
1027
1028 # Some systems put ldexp and frexp in libm instead of libc; assume
1029 # they're both in the same place.  jcf-dump needs them.
1030 save_LIBS="$LIBS"
1031 LIBS=
1032 AC_SEARCH_LIBS(ldexp, m)
1033 LDEXP_LIB="$LIBS"
1034 LIBS="$save_LIBS"
1035 AC_SUBST(LDEXP_LIB)
1036
1037 # Use <inttypes.h> only if it exists,
1038 # doesn't clash with <sys/types.h>, and declares intmax_t.
1039 AC_MSG_CHECKING(for inttypes.h)
1040 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1041 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1042 [[#include <sys/types.h>
1043 #include <inttypes.h>]],
1044   [[intmax_t i = -1;]])],
1045   [gcc_cv_header_inttypes_h=yes],
1046   [gcc_cv_header_inttypes_h=no])])
1047 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1048 if test $gcc_cv_header_inttypes_h = yes; then
1049   AC_DEFINE(HAVE_INTTYPES_H, 1,
1050         [Define if you have a working <inttypes.h> header file.])
1051 fi
1052
1053 dnl Disabled until we have a complete test for buggy enum bitfields.
1054 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1055
1056 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1057   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1058   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1059   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1060   putchar_unlocked putc_unlocked)
1061 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1062         sysconf strsignal getrusage nl_langinfo \
1063         gettimeofday mbstowcs wcswidth mmap setlocale \
1064         gcc_UNLOCKED_FUNCS madvise)
1065
1066 if test x$ac_cv_func_mbstowcs = xyes; then
1067   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1068 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1069 int main()
1070 {
1071   mbstowcs(0, "", 0);
1072   return 0;
1073 }]])],
1074     [gcc_cv_func_mbstowcs_works=yes],
1075     [gcc_cv_func_mbstowcs_works=no],
1076     [gcc_cv_func_mbstowcs_works=yes])])
1077   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1078     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1079   [Define this macro if mbstowcs does not crash when its
1080    first argument is NULL.])
1081   fi
1082 fi
1083
1084 AC_CHECK_TYPE(ssize_t, int)
1085 AC_CHECK_TYPE(caddr_t, char *)
1086
1087 GCC_AC_FUNC_MMAP_BLACKLIST
1088
1089 case "${host}" in
1090 *-*-*vms*)
1091   # Under VMS, vfork works very differently than on Unix. The standard test
1092   # won't work, and it isn't easily adaptable. It makes more sense to
1093   # just force it.
1094   ac_cv_func_vfork_works=yes
1095   ;;
1096 esac
1097 AC_FUNC_FORK
1098
1099 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which exposes a different
1100 # iconv() prototype.
1101 AC_LANG_PUSH([C++])
1102 AM_ICONV
1103 AC_LANG_POP([C++])
1104
1105 # Until we have in-tree GNU iconv:
1106 LIBICONV_DEP=
1107 AC_SUBST(LIBICONV_DEP)
1108
1109 AM_LC_MESSAGES
1110
1111 AM_LANGINFO_CODESET
1112
1113 # We will need to find libiberty.h and ansidecl.h
1114 saved_CFLAGS="$CFLAGS"
1115 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1116 saved_CXXFLAGS="$CXXFLAGS"
1117 CXXFLAGS="$CXXFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1118 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1119         strsignal strstr stpcpy strverscmp \
1120         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1121         free basename getopt clock getpagesize ffs gcc_UNLOCKED_FUNCS, , ,[
1122 #include "ansidecl.h"
1123 #include "system.h"])
1124
1125 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1126 #include "ansidecl.h"
1127 #include "system.h"
1128 #ifdef HAVE_SYS_RESOURCE_H
1129 #include <sys/resource.h>
1130 #endif
1131 ])
1132
1133 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1134 #include "ansidecl.h"
1135 #include "system.h"
1136 #ifdef HAVE_SYS_RESOURCE_H
1137 #include <sys/resource.h>
1138 #endif
1139 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1140 [Define to `long' if <sys/resource.h> doesn't define.])])
1141
1142 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1143 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1144 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1145 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1146 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1147 #include "ansidecl.h"
1148 #include "system.h"
1149 #ifdef HAVE_LDFCN_H
1150 #undef FREAD
1151 #undef FWRITE
1152 #include <ldfcn.h>
1153 #endif
1154 ])
1155
1156 gcc_AC_CHECK_DECLS(times, , ,[
1157 #include "ansidecl.h"
1158 #include "system.h"
1159 #ifdef HAVE_SYS_TIMES_H
1160 #include <sys/times.h>
1161 #endif
1162 ])
1163
1164 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1165 #include "ansidecl.h"
1166 #include "system.h"
1167 #include <signal.h>
1168 ])
1169
1170 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which hides the madvise()
1171 # prototype.
1172 AC_LANG_PUSH([C++])
1173 gcc_AC_CHECK_DECLS(madvise, , ,[
1174   #include "ansidecl.h"
1175   #include "system.h"
1176 ])
1177 AC_LANG_POP([C++])
1178
1179 # More time-related stuff.
1180 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1181 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1182 #include "ansidecl.h"
1183 #include "system.h"
1184 #ifdef HAVE_SYS_TIMES_H
1185 #include <sys/times.h>
1186 #endif
1187 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1188 if test $ac_cv_struct_tms = yes; then
1189   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1190   [Define if <sys/times.h> defines struct tms.])
1191 fi
1192
1193 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1194 # revisit after autoconf 2.50.
1195 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1196 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1197 #include "ansidecl.h"
1198 #include "system.h"
1199 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1200 if test $gcc_cv_type_clock_t = yes; then
1201   AC_DEFINE(HAVE_CLOCK_T, 1,
1202   [Define if <time.h> defines clock_t.])
1203 fi
1204
1205 # Check if F_SETLKW is supported by fcntl.
1206 AC_CACHE_CHECK(for F_SETLKW, ac_cv_f_setlkw, [
1207 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1208 #include <fcntl.h>]], [[
1209 struct flock fl;
1210 fl.l_whence = 0;
1211 fl.l_start = 0;
1212 fl.l_len = 0;
1213 fl.l_pid = 0;
1214 return fcntl (1, F_SETLKW, &fl);]])],
1215 [ac_cv_f_setlkw=yes],[ac_cv_f_setlkw=no])])
1216 if test $ac_cv_f_setlkw = yes; then
1217   AC_DEFINE(HOST_HAS_F_SETLKW, 1,
1218   [Define if F_SETLKW supported by fcntl.])
1219 fi
1220
1221 # Restore CFLAGS, CXXFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1222 CFLAGS="$saved_CFLAGS"
1223 CXXFLAGS="$saved_CXXFLAGS"
1224
1225 # mkdir takes a single argument on some systems.
1226 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1227
1228 # File extensions
1229 manext='.1'
1230 objext='.o'
1231 AC_SUBST(manext)
1232 AC_SUBST(objext)
1233
1234 # With Setjmp/Longjmp based exception handling.
1235 AC_ARG_ENABLE(sjlj-exceptions,
1236 [AS_HELP_STRING([--enable-sjlj-exceptions],
1237                 [arrange to use setjmp/longjmp exception handling])],
1238 [case $target in
1239   *-*-hpux10*)
1240     if test $enableval != yes; then
1241       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1242       enableval=yes
1243     fi
1244     ;;
1245 esac
1246 force_sjlj_exceptions=yes],
1247 [case $target in
1248   *-*-hpux10*)
1249     force_sjlj_exceptions=yes
1250     enableval=yes
1251     ;;
1252   *)
1253     force_sjlj_exceptions=no
1254     ;;
1255 esac])
1256 if test $force_sjlj_exceptions = yes; then
1257   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1258   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1259     [Define 0/1 to force the choice for exception handling model.])
1260 fi
1261
1262 # --------------------------------------------------------
1263 # Build, host, and target specific configuration fragments
1264 # --------------------------------------------------------
1265
1266 # Collect build-machine-specific information.
1267 . ${srcdir}/config.build
1268
1269 # Collect host-machine-specific information.
1270 . ${srcdir}/config.host
1271
1272 target_gtfiles=
1273
1274 # Collect target-machine-specific information.
1275 . ${srcdir}/config.gcc
1276
1277 extra_objs="${host_extra_objs} ${extra_objs}"
1278 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1279
1280 # Default the target-machine variables that were not explicitly set.
1281 if test x"$tm_file" = x
1282 then tm_file=$cpu_type/$cpu_type.h; fi
1283
1284 if test x"$extra_headers" = x
1285 then extra_headers=; fi
1286
1287 if test x$md_file = x
1288 then md_file=$cpu_type/$cpu_type.md; fi
1289
1290 if test x$out_file = x
1291 then out_file=$cpu_type/$cpu_type.c; fi
1292
1293 if test x"$tmake_file" = x
1294 then tmake_file=$cpu_type/t-$cpu_type
1295 fi
1296
1297 # Support --enable-initfini-array.
1298 if test x$enable_initfini_array != xno; then
1299   tm_file="${tm_file} initfini-array.h"
1300 fi
1301
1302 if test x"$dwarf2" = xyes
1303 then tm_file="$tm_file tm-dwarf2.h"
1304 fi
1305
1306 # Say what files are being used for the output code and MD file.
1307 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1308 echo "Using \`$srcdir/config/$md_file' as machine description file."
1309
1310 # If any of the xm_file variables contain nonexistent files, warn
1311 # about them and drop them.
1312
1313 bx=
1314 for x in $build_xm_file; do
1315   if    test -f $srcdir/config/$x
1316   then      bx="$bx $x"
1317   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1318   fi
1319 done
1320 build_xm_file="$bx"
1321
1322 hx=
1323 for x in $host_xm_file; do
1324   if    test -f $srcdir/config/$x
1325   then      hx="$hx $x"
1326   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1327   fi
1328 done
1329 host_xm_file="$hx"
1330
1331 tx=
1332 for x in $xm_file; do
1333   if    test -f $srcdir/config/$x
1334   then      tx="$tx $x"
1335   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1336   fi
1337 done
1338 xm_file="$tx"
1339
1340 count=a
1341 for f in $tm_file; do
1342         count=${count}x
1343 done
1344 if test $count = ax; then
1345         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1346 else
1347         echo "Using the following target machine macro files:"
1348         for f in $tm_file; do
1349                 echo "  $srcdir/config/$f"
1350         done
1351 fi
1352
1353 if test x$need_64bit_hwint = xyes; then
1354         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1355 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1356 fi
1357
1358 if test x$use_long_long_for_widest_fast_int = xyes; then
1359         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1360 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1361 efficiently supported by the host hardware.])
1362 fi
1363
1364 gnu_ld_bool=`if test x"$gnu_ld" = x"yes"; then echo 1; else echo 0; fi`
1365 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld_bool, [Define to 1 if using GNU ld.])
1366
1367 gnu_as_bool=`if test x"$gas" = x"yes"; then echo 1; else echo 0; fi`
1368 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as_bool, [Define to 1 if using GNU as.])
1369
1370 count=a
1371 for f in $host_xm_file; do
1372         count=${count}x
1373 done
1374 if test $count = a; then
1375         :
1376 elif test $count = ax; then
1377         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1378 else
1379         echo "Using the following host machine macro files:"
1380         for f in $host_xm_file; do
1381                 echo "  $srcdir/config/$f"
1382         done
1383 fi
1384 echo "Using ${out_host_hook_obj} for host machine hooks."
1385
1386 if test "$host_xm_file" != "$build_xm_file"; then
1387         count=a
1388         for f in $build_xm_file; do
1389                 count=${count}x
1390         done
1391         if test $count = a; then
1392                 :
1393         elif test $count = ax; then
1394                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1395         else
1396                 echo "Using the following build machine macro files:"
1397                 for f in $build_xm_file; do
1398                         echo "  $srcdir/config/$f"
1399                 done
1400         fi
1401 fi
1402
1403 if test -n "$configured_native_system_header_dir"; then
1404   native_system_header_dir=$configured_native_system_header_dir
1405 fi
1406 NATIVE_SYSTEM_HEADER_DIR="$native_system_header_dir"
1407 AC_SUBST(NATIVE_SYSTEM_HEADER_DIR)
1408
1409 case ${host} in
1410   powerpc*-*-darwin*)
1411     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1412       gcc_cv_mcontext_underscores,
1413       AC_COMPILE_IFELSE([
1414 #include <sys/cdefs.h>
1415 #include <sys/signal.h>
1416 #include <ucontext.h>
1417 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1418 ],
1419         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1420       if test $gcc_cv_mcontext_underscores = yes; then
1421         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1422           [mcontext_t fields start with __])
1423       fi
1424     ;;
1425 esac
1426
1427 # ---------
1428 # Threading
1429 # ---------
1430
1431 # Check if a valid thread package
1432 case ${enable_threads} in
1433   "" | no)
1434     # No threads
1435     target_thread_file='single'
1436     ;;
1437   yes)
1438     # default
1439     target_thread_file='single'
1440     ;;
1441   aix | dce | lynx | mipssde | posix | rtems | \
1442   single | tpf | vxworks | win32)
1443     target_thread_file=${enable_threads}
1444     ;;
1445   *)
1446     echo "${enable_threads} is an unknown thread package" 1>&2
1447     exit 1
1448     ;;
1449 esac
1450
1451 if test x${thread_file} = x; then
1452   # No thread file set by target-specific clauses in config.gcc,
1453   # so use file chosen by default logic above
1454   thread_file=${target_thread_file}
1455 fi
1456
1457 # --------
1458 # UNSORTED
1459 # --------
1460
1461 use_cxa_atexit=no
1462 if test x$enable___cxa_atexit = xyes || \
1463    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1464   if test x$host = x$target; then
1465     case $host in
1466       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1467       # keyed to flag_use_cxa_atexit
1468       *-*-mingw32*)
1469         use_cxa_atexit=yes
1470         ;;
1471       powerpc-ibm-aix*)
1472         use_cxa_atexit=yes
1473         ;;
1474       *)
1475         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1476           [echo "__cxa_atexit can't be enabled on this target"])
1477         ;;
1478     esac
1479   else
1480     # We can't check for __cxa_atexit when building a cross, so assume
1481     # it is available
1482     use_cxa_atexit=yes
1483   fi
1484   if test x$use_cxa_atexit = xyes; then
1485     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1486       [Define if you want to use __cxa_atexit, rather than atexit, to
1487       register C++ destructors for local statics and global objects.
1488       This is essential for fully standards-compliant handling of
1489       destructors, but requires __cxa_atexit in libc.])
1490   fi
1491 fi
1492
1493 # Look for a file containing extra machine modes.
1494 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1495   extra_modes_file='$(srcdir)'/config/${extra_modes}
1496   AC_SUBST(extra_modes_file)
1497   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1498   [Define to the name of a file containing a list of extra machine modes
1499    for this architecture.])
1500 fi
1501
1502 # Convert extra_options into a form suitable for Makefile use.
1503 extra_opt_files=
1504 all_opt_files=
1505 for f in $extra_options; do
1506   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1507   all_opt_files="$all_opt_files $srcdir/config/$f"
1508 done
1509 AC_SUBST(extra_opt_files)
1510
1511 # auto-host.h is the file containing items generated by autoconf and is
1512 # the first file included by config.h.
1513 # If host=build, it is correct to have bconfig include auto-host.h
1514 # as well.  If host!=build, we are in error and need to do more
1515 # work to find out the build config parameters.
1516 if test x$host = x$build
1517 then
1518         build_auto=auto-host.h
1519 else
1520         # We create a subdir, then run autoconf in the subdir.
1521         # To prevent recursion we set host and build for the new
1522         # invocation of configure to the build for this invocation
1523         # of configure.
1524         tempdir=build.$$
1525         rm -rf $tempdir
1526         mkdir $tempdir
1527         cd $tempdir
1528         case ${srcdir} in
1529         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1530         *) realsrcdir=../${srcdir};;
1531         esac
1532         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1533         LDFLAGS="${LDFLAGS_FOR_BUILD}" GMPINC="" \
1534         ${realsrcdir}/configure \
1535                 --enable-languages=${enable_languages-all} \
1536                 --target=$target_alias --host=$build_alias --build=$build_alias
1537
1538         # We just finished tests for the build machine, so rename
1539         # the file auto-build.h in the gcc directory.
1540         mv auto-host.h ../auto-build.h
1541         cd ..
1542         rm -rf $tempdir
1543         build_auto=auto-build.h
1544 fi
1545 AC_SUBST(build_subdir)
1546
1547 tm_file="${tm_file} defaults.h"
1548 tm_p_file="${tm_p_file} tm-preds.h"
1549 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1550 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1551 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1552 # put this back in temporarily.
1553 xm_file="auto-host.h ansidecl.h ${xm_file}"
1554
1555 # --------
1556 # UNSORTED
1557 # --------
1558
1559 changequote(,)dnl
1560 # Compile in configure arguments.
1561 if test -f configargs.h ; then
1562         # Being re-configured.
1563         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1564         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1565 else
1566         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1567 fi
1568
1569 # Double all backslashes and backslash all quotes to turn
1570 # gcc_config_arguments into a C string.
1571 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1572 $gcc_config_arguments
1573 EOF
1574 gcc_config_arguments_str=`cat conftest.out`
1575 rm -f conftest.out
1576
1577 cat > configargs.h <<EOF
1578 /* Generated automatically. */
1579 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1580 static const char thread_model[] = "$thread_file";
1581
1582 static const struct {
1583   const char *name, *value;
1584 } configure_default_options[] = $configure_default_options;
1585 EOF
1586 changequote([,])dnl
1587
1588 changequote(,)dnl
1589 gcc_BASEVER=`cat $srcdir/BASE-VER`
1590 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1591 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1592 if test -f $srcdir/REVISION ; then
1593         gcc_REVISION=`cat $srcdir/REVISION`
1594 else
1595         gcc_REVISION=""
1596 fi
1597 cat > plugin-version.h <<EOF
1598 #include "configargs.h"
1599
1600 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
1601 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
1602 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
1603 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
1604
1605 static char basever[] = "$gcc_BASEVER";
1606 static char datestamp[] = "$gcc_DATESTAMP";
1607 static char devphase[] = "$gcc_DEVPHASE";
1608 static char revision[] = "$gcc_REVISION";
1609
1610 /* FIXME plugins: We should make the version information more precise.
1611    One way to do is to add a checksum. */
1612
1613 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1614                                                 devphase, revision,
1615                                                 configuration_arguments};
1616 EOF
1617 changequote([,])dnl
1618
1619 # Internationalization
1620 ZW_GNU_GETTEXT_SISTER_DIR
1621
1622 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1623 # -liconv on the link line twice.
1624 case "$LIBINTL" in *$LIBICONV*)
1625         LIBICONV= ;;
1626 esac
1627
1628 AC_ARG_ENABLE(secureplt,
1629 [AS_HELP_STRING([--enable-secureplt],
1630                 [enable -msecure-plt by default for PowerPC])],
1631 [], [])
1632
1633 AC_ARG_ENABLE(leading-mingw64-underscores,
1634   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1635                  [enable leading underscores on 64 bit mingw targets]),
1636   [],[])
1637 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1638   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1639     [Define if we should use leading underscore on 64 bit mingw targets])])
1640
1641 AC_ARG_ENABLE(cld,
1642 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1643 [enable_cld=no])
1644
1645 AC_ARG_ENABLE(frame-pointer,
1646 [AS_HELP_STRING([--enable-frame-pointer],
1647                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1648 [
1649 case $target_os in
1650 linux* | darwin[[8912]]*)
1651   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1652   # DWARF2.
1653   enable_frame_pointer=no
1654   ;;
1655 *)
1656   enable_frame_pointer=yes
1657   ;;
1658 esac
1659 ])
1660
1661 # Windows32 Registry support for specifying GCC installation paths.
1662 AC_ARG_ENABLE(win32-registry,
1663 [AS_HELP_STRING([--disable-win32-registry],
1664                 [disable lookup of installation paths in the
1665                  Registry on Windows hosts])
1666 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1667 AS_HELP_STRING([--enable-win32-registry=KEY],
1668                [use KEY instead of GCC version as the last portion
1669                 of the registry key])],,)
1670
1671 case $host_os in
1672   win32 | pe | cygwin* | mingw32* | uwin*)
1673     if test "x$enable_win32_registry" != xno; then
1674       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1675     fi
1676
1677     if test "x$enable_win32_registry" != xno; then
1678       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1679   [Define to 1 if installation paths should be looked up in the Windows
1680    Registry. Ignored on non-Windows hosts.])
1681
1682       if test "x$enable_win32_registry" != xyes \
1683          && test "x$enable_win32_registry" != x; then
1684         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1685   [Define to be the last component of the Windows registry key under which
1686    to look for installation paths.  The full key used will be
1687    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1688    The default is the GCC version number.])
1689       fi
1690     fi
1691   ;;
1692 esac
1693
1694 # Get an absolute path to the GCC top-level source directory
1695 holddir=`${PWDCMD-pwd}`
1696 cd $srcdir
1697 topdir=`${PWDCMD-pwd}`
1698 cd $holddir
1699
1700 # Conditionalize the makefile for this host machine.
1701 xmake_file=
1702 for f in ${host_xmake_file}
1703 do
1704         if test -f ${srcdir}/config/$f
1705         then
1706                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1707         fi
1708 done
1709
1710 # Conditionalize the makefile for this target machine.
1711 tmake_file_=
1712 for f in ${tmake_file}
1713 do
1714         if test -f ${srcdir}/config/$f
1715         then
1716                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1717         fi
1718 done
1719 tmake_file="${tmake_file_}"
1720
1721 out_object_file=`basename $out_file .c`.o
1722 common_out_object_file=`basename $common_out_file .c`.o
1723
1724 tm_file_list="options.h"
1725 tm_include_list="options.h insn-constants.h"
1726 for f in $tm_file; do
1727   case $f in
1728     ./* )
1729        f=`echo $f | sed 's/^..//'`
1730        tm_file_list="${tm_file_list} $f"
1731        tm_include_list="${tm_include_list} $f"
1732        ;;
1733     defaults.h )
1734        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1735        tm_include_list="${tm_include_list} $f"
1736        ;;
1737     * )
1738        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1739        tm_include_list="${tm_include_list} config/$f"
1740        ;;
1741   esac
1742 done
1743
1744 tm_p_file_list=
1745 tm_p_include_list=
1746 for f in $tm_p_file; do
1747   case $f in
1748     tm-preds.h )
1749        tm_p_file_list="${tm_p_file_list} $f"
1750        tm_p_include_list="${tm_p_include_list} $f"
1751        ;;
1752     * )
1753        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1754        tm_p_include_list="${tm_p_include_list} config/$f"
1755   esac
1756 done
1757
1758 xm_file_list=
1759 xm_include_list=
1760 for f in $xm_file; do
1761   case $f in
1762     ansidecl.h )
1763        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1764        xm_include_list="${xm_include_list} $f"
1765        ;;
1766     auto-host.h )
1767        xm_file_list="${xm_file_list} $f"
1768        xm_include_list="${xm_include_list} $f"
1769        ;;
1770     * )
1771        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1772        xm_include_list="${xm_include_list} config/$f"
1773        ;;
1774   esac
1775 done
1776
1777 host_xm_file_list=
1778 host_xm_include_list=
1779 for f in $host_xm_file; do
1780   case $f in
1781     ansidecl.h )
1782        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1783        host_xm_include_list="${host_xm_include_list} $f"
1784        ;;
1785     auto-host.h )
1786        host_xm_file_list="${host_xm_file_list} $f"
1787        host_xm_include_list="${host_xm_include_list} $f"
1788        ;;
1789     * )
1790        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1791        host_xm_include_list="${host_xm_include_list} config/$f"
1792        ;;
1793   esac
1794 done
1795
1796 build_xm_file_list=
1797 for f in $build_xm_file; do
1798   case $f in
1799     ansidecl.h )
1800        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1801        build_xm_include_list="${build_xm_include_list} $f"
1802        ;;
1803     auto-build.h | auto-host.h )
1804        build_xm_file_list="${build_xm_file_list} $f"
1805        build_xm_include_list="${build_xm_include_list} $f"
1806        ;;
1807     * )
1808        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1809        build_xm_include_list="${build_xm_include_list} config/$f"
1810        ;;
1811   esac
1812 done
1813
1814 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1815 # cross-compiler which does not use the native headers and libraries.
1816 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1817 CROSS=                                          AC_SUBST(CROSS)
1818 ALL=all.internal                                AC_SUBST(ALL)
1819 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1820
1821 if test "x$with_build_sysroot" != x; then
1822   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1823 else
1824   # This value is used, even on a native system, because
1825   # CROSS_SYSTEM_HEADER_DIR is just
1826   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1827   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1828 fi
1829
1830 if test x$host != x$target
1831 then
1832         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1833         ALL=all.cross
1834         SYSTEM_HEADER_DIR=$build_system_header_dir
1835         case "$host","$target" in
1836         # Darwin crosses can use the host system's libraries and headers,
1837         # because of the fat library support.  Of course, it must be the
1838         # same version of Darwin on both sides.  Allow the user to
1839         # just say --target=foo-darwin without a version number to mean
1840         # "the version on this system".
1841             *-*-darwin*,*-*-darwin*)
1842                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1843                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1844                 if test $hostos = $targetos -o $targetos = darwin ; then
1845                     CROSS=
1846                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1847                     with_headers=yes
1848                 fi
1849                 ;;
1850
1851             i?86-*-*,x86_64-*-* \
1852             | powerpc*-*-*,powerpc64*-*-*)
1853                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1854         esac
1855
1856         case $target in
1857                 *-*-mingw*)
1858                         if test "x$with_headers" = x; then
1859                                 with_headers=yes
1860                         fi
1861                         ;;
1862                 *)
1863                         ;;
1864         esac
1865 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1866         SYSTEM_HEADER_DIR=$build_system_header_dir
1867 fi
1868
1869 # If this is a cross-compiler that does not
1870 # have its own set of headers then define
1871 # inhibit_libc
1872
1873 # If this is using newlib, without having the headers available now,
1874 # then define inhibit_libc in LIBGCC2_CFLAGS.
1875 # This prevents libgcc2 from containing any code which requires libc
1876 # support.
1877 : ${inhibit_libc=false}
1878 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1879        test x$with_newlib = xyes ; } &&
1880      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1881        inhibit_libc=true
1882 fi
1883 AC_SUBST(inhibit_libc)
1884
1885 # When building gcc with a cross-compiler, we need to adjust things so
1886 # that the generator programs are still built with the native compiler.
1887 # Also, we cannot run fixincludes.
1888
1889 # These are the normal (build=host) settings:
1890 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1891 CXX_FOR_BUILD='$(CXX)'          AC_SUBST(CXX_FOR_BUILD)
1892 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1893 BUILD_CXXFLAGS='$(ALL_CXXFLAGS)' AC_SUBST(BUILD_CXXFLAGS)
1894 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1895 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1896
1897 # And these apply if build != host, or we are generating coverage data
1898 if test x$build != x$host || test "x$coverage_flags" != x
1899 then
1900     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1901     BUILD_CXXFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CXXFLAGS_FOR_BUILD)'
1902     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1903 fi
1904
1905 # Expand extra_headers to include complete path.
1906 # This substitutes for lots of t-* files.
1907 extra_headers_list=
1908 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1909 for file in ${extra_headers} ; do
1910   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1911 done
1912
1913 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1914 if test x"$use_gcc_tgmath" = xyes
1915 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1916 fi
1917
1918 # Define collect2 in Makefile.
1919 case $host_can_use_collect2 in
1920   no) collect2= ;;
1921   *) collect2='collect2$(exeext)' ;;
1922 esac
1923 AC_SUBST([collect2])
1924
1925 # Add a definition of USE_COLLECT2 if system wants one.
1926 case $use_collect2 in
1927   no) use_collect2= ;;
1928   "") ;;
1929   *)
1930     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1931     xm_defines="${xm_defines} USE_COLLECT2"
1932     case $host_can_use_collect2 in
1933       no)
1934         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1935         ;;
1936     esac
1937     ;;
1938 esac
1939
1940 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
1941 [Define to the name of the LTO plugin DSO that must be
1942   passed to the linker's -plugin=LIB option.])
1943
1944 # ---------------------------
1945 # Assembler & linker features
1946 # ---------------------------
1947
1948 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1949 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1950 # However when ld-new is first executed from the build tree, libtool will
1951 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1952 # to the build tree.  While doing this we need to use the previous-stage
1953 # linker, or we have an infinite loop.  The presence of a shell script as
1954 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1955 # the gcc/collect-ld script.  So we need to know how libtool works, or
1956 # exec-tool will fail.
1957
1958 m4_defun([_LT_CONFIG_COMMANDS], [])
1959 AC_PROG_LIBTOOL
1960 AC_SUBST(objdir)
1961 AC_SUBST(enable_fast_install)
1962
1963 # Identify the assembler which will work hand-in-glove with the newly
1964 # built GCC, so that we can examine its features.  This is the assembler
1965 # which will be driven by the driver program.
1966 #
1967 # If build != host, and we aren't building gas in-tree, we identify a
1968 # build->target assembler and hope that it will have the same features
1969 # as the host->target assembler we'll be using.
1970 gcc_cv_gas_major_version=
1971 gcc_cv_gas_minor_version=
1972 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1973
1974 m4_pattern_allow([AS_FOR_TARGET])dnl
1975 AS_VAR_SET_IF(gcc_cv_as,, [
1976 if test -x "$DEFAULT_ASSEMBLER"; then
1977         gcc_cv_as="$DEFAULT_ASSEMBLER"
1978 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1979      && test -f ../gas/Makefile \
1980      && test x$build = x$host; then
1981         gcc_cv_as=../gas/as-new$build_exeext
1982 elif test -x as$build_exeext; then
1983         # Build using assembler in the current directory.
1984         gcc_cv_as=./as$build_exeext
1985 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
1986         gcc_cv_as="$AS_FOR_TARGET"
1987 else
1988         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1989 fi])
1990
1991 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1992 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1993 case "$ORIGINAL_AS_FOR_TARGET" in
1994   ./as | ./as$build_exeext) ;;
1995   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1996 esac
1997
1998 AC_MSG_CHECKING(what assembler to use)
1999 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
2000   # Single tree build which includes gas.  We want to prefer it
2001   # over whatever linker top-level may have detected, since
2002   # we'll use what we're building after installation anyway.
2003   AC_MSG_RESULT(newly built gas)
2004   in_tree_gas=yes
2005   _gcc_COMPUTE_GAS_VERSION
2006   in_tree_gas_is_elf=no
2007   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
2008      || (grep 'obj_format = multi' ../gas/Makefile \
2009          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
2010   then
2011     in_tree_gas_is_elf=yes
2012   fi
2013 else
2014   AC_MSG_RESULT($gcc_cv_as)
2015   in_tree_gas=no
2016 fi
2017
2018 default_ld=
2019 AC_ARG_ENABLE(ld,
2020 [[  --enable-ld[=ARG]       build ld [ARG={default,yes,no}]]],
2021 [case "${enableval}" in
2022  no)
2023    default_ld=ld.gold
2024    ;;
2025  esac])
2026
2027 AC_ARG_ENABLE(gold,
2028 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
2029 [case "${enableval}" in
2030  default)
2031    install_gold_as_default=yes
2032    ;;
2033  yes)
2034    if test x${default_ld} != x; then
2035      install_gold_as_default=yes
2036    fi
2037    ;;
2038  no)
2039    ;;
2040  *)
2041    AC_MSG_ERROR([invalid --enable-gold argument])
2042    ;;
2043  esac],
2044 [install_gold_as_default=no])
2045
2046 # Identify the linker which will work hand-in-glove with the newly
2047 # built GCC, so that we can examine its features.  This is the linker
2048 # which will be driven by the driver program.
2049 #
2050 # If build != host, and we aren't building gas in-tree, we identify a
2051 # build->target linker and hope that it will have the same features
2052 # as the host->target linker we'll be using.
2053 gcc_cv_gld_major_version=
2054 gcc_cv_gld_minor_version=
2055 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
2056 gcc_cv_ld_gold_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gold
2057 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
2058
2059 AS_VAR_SET_IF(gcc_cv_ld,, [
2060 if test -x "$DEFAULT_LINKER"; then
2061         gcc_cv_ld="$DEFAULT_LINKER"
2062 elif test $install_gold_as_default = yes \
2063      && test -f $gcc_cv_ld_gold_srcdir/configure.ac \
2064      && test -f ../gold/Makefile \
2065      && test x$build = x$host; then
2066         gcc_cv_ld=../gold/ld-new$build_exeext
2067 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
2068      && test -f ../ld/Makefile \
2069      && test x$build = x$host; then
2070         gcc_cv_ld=../ld/ld-new$build_exeext
2071 elif test -x collect-ld$build_exeext; then
2072         # Build using linker in the current directory.
2073         gcc_cv_ld=./collect-ld$build_exeext
2074 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
2075         gcc_cv_ld="$LD_FOR_TARGET"
2076 else
2077         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
2078 fi])
2079
2080 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
2081 PLUGIN_LD_SUFFIX=`basename $gcc_cv_ld | sed -e "s,$target_alias-,,"`
2082 # if the PLUGIN_LD is set ld-new, just have it as ld
2083 # as that is the installed named.
2084 if test x$PLUGIN_LD_SUFFIX = xld-new \
2085    || test x$PLUGIN_LD_SUFFIX = xcollect-ld ; then
2086   PLUGIN_LD_SUFFIX=ld
2087 fi
2088 AC_ARG_WITH(plugin-ld,
2089 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
2090 [if test x"$withval" != x; then
2091    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
2092    PLUGIN_LD_SUFFIX=`echo $withval | sed -e "s,$target_alias-,,"`
2093  fi])
2094 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
2095 AC_DEFINE_UNQUOTED(PLUGIN_LD_SUFFIX, "$PLUGIN_LD_SUFFIX", [Specify plugin linker])
2096
2097 # Check to see if we are using gold instead of ld
2098 AC_MSG_CHECKING(whether we are using gold)
2099 ld_is_gold=no
2100 if test x$gcc_cv_ld != x; then
2101   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2102      | grep "GNU gold" > /dev/null; then
2103     ld_is_gold=yes
2104   fi
2105 fi
2106 AC_MSG_RESULT($ld_is_gold)
2107
2108 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
2109 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
2110 case "$ORIGINAL_LD_FOR_TARGET" in
2111   ./collect-ld | ./collect-ld$build_exeext) ;;
2112   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
2113 esac
2114
2115 AC_MSG_CHECKING(what linker to use)
2116 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
2117    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
2118         # Single tree build which includes ld.  We want to prefer it
2119         # over whatever linker top-level may have detected, since
2120         # we'll use what we're building after installation anyway.
2121         AC_MSG_RESULT(newly built ld)
2122         in_tree_ld=yes
2123         in_tree_ld_is_elf=no
2124         if (grep 'EMUL = .*elf' ../ld/Makefile \
2125             || grep 'EMUL = .*linux' ../ld/Makefile \
2126             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2127           in_tree_ld_is_elf=yes
2128         elif test "$ld_is_gold" = yes; then
2129           in_tree_ld_is_elf=yes
2130         fi
2131         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
2132         do
2133 changequote(,)dnl
2134                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*VERSION=[^0-9A-Za-z_]*\([0-9]*\.[0-9]*.*\)/VERSION=\1/p' < $f`
2135                 if test x$gcc_cv_gld_version != x; then
2136                         break
2137                 fi
2138         done
2139         case $gcc_cv_gld_version in
2140           VERSION=[0-9]*) ;;
2141 changequote([,])dnl
2142           *) AC_MSG_ERROR([[cannot find version of in-tree linker]]) ;;
2143 changequote(,)dnl
2144         esac
2145         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2146         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2147 changequote([,])dnl
2148         ORIGINAL_LD_BFD_FOR_TARGET=../ld/ld-new$build_exeext
2149         ORIGINAL_LD_GOLD_FOR_TARGET=../gold/ld-new$build_exeext
2150 else
2151         AC_MSG_RESULT($gcc_cv_ld)
2152         in_tree_ld=no
2153         gcc_cvs_ld_program=`dirname $gcc_cv_ld`/`basename $gcc_cv_ld $host_exeext`
2154         ORIGINAL_LD_BFD_FOR_TARGET=${gcc_cvs_ld_program}.bfd$host_exeext
2155         ORIGINAL_LD_GOLD_FOR_TARGET=${gcc_cvs_ld_program}.gold$host_exeext
2156 fi
2157
2158 AC_SUBST(ORIGINAL_LD_BFD_FOR_TARGET)
2159 AC_SUBST(ORIGINAL_LD_GOLD_FOR_TARGET)
2160
2161 # Figure out what nm we will be using.
2162 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2163 AS_VAR_SET_IF(gcc_cv_nm,, [
2164 if test -f $gcc_cv_binutils_srcdir/configure.in \
2165      && test -f ../binutils/Makefile \
2166      && test x$build = x$host; then
2167         gcc_cv_nm=../binutils/nm-new$build_exeext
2168 elif test -x nm$build_exeext; then
2169         gcc_cv_nm=./nm$build_exeext
2170 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2171         gcc_cv_nm="$NM_FOR_TARGET"
2172 else
2173         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2174 fi])
2175
2176 AC_MSG_CHECKING(what nm to use)
2177 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2178         # Single tree build which includes binutils.
2179         AC_MSG_RESULT(newly built nm)
2180         in_tree_nm=yes
2181 else
2182         AC_MSG_RESULT($gcc_cv_nm)
2183         in_tree_nm=no
2184 fi
2185
2186 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2187 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2188 case "$ORIGINAL_NM_FOR_TARGET" in
2189   ./nm | ./nm$build_exeext) ;;
2190   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2191 esac
2192
2193
2194 # Figure out what objdump we will be using.
2195 AS_VAR_SET_IF(gcc_cv_objdump,, [
2196 if test -f $gcc_cv_binutils_srcdir/configure.in \
2197      && test -f ../binutils/Makefile \
2198      && test x$build = x$host; then
2199         # Single tree build which includes binutils.
2200         gcc_cv_objdump=../binutils/objdump$build_exeext
2201 elif test -x objdump$build_exeext; then
2202         gcc_cv_objdump=./objdump$build_exeext
2203 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2204         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2205 else
2206         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2207 fi])
2208
2209 AC_MSG_CHECKING(what objdump to use)
2210 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2211         # Single tree build which includes binutils.
2212         AC_MSG_RESULT(newly built objdump)
2213 elif test x$gcc_cv_objdump = x; then
2214         AC_MSG_RESULT(not found)
2215 else
2216         AC_MSG_RESULT($gcc_cv_objdump)
2217 fi
2218
2219 # Figure out what readelf we will be using.
2220 AS_VAR_SET_IF(gcc_cv_readelf,, [
2221 if test -f $gcc_cv_binutils_srcdir/configure.in \
2222      && test -f ../binutils/Makefile \
2223      && test x$build = x$host; then
2224         # Single tree build which includes binutils.
2225         gcc_cv_readelf=../binutils/readelf$build_exeext
2226 elif test -x readelf$build_exeext; then
2227         gcc_cv_readelf=./readelf$build_exeext
2228 else
2229         AC_PATH_PROG(gcc_cv_readelf, readelf)
2230 fi])
2231
2232 AC_MSG_CHECKING(what readelf to use)
2233 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2234         # Single tree build which includes binutils.
2235         AC_MSG_RESULT(newly built readelf)
2236 elif test x$gcc_cv_readelf = x; then
2237         AC_MSG_RESULT(not found)
2238 else
2239         AC_MSG_RESULT($gcc_cv_readelf)
2240 fi
2241
2242 # Figure out what assembler alignment features are present.
2243 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2244  [2,6,0],,
2245 [.balign 4
2246 .p2align 2],,
2247 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2248   [Define if your assembler supports .balign and .p2align.])])
2249
2250 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2251  [2,8,0],,
2252  [.p2align 4,,7],,
2253 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2254   [Define if your assembler supports specifying the maximum number
2255    of bytes to skip when using the GAS .p2align command.])])
2256
2257 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2258  [2,8,0],,
2259  [.literal16],,
2260 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2261   [Define if your assembler supports .literal16.])])
2262
2263 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2264  [elf,2,9,0],,
2265  [conftest_label1: .word 0
2266 .subsection -1
2267 conftest_label2: .word 0
2268 .previous],
2269  [if test x$gcc_cv_nm != x; then
2270     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2271     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2272     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2273     then :
2274     else gcc_cv_as_subsection_m1=yes
2275     fi
2276     rm -f conftest.nm1 conftest.nm2
2277   fi],
2278  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2279   [Define if your assembler supports .subsection and .subsection -1 starts
2280    emitting at the beginning of your section.])])
2281
2282 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2283  [2,2,0],,
2284  [      .weak foobar],,
2285 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2286
2287 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2288  [2,17,0],,
2289  [      .weakref foobar, barfnot],,
2290 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2291
2292 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2293  [2,15,91],,
2294  [      .SPACE $TEXT$
2295         .NSUBSPA $CODE$,COMDAT],,
2296 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2297
2298 # .hidden needs to be supported in both the assembler and the linker,
2299 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2300 # This is irritatingly difficult to feature test for; we have to check the
2301 # date string after the version number.  If we've got an in-tree
2302 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2303 # to be safe.
2304 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2305 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2306  [elf,2,13,0],,
2307 [       .hidden foobar
2308 foobar:],[
2309 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2310 # STV_HIDDEN, so disable .hidden support if so.
2311 case "${target}" in
2312   i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2313     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2314       cat > conftest.s <<EOF
2315 .globl hidden
2316         .hidden hidden
2317 hidden:
2318 .globl default
2319         .set    default,hidden
2320 EOF
2321       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2322         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2323         grep '\.hidden default' > /dev/null; then
2324         gcc_cv_as_hidden=no
2325       else
2326         gcc_cv_as_hidden=yes
2327       fi
2328     else
2329       # Assume bug is present if objdump is missing.
2330       gcc_cv_as_hidden=no
2331     fi
2332     ;;
2333   *)
2334     gcc_cv_as_hidden=yes
2335     ;;
2336 esac])
2337 case "${target}" in
2338   *-*-darwin*)
2339     # Darwin as has some visibility support, though with a different syntax.
2340     gcc_cv_as_hidden=yes
2341     ;;
2342 esac
2343
2344 # gnu_indirect_function type is an extension proposed at
2345 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2346 # selection of function implementation
2347 AC_ARG_ENABLE(gnu-indirect-function,
2348  [AS_HELP_STRING([--enable-gnu-indirect-function],
2349                  [enable the use of the @gnu_indirect_function to glibc systems])],
2350  [case $enable_gnu_indirect_function in
2351     yes | no) ;;
2352     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2353 Valid choices are 'yes' and 'no'.]) ;;
2354   esac],
2355  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2356
2357 gif=`if test x$enable_gnu_indirect_function = xyes; then echo 1; else echo 0; fi`
2358 AC_DEFINE_UNQUOTED(HAVE_GNU_INDIRECT_FUNCTION, $gif,
2359 [Define if your system supports gnu indirect functions.])
2360
2361
2362 changequote(,)dnl
2363 if test $in_tree_ld != yes ; then
2364   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2365   if echo "$ld_ver" | grep GNU > /dev/null; then
2366     if test x"$ld_is_gold" = xyes; then
2367       # GNU gold --version looks like this:
2368       #
2369       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2370       #
2371       # We extract the binutils version which is more familiar and specific
2372       # than the gold version.
2373       ld_vers=`echo $ld_ver | sed -n \
2374           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2375     else
2376       # GNU ld --version looks like this:
2377       #
2378       # GNU ld (GNU Binutils) 2.21.51.20110225
2379       ld_vers=`echo $ld_ver | sed -n \
2380           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2381     fi
2382     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2383     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2384     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2385     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2386   else
2387     case "${target}" in
2388       *-*-solaris2*)
2389         # See acinclude.m4 (gcc_SUN_LD_VERSION) for the version number
2390         # format.
2391         #
2392         # Don't reuse gcc_gv_sun_ld_vers_* in case a linker other than
2393         # /usr/ccs/bin/ld has been configured.
2394         ld_ver=`$gcc_cv_ld -V 2>&1`
2395         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2396           ld_vers=`echo $ld_ver | sed -n \
2397             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2398           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2399           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2400         fi
2401         ;;
2402     esac
2403   fi
2404 fi
2405 changequote([,])dnl
2406
2407 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2408 [[if test $in_tree_ld = yes ; then
2409   gcc_cv_ld_hidden=no
2410   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2411      && test $in_tree_ld_is_elf = yes; then
2412      gcc_cv_ld_hidden=yes
2413   fi
2414 else
2415   gcc_cv_ld_hidden=yes
2416   if test x"$ld_is_gold" = xyes; then
2417     :
2418   elif echo "$ld_ver" | grep GNU > /dev/null; then
2419     case "${target}" in
2420       mmix-knuth-mmixware)
2421         # The linker emits by default mmo, not ELF, so "no" is appropriate.
2422         gcc_cv_ld_hidden=no
2423         ;;
2424     esac
2425     if test 0"$ld_date" -lt 20020404; then
2426       if test -n "$ld_date"; then
2427         # If there was date string, but was earlier than 2002-04-04, fail
2428         gcc_cv_ld_hidden=no
2429       elif test -z "$ld_vers"; then
2430         # If there was no date string nor ld version number, something is wrong
2431         gcc_cv_ld_hidden=no
2432       else
2433         test -z "$ld_vers_patch" && ld_vers_patch=0
2434         if test "$ld_vers_major" -lt 2; then
2435           gcc_cv_ld_hidden=no
2436         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2437           gcc_cv_ld_hidden="no"
2438         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2439           gcc_cv_ld_hidden=no
2440         fi
2441       fi
2442     fi
2443   else
2444     case "${target}" in
2445       *-*-darwin*)
2446         # Darwin ld has some visibility support.
2447         gcc_cv_ld_hidden=yes
2448         ;;
2449       hppa64*-*-hpux* | ia64*-*-hpux*)
2450         gcc_cv_ld_hidden=yes
2451         ;;
2452       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2453         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2454         # .symbolic was only added in Solaris 9 12/02.
2455         gcc_cv_ld_hidden=yes
2456         ;;
2457       *)
2458         gcc_cv_ld_hidden=no
2459         ;;
2460     esac
2461   fi
2462 fi]])
2463 libgcc_visibility=no
2464 AC_SUBST(libgcc_visibility)
2465 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2466 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2467   libgcc_visibility=yes
2468   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2469   [Define if your assembler and linker support .hidden.])
2470 fi
2471
2472 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2473 gcc_cv_ld_ro_rw_mix=unknown
2474 if test $in_tree_ld = yes ; then
2475   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2476      && test $in_tree_ld_is_elf = yes; then
2477     gcc_cv_ld_ro_rw_mix=read-write
2478   fi
2479 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2480   echo '.section myfoosect, "a"' > conftest1.s
2481   echo '.section myfoosect, "aw"' > conftest2.s
2482   echo '.byte 1' >> conftest2.s
2483   echo '.section myfoosect, "a"' > conftest3.s
2484   echo '.byte 0' >> conftest3.s
2485   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2486      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2487      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2488      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2489         conftest2.o conftest3.o > /dev/null 2>&1; then
2490     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2491                          | sed -e '/myfoosect/!d' -e N`
2492     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2493       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2494         gcc_cv_ld_ro_rw_mix=read-only
2495       else
2496         gcc_cv_ld_ro_rw_mix=read-write
2497       fi
2498     fi
2499   fi
2500 changequote(,)dnl
2501   rm -f conftest.* conftest[123].*
2502 changequote([,])dnl
2503 fi
2504 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2505         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2506   [Define if your linker links a mix of read-only
2507    and read-write sections into a read-write section.])
2508 fi
2509 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2510
2511 gcc_AC_INITFINI_ARRAY
2512
2513 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2514 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2515   [elf,2,11,0],,
2516 [       .data
2517         .uleb128 L2 - L1
2518 L1:
2519         .uleb128 1280
2520         .sleb128 -1010
2521 L2:],
2522 [[# GAS versions before 2.11 do not support uleb128,
2523   # despite appearing to.
2524   # ??? There exists an elf-specific test that will crash
2525   # the assembler.  Perhaps it's better to figure out whether
2526   # arbitrary sections are supported and try the test.
2527   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2528   if echo "$as_ver" | grep GNU > /dev/null; then
2529     as_vers=`echo $as_ver | sed -n \
2530         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2531     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2532     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2533     if test $as_major -eq 2 && test $as_minor -lt 11
2534     then :
2535     else gcc_cv_as_leb128=yes
2536     fi
2537   fi]],
2538   [AC_DEFINE(HAVE_AS_LEB128, 1,
2539     [Define if your assembler supports .sleb128 and .uleb128.])])
2540
2541 # Check if we have assembler support for unwind directives.
2542 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2543   ,,
2544 [       .text
2545         .cfi_startproc
2546         .cfi_offset 0, 0
2547         .cfi_same_value 1
2548         .cfi_def_cfa 1, 2
2549         .cfi_escape 1, 2, 3, 4, 5
2550         .cfi_endproc],
2551 [case "$target" in
2552   *-*-solaris*)
2553     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2554     # read-only and read-write sections, we need to make sure that the
2555     # assembler used emits read-write .eh_frame sections.
2556     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2557       if test "x$gcc_cv_objdump" != x; then
2558         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2559                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2560           gcc_cv_as_cfi_directive=no
2561         else
2562           case "$target" in
2563             i?86-*-solaris2.1[[0-9]]* | x86_64-*-solaris2.1[[0-9]]*)
2564               # On Solaris/x86, make sure that GCC and gas agree on using
2565               # read-only .eh_frame sections for 64-bit.
2566               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2567                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2568                         sed -e /.eh_frame/!d -e N | \
2569                         grep READONLY > /dev/null; then
2570                 gcc_cv_as_cfi_directive=yes
2571               else
2572                 gcc_cv_as_cfi_directive=no
2573               fi
2574               ;;
2575             *)
2576               gcc_cv_as_cfi_directive=yes
2577               ;;
2578           esac
2579         fi
2580       else
2581         # no objdump, err on the side of caution
2582         gcc_cv_as_cfi_directive=no
2583       fi
2584     else
2585       gcc_cv_as_cfi_directive=yes
2586     fi
2587     ;;
2588   *-*-*)
2589     gcc_cv_as_cfi_directive=yes
2590     ;;
2591 esac])
2592 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2593 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2594   ,,
2595 [       .text
2596         .cfi_startproc
2597         .cfi_adjust_cfa_offset 64
2598         .skip 75040, 0
2599         .cfi_adjust_cfa_offset 128
2600         .cfi_endproc],
2601 [[
2602 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2603     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2604    gcc_cv_as_cfi_advance_working=yes
2605 fi
2606 ]])
2607 else
2608   # no objdump, err on the side of caution
2609   gcc_cv_as_cfi_advance_working=no
2610 fi
2611 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2612 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2613   [`if test $gcc_cv_as_cfi_directive = yes \
2614        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2615   [Define 0/1 if your assembler supports CFI directives.])
2616
2617 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2618 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2619   gcc_cv_as_cfi_personality_directive, ,,
2620 [       .text
2621         .cfi_startproc
2622         .cfi_personality 0, symbol
2623         .cfi_endproc])
2624 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2625   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2626     then echo 1; else echo 0; fi`],
2627   [Define 0/1 if your assembler supports .cfi_personality.])
2628
2629 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2630   gcc_cv_as_cfi_sections_directive, ,,
2631 [       .text
2632         .cfi_sections .debug_frame, .eh_frame
2633         .cfi_startproc
2634         .cfi_endproc],
2635 [case $target_os in
2636   win32 | pe | cygwin* | mingw32* | uwin*)
2637     # Need to check that we generated the correct relocation for the
2638     # .debug_frame section.  This was fixed for binutils 2.21.
2639     gcc_cv_as_cfi_sections_directive=no
2640     if test "x$gcc_cv_objdump" != x; then
2641      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2642         grep secrel > /dev/null; then
2643       gcc_cv_as_cfi_sections_directive=yes
2644      fi
2645     fi
2646     ;;
2647   *)
2648     gcc_cv_as_cfi_sections_directive=yes
2649     ;;
2650 esac])
2651 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2652 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2653   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2654     then echo 1; else echo 0; fi`],
2655   [Define 0/1 if your assembler supports .cfi_sections.])
2656
2657 # GAS versions up to and including 2.11.0 may mis-optimize
2658 # .eh_frame data.
2659 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2660   [elf,2,12,0],,
2661 [       .text
2662 .LFB1:
2663         .4byte  0
2664 .L1:
2665         .4byte  0
2666 .LFE1:
2667         .section        .eh_frame,"aw",@progbits
2668 __FRAME_BEGIN__:
2669         .4byte  .LECIE1-.LSCIE1
2670 .LSCIE1:
2671         .4byte  0x0
2672         .byte   0x1
2673         .ascii "z\0"
2674         .byte   0x1
2675         .byte   0x78
2676         .byte   0x1a
2677         .byte   0x0
2678         .byte   0x4
2679         .4byte  1
2680         .p2align 1
2681 .LECIE1:
2682 .LSFDE1:
2683         .4byte  .LEFDE1-.LASFDE1
2684 .LASFDE1:
2685         .4byte  .LASFDE1-__FRAME_BEGIN__
2686         .4byte  .LFB1
2687         .4byte  .LFE1-.LFB1
2688         .byte   0x4
2689         .4byte  .LFE1-.LFB1
2690         .byte   0x4
2691         .4byte  .L1-.LFB1
2692 .LEFDE1:],
2693 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2694 cat > conftest.lit <<EOF
2695  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2696  0010 01000000 12000000 18000000 00000000  ................
2697  0020 08000000 04080000 0044               .........D      @&t@
2698 EOF
2699 cat > conftest.big <<EOF
2700  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2701  0010 00000001 00000012 00000018 00000000  ................
2702  0020 00000008 04000000 0844               .........D      @&t@
2703 EOF
2704   # If the assembler didn't choke, and we can objdump,
2705   # and we got the correct data, then succeed.
2706   # The text in the here-document typically retains its unix-style line
2707   # endings, while the output of objdump will use host line endings.
2708   # Therefore, use diff -b for the comparisons.
2709   if test x$gcc_cv_objdump != x \
2710   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2711      | tail -3 > conftest.got \
2712   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2713     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2714   then
2715     gcc_cv_as_eh_frame=yes
2716   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2717     gcc_cv_as_eh_frame=buggy
2718   else
2719     # Uh oh, what do we do now?
2720     gcc_cv_as_eh_frame=no
2721   fi])
2722
2723 if test $gcc_cv_as_eh_frame = buggy; then
2724   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2725   [Define if your assembler mis-optimizes .eh_frame data.])
2726 fi
2727
2728 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2729  [elf,2,12,0], [--fatal-warnings],
2730  [.section .rodata.str, "aMS", @progbits, 1])
2731 if test $gcc_cv_as_shf_merge = no; then
2732   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2733     [elf,2,12,0], [--fatal-warnings],
2734     [.section .rodata.str, "aMS", %progbits, 1])
2735 fi
2736 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2737   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2738 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2739
2740 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
2741  gcc_cv_as_comdat_group,
2742  [elf,2,16,0], [--fatal-warnings],
2743  [.section .text,"axG",@progbits,.foo,comdat])
2744 if test $gcc_cv_as_comdat_group = yes; then
2745   gcc_cv_as_comdat_group_percent=no
2746   gcc_cv_as_comdat_group_group=no
2747 else
2748  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
2749    gcc_cv_as_comdat_group_percent,
2750    [elf,2,16,0], [--fatal-warnings],
2751    [.section .text,"axG",%progbits,.foo,comdat])
2752  if test $gcc_cv_as_comdat_group_percent = yes; then
2753    gcc_cv_as_comdat_group_group=no
2754  else
2755    if test -z "${gcc_cv_as_comdat_group_group+set}"; then
2756      gcc_cv_as_comdat_group_group=no
2757    fi
2758    case "${target}" in
2759      # Sun as uses a completely different syntax.
2760      *-*-solaris2*)
2761        case "${target}" in
2762          sparc*-*-solaris2*)
2763            conftest_s='
2764                .group foo,".text%foo",#comdat
2765                .section ".text%foo", #alloc,#execinstr,#progbits
2766                .globl foo
2767              foo:
2768              '
2769            ;;
2770          i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2771            conftest_s='
2772                .group foo,.text%foo,#comdat
2773                .section .text%foo, "ax", @progbits
2774                .globl  foo
2775              foo:
2776              '
2777            ;;
2778        esac
2779        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
2780          gcc_cv_as_comdat_group_group,
2781          ,, [$conftest_s])
2782        ;;
2783    esac
2784  fi
2785 fi
2786 if test x"$ld_is_gold" = xyes; then
2787   comdat_group=yes
2788 elif test $in_tree_ld = yes ; then
2789   comdat_group=no
2790   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2791      && test $in_tree_ld_is_elf = yes; then
2792      comdat_group=yes
2793   fi
2794 elif echo "$ld_ver" | grep GNU > /dev/null; then
2795   comdat_group=yes
2796   if test 0"$ld_date" -lt 20050308; then
2797     if test -n "$ld_date"; then
2798       # If there was date string, but was earlier than 2005-03-08, fail
2799       comdat_group=no
2800     elif test "$ld_vers_major" -lt 2; then
2801       comdat_group=no
2802     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2803       comdat_group=no
2804     fi
2805   fi
2806 else
2807 changequote(,)dnl
2808   case "${target}" in
2809     *-*-solaris2.1[1-9]*)
2810       comdat_group=no
2811       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2812       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2813       # version 1.688.
2814       #
2815       # If using Sun as for COMDAT group as emitted by GCC, one needs at
2816       # least ld version 1.2267.
2817       if test "$ld_vers_major" -gt 1; then
2818         comdat_group=yes
2819       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
2820         comdat_group=yes
2821       elif test "$ld_vers_minor" -ge 2267; then
2822         comdat_group=yes
2823       fi
2824       ;;
2825     *)
2826       # Assume linkers other than GNU ld don't support COMDAT group.
2827       comdat_group=no
2828       ;;
2829   esac
2830 changequote([,])dnl
2831 fi
2832 # Allow overriding the automatic COMDAT group tests above.
2833 AC_ARG_ENABLE(comdat,
2834   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2835   [comdat_group="$enable_comdat"])
2836 if test $comdat_group = no; then
2837   gcc_cv_as_comdat_group=no
2838   gcc_cv_as_comdat_group_percent=no
2839   gcc_cv_as_comdat_group_group=no
2840 fi
2841 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2842   [`if test $gcc_cv_as_comdat_group = yes \
2843     || test $gcc_cv_as_comdat_group_percent = yes \
2844     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
2845 [Define 0/1 if your assembler and linker support COMDAT groups.])
2846
2847 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2848  gcc_cv_as_discriminator,
2849  [2,19,51],,
2850 [       .text
2851         .file 1 "conf.c"
2852         .loc 1 1 0 discriminator 1],,
2853 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2854   [Define if your assembler supports the .loc discriminator sub-directive.])])
2855
2856 # Thread-local storage - the check is heavily parameterized.
2857 conftest_s=
2858 tls_first_major=
2859 tls_first_minor=
2860 tls_as_opt=
2861 case "$target" in
2862 changequote(,)dnl
2863   alpha*-*-*)
2864     conftest_s='
2865         .section ".tdata","awT",@progbits
2866 foo:    .long   25
2867         .text
2868         ldq     $27,__tls_get_addr($29)         !literal!1
2869         lda     $16,foo($29)                    !tlsgd!1
2870         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2871         ldq     $27,__tls_get_addr($29)         !literal!2
2872         lda     $16,foo($29)                    !tlsldm!2
2873         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2874         ldq     $1,foo($29)                     !gotdtprel
2875         ldah    $2,foo($29)                     !dtprelhi
2876         lda     $3,foo($2)                      !dtprello
2877         lda     $4,foo($29)                     !dtprel
2878         ldq     $1,foo($29)                     !gottprel
2879         ldah    $2,foo($29)                     !tprelhi
2880         lda     $3,foo($2)                      !tprello
2881         lda     $4,foo($29)                     !tprel'
2882         tls_first_major=2
2883         tls_first_minor=13
2884         tls_as_opt=--fatal-warnings
2885         ;;
2886   cris-*-*|crisv32-*-*)
2887     conftest_s='
2888         .section ".tdata","awT",@progbits
2889 x:      .long   25
2890         .text
2891         move.d x:IE,$r10
2892         nop'
2893         tls_first_major=2
2894         tls_first_minor=20
2895         tls_as_opt=--fatal-warnings
2896         ;;
2897   frv*-*-*)
2898     conftest_s='
2899         .section ".tdata","awT",@progbits
2900 x:      .long   25
2901         .text
2902         call    #gettlsoff(x)'
2903         tls_first_major=2
2904         tls_first_minor=14
2905         ;;
2906   hppa*-*-linux*)
2907     conftest_s='
2908 t1:     .reg    %r20
2909 t2:     .reg    %r21
2910 gp:     .reg    %r19
2911         .section ".tdata","awT",@progbits
2912 foo:    .long   25
2913         .text
2914         .align  4
2915         addil LT%foo-$tls_gdidx$,gp
2916         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2917         b __tls_get_addr
2918         nop
2919         addil LT%foo-$tls_ldidx$,gp
2920         b __tls_get_addr
2921         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2922         addil LR%foo-$tls_dtpoff$,%ret0
2923         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2924         mfctl %cr27,%t1
2925         addil LT%foo-$tls_ieoff$,gp
2926         ldw RT%foo-$tls_ieoff$(%r1),%t2
2927         add %t1,%t2,%t3
2928         mfctl %cr27,%t1
2929         addil LR%foo-$tls_leoff$,%t1
2930         ldo RR%foo-$tls_leoff$(%r1),%t2'
2931         tls_first_major=2
2932         tls_first_minor=15
2933         tls_as_opt=--fatal-warnings
2934         ;;
2935   arm*-*-*)
2936     conftest_s='
2937         .section ".tdata","awT",%progbits
2938 foo:    .long   25
2939         .text
2940 .word foo(gottpoff)
2941 .word foo(tpoff)
2942 .word foo(tlsgd)
2943 .word foo(tlsldm)
2944 .word foo(tlsldo)'
2945         tls_first_major=2
2946         tls_first_minor=17
2947         ;;
2948   i[34567]86-*-* | x86_64-*-solaris2.1[0-9]*)
2949     case "$target" in
2950       i[34567]86-*-solaris2.*)
2951         on_solaris=yes
2952         tga_func=___tls_get_addr
2953         ;;
2954       x86_64-*-solaris2.1[0-9]*)
2955         on_solaris=yes
2956         tga_func=__tls_get_addr
2957         ;;
2958       *)
2959         on_solaris=no
2960         ;;
2961     esac
2962     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2963       conftest_s='
2964         .section .tdata,"awt",@progbits'
2965       tls_first_major=0
2966       tls_first_minor=0
2967 changequote([,])dnl
2968       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2969 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2970 changequote(,)dnl
2971     else
2972       conftest_s='
2973         .section ".tdata","awT",@progbits'
2974       tls_first_major=2
2975       tls_first_minor=14
2976       tls_as_opt="--fatal-warnings"
2977     fi
2978     conftest_s="$conftest_s
2979 foo:    .long   25
2980         .text
2981         movl    %gs:0, %eax
2982         leal    foo@tlsgd(,%ebx,1), %eax
2983         leal    foo@tlsldm(%ebx), %eax
2984         leal    foo@dtpoff(%eax), %edx
2985         movl    foo@gottpoff(%ebx), %eax
2986         subl    foo@gottpoff(%ebx), %eax
2987         addl    foo@gotntpoff(%ebx), %eax
2988         movl    foo@indntpoff, %eax
2989         movl    \$foo@tpoff, %eax
2990         subl    \$foo@tpoff, %eax
2991         leal    foo@ntpoff(%ecx), %eax"
2992     ;;
2993   x86_64-*-*)
2994     conftest_s='
2995         .section ".tdata","awT",@progbits
2996 foo:    .long   25
2997         .text
2998         movq    %fs:0, %rax
2999         leaq    foo@TLSGD(%rip), %rdi
3000         leaq    foo@TLSLD(%rip), %rdi
3001         leaq    foo@DTPOFF(%rax), %rdx
3002         movq    foo@GOTTPOFF(%rip), %rax
3003         movq    $foo@TPOFF, %rax'
3004         tls_first_major=2
3005         tls_first_minor=14
3006         tls_as_opt=--fatal-warnings
3007         ;;
3008   ia64-*-*)
3009     conftest_s='
3010         .section ".tdata","awT",@progbits
3011 foo:    data8   25
3012         .text
3013         addl    r16 = @ltoff(@dtpmod(foo#)), gp
3014         addl    r17 = @ltoff(@dtprel(foo#)), gp
3015         addl    r18 = @ltoff(@tprel(foo#)), gp
3016         addl    r19 = @dtprel(foo#), gp
3017         adds    r21 = @dtprel(foo#), r13
3018         movl    r23 = @dtprel(foo#)
3019         addl    r20 = @tprel(foo#), gp
3020         adds    r22 = @tprel(foo#), r13
3021         movl    r24 = @tprel(foo#)'
3022         tls_first_major=2
3023         tls_first_minor=13
3024         tls_as_opt=--fatal-warnings
3025         ;;
3026   microblaze*-*-*)
3027     conftest_s='
3028         .section .tdata,"awT",@progbits
3029 x:
3030         .word 2
3031         .text
3032         addik r5,r20,x@TLSGD
3033         addik r5,r20,x@TLSLDM'
3034         tls_first_major=2
3035         tls_first_minor=20
3036         tls_as_opt='--fatal-warnings'
3037         ;;
3038   mips*-*-*)
3039     conftest_s='
3040         .section .tdata,"awT",@progbits
3041 x:
3042         .word 2
3043         .text
3044         addiu $4, $28, %tlsgd(x)
3045         addiu $4, $28, %tlsldm(x)
3046         lui $4, %dtprel_hi(x)
3047         addiu $4, $4, %dtprel_lo(x)
3048         lw $4, %gottprel(x)($28)
3049         lui $4, %tprel_hi(x)
3050         addiu $4, $4, %tprel_lo(x)'
3051         tls_first_major=2
3052         tls_first_minor=16
3053         tls_as_opt='-32 --fatal-warnings'
3054         ;;
3055   m68k-*-*)
3056     conftest_s='
3057         .section .tdata,"awT",@progbits
3058 x:
3059         .word 2
3060         .text
3061 foo:
3062         move.l x@TLSGD(%a5),%a0
3063         move.l x@TLSLDM(%a5),%a0
3064         move.l x@TLSLDO(%a5),%a0
3065         move.l x@TLSIE(%a5),%a0
3066         move.l x@TLSLE(%a5),%a0'
3067         tls_first_major=2
3068         tls_first_minor=19
3069         tls_as_opt='--fatal-warnings'
3070         ;;
3071   aarch64*-*-*)
3072     conftest_s='
3073         .section ".tdata","awT",%progbits
3074 foo:    .long   25
3075         .text
3076         adrp  x0, :tlsgd:x
3077         add   x0, x0, #:tlsgd_lo12:x
3078         bl    __tls_get_addr
3079         nop'
3080         tls_first_major=2
3081         tls_first_minor=20
3082         tls_as_opt='--fatal-warnings'
3083         ;;
3084   powerpc-ibm-aix*)
3085     conftest_s='
3086         .extern __get_tpointer
3087         .toc
3088 LC..1:
3089         .tc a[TC],a[TL]@le
3090         .csect .text[PR]
3091 .tlstest:
3092         lwz 9,LC..1(2)
3093         bla __get_tpointer
3094         lwzx 3,9,3
3095         .globl a
3096         .csect a[TL],4
3097 a:
3098         .space 4'
3099         tls_first_major=0
3100         tls_first_minor=0
3101         ;;
3102   powerpc64*-*-*)
3103     conftest_s='
3104         .section ".tdata","awT",@progbits
3105         .align 3
3106 ld0:    .space 8
3107 ld1:    .space 8
3108 x1:     .space 8
3109 x2:     .space 8
3110 x3:     .space 8
3111         .text
3112         addi 3,2,ld0@got@tlsgd
3113         bl .__tls_get_addr
3114         nop
3115         addi 3,2,ld1@toc
3116         bl .__tls_get_addr
3117         nop
3118         addi 3,2,x1@got@tlsld
3119         bl .__tls_get_addr
3120         nop
3121         addi 9,3,x1@dtprel
3122         bl .__tls_get_addr
3123         nop
3124         addis 9,3,x2@dtprel@ha
3125         addi 9,9,x2@dtprel@l
3126         bl .__tls_get_addr
3127         nop
3128         ld 9,x3@got@dtprel(2)
3129         add 9,9,3
3130         bl .__tls_get_addr
3131         nop'
3132         tls_first_major=2
3133         tls_first_minor=14
3134         tls_as_opt="-a64 --fatal-warnings"
3135         ;;
3136   powerpc*-*-*)
3137     conftest_s='
3138         .section ".tdata","awT",@progbits
3139         .align 2
3140 ld0:    .space 4
3141 ld1:    .space 4
3142 x1:     .space 4
3143 x2:     .space 4
3144 x3:     .space 4
3145         .text
3146         addi 3,31,ld0@got@tlsgd
3147         bl __tls_get_addr
3148         addi 3,31,x1@got@tlsld
3149         bl __tls_get_addr
3150         addi 9,3,x1@dtprel
3151         addis 9,3,x2@dtprel@ha
3152         addi 9,9,x2@dtprel@l
3153         lwz 9,x3@got@tprel(31)
3154         add 9,9,x@tls
3155         addi 9,2,x1@tprel
3156         addis 9,2,x2@tprel@ha
3157         addi 9,9,x2@tprel@l'
3158         tls_first_major=2
3159         tls_first_minor=14
3160         tls_as_opt="-a32 --fatal-warnings"
3161         ;;
3162   s390-*-*)
3163     conftest_s='
3164         .section ".tdata","awT",@progbits
3165 foo:    .long   25
3166         .text
3167         .long   foo@TLSGD
3168         .long   foo@TLSLDM
3169         .long   foo@DTPOFF
3170         .long   foo@NTPOFF
3171         .long   foo@GOTNTPOFF
3172         .long   foo@INDNTPOFF
3173         l       %r1,foo@GOTNTPOFF(%r12)
3174         l       %r1,0(%r1):tls_load:foo
3175         bas     %r14,0(%r1,%r13):tls_gdcall:foo
3176         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
3177         tls_first_major=2
3178         tls_first_minor=14
3179         tls_as_opt="-m31 --fatal-warnings"
3180         ;;
3181   s390x-*-*)
3182     conftest_s='
3183         .section ".tdata","awT",@progbits
3184 foo:    .long   25
3185         .text
3186         .quad   foo@TLSGD
3187         .quad   foo@TLSLDM
3188         .quad   foo@DTPOFF
3189         .quad   foo@NTPOFF
3190         .quad   foo@GOTNTPOFF
3191         lg      %r1,foo@GOTNTPOFF(%r12)
3192         larl    %r1,foo@INDNTPOFF
3193         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
3194         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
3195         tls_first_major=2
3196         tls_first_minor=14
3197         tls_as_opt="-m64 -Aesame --fatal-warnings"
3198         ;;
3199   sh-*-* | sh[34]-*-*)
3200     conftest_s='
3201         .section ".tdata","awT",@progbits
3202 foo:    .long   25
3203         .text
3204         .long   foo@TLSGD
3205         .long   foo@TLSLDM
3206         .long   foo@DTPOFF
3207         .long   foo@GOTTPOFF
3208         .long   foo@TPOFF'
3209         tls_first_major=2
3210         tls_first_minor=13
3211         tls_as_opt=--fatal-warnings
3212         ;;
3213   sparc*-*-*)
3214     case "$target" in
3215       sparc*-sun-solaris2.*)
3216         on_solaris=yes
3217         tga_func=__tls_get_addr
3218         ;;
3219       *)
3220         on_solaris=no
3221         ;;
3222     esac
3223     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3224       conftest_s='
3225         .section ".tdata",#alloc,#write,#tls'
3226         tls_first_major=0
3227         tls_first_minor=0
3228     else
3229       conftest_s='
3230         .section ".tdata","awT",@progbits'
3231         tls_first_major=2
3232         tls_first_minor=14
3233         tls_as_opt="-32 --fatal-warnings"
3234     fi
3235     conftest_s="$conftest_s
3236 foo:    .long   25
3237         .text
3238         sethi   %tgd_hi22(foo), %o0
3239         add     %o0, %tgd_lo10(foo), %o1
3240         add     %l7, %o1, %o0, %tgd_add(foo)
3241         call    __tls_get_addr, %tgd_call(foo)
3242         sethi   %tldm_hi22(foo), %l1
3243         add     %l1, %tldm_lo10(foo), %l2
3244         add     %l7, %l2, %o0, %tldm_add(foo)
3245         call    __tls_get_addr, %tldm_call(foo)
3246         sethi   %tldo_hix22(foo), %l3
3247         xor     %l3, %tldo_lox10(foo), %l4
3248         add     %o0, %l4, %l5, %tldo_add(foo)
3249         sethi   %tie_hi22(foo), %o3
3250         add     %o3, %tie_lo10(foo), %o3
3251         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3252         add     %g7, %o2, %o4, %tie_add(foo)
3253         sethi   %tle_hix22(foo), %l1
3254         xor     %l1, %tle_lox10(foo), %o5
3255         ld      [%g7 + %o5], %o1"
3256         ;;
3257   tilepro*-*-*)
3258       conftest_s='
3259         .section ".tdata","awT",@progbits
3260 foo:    .long   25
3261         .text
3262         addli   r0, zero, tls_gd(foo)
3263         auli    r0, zero, tls_gd_ha16(foo)
3264         addli   r0, r0, tls_gd_lo16(foo)
3265         jal     __tls_get_addr
3266         addli   r0, zero, tls_ie(foo)
3267         auli    r0, r0, tls_ie_ha16(foo)
3268         addli   r0, r0, tls_ie_lo16(foo)'
3269         tls_first_major=2
3270         tls_first_minor=22
3271         tls_as_opt="--fatal-warnings"
3272         ;;
3273   tilegx*-*-*)
3274       conftest_s='
3275         .section ".tdata","awT",@progbits
3276 foo:    .long   25
3277         .text
3278         shl16insli r0, zero, hw0_last_tls_gd(foo)
3279         shl16insli r0, zero, hw1_last_tls_gd(foo)
3280         shl16insli r0, r0,   hw0_tls_gd(foo)
3281         jal        __tls_get_addr
3282         shl16insli r0, zero, hw1_last_tls_ie(foo)
3283         shl16insli r0, r0,   hw0_tls_ie(foo)'
3284         tls_first_major=2
3285         tls_first_minor=22
3286         tls_as_opt="--fatal-warnings"
3287         ;;
3288   xtensa*-*-*)
3289     conftest_s='
3290         .section ".tdata","awT",@progbits
3291 foo:    .long   25
3292         .text
3293         movi    a8, foo@TLSFUNC
3294         movi    a10, foo@TLSARG
3295         callx8.tls a8, foo@TLSCALL'
3296         tls_first_major=2
3297         tls_first_minor=19
3298         ;;
3299 changequote([,])dnl
3300 esac
3301 set_have_as_tls=no
3302 if test "x$enable_tls" = xno ; then
3303   : # TLS explicitly disabled.
3304 elif test "x$enable_tls" = xyes ; then
3305   set_have_as_tls=yes # TLS explicitly enabled.
3306 elif test -z "$tls_first_major"; then
3307   : # If we don't have a check, assume no support.
3308 else
3309   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3310   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3311   [set_have_as_tls=yes])
3312 fi
3313 case "$target" in
3314   # TLS was introduced in the Solaris 9 FCS release.  Support for GNU-style
3315   # TLS on x86 was only introduced in Solaris 9 4/04, replacing the earlier
3316   # Sun style that Sun ld and GCC don't support any longer.
3317   *-*-solaris2.*)
3318     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
3319     ld_tls_support=no
3320     # Check ld and ld.so.1 TLS support.
3321     if echo "$ld_ver" | grep GNU > /dev/null; then
3322       # Assume all interesting versions of GNU ld have TLS support.
3323       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
3324       ld_tls_support=yes
3325     else
3326       case "$target" in
3327         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
3328         i?86-*-solaris2.9)
3329           min_tls_ld_vers_minor=374
3330           ;;
3331         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
3332         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
3333           min_tls_ld_vers_minor=343
3334           ;;
3335       esac
3336       if test "$ld_vers_major" -gt 1 || \
3337         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3338         ld_tls_support=yes
3339       else
3340         set_have_as_tls=no
3341       fi
3342     fi
3343     AC_MSG_RESULT($ld_tls_support)
3344
3345     save_LIBS="$LIBS"
3346     save_LDFLAGS="$LDFLAGS"
3347     LIBS=
3348     LDFLAGS=
3349
3350     AC_MSG_CHECKING(library containing $tga_func)
3351     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3352     # (32-bit x86) only lived in libthread, so check for that.  Keep
3353     # set_have_as_tls if found, disable if not.
3354     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3355     # Clear LIBS if we cannot support TLS.
3356     if test $set_have_as_tls = no; then
3357       LIBS=
3358     fi
3359     # Always define LIB_TLS_SPEC, even without TLS support.
3360     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3361         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3362     AC_MSG_RESULT($LIBS)
3363
3364     LIBS="$save_LIBS"
3365     LDFLAGS="$save_LDFLAGS"
3366     ;;
3367 esac
3368 if test $set_have_as_tls = yes ; then
3369   AC_DEFINE(HAVE_AS_TLS, 1,
3370             [Define if your assembler and linker support thread-local storage.])
3371 fi
3372
3373 # Target-specific assembler checks.
3374
3375 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3376 gcc_cv_ld_static_dynamic=no
3377 gcc_cv_ld_static_option='-Bstatic'
3378 gcc_cv_ld_dynamic_option='-Bdynamic'
3379 if test $in_tree_ld = yes ; then
3380   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3381     gcc_cv_ld_static_dynamic=yes
3382   fi
3383 elif test x$gcc_cv_ld != x; then
3384   # Check if linker supports -Bstatic/-Bdynamic option
3385   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3386      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3387       gcc_cv_ld_static_dynamic=yes
3388   else
3389     case "$target" in
3390       # AIX ld uses -b flags
3391       *-*-aix4.[[23]]* | *-*-aix[[5-9]]*)
3392         gcc_cv_ld_static_dynamic=yes
3393         gcc_cv_ld_static_option="-bstatic"
3394         gcc_cv_ld_dynamic_option="-bdynamic"
3395         ;;
3396       # HP-UX ld uses -a flags to select between shared and archive.
3397       *-*-hpux*)
3398         if test x"$gnu_ld" = xno; then
3399           gcc_cv_ld_static_dynamic=yes
3400           gcc_cv_ld_static_option="-aarchive_shared"
3401           gcc_cv_ld_dynamic_option="-adefault"
3402         fi
3403         ;;
3404       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3405       *-*-solaris2*)
3406         gcc_cv_ld_static_dynamic=yes
3407         ;;
3408     esac
3409   fi
3410 fi
3411 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3412         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3413 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3414         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3415 [Define to the linker option to disable use of shared objects.])
3416         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3417 [Define to the linker option to enable use of shared objects.])
3418 fi
3419 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3420
3421 if test x"$demangler_in_ld" = xyes; then
3422   AC_MSG_CHECKING(linker --demangle support)
3423   gcc_cv_ld_demangle=no
3424   if test $in_tree_ld = yes; then
3425     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3426       gcc_cv_ld_demangle=yes
3427     fi
3428   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3429     # Check if the GNU linker supports --demangle option
3430     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3431       gcc_cv_ld_demangle=yes
3432     fi
3433   fi
3434   if test x"$gcc_cv_ld_demangle" = xyes; then
3435     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3436 [Define if your linker supports --demangle option.])
3437   fi
3438   AC_MSG_RESULT($gcc_cv_ld_demangle)
3439 fi
3440
3441 AC_MSG_CHECKING(linker plugin support)
3442 gcc_cv_lto_plugin=0
3443 if test -f liblto_plugin.la; then
3444   save_ld_ver="$ld_ver"
3445   save_ld_vers_major="$ld_vers_major"
3446   save_ld_vers_minor="$ld_vers_minor"
3447   save_ld_is_gold="$ld_is_gold"
3448
3449   ld_is_gold=no
3450
3451   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3452     ld_ver="GNU ld"
3453     # FIXME: ld_is_gold?
3454     ld_vers_major="$gcc_cv_gld_major_version"
3455     ld_vers_minor="$gcc_cv_gld_minor_version"
3456   else
3457     # Determine plugin linker version.
3458     # FIXME: Partial duplicate from above, generalize.
3459 changequote(,)dnl
3460     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
3461     if echo "$ld_ver" | grep GNU > /dev/null; then
3462       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
3463         ld_is_gold=yes
3464         ld_vers=`echo $ld_ver | sed -n \
3465             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3466       else
3467         ld_vers=`echo $ld_ver | sed -n \
3468             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3469       fi
3470       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3471       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3472     fi
3473 changequote([,])dnl
3474   fi
3475
3476   # Determine plugin support.
3477   if echo "$ld_ver" | grep GNU > /dev/null; then
3478     # Require GNU ld or gold 2.21+ for plugin support by default.
3479     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3480       gcc_cv_lto_plugin=2
3481     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3482     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3483       gcc_cv_lto_plugin=1
3484     fi
3485   fi
3486
3487   ld_ver="$save_ld_ver"
3488   ld_vers_major="$save_ld_vers_major"
3489   ld_vers_minor="$save_ld_vers_minor"
3490   ld_is_gold="$save_ld_is_gold"
3491 fi
3492 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3493   [Define to the level of your linker's plugin support.])
3494 AC_MSG_RESULT($gcc_cv_lto_plugin)
3495
3496 case "$target" in
3497   aarch64*-*-*)
3498     gcc_GAS_CHECK_FEATURE([-mabi option], gcc_cv_as_aarch64_mabi,,
3499                           [-mabi=lp64], [.text],,,)
3500     if test x$gcc_cv_as_aarch64_mabi = xyes; then
3501       AC_DEFINE(HAVE_AS_MABI_OPTION, 1,
3502                 [Define if your assembler supports the -mabi option.])
3503     else
3504       if test x$with_abi = xilp32; then
3505         AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3506                      Upgrade the Assembler.])
3507       fi
3508       if test x"$with_multilib_list" = xdefault; then
3509         TM_MULTILIB_CONFIG=lp64
3510       else
3511         aarch64_multilibs=`echo $with_multilib_list | sed -e 's/,/ /g'`
3512         for aarch64_multilib in ${aarch64_multilibs}; do
3513           case ${aarch64_multilib} in
3514             ilp32)
3515               AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3516                             Upgrade the Assembler.])
3517               ;;
3518             *)
3519               ;;
3520           esac
3521         done
3522       fi
3523     fi
3524     ;;
3525
3526   # All TARGET_ABI_OSF targets.
3527   alpha*-*-linux* | alpha*-*-*bsd*)
3528     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3529         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3530 [       .set nomacro
3531         .text
3532         extbl   $3, $2, $3      !lituse_bytoff!1
3533         ldq     $2, a($29)      !literal!1
3534         ldq     $4, b($29)      !literal!2
3535         ldq_u   $3, 0($2)       !lituse_base!1
3536         ldq     $27, f($29)     !literal!5
3537         jsr     $26, ($27), f   !lituse_jsr!5
3538         ldah    $29, 0($26)     !gpdisp!3
3539         lda     $0, c($29)      !gprel
3540         ldah    $1, d($29)      !gprelhigh
3541         lda     $1, d($1)       !gprellow
3542         lda     $29, 0($29)     !gpdisp!3],,
3543     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3544   [Define if your assembler supports explicit relocations.])])
3545     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3546         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3547 [       .set nomacro
3548         .text
3549         ldq     $27, a($29)     !literal!1
3550         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3551     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3552   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3553     ;;
3554
3555   cris-*-*)
3556     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3557       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3558       [-no-mul-bug-abort], [.text],,
3559       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3560                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3561     ;;
3562
3563   sparc*-*-*)
3564     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3565       [.register %g2, #scratch],,
3566       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3567                 [Define if your assembler supports .register.])])
3568
3569     gcc_GAS_CHECK_FEATURE([@%:@nobits], gcc_cv_as_sparc_nobits,,,
3570       [.section "nobits",#alloc,#write,#nobits
3571        .section "progbits",#alloc,#write,#progbits])
3572     AC_DEFINE_UNQUOTED(HAVE_AS_SPARC_NOBITS,
3573       [`if test $gcc_cv_as_sparc_nobits = yes; then echo 1; else echo 0; fi`],
3574       [Define to 1 if your assembler supports #nobits, 0 otherwise.])
3575
3576     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3577       [-relax], [.text],,
3578       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3579                 [Define if your assembler supports -relax option.])])
3580
3581     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3582       gcc_cv_as_sparc_gotdata_op,,
3583       [-K PIC],
3584 [.text
3585 .align 4
3586 foo:
3587         nop
3588 bar:
3589         sethi %gdop_hix22(foo), %g1
3590         xor    %g1, %gdop_lox10(foo), %g1
3591         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3592       [if test x$gcc_cv_ld != x \
3593        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3594          if test x$gcc_cv_objdump != x; then
3595            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3596               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3597                gcc_cv_as_sparc_gotdata_op=no
3598            else
3599                gcc_cv_as_sparc_gotdata_op=yes
3600            fi
3601          fi
3602        fi
3603        rm -f conftest],
3604       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3605                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3606
3607     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3608       gcc_cv_as_sparc_ua_pcrel,,
3609       [-K PIC],
3610 [.text
3611 foo:
3612         nop
3613 .data
3614 .align 4
3615 .byte 0
3616 .uaword %r_disp32(foo)],
3617       [if test x$gcc_cv_ld != x \
3618        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3619          gcc_cv_as_sparc_ua_pcrel=yes
3620        fi
3621        rm -f conftest],
3622       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3623                 [Define if your assembler and linker support unaligned PC relative relocs.])
3624
3625       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3626         gcc_cv_as_sparc_ua_pcrel_hidden,,
3627         [-K PIC],
3628 [.data
3629 .align 4
3630 .byte 0x31
3631 .uaword %r_disp32(foo)
3632 .byte 0x32, 0x33, 0x34
3633 .global foo
3634 .hidden foo
3635 foo:
3636 .skip 4],
3637         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3638          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3639          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3640             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3641             if $gcc_cv_objdump -R conftest 2> /dev/null \
3642                | grep 'DISP32' > /dev/null 2>&1; then
3643                 :
3644             else
3645                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3646             fi
3647          fi
3648          rm -f conftest],
3649          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3650                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3651     ]) # unaligned pcrel relocs
3652
3653     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3654       gcc_cv_as_sparc_offsetable_lo10,,
3655       [-xarch=v9],
3656 [.text
3657         or %g1, %lo(ab) + 12, %g1
3658         or %g1, %lo(ab + 12), %g1],
3659       [if test x$gcc_cv_objdump != x \
3660        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3661           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3662          gcc_cv_as_sparc_offsetable_lo10=yes
3663        fi],
3664        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3665                  [Define if your assembler supports offsetable %lo().])])
3666
3667     gcc_GAS_CHECK_FEATURE([FMAF, HPC, and VIS 3.0 instructions],
3668       gcc_cv_as_sparc_fmaf,,
3669       [-xarch=v9d],
3670       [.text
3671        .register %g2, #scratch
3672        .register %g3, #scratch
3673        .align 4
3674        fmaddd %f0, %f2, %f4, %f6
3675        addxccc %g1, %g2, %g3
3676        fsrl32 %f2, %f4, %f8
3677        fnaddd %f10, %f12, %f14],,
3678       [AC_DEFINE(HAVE_AS_FMAF_HPC_VIS3, 1,
3679                 [Define if your assembler supports FMAF, HPC, and VIS 3.0 instructions.])])
3680
3681     gcc_GAS_CHECK_FEATURE([SPARC4 instructions],
3682       gcc_cv_as_sparc_sparc4,,
3683       [-xarch=sparc4],
3684       [.text
3685        .register %g2, #scratch
3686        .register %g3, #scratch
3687        .align 4
3688        cxbe %g2, %g3, 1f
3689 1:     cwbneg %g2, %g3, 1f
3690 1:     sha1
3691        md5
3692        aes_kexpand0 %f4, %f6, %f8
3693        des_round %f38, %f40, %f42, %f44
3694        camellia_f %f54, %f56, %f58, %f60
3695        kasumi_fi_xor %f46, %f48, %f50, %f52],,
3696       [AC_DEFINE(HAVE_AS_SPARC4, 1,
3697                 [Define if your assembler supports SPARC4 instructions.])])
3698
3699     gcc_GAS_CHECK_FEATURE([LEON instructions],
3700       gcc_cv_as_sparc_leon,,
3701       [-Aleon],
3702       [.text
3703        .register %g2, #scratch
3704        .register %g3, #scratch
3705        .align 4
3706        smac %g2, %g3, %g1
3707        umac %g2, %g3, %g1
3708        cas [[%g2]], %g3, %g1],,
3709       [AC_DEFINE(HAVE_AS_LEON, 1,
3710                 [Define if your assembler supports LEON instructions.])])
3711     ;;
3712
3713 changequote(,)dnl
3714   i[34567]86-*-* | x86_64-*-*)
3715 changequote([,])dnl
3716     case $target_os in
3717       cygwin*)
3718         # Full C++ conformance when using a shared libstdc++-v3 requires some
3719         # support from the Cygwin DLL, which in more recent versions exports
3720         # wrappers to aid in interposing and redirecting operators new, delete,
3721         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3722         # are configuring for a version of Cygwin that exports the wrappers.
3723         if test x$host = x$target && test x$host_cpu = xi686; then
3724           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3725         else
3726           # Can't check presence of libc functions during cross-compile, so
3727           # we just have to assume we're building for an up-to-date target.
3728           gcc_ac_cygwin_dll_wrappers=yes
3729         fi
3730         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3731           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3732           [Define if you want to generate code by default that assumes that the
3733            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3734     esac
3735     case $target_os in
3736       cygwin* | pe | mingw32* | interix*)
3737         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3738         # definition is used unconditionally to initialise the default state of
3739         # the target option variable that governs usage of the feature.
3740         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3741          [2,19,52],,[.comm foo,1,32])
3742         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3743           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3744           [Define if your assembler supports specifying the alignment
3745            of objects allocated using the GAS .comm command.])
3746         # Used for DWARF 2 in PE
3747         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3748           gcc_cv_as_ix86_pe_secrel32,
3749           [2,15,91],,
3750 [.text
3751 foo:    nop
3752 .data
3753         .secrel32 foo],
3754           [if test x$gcc_cv_ld != x \
3755            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3756              gcc_cv_as_ix86_pe_secrel32=yes
3757            fi
3758            rm -f conftest],
3759           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3760             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3761         # Test if the assembler supports the extended form of the .section
3762         # directive that specifies section alignment.  LTO support uses this,
3763         # but normally only after installation, so we warn but don't fail the
3764         # configure if LTO is enabled but the assembler does not support it.
3765         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3766           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3767         if test x$gcc_cv_as_section_has_align != xyes; then
3768           case ",$enable_languages," in
3769             *,lto,*)
3770               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3771               ;;
3772           esac
3773         fi
3774         # Test if the assembler supports the section flag 'e' for specifying
3775         # an excluded section.
3776         gcc_GAS_CHECK_FEATURE([.section with e], gcc_cv_as_section_has_e,
3777           [2,22,51],,
3778 [.section foo1,"e"
3779 .byte 0,0,0,0])
3780         AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_EXCLUDE,
3781           [`if test $gcc_cv_as_section_has_e = yes; then echo 1; else echo 0; fi`],
3782           [Define if your assembler supports specifying the section flag e.])
3783         ;;
3784     esac
3785
3786     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3787        gcc_cv_as_ix86_filds,,,
3788        [filds mem; fists mem],,
3789        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3790          [Define if your assembler uses filds and fists mnemonics.])])
3791
3792     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3793        gcc_cv_as_ix86_fildq,,,
3794        [fildq mem; fistpq mem],,
3795        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3796          [Define if your assembler uses fildq and fistq mnemonics.])])
3797
3798     gcc_GAS_CHECK_FEATURE([cmov syntax],
3799       gcc_cv_as_ix86_cmov_sun_syntax,,,
3800       [cmovl.l %edx, %eax],,
3801       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3802         [Define if your assembler supports the Sun syntax for cmov.])])
3803
3804     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3805       gcc_cv_as_ix86_ffreep,,,
3806       [ffreep %st(1)],,
3807       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3808         [Define if your assembler supports the ffreep mnemonic.])])
3809
3810     gcc_GAS_CHECK_FEATURE([.quad directive],
3811       gcc_cv_as_ix86_quad,,,
3812       [.quad 0],,
3813       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3814         [Define if your assembler supports the .quad directive.])])
3815
3816     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3817       gcc_cv_as_ix86_sahf,,,
3818       [.code64
3819        sahf],,
3820       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3821         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3822
3823     gcc_GAS_CHECK_FEATURE([interunit movq mnemonic],
3824       gcc_cv_as_ix86_interunit_movq,,,
3825       [.code64
3826        movq %mm0, %rax
3827        movq %rax, %xmm0])
3828     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_INTERUNIT_MOVQ,
3829       [`if test $gcc_cv_as_ix86_interunit_movq = yes; then echo 1; else echo 0; fi`],
3830       [Define if your assembler supports interunit movq mnemonic.])
3831
3832     gcc_GAS_CHECK_FEATURE([hle prefixes],
3833       gcc_cv_as_ix86_hle,,,
3834       [lock xacquire cmpxchg %esi, (%ecx)],,
3835       [AC_DEFINE(HAVE_AS_IX86_HLE, 1,
3836         [Define if your assembler supports HLE prefixes.])])
3837
3838     gcc_GAS_CHECK_FEATURE([swap suffix],
3839       gcc_cv_as_ix86_swap,,,
3840       [movl.s %esp, %ebp],,
3841       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3842         [Define if your assembler supports the swap suffix.])])
3843
3844     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3845       gcc_cv_as_ix86_diff_sect_delta,,,
3846       [.section .rodata
3847 .L1:
3848         .long .L2-.L1
3849         .long .L3-.L1
3850         .text
3851 .L3:    nop
3852 .L2:    nop],,
3853       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3854         [Define if your assembler supports the subtraction of symbols in different sections.])])
3855
3856     # These two are used unconditionally by i386.[ch]; it is to be defined
3857     # to 1 if the feature is present, 0 otherwise.
3858     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3859         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3860 [       .text
3861 .L0:
3862         nop
3863         .data
3864         .long .L0@GOTOFF])
3865     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3866       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3867       [Define true if the assembler supports '.long foo@GOTOFF'.])
3868
3869     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3870         gcc_cv_as_ix86_rep_lock_prefix,,,
3871         [rep movsl
3872          rep ret
3873          rep nop
3874          rep bsf %ecx, %eax
3875          rep bsr %ecx, %eax
3876          lock addl %edi, (%eax,%esi)
3877          lock orl $0, (%esp)],,
3878         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3879           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3880
3881     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
3882         gcc_cv_as_ix86_tlsgdplt,,,
3883         [call    tls_gd@tlsgdplt],
3884         [if test x$gcc_cv_ld != x \
3885          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3886            gcc_cv_as_ix86_tlsgdplt=yes
3887          fi
3888          rm -f conftest],
3889       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
3890         [Define if your assembler and linker support @tlsgdplt.])])
3891
3892     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
3893         gcc_cv_as_ix86_tlsldmplt,,,
3894         [tls_ld:
3895          call    tls_ld@tlsldmplt],
3896         [if test x$gcc_cv_ld != x \
3897          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3898            gcc_cv_as_ix86_tlsldmplt=yes
3899          fi
3900          rm -f conftest],
3901       [AC_DEFINE(HAVE_AS_IX86_TLSLDMPLT, 1,
3902         [Define if your assembler and linker support @tlsldmplt.])])
3903
3904     ;;
3905
3906   ia64*-*-*)
3907     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3908         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3909 [       .text
3910         addl r15 = @ltoffx(x#), gp
3911         ;;
3912         ld8.mov r16 = [[r15]], x#],,
3913     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3914           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3915
3916     ;;
3917
3918   powerpc*-*-*)
3919     case $target in
3920       *-*-aix*) conftest_s='    .machine "pwr5"
3921         .csect .text[[PR]]
3922         mfcr 3,128';;
3923       *-*-darwin*)
3924         gcc_GAS_CHECK_FEATURE([.machine directive support],
3925           gcc_cv_as_machine_directive,,,
3926           [     .machine ppc7400])
3927         if test x$gcc_cv_as_machine_directive != xyes; then
3928           echo "*** This target requires an assembler supporting \".machine\"" >&2
3929           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3930           test x$build = x$target && exit 1
3931         fi
3932         conftest_s='    .text
3933         mfcr r3,128';;
3934       *) conftest_s='   .machine power4
3935         .text
3936         mfcr 3,128';;
3937     esac
3938
3939     gcc_GAS_CHECK_FEATURE([mfcr field support],
3940       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3941       [$conftest_s],,
3942       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3943           [Define if your assembler supports mfcr field.])])
3944
3945     case $target in
3946       *-*-aix*) conftest_s='    .machine "pwr5"
3947         .csect .text[[PR]]
3948         popcntb 3,3';;
3949       *) conftest_s='   .machine power5
3950         .text
3951         popcntb 3,3';;
3952     esac
3953
3954     gcc_GAS_CHECK_FEATURE([popcntb support],
3955       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3956       [$conftest_s],,
3957       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3958           [Define if your assembler supports popcntb field.])])
3959
3960     case $target in
3961       *-*-aix*) conftest_s='    .machine "pwr5x"
3962         .csect .text[[PR]]
3963         frin 1,1';;
3964       *) conftest_s='   .machine power5
3965         .text
3966         frin 1,1';;
3967     esac
3968
3969     gcc_GAS_CHECK_FEATURE([fp round support],
3970       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3971       [$conftest_s],,
3972       [AC_DEFINE(HAVE_AS_FPRND, 1,
3973           [Define if your assembler supports fprnd.])])
3974
3975     case $target in
3976       *-*-aix*) conftest_s='    .machine "pwr6"
3977         .csect .text[[PR]]
3978         mffgpr 1,3';;
3979       *) conftest_s='   .machine power6
3980         .text
3981         mffgpr 1,3';;
3982     esac
3983
3984     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3985       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3986       [$conftest_s],,
3987       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3988           [Define if your assembler supports mffgpr and mftgpr.])])
3989
3990     case $target in
3991       *-*-aix*) conftest_s='    .csect .text[[PR]]
3992 LCF..0:
3993         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3994       *-*-darwin*)
3995         conftest_s='    .text
3996 LCF0:
3997         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3998       *) conftest_s='   .text
3999 .LCF0:
4000         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
4001     esac
4002
4003     gcc_GAS_CHECK_FEATURE([rel16 relocs],
4004       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
4005       [$conftest_s],,
4006       [AC_DEFINE(HAVE_AS_REL16, 1,
4007           [Define if your assembler supports R_PPC_REL16 relocs.])])
4008
4009     case $target in
4010       *-*-aix*) conftest_s='    .machine "pwr6"
4011         .csect .text[[PR]]
4012         cmpb 3,4,5';;
4013       *) conftest_s='   .machine power6
4014         .text
4015         cmpb 3,4,5';;
4016     esac
4017
4018     gcc_GAS_CHECK_FEATURE([compare bytes support],
4019       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
4020       [$conftest_s],,
4021       [AC_DEFINE(HAVE_AS_CMPB, 1,
4022           [Define if your assembler supports cmpb.])])
4023
4024     case $target in
4025       *-*-aix*) conftest_s='    .machine "pwr6"
4026         .csect .text[[PR]]
4027         dadd 1,2,3';;
4028       *) conftest_s='   .machine power6
4029         .text
4030         dadd 1,2,3';;
4031     esac
4032
4033     gcc_GAS_CHECK_FEATURE([decimal float support],
4034       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
4035       [$conftest_s],,
4036       [AC_DEFINE(HAVE_AS_DFP, 1,
4037           [Define if your assembler supports DFP instructions.])])
4038
4039     case $target in
4040       *-*-aix*) conftest_s='    .machine "pwr7"
4041         .csect .text[[PR]]
4042         lxvd2x 1,2,3';;
4043       *) conftest_s='   .machine power7
4044         .text
4045         lxvd2x 1,2,3';;
4046     esac
4047
4048     gcc_GAS_CHECK_FEATURE([vector-scalar support],
4049       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
4050       [$conftest_s],,
4051       [AC_DEFINE(HAVE_AS_VSX, 1,
4052           [Define if your assembler supports VSX instructions.])])
4053
4054     case $target in
4055       *-*-aix*) conftest_s='    .machine "pwr7"
4056         .csect .text[[PR]]
4057         popcntd 3,3';;
4058       *) conftest_s='   .machine power7
4059         .text
4060         popcntd 3,3';;
4061     esac
4062
4063     gcc_GAS_CHECK_FEATURE([popcntd support],
4064       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
4065       [$conftest_s],,
4066       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
4067           [Define if your assembler supports POPCNTD instructions.])])
4068
4069     case $target in
4070       *-*-aix*) conftest_s='    .machine "pwr8"
4071         .csect .text[[PR]]';;
4072       *) conftest_s='   .machine power8
4073         .text';;
4074     esac
4075
4076     gcc_GAS_CHECK_FEATURE([power8 support],
4077       gcc_cv_as_powerpc_power8, [2,19,2], -a32,
4078       [$conftest_s],,
4079       [AC_DEFINE(HAVE_AS_POWER8, 1,
4080           [Define if your assembler supports POWER8 instructions.])])
4081
4082     case $target in
4083       *-*-aix*) conftest_s='    .csect .text[[PR]]
4084         lwsync';;
4085       *) conftest_s='   .text
4086         lwsync';;
4087     esac
4088
4089     gcc_GAS_CHECK_FEATURE([lwsync support],
4090       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
4091       [$conftest_s],,
4092       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
4093           [Define if your assembler supports LWSYNC instructions.])])
4094
4095     case $target in
4096       *-*-aix*) conftest_s='    .machine "476"
4097         .csect .text[[PR]]
4098         dci 0';;
4099       *) conftest_s='   .machine "476"
4100         .text
4101         dci 0';;
4102     esac
4103
4104     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
4105       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
4106       [$conftest_s],,
4107       [AC_DEFINE(HAVE_AS_DCI, 1,
4108           [Define if your assembler supports the DCI/ICI instructions.])])
4109
4110     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4111       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
4112       [.gnu_attribute 4,1],,
4113       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4114           [Define if your assembler supports .gnu_attribute.])])
4115
4116     gcc_GAS_CHECK_FEATURE([tls marker support],
4117       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
4118       [ bl __tls_get_addr(x@tlsgd)],,
4119       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
4120           [Define if your assembler supports arg info for __tls_get_addr.])])
4121
4122     case $target in
4123       *-*-aix*)
4124         gcc_GAS_CHECK_FEATURE([.ref support],
4125           gcc_cv_as_aix_ref, [2,21,0],,
4126           [     .csect stuff[[rw]]
4127              stuff:
4128                 .long 1
4129                 .extern sym
4130                 .ref sym
4131           ],,
4132           [AC_DEFINE(HAVE_AS_REF, 1,
4133             [Define if your assembler supports .ref])])
4134         ;;
4135     esac
4136     ;;
4137
4138   mips*-*-*)
4139     gcc_GAS_CHECK_FEATURE([explicit relocation support],
4140       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
4141 [       lw $4,%gp_rel(foo)($4)],,
4142       [if test x$target_cpu_default = x
4143        then target_cpu_default=MASK_EXPLICIT_RELOCS
4144        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
4145        fi])
4146     gcc_GAS_CHECK_FEATURE([-mno-shared support],
4147       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
4148       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
4149                  [Define if the assembler understands -mno-shared.])])
4150
4151     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4152       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
4153       [.gnu_attribute 4,1],,
4154       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4155           [Define if your assembler supports .gnu_attribute.])])
4156
4157     gcc_GAS_CHECK_FEATURE([.micromips support],
4158       gcc_cv_as_micromips_support,,[--fatal-warnings],
4159       [.set micromips],,
4160       [AC_DEFINE(HAVE_GAS_MICROMIPS, 1,
4161           [Define if your assembler supports the .set micromips directive])])
4162
4163     gcc_GAS_CHECK_FEATURE([.dtprelword support],
4164       gcc_cv_as_mips_dtprelword, [2,18,0],,
4165       [.section .tdata,"awT",@progbits
4166 x:
4167         .word 2
4168         .text
4169         .dtprelword x+0x8000],,
4170       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
4171           [Define if your assembler supports .dtprelword.])])
4172
4173     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
4174       gcc_cv_as_mips_dspr1_mult,,,
4175 [       .set    mips32r2
4176         .set    nodspr2
4177         .set    dsp
4178         madd    $ac3,$4,$5
4179         maddu   $ac3,$4,$5
4180         msub    $ac3,$4,$5
4181         msubu   $ac3,$4,$5
4182         mult    $ac3,$4,$5
4183         multu   $ac3,$4,$5],,
4184       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
4185           [Define if your assembler supports DSPR1 mult.])])
4186
4187     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
4188     gcc_cv_as_ld_jalr_reloc=no
4189     if test $gcc_cv_as_mips_explicit_relocs = yes; then
4190       if test $in_tree_ld = yes ; then
4191         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
4192            && test $in_tree_ld_is_elf = yes; then
4193           gcc_cv_as_ld_jalr_reloc=yes
4194         fi
4195       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
4196         echo '  .ent x' > conftest.s
4197         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
4198         echo '  ld $25,%call16(y)($28)' >> conftest.s
4199         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
4200         echo '1:        jalr $25' >> conftest.s
4201         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
4202         echo '1:        jalr $25' >> conftest.s
4203         echo '  .end x' >> conftest.s
4204         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
4205            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
4206           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
4207              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
4208             gcc_cv_as_ld_jalr_reloc=yes
4209           fi
4210         fi
4211         rm -f conftest.*
4212       fi
4213     fi
4214     if test $gcc_cv_as_ld_jalr_reloc = yes; then
4215       if test x$target_cpu_default = x; then
4216         target_cpu_default=MASK_RELAX_PIC_CALLS
4217       else
4218         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
4219       fi
4220     fi
4221     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
4222
4223     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
4224       [gcc_cv_ld_mips_personality_relaxation],
4225       [gcc_cv_ld_mips_personality_relaxation=no
4226        if test $in_tree_ld = yes ; then
4227          if test "$gcc_cv_gld_major_version" -eq 2 \
4228                  -a "$gcc_cv_gld_minor_version" -ge 21 \
4229                  -o "$gcc_cv_gld_major_version" -gt 2; then
4230            gcc_cv_ld_mips_personality_relaxation=yes
4231          fi
4232        elif test x$gcc_cv_as != x \
4233                  -a x$gcc_cv_ld != x \
4234                  -a x$gcc_cv_readelf != x ; then
4235          cat > conftest.s <<EOF
4236         .cfi_startproc
4237         .cfi_personality 0x80,indirect_ptr
4238         .ent test
4239 test:
4240         nop
4241         .end test
4242         .cfi_endproc
4243
4244         .section .data,"aw",@progbits
4245 indirect_ptr:
4246         .dc.a personality
4247 EOF
4248          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
4249             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
4250            if $gcc_cv_readelf -d conftest 2>&1 \
4251               | grep TEXTREL > /dev/null 2>&1; then
4252              :
4253            elif $gcc_cv_readelf --relocs conftest 2>&1 \
4254                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
4255              :
4256            else
4257              gcc_cv_ld_mips_personality_relaxation=yes
4258            fi
4259          fi
4260        fi
4261        rm -f conftest.s conftest.o conftest])
4262     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
4263             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
4264       [Define if your linker can relax absolute .eh_frame personality
4265 pointers into PC-relative form.])
4266     fi
4267
4268     gcc_GAS_CHECK_FEATURE([-mnan= support],
4269       gcc_cv_as_mips_nan,,
4270       [-mnan=2008],,,
4271       [AC_DEFINE(HAVE_AS_NAN, 1,
4272                  [Define if the assembler understands -mnan=.])])
4273     if test x$gcc_cv_as_mips_nan = xno \
4274        && test x$with_nan != x; then
4275       AC_MSG_ERROR(
4276         [Requesting --with-nan= requires assembler support for -mnan=])
4277     fi
4278     ;;
4279 esac
4280
4281 # Mips and HP-UX need the GNU assembler.
4282 # Linux on IA64 might be able to use the Intel assembler.
4283
4284 case "$target" in
4285   mips*-*-* | *-*-hpux* )
4286     if test x$gas_flag = xyes \
4287        || test x"$host" != x"$build" \
4288        || test ! -x "$gcc_cv_as" \
4289        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
4290       :
4291     else
4292       echo "*** This configuration requires the GNU assembler" >&2
4293       exit 1
4294     fi
4295     ;;
4296 esac
4297
4298 # ??? Not all targets support dwarf2 debug_line, even within a version
4299 # of gas.  Moreover, we need to emit a valid instruction to trigger any
4300 # info to the output file.  So, as supported targets are added to gas 2.11,
4301 # add some instruction here to (also) show we expect this might work.
4302 # ??? Once 2.11 is released, probably need to add first known working
4303 # version to the per-target configury.
4304 case "$cpu_type" in
4305   aarch64 | alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze \
4306   | mips | pa | rs6000 | score | sparc | spu | tilegx | tilepro | xstormy16 \
4307   | xtensa)
4308     insn="nop"
4309     ;;
4310   ia64 | s390)
4311     insn="nop 0"
4312     ;;
4313   mmix)
4314     insn="swym 0"
4315     ;;
4316 esac
4317 if test x"$insn" != x; then
4318  conftest_s="\
4319         .file 1 \"conftest.s\"
4320         .loc 1 3 0
4321         $insn"
4322  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
4323   gcc_cv_as_dwarf2_debug_line,
4324   [elf,2,11,0],, [$conftest_s],
4325   [if test x$gcc_cv_objdump != x \
4326    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
4327       | grep debug_line > /dev/null 2>&1; then
4328      gcc_cv_as_dwarf2_debug_line=yes
4329    fi])
4330
4331 # The .debug_line file table must be in the exact order that
4332 # we specified the files, since these indices are also used
4333 # by DW_AT_decl_file.  Approximate this test by testing if
4334 # the assembler bitches if the same index is assigned twice.
4335  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
4336   gcc_cv_as_dwarf2_file_buggy,,,
4337 [       .file 1 "foo.s"
4338         .file 1 "bar.s"])
4339
4340  if test $gcc_cv_as_dwarf2_debug_line = yes \
4341  && test $gcc_cv_as_dwarf2_file_buggy = no; then
4342         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
4343   [Define if your assembler supports dwarf2 .file/.loc directives,
4344    and preserves file table indices exactly as given.])
4345  fi
4346
4347  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
4348   gcc_cv_as_gdwarf2_flag,
4349   [elf,2,11,0], [--gdwarf2], [$insn],,
4350   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
4351 [Define if your assembler supports the --gdwarf2 option.])])
4352
4353  gcc_GAS_CHECK_FEATURE([--gstabs option],
4354   gcc_cv_as_gstabs_flag,
4355   [elf,2,11,0], [--gstabs], [$insn],
4356   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
4357    # and warns about it, but still exits successfully.  So check for
4358    # this.
4359    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
4360    then :
4361    else gcc_cv_as_gstabs_flag=yes
4362    fi],
4363   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
4364 [Define if your assembler supports the --gstabs option.])])
4365
4366  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
4367   gcc_cv_as_debug_prefix_map_flag,
4368   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
4369   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
4370 [Define if your assembler supports the --debug-prefix-map option.])])
4371 fi
4372
4373 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
4374  ,,
4375 [.lcomm bar,4,16],,
4376 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
4377   [Define if your assembler supports .lcomm with an alignment field.])])
4378
4379 if test x$with_sysroot = x && test x$host = x$target \
4380    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4381    && test "$prefix" != "NONE"; then
4382   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4383 [Define to PREFIX/include if cpp should also search that directory.])
4384 fi
4385
4386 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4387   if test "x$with_headers" != x; then
4388     target_header_dir=$with_headers
4389   elif test "x$with_sysroot" = x; then
4390     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-include"
4391   elif test "x$with_build_sysroot" != "x"; then
4392     target_header_dir="${with_build_sysroot}${native_system_header_dir}"
4393   elif test "x$with_sysroot" = xyes; then
4394     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-root${native_system_header_dir}"
4395   else
4396     target_header_dir="${with_sysroot}${native_system_header_dir}"
4397   fi
4398 else
4399   target_header_dir=${native_system_header_dir}
4400 fi
4401
4402 # Determine the version of glibc, if any, used on the target.
4403 AC_MSG_CHECKING([for target glibc version])
4404 AC_ARG_WITH([glibc-version],
4405   [AS_HELP_STRING([--with-glibc-version=M.N],
4406     [assume GCC used with glibc version M.N or later])], [
4407 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
4408   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
4409   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
4410 else
4411   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
4412 fi], [
4413 glibc_version_major=0
4414 glibc_version_minor=0
4415 [if test -f $target_header_dir/features.h \
4416   && glibc_version_major_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC__[    ]+[0-9]' $target_header_dir/features.h` \
4417   && glibc_version_minor_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+[0-9]' $target_header_dir/features.h`; then
4418   glibc_version_major=`echo "$glibc_version_major_define" | sed -e 's/.*__GLIBC__[      ]*//'`
4419   glibc_version_minor=`echo "$glibc_version_minor_define" | sed -e 's/.*__GLIBC_MINOR__[        ]*//'`
4420 fi]])
4421 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
4422
4423 AC_ARG_ENABLE(gnu-unique-object,
4424  [AS_HELP_STRING([--enable-gnu-unique-object],
4425    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
4426  [case $enable_gnu_unique_object in
4427     yes | no) ;;
4428     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
4429 Valid choices are 'yes' and 'no'.]) ;;
4430   esac],
4431  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
4432    [elf,2,19,52],,
4433    [.type foo, '$target_type_format_char'gnu_unique_object],,
4434 # We need to unquote above to to use the definition from config.gcc.
4435 # Also check for ld.so support, i.e. glibc 2.11 or higher.
4436    [GCC_GLIBC_VERSION_GTE_IFELSE([2], [11], [enable_gnu_unique_object=yes], )]
4437    )])
4438 if test x$enable_gnu_unique_object = xyes; then
4439   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
4440    [Define if your assembler supports @gnu_unique_object.])
4441 fi
4442
4443 AC_CACHE_CHECK([assembler for tolerance to line number 0],
4444  [gcc_cv_as_line_zero],
4445  [gcc_cv_as_line_zero=no
4446   if test $in_tree_gas = yes; then
4447     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
4448   elif test "x$gcc_cv_as" != x; then
4449     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
4450     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
4451        test "x`cat conftest.out`" = x
4452     then
4453       gcc_cv_as_line_zero=yes
4454     else
4455       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
4456       cat conftest.s >&AS_MESSAGE_LOG_FD
4457       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4458       cat conftest.out >&AS_MESSAGE_LOG_FD
4459     fi
4460     rm -f conftest.o conftest.s conftest.out
4461   fi])
4462 if test "x$gcc_cv_as_line_zero" = xyes; then
4463   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4464 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4465 fi
4466
4467 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4468 gcc_cv_ld_eh_frame_hdr=no
4469 if test $in_tree_ld = yes ; then
4470   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4471      && test $in_tree_ld_is_elf = yes; then
4472     gcc_cv_ld_eh_frame_hdr=yes
4473   fi
4474 elif test x$gcc_cv_ld != x; then
4475   if echo "$ld_ver" | grep GNU > /dev/null; then
4476     # Check if linker supports --eh-frame-hdr option
4477     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4478       gcc_cv_ld_eh_frame_hdr=yes
4479     fi
4480   else
4481     case "$target" in
4482       *-*-solaris2*)
4483         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4484         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4485           gcc_cv_ld_eh_frame_hdr=yes
4486         fi
4487         ;;
4488     esac
4489   fi
4490 fi
4491 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4492 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4493         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4494 [Define if your linker supports .eh_frame_hdr.])
4495 fi
4496 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4497
4498 AC_MSG_CHECKING(linker CIEv3 in .eh_frame support)
4499 gcc_cv_ld_eh_frame_ciev3=no
4500 if test $in_tree_ld = yes ; then
4501   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4502      && test $in_tree_ld_is_elf = yes; then
4503     gcc_cv_ld_eh_frame_ciev3=yes
4504   fi
4505 elif test x$gcc_cv_ld != x; then
4506   if echo "$ld_ver" | grep GNU > /dev/null; then
4507     gcc_cv_ld_eh_frame_ciev3=yes
4508     if test 0"$ld_date" -lt 20040513; then
4509       if test -n "$ld_date"; then
4510         # If there was date string, but was earlier than 2004-05-13, fail
4511         gcc_cv_ld_eh_frame_ciev3=no
4512       elif test "$ld_vers_major" -lt 2; then
4513         gcc_cv_ld_eh_frame_ciev3=no
4514       elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
4515         gcc_cv_ld_eh_frame_ciev3=no
4516       fi
4517     fi
4518   else
4519     case "$target" in
4520       *-*-solaris2*)
4521         # Sun ld added support for CIE v3 in .eh_frame in Solaris 11.1.
4522         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2324; then
4523           gcc_cv_ld_eh_frame_ciev3=yes
4524         fi
4525         ;;
4526     esac
4527   fi
4528 fi
4529 AC_DEFINE_UNQUOTED(HAVE_LD_EH_FRAME_CIEV3,
4530   [`if test x"$gcc_cv_ld_eh_frame_ciev3" = xyes; then echo 1; else echo 0; fi`],
4531   [Define 0/1 if your linker supports CIE v3 in .eh_frame.])
4532 AC_MSG_RESULT($gcc_cv_ld_eh_frame_ciev3)
4533
4534 AC_MSG_CHECKING(linker position independent executable support)
4535 gcc_cv_ld_pie=no
4536 if test $in_tree_ld = yes ; then
4537   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
4538      && test $in_tree_ld_is_elf = yes; then
4539     gcc_cv_ld_pie=yes
4540   fi
4541 elif test x$gcc_cv_ld != x; then
4542         # Check if linker supports -pie option
4543         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
4544                 gcc_cv_ld_pie=yes
4545         fi
4546 fi
4547 if test x"$gcc_cv_ld_pie" = xyes; then
4548         AC_DEFINE(HAVE_LD_PIE, 1,
4549 [Define if your linker supports -pie option.])
4550 fi
4551 AC_MSG_RESULT($gcc_cv_ld_pie)
4552
4553 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
4554 gcc_cv_ld_eh_gc_sections=no
4555 if test $in_tree_ld = yes ; then
4556   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
4557      && test $in_tree_ld_is_elf = yes; then
4558     gcc_cv_ld_eh_gc_sections=yes
4559   fi
4560 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
4561   cat > conftest.s <<EOF
4562         .section        .text
4563 .globl _start
4564         .type _start, @function
4565 _start:
4566         .long foo
4567         .size _start, .-_start
4568         .section        .text.foo,"ax",@progbits
4569         .type foo, @function
4570 foo:
4571         .long 0
4572         .size foo, .-foo
4573         .section        .gcc_except_table.foo,"a",@progbits
4574 .L0:
4575         .long 0
4576         .section        .eh_frame,"a",@progbits
4577         .long .L0
4578 EOF
4579   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4580     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4581          | grep "gc-sections option ignored" > /dev/null; then
4582       gcc_cv_ld_eh_gc_sections=no
4583     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4584          | grep gcc_except_table > /dev/null; then
4585       gcc_cv_ld_eh_gc_sections=yes
4586       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
4587       if test x$gcc_cv_as_comdat_group != xyes; then
4588         gcc_cv_ld_eh_gc_sections=no
4589         cat > conftest.s <<EOF
4590         .section        .text
4591 .globl _start
4592         .type _start, @function
4593 _start:
4594         .long foo
4595         .size _start, .-_start
4596         .section        .gnu.linkonce.t.foo,"ax",@progbits
4597         .type foo, @function
4598 foo:
4599         .long 0
4600         .size foo, .-foo
4601         .section        .gcc_except_table.foo,"a",@progbits
4602 .L0:
4603         .long 0
4604         .section        .eh_frame,"a",@progbits
4605         .long .L0
4606 EOF
4607         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4608           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4609                | grep "gc-sections option ignored" > /dev/null; then
4610             gcc_cv_ld_eh_gc_sections=no
4611           elif $gcc_cv_objdump -h conftest 2> /dev/null \
4612                | grep gcc_except_table > /dev/null; then
4613             gcc_cv_ld_eh_gc_sections=yes
4614           fi
4615         fi
4616       fi
4617     fi
4618   fi
4619   rm -f conftest.s conftest.o conftest
4620 fi
4621 case "$target" in
4622   hppa*-*-linux*)
4623     # ??? This apparently exposes a binutils bug with PC-relative relocations.
4624     gcc_cv_ld_eh_gc_sections=no
4625     ;;
4626 esac
4627 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
4628         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
4629   [Define if your linker supports garbage collection of
4630    sections in presence of EH frames.])
4631 fi
4632 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
4633
4634 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
4635 gcc_cv_ld_eh_gc_sections_bug=no
4636 if test $in_tree_ld = yes ; then
4637   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
4638      && test $in_tree_ld_is_elf = yes; then
4639     gcc_cv_ld_eh_gc_sections_bug=yes
4640   fi
4641 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
4642   gcc_cv_ld_eh_gc_sections_bug=yes
4643   cat > conftest.s <<EOF
4644         .section        .text
4645 .globl _start
4646         .type _start, @function
4647 _start:
4648         .long foo
4649         .size _start, .-_start
4650         .section        .text.startup.foo,"ax",@progbits
4651         .type foo, @function
4652 foo:
4653         .long 0
4654         .size foo, .-foo
4655         .section        .gcc_except_table.foo,"a",@progbits
4656 .L0:
4657         .long 0
4658         .section        .eh_frame,"a",@progbits
4659         .long .L0
4660 EOF
4661   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4662     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4663          | grep "gc-sections option ignored" > /dev/null; then
4664       :
4665     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4666          | grep gcc_except_table > /dev/null; then
4667       gcc_cv_ld_eh_gc_sections_bug=no
4668     fi
4669   fi
4670   rm -f conftest.s conftest.o conftest
4671 fi
4672 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
4673         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
4674   [Define if your linker has buggy garbage collection of
4675    sections support when .text.startup.foo like sections are used.])
4676 fi
4677 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
4678
4679 # --------
4680 # UNSORTED
4681 # --------
4682
4683 AC_CACHE_CHECK(linker --as-needed support,
4684 gcc_cv_ld_as_needed,
4685 [gcc_cv_ld_as_needed=no
4686 gcc_cv_ld_as_needed_option='--as-needed'
4687 gcc_cv_ld_no_as_needed_option='--no-as-needed'
4688 if test $in_tree_ld = yes ; then
4689   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4690      && test $in_tree_ld_is_elf = yes; then
4691     gcc_cv_ld_as_needed=yes
4692   fi
4693 elif test x$gcc_cv_ld != x; then
4694         # Check if linker supports --as-needed and --no-as-needed options
4695         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
4696                 gcc_cv_ld_as_needed=yes
4697         else
4698           case "$target" in
4699             # Solaris 2 ld always supports -z ignore/-z record.
4700             *-*-solaris2*)
4701               gcc_cv_ld_as_needed=yes
4702               gcc_cv_ld_as_needed_option="-z ignore"
4703               gcc_cv_ld_no_as_needed_option="-z record"
4704               ;;
4705           esac
4706         fi
4707 fi
4708 # --as-needed/-z ignore can only be used if libgcc_s.so.1 uses
4709 # dl_iterate_phdr, i.e. since Solaris 11.
4710 case "$target" in
4711   *-*-solaris2.1[[1-9]]*)
4712     case "$target" in
4713     i?86-*-* | x86_64-*-*)
4714       if echo "$ld_ver" | grep GNU > /dev/null; then
4715         # Doesn't work with gld on Solaris/x86 due to PR ld/12320.
4716         gcc_cv_ld_as_needed=no
4717       fi
4718       ;;
4719     esac
4720     ;;
4721   *-*-solaris2*)
4722     gcc_cv_ld_as_needed=no
4723     ;;
4724 esac
4725 ])
4726 if test x"$gcc_cv_ld_as_needed" = xyes; then
4727         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
4728 [Define if your linker supports --as-needed/--no-as-needed or equivalent options.])
4729         AC_DEFINE_UNQUOTED(LD_AS_NEEDED_OPTION, "$gcc_cv_ld_as_needed_option",
4730 [Define to the linker option to ignore unused dependencies.])
4731         AC_DEFINE_UNQUOTED(LD_NO_AS_NEEDED_OPTION, "$gcc_cv_ld_no_as_needed_option",
4732 [Define to the linker option to keep unused dependencies.])
4733 fi
4734
4735 case "$target:$tm_file" in
4736   powerpc64-*-freebsd* | powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
4737   case "$target" in
4738      *le-*-linux*)
4739      emul_name="-melf64lppc"
4740       ;;
4741      *-*-linux*)
4742      emul_name="-melf64ppc"
4743       ;;
4744      *-*-freebsd*)
4745      emul_name="-melf64ppc_fbsd"
4746       ;;
4747   esac
4748     AC_CACHE_CHECK(linker support for omitting dot symbols,
4749     gcc_cv_ld_no_dot_syms,
4750     [gcc_cv_ld_no_dot_syms=no
4751     if test x"$ld_is_gold" = xyes; then
4752       gcc_cv_ld_no_dot_syms=yes
4753     elif test $in_tree_ld = yes ; then
4754       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
4755         gcc_cv_ld_no_dot_syms=yes
4756       fi
4757     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4758       cat > conftest1.s <<EOF
4759         .text
4760         bl .foo
4761 EOF
4762       cat > conftest2.s <<EOF
4763         .section ".opd","aw"
4764         .align 3
4765         .globl foo
4766         .type foo,@function
4767 foo:
4768         .quad .LEfoo,.TOC.@tocbase,0
4769         .text
4770 .LEfoo:
4771         blr
4772         .size foo,.-.LEfoo
4773 EOF
4774       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
4775          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
4776          && $gcc_cv_ld $emul_name -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
4777         gcc_cv_ld_no_dot_syms=yes
4778       fi
4779       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
4780     fi
4781     ])
4782     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
4783       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
4784     [Define if your PowerPC64 linker only needs function descriptor syms.])
4785     fi
4786
4787     AC_CACHE_CHECK(linker large toc support,
4788     gcc_cv_ld_large_toc,
4789     [gcc_cv_ld_large_toc=no
4790     if test x"$ld_is_gold" = xyes; then
4791       gcc_cv_ld_large_toc=yes
4792     elif test $in_tree_ld = yes ; then
4793       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
4794         gcc_cv_ld_large_toc=yes
4795       fi
4796     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4797       cat > conftest.s <<EOF
4798         .section ".tbss","awT",@nobits
4799         .align 3
4800 ie0:    .space 8
4801         .global _start
4802         .text
4803 _start:
4804         addis 9,13,ie0@got@tprel@ha
4805         ld 9,ie0@got@tprel@l(9)
4806 EOF
4807       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
4808          && $gcc_cv_ld $emul_name --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
4809         gcc_cv_ld_large_toc=yes
4810       fi
4811       rm -f conftest conftest.o conftest.s
4812     fi
4813     ])
4814     if test x"$gcc_cv_ld_large_toc" = xyes; then
4815       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4816     [Define if your PowerPC64 linker supports a large TOC.])
4817     fi
4818     ;;
4819 esac
4820
4821 case "$target" in
4822   *-*-aix*)
4823     AC_CACHE_CHECK(linker large toc support,
4824     gcc_cv_ld_large_toc,
4825     [gcc_cv_ld_large_toc=no
4826     if test x$gcc_cv_as != x ; then
4827       cat > conftest.s <<EOF
4828         .toc
4829 LC..1:
4830         .tc a[[TC]],a[[RW]]
4831         .extern a[[RW]]
4832         .csect .text[[PR]]
4833 .largetoctest:
4834         addis 9,LC..1@u(2)
4835         ld 3,LC..1@l(9)
4836 EOF
4837       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1; then
4838         gcc_cv_ld_large_toc=yes
4839       fi
4840       rm -f conftest conftest.o conftest.s
4841     fi
4842     ])
4843     if test x"$gcc_cv_ld_large_toc" = xyes; then
4844       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4845     [Define if your PowerPC64 linker supports a large TOC.])
4846     fi
4847     ;;
4848 esac
4849
4850 AC_CACHE_CHECK(linker --build-id support,
4851   gcc_cv_ld_buildid,
4852   [gcc_cv_ld_buildid=no
4853   if test $in_tree_ld = yes ; then
4854     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4855        "$gcc_cv_gld_minor_version" -ge 18 -o \
4856        "$gcc_cv_gld_major_version" -gt 2 \
4857        && test $in_tree_ld_is_elf = yes; then
4858       gcc_cv_ld_buildid=yes
4859     fi
4860   elif test x$gcc_cv_ld != x; then
4861     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4862       gcc_cv_ld_buildid=yes
4863     fi
4864   fi])
4865 if test x"$gcc_cv_ld_buildid" = xyes; then
4866   AC_DEFINE(HAVE_LD_BUILDID, 1,
4867   [Define if your linker supports --build-id.])
4868 fi
4869
4870 AC_ARG_ENABLE(linker-build-id,
4871 [AS_HELP_STRING([--enable-linker-build-id],
4872                 [compiler will always pass --build-id to linker])],
4873 [],
4874 enable_linker_build_id=no)
4875
4876 if test x"$enable_linker_build_id" = xyes; then
4877   if test x"$gcc_cv_ld_buildid" = xyes; then
4878     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4879     [Define if gcc should always pass --build-id to linker.])
4880   else
4881     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4882   fi
4883 fi
4884
4885 # In binutils 2.21, GNU ld gained support for new emulations fully
4886 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
4887 AC_CACHE_CHECK(linker *_sol2 emulation support,
4888   gcc_cv_ld_sol2_emulation,
4889   [gcc_cv_ld_sol2_emulation=no
4890   if test $in_tree_ld = yes ; then
4891     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4892        "$gcc_cv_gld_minor_version" -ge 21 -o \
4893        "$gcc_cv_gld_major_version" -gt 2 \
4894        && test $in_tree_ld_is_elf = yes; then
4895       gcc_cv_ld_sol2_emulation=yes
4896     fi
4897   elif test x$gcc_cv_ld != x; then
4898     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
4899        grep _sol2 > /dev/null; then
4900       gcc_cv_ld_sol2_emulation=yes
4901     fi
4902   fi])
4903 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
4904   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
4905   [Define if your linker supports the *_sol2 emulations.])
4906 fi
4907
4908 AC_CACHE_CHECK(linker --sysroot support,
4909   gcc_cv_ld_sysroot,
4910   [gcc_cv_ld_sysroot=no
4911   if test $in_tree_ld = yes ; then
4912       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4913         gcc_cv_ld_sysroot=yes
4914       fi
4915   elif test x$gcc_cv_ld != x; then
4916     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4917       gcc_cv_ld_sysroot=yes
4918     fi
4919   fi])
4920 if test x"$gcc_cv_ld_sysroot" = xyes; then
4921   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4922   [Define if your linker supports --sysroot.])
4923 fi
4924
4925 # Test for stack protector support in target C library.
4926 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4927       gcc_cv_libc_provides_ssp,
4928       [gcc_cv_libc_provides_ssp=no
4929     case "$target" in
4930        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4931       # glibc 2.4 and later provides __stack_chk_fail and
4932       # either __stack_chk_guard, or TLS access to stack guard canary.
4933       GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_libc_provides_ssp=yes], [
4934       [if test -f $target_header_dir/features.h \
4935          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4936             $target_header_dir/features.h > /dev/null; then
4937         if $EGREP '^[   ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4938              $target_header_dir/features.h > /dev/null && \
4939              test -f $target_header_dir/bits/uClibc_config.h && \
4940              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4941              $target_header_dir/bits/uClibc_config.h > /dev/null; then
4942           gcc_cv_libc_provides_ssp=yes
4943         fi
4944       # all versions of Bionic support stack protector
4945       elif test -f $target_header_dir/sys/cdefs.h \
4946         && $EGREP '^[  ]*#[    ]*define[       ]+__BIONIC__[   ]+1' \
4947            $target_header_dir/sys/cdefs.h > /dev/null; then
4948          gcc_cv_libc_provides_ssp=yes
4949       fi]])
4950         ;;
4951        *-*-gnu*)
4952          # Avoid complicated tests (see
4953          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4954          # simply assert that glibc does provide this, which is true for all
4955          # realistically usable GNU/Hurd configurations.
4956          gcc_cv_libc_provides_ssp=yes;;
4957        *-*-darwin* | *-*-freebsd*)
4958          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4959            [echo "no __stack_chk_fail on this target"])
4960         ;;
4961   *) gcc_cv_libc_provides_ssp=no ;;
4962     esac])
4963
4964 if test x$gcc_cv_libc_provides_ssp = xyes; then
4965   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4966             [Define if your target C library provides stack protector support])
4967 fi
4968
4969 # Test for <sys/sdt.h> on the target.
4970 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
4971 AC_MSG_CHECKING(sys/sdt.h in the target C library)
4972 have_sys_sdt_h=no
4973 if test -f $target_header_dir/sys/sdt.h; then
4974   have_sys_sdt_h=yes
4975   AC_DEFINE(HAVE_SYS_SDT_H, 1,
4976             [Define if your target C library provides sys/sdt.h])
4977 fi
4978 AC_MSG_RESULT($have_sys_sdt_h)
4979
4980 # Check if TFmode long double should be used by default or not.
4981 # Some glibc targets used DFmode long double, but with glibc 2.4
4982 # and later they can use TFmode.
4983 case "$target" in
4984   powerpc*-*-linux* | \
4985   sparc*-*-linux* | \
4986   s390*-*-linux* | \
4987   alpha*-*-linux*)
4988     AC_ARG_WITH(long-double-128,
4989       [AS_HELP_STRING([--with-long-double-128],
4990                       [use 128-bit long double by default])],
4991       gcc_cv_target_ldbl128="$with_long_double_128",
4992       [GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_target_ldbl128=yes], [
4993       [gcc_cv_target_ldbl128=no
4994       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4995         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4996       && gcc_cv_target_ldbl128=yes
4997       ]])])
4998     ;;
4999 esac
5000 if test x$gcc_cv_target_ldbl128 = xyes; then
5001   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
5002             [Define if TFmode long double should be the default])
5003 fi
5004
5005 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
5006 gcc_cv_target_dl_iterate_phdr=unknown
5007 case "$target" in
5008   # Restrict to Solaris 11+.  While most of the Solaris 11 linker changes
5009   # were backported to Solaris 10 Update 10, dl_iterate_phdr only lives in
5010   # libdl there, both complicating its use and breaking compatibility
5011   # between Solaris 10 updates.
5012   *-*-solaris2.1[[1-9]]*)
5013     # <link.h> needs both a dl_iterate_phdr declaration and support for
5014     # compilation with largefile support.
5015     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
5016       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
5017       gcc_cv_target_dl_iterate_phdr=yes
5018     else
5019       gcc_cv_target_dl_iterate_phdr=no
5020     fi
5021     ;;
5022 esac
5023 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
5024 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
5025    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
5026 [Define if your target C library provides the `dl_iterate_phdr' function.])
5027 fi
5028 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
5029
5030 # We no longer support different GC mechanisms.  Emit an error if
5031 # the user configures with --with-gc.
5032 AC_ARG_WITH(gc,
5033 [AS_HELP_STRING([--with-gc={page,zone}],
5034                 [this option is not supported anymore.  It used to choose
5035                  the garbage collection mechanism to use with the compiler])],
5036 [AC_MSG_ERROR([Configure option --with-gc is only supported up to GCC 4.7.x])],
5037 [])
5038
5039 # Libraries to use on the host.  This will normally be set by the top
5040 # level Makefile.  Here we simply capture the value for our Makefile.
5041 if test -z "${HOST_LIBS+set}"; then
5042   HOST_LIBS=
5043 fi
5044 AC_SUBST(HOST_LIBS)
5045
5046 # Use the system's zlib library.
5047 zlibdir=-L../zlib
5048 zlibinc="-I\$(srcdir)/../zlib"
5049 AC_ARG_WITH(system-zlib,
5050 [AS_HELP_STRING([--with-system-zlib], [use installed libz])],
5051 zlibdir=
5052 zlibinc=
5053 )
5054 AC_SUBST(zlibdir)
5055 AC_SUBST(zlibinc)
5056
5057 dnl Very limited version of automake's enable-maintainer-mode
5058
5059 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
5060   dnl maintainer-mode is disabled by default
5061   AC_ARG_ENABLE(maintainer-mode,
5062 [AS_HELP_STRING([--enable-maintainer-mode],
5063                 [enable make rules and dependencies not useful
5064                  (and sometimes confusing) to the casual installer])],
5065       maintainer_mode=$enableval,
5066       maintainer_mode=no)
5067
5068 AC_MSG_RESULT($maintainer_mode)
5069
5070 if test "$maintainer_mode" = "yes"; then
5071   MAINT=''
5072 else
5073   MAINT='#'
5074 fi
5075 AC_SUBST(MAINT)dnl
5076
5077 dnl Whether to prevent multiple front-ends from linking at the same time
5078
5079 AC_MSG_CHECKING([whether to avoid linking multiple front-ends at once])
5080   AC_ARG_ENABLE(link-mutex,
5081 [AS_HELP_STRING([--enable-link-mutex],
5082                 [avoid linking multiple front-ends at once to avoid thrashing
5083                  on the build machine])],
5084       do_link_mutex=$enableval,
5085       do_link_mutex=no)
5086 AC_MSG_RESULT($do_link_mutex)
5087
5088 if test "$do_link_mutex" = "yes"; then
5089    DO_LINK_MUTEX=true
5090 else
5091    DO_LINK_MUTEX=false
5092 fi
5093 AC_SUBST(DO_LINK_MUTEX)
5094
5095 # --------------
5096 # Language hooks
5097 # --------------
5098
5099 # Make empty files to contain the specs and options for each language.
5100 # Then add #include lines to for a compiler that has specs and/or options.
5101
5102 subdirs=
5103 lang_opt_files=
5104 lang_specs_files=
5105 lang_tree_files=
5106 # These (without "all_") are set in each config-lang.in.
5107 # `language' must be a single word so is spelled singularly.
5108 all_languages=
5109 all_compilers=
5110 all_outputs='Makefile'
5111 # List of language makefile fragments.
5112 all_lang_makefrags=
5113 # Additional files for gengtype
5114 all_gtfiles="$target_gtfiles"
5115
5116 # These are the languages that are set in --enable-languages,
5117 # and are available in the GCC tree.
5118 all_selected_languages=
5119
5120 # Add the language fragments.
5121 # Languages are added via two mechanisms.  Some information must be
5122 # recorded in makefile variables, these are defined in config-lang.in.
5123 # We accumulate them and plug them into the main Makefile.
5124 # The other mechanism is a set of hooks for each of the main targets
5125 # like `clean', `install', etc.
5126
5127 language_hooks="Make-hooks"
5128
5129 for lang in ${srcdir}/*/config-lang.in
5130 do
5131 changequote(,)dnl
5132         test "$lang" = "${srcdir}/*/config-lang.in" && continue
5133
5134         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
5135         if test "x$lang_alias" = x
5136         then
5137               echo "$lang doesn't set \$language." 1>&2
5138               exit 1
5139         fi
5140         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
5141         subdirs="$subdirs $subdir"
5142
5143         # $gcc_subdir is where the gcc integration files are to be found
5144         # for a language, both for internal compiler purposes (compiler
5145         # sources implementing front-end to GCC tree converters), and for
5146         # build infrastructure purposes (Make-lang.in, etc.)
5147         #
5148         # This will be <subdir> (relative to $srcdir) if a line like
5149         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
5150         # is found in <langdir>/config-lang.in, and will remain <langdir>
5151         # otherwise.
5152         #
5153         # Except for the language alias (fetched above), the regular
5154         # "config-lang.in" contents are always retrieved from $gcc_subdir,
5155         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
5156         # only this and the language alias.
5157
5158         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
5159         if [ "$gcc_subdir" = "" ]; then
5160            gcc_subdir="$subdir"
5161         fi
5162
5163         case ",$enable_languages," in
5164         *,$lang_alias,*)
5165             all_selected_languages="$all_selected_languages $lang_alias"
5166             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
5167                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
5168             fi
5169             ;;
5170         esac
5171 changequote([,])dnl
5172
5173         language=
5174         boot_language=
5175         compilers=
5176         outputs=
5177         gtfiles=
5178         subdir_requires=
5179         . ${srcdir}/$gcc_subdir/config-lang.in
5180         if test "x$language" = x
5181         then
5182                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
5183                 exit 1
5184         fi
5185
5186         ok=:
5187         case ",$enable_languages," in
5188                 *,$lang_alias,*) ;;
5189                 *)
5190                         for i in $subdir_requires; do
5191                                 test -f "${srcdir}/$i/config-lang.in" && continue
5192                                 ok=false
5193                                 break
5194                         done
5195                 ;;
5196         esac
5197         $ok || continue
5198
5199         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
5200         if test -f $srcdir/$gcc_subdir/lang.opt; then
5201             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
5202             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
5203         fi
5204         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
5205             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
5206         fi
5207         all_languages="$all_languages $language"
5208         all_compilers="$all_compilers $compilers"
5209         all_outputs="$all_outputs $outputs"
5210         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
5211         case ",$enable_languages," in
5212                 *,lto,*)
5213                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
5214                     enable_lto=yes
5215                     AC_SUBST(enable_lto)
5216                     ;;
5217                 *) ;;
5218         esac
5219 done
5220
5221 check_languages=
5222 for language in $all_selected_languages
5223 do
5224         check_languages="$check_languages check-$language"
5225 done
5226
5227 # We link each language in with a set of hooks, reached indirectly via
5228 # lang.${target}.  Only do so for selected languages.
5229
5230 rm -f Make-hooks
5231 touch Make-hooks
5232 target_list="all.cross start.encap rest.encap tags \
5233         install-common install-man install-info install-pdf install-html dvi \
5234         pdf html uninstall info man srcextra srcman srcinfo \
5235         mostlyclean clean distclean maintainer-clean install-plugin"
5236
5237 for t in $target_list
5238 do
5239         x=
5240         for lang in $all_selected_languages
5241         do
5242                 x="$x $lang.$t"
5243         done
5244         echo "lang.$t: $x" >> Make-hooks
5245 done
5246
5247 # --------
5248 # Option include files
5249 # --------
5250
5251 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
5252 option_includes="option-includes.mk"
5253 AC_SUBST_FILE(option_includes)
5254
5255 # --------
5256 # UNSORTED
5257 # --------
5258
5259 # Create .gdbinit.
5260
5261 echo "dir ." > .gdbinit
5262 echo "dir ${srcdir}" >> .gdbinit
5263 if test x$gdb_needs_out_file_path = xyes
5264 then
5265         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
5266 fi
5267 if test "x$subdirs" != x; then
5268         for s in $subdirs
5269         do
5270                 echo "dir ${srcdir}/$s" >> .gdbinit
5271         done
5272 fi
5273 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
5274 echo "python import sys; sys.path.append('${srcdir}'); import gdbhooks" >> .gdbinit
5275
5276 # Put a breakpoint on __asan_report_error to help with debugging buffer
5277 # overflow.
5278 case "$CFLAGS" in
5279 *-fsanitize=address*)
5280   echo "source ${srcdir}/gdbasan.in" >> .gdbinit
5281   ;;
5282 esac
5283
5284 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
5285 AC_SUBST(gcc_tooldir)
5286 AC_SUBST(dollar)
5287
5288 # Find a directory in which to install a shared libgcc.
5289
5290 AC_ARG_ENABLE(version-specific-runtime-libs,
5291 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
5292                 [specify that runtime libraries should be
5293                  installed in a compiler-specific directory])])
5294
5295 # Substitute configuration variables
5296 AC_SUBST(subdirs)
5297 AC_SUBST(srcdir)
5298 AC_SUBST(all_compilers)
5299 AC_SUBST(all_gtfiles)
5300 AC_SUBST(all_lang_makefrags)
5301 AC_SUBST(all_languages)
5302 AC_SUBST(all_selected_languages)
5303 AC_SUBST(build_exeext)
5304 AC_SUBST(build_install_headers_dir)
5305 AC_SUBST(build_xm_file_list)
5306 AC_SUBST(build_xm_include_list)
5307 AC_SUBST(build_xm_defines)
5308 AC_SUBST(build_file_translate)
5309 AC_SUBST(check_languages)
5310 AC_SUBST(cpp_install_dir)
5311 AC_SUBST(xmake_file)
5312 AC_SUBST(tmake_file)
5313 AC_SUBST(TM_ENDIAN_CONFIG)
5314 AC_SUBST(TM_MULTILIB_CONFIG)
5315 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
5316 AC_SUBST(extra_gcc_objs)
5317 AC_SUBST(user_headers_inc_next_pre)
5318 AC_SUBST(user_headers_inc_next_post)
5319 AC_SUBST(extra_headers_list)
5320 AC_SUBST(extra_objs)
5321 AC_SUBST(extra_programs)
5322 AC_SUBST(float_h_file)
5323 AC_SUBST(gcc_config_arguments)
5324 AC_SUBST(gcc_gxx_include_dir)
5325 AC_SUBST(gcc_gxx_include_dir_add_sysroot)
5326 AC_SUBST(host_exeext)
5327 AC_SUBST(host_xm_file_list)
5328 AC_SUBST(host_xm_include_list)
5329 AC_SUBST(host_xm_defines)
5330 AC_SUBST(out_host_hook_obj)
5331 AC_SUBST(install)
5332 AC_SUBST(lang_opt_files)
5333 AC_SUBST(lang_specs_files)
5334 AC_SUBST(lang_tree_files)
5335 AC_SUBST(local_prefix)
5336 AC_SUBST(md_file)
5337 AC_SUBST(objc_boehm_gc)
5338 AC_SUBST(out_file)
5339 AC_SUBST(out_object_file)
5340 AC_SUBST(common_out_file)
5341 AC_SUBST(common_out_object_file)
5342 AC_SUBST(tm_file_list)
5343 AC_SUBST(tm_include_list)
5344 AC_SUBST(tm_defines)
5345 AC_SUBST(tm_p_file_list)
5346 AC_SUBST(tm_p_include_list)
5347 AC_SUBST(xm_file_list)
5348 AC_SUBST(xm_include_list)
5349 AC_SUBST(xm_defines)
5350 AC_SUBST(use_gcc_stdint)
5351 AC_SUBST(c_target_objs)
5352 AC_SUBST(cxx_target_objs)
5353 AC_SUBST(fortran_target_objs)
5354 AC_SUBST(target_cpu_default)
5355
5356 AC_SUBST_FILE(language_hooks)
5357
5358 # Echo link setup.
5359 if test x${build} = x${host} ; then
5360   if test x${host} = x${target} ; then
5361     echo "Links are now set up to build a native compiler for ${target}." 1>&2
5362   else
5363     echo "Links are now set up to build a cross-compiler" 1>&2
5364     echo " from ${host} to ${target}." 1>&2
5365   fi
5366 else
5367   if test x${host} = x${target} ; then
5368     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
5369     echo " for ${target}." 1>&2
5370   else
5371     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
5372     echo " from ${host} to ${target}." 1>&2
5373   fi
5374 fi
5375
5376 AC_ARG_VAR(GMPLIBS,[How to link GMP])
5377 AC_ARG_VAR(GMPINC,[How to find GMP include files])
5378
5379 AC_ARG_VAR(ISLLIBS,[How to link ISL])
5380 AC_ARG_VAR(ISLINC,[How to find ISL include files])
5381
5382 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
5383 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
5384 if test "x${CLOOGLIBS}" != "x" ; then
5385    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
5386 fi
5387
5388 # Check for plugin support
5389 AC_ARG_ENABLE(plugin,
5390 [AS_HELP_STRING([--enable-plugin], [enable plugin support])],
5391 enable_plugin=$enableval,
5392 enable_plugin=yes; default_plugin=yes)
5393
5394 pluginlibs=
5395
5396 case "${host}" in
5397   *-*-darwin*)
5398     if test x$build = x$host; then
5399       export_sym_check="nm${exeext} -g"
5400     elif test x$host = x$target; then
5401       export_sym_check="$gcc_cv_nm -g"
5402     else
5403       export_sym_check=
5404     fi
5405   ;;
5406   *)
5407     if test x$build = x$host; then
5408       export_sym_check="objdump${exeext} -T"
5409     elif test x$host = x$target; then
5410       export_sym_check="$gcc_cv_objdump -T"
5411     else
5412       export_sym_check=
5413     fi
5414   ;;
5415 esac
5416
5417 if test x"$enable_plugin" = x"yes"; then
5418
5419   AC_MSG_CHECKING([for exported symbols])
5420   if test "x$export_sym_check" != x; then
5421     echo "int main() {return 0;} int foobar() {return 0;}" > conftest.c
5422     ${CC} ${CFLAGS} ${LDFLAGS} conftest.c -o conftest$ac_exeext > /dev/null 2>&1
5423     if $export_sym_check conftest$ac_exeext | grep -q foobar > /dev/null; then
5424       : # No need to use a flag
5425       AC_MSG_RESULT([yes])
5426     else
5427       AC_MSG_RESULT([yes])
5428       AC_MSG_CHECKING([for -rdynamic])
5429       ${CC} ${CFLAGS} ${LDFLAGS} -rdynamic conftest.c -o conftest$ac_exeext > /dev/null 2>&1
5430       if $export_sym_check conftest$ac_exeext | grep -q foobar > /dev/null; then
5431         plugin_rdynamic=yes
5432         pluginlibs="-rdynamic"
5433       else
5434         plugin_rdynamic=no
5435         enable_plugin=no
5436       fi
5437       AC_MSG_RESULT([$plugin_rdynamic])
5438     fi
5439   else
5440     AC_MSG_RESULT([unable to check])
5441   fi
5442
5443   # Check -ldl
5444   saved_LIBS="$LIBS"
5445   AC_SEARCH_LIBS([dlopen], [dl])
5446   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
5447     pluginlibs="$pluginlibs -ldl"
5448   fi
5449   LIBS="$saved_LIBS"
5450
5451   # Check that we can build shared objects with -fPIC -shared
5452   saved_LDFLAGS="$LDFLAGS"
5453   saved_CFLAGS="$CFLAGS"
5454   case "${host}" in
5455     *-*-darwin*)
5456       CFLAGS=`echo $CFLAGS | sed s/-mdynamic-no-pic//g`
5457       CFLAGS="$CFLAGS -fPIC"
5458       LDFLAGS="$LDFLAGS -shared -undefined dynamic_lookup"
5459     ;;
5460     *)
5461       CFLAGS="$CFLAGS -fPIC"
5462       LDFLAGS="$LDFLAGS -fPIC -shared"
5463     ;;
5464   esac
5465   AC_MSG_CHECKING([for -fPIC -shared])
5466   AC_TRY_LINK(
5467     [extern int X;],[return X == 0;],
5468     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
5469     [AC_MSG_RESULT([no]); have_pic_shared=no])
5470   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
5471     pluginlibs=
5472     enable_plugin=no
5473   fi
5474   LDFLAGS="$saved_LDFLAGS"
5475   CFLAGS="$saved_CFLAGS"
5476
5477   # If plugin support had been requested but not available, fail.
5478   if test x"$enable_plugin" = x"no" ; then
5479     if test x"$default_plugin" != x"yes"; then
5480       AC_MSG_ERROR([
5481 Building GCC with plugin support requires a host that supports
5482 -fPIC, -shared, -ldl and -rdynamic.])
5483     fi
5484   fi
5485 fi
5486
5487 AC_SUBST(pluginlibs)
5488 AC_SUBST(enable_plugin)
5489 if test x"$enable_plugin" = x"yes"; then
5490   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
5491 fi
5492
5493
5494 # Enable --enable-host-shared
5495 AC_ARG_ENABLE(host-shared,
5496 [AS_HELP_STRING([--enable-host-shared],
5497                 [build host code as shared libraries])],
5498 [PICFLAG=-fPIC], [PICFLAG=])
5499 AC_SUBST(enable_host_shared)
5500 AC_SUBST(PICFLAG)
5501
5502
5503 AC_ARG_ENABLE(libquadmath-support,
5504 [AS_HELP_STRING([--disable-libquadmath-support],
5505   [disable libquadmath support for Fortran])],
5506 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
5507 ENABLE_LIBQUADMATH_SUPPORT=yes)
5508 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
5509   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
5510             [Define to 1 to enable libquadmath support])
5511 fi
5512
5513
5514 # Specify what hash style to use by default.
5515 AC_ARG_WITH([linker-hash-style],
5516 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
5517                 [specify the linker hash style])],
5518 [case x"$withval" in
5519    xsysv)
5520      LINKER_HASH_STYLE=sysv
5521      ;;
5522    xgnu)
5523      LINKER_HASH_STYLE=gnu
5524      ;;
5525    xboth)
5526      LINKER_HASH_STYLE=both
5527      ;;
5528    *)
5529      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
5530      ;;
5531  esac],
5532 [LINKER_HASH_STYLE=''])
5533 if test x"${LINKER_HASH_STYLE}" != x; then
5534   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
5535                                          [The linker hash style])
5536 fi
5537
5538 # Configure the subdirectories
5539 # AC_CONFIG_SUBDIRS($subdirs)
5540
5541 # Create the Makefile
5542 # and configure language subdirectories
5543 AC_CONFIG_FILES($all_outputs)
5544
5545 AC_CONFIG_COMMANDS([default],
5546 [
5547 case ${CONFIG_HEADERS} in
5548   *auto-host.h:config.in*)
5549   echo > cstamp-h ;;
5550 esac
5551 # Make sure all the subdirs exist.
5552 for d in $subdirs doc build common c-family
5553 do
5554     test -d $d || mkdir $d
5555 done
5556 ],
5557 [subdirs='$subdirs'])
5558 AC_OUTPUT
5559