libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  45 i*86-*-gnu*) TARGET=X86; TARGETDIR=x86;;
  46 i*86-*-solaris2.1[[0-9]]*) TARGET=X86_64; TARGETDIR=x86;;
  47 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  48 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  49 i*86-*-darwin*) TARGET=X86_DARWIN; TARGETDIR=x86;;
  50 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-rtems*) TARGET=X86; TARGETDIR=x86;;
  53 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  54 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  55 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  56 frv-*-*) TARGET=FRV; TARGETDIR=frv;;
  57 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  58 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc*-*-rtems*) TARGET=SPARC; TARGETDIR=sparc;;
  61 sparc64-*-linux* | sparc64-*-freebsd* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
  62 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
  63 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  64 m32r*-*-linux* ) TARGET=M32R; TARGETDIR=m32r;;
  65 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  66 mips64*-*);;
  67 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
  68 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  69 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  70 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  71 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  72 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  73 powerpc-*-freebsd*) TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc;;
  74 powerpc*-*-rtems*) TARGET=POWERPC; TARGETDIR=powerpc;;
  75 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  76 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  77 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
  78 arm*-*-rtems*) TARGET=ARM; TARGETDIR=arm;;
  79 cris-*-*) TARGET=LIBFFI_CRIS; TARGETDIR=cris;;
  80 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  81 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  82 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
  83 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  84 sh-*-rtems*) TARGET=SH; TARGETDIR=sh;;
  85 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  86 hppa*-*-linux* | parisc*-*-linux*) TARGET=PA_LINUX; TARGETDIR=pa;;
  87 hppa*64-*-hpux*) TARGET=PA64_HPUX; TARGETDIR=pa;;
  88 hppa*-*-hpux*) TARGET=PA_HPUX; TARGETDIR=pa;;
  89 esac
  90
  91 AC_SUBST(AM_RUNTESTFLAGS)
  92
  93 if test $TARGETDIR = unknown; then
  94   AC_MSG_ERROR(["libffi has not been ported to $host."])
  95 fi
  96
  97 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
  98 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  99 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 100 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 101 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 102 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 103 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 104 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 105 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 106 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 107 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 108 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 109 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 110 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 111 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 112 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 113 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 114 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 115 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 116 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 117 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 118 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 119 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 120 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 121
 122 case x$TARGET in
 123   xMIPS*) TARGET=MIPS ;;
 124   *) ;;
 125 esac
 126
 127 AC_HEADER_STDC
 128 AC_CHECK_FUNCS(memcpy)
 129 AC_FUNC_ALLOCA
 130
 131 AC_CHECK_SIZEOF(double)
 132 AC_CHECK_SIZEOF(long double)
 133
 134 # Also AC_SUBST this variable for ffi.h.
 135 HAVE_LONG_DOUBLE=0
 136 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 137   if test $ac_cv_sizeof_long_double != 0; then
 138     HAVE_LONG_DOUBLE=1
 139     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 140   fi
 141 fi
 142 AC_SUBST(HAVE_LONG_DOUBLE)
 143
 144 AC_C_BIGENDIAN
 145
 146 if test x$TARGET = xSPARC; then
 147     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 148         libffi_cv_as_sparc_ua_pcrel, [
 149         save_CFLAGS="$CFLAGS"
 150         save_LDFLAGS="$LDFLAGS"
 151         CFLAGS="$CFLAGS -fpic"
 152         LDFLAGS="$LDFLAGS -shared"
 153         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 154                     [libffi_cv_as_sparc_ua_pcrel=yes],
 155                     [libffi_cv_as_sparc_ua_pcrel=no])
 156         CFLAGS="$save_CFLAGS"
 157         LDFLAGS="$save_LDFLAGS"])
 158     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 159         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 160                   [Define if your assembler and linker support unaligned PC relative relocs.])
 161     fi
 162
 163     AC_CACHE_CHECK([assembler .register pseudo-op support],
 164        libffi_cv_as_register_pseudo_op, [
 165        libffi_cv_as_register_pseudo_op=unknown
 166        # Check if we have .register
 167        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 168                        [libffi_cv_as_register_pseudo_op=yes],
 169                        [libffi_cv_as_register_pseudo_op=no])
 170     ])
 171     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 172        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 173                [Define if your assembler supports .register.])
 174     fi
 175 fi
 176
 177 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 178     libffi_cv_ro_eh_frame, [
 179         libffi_cv_ro_eh_frame=no
 180         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 181         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 182             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 183                 libffi_cv_ro_eh_frame=yes
 184             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 185                  | grep -v '#write' > /dev/null; then
 186                 libffi_cv_ro_eh_frame=yes
 187             fi
 188         fi
 189         rm -f conftest.*
 190     ])
 191 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 192     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 193               [Define if .eh_frame sections should be read-only.])
 194     AC_DEFINE(EH_FRAME_FLAGS, "a",
 195               [Define to the flags needed for the .section .eh_frame directive.])
 196 else
 197     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 198               [Define to the flags needed for the .section .eh_frame directive.])
 199 fi
 200
 201 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 202     libffi_cv_hidden_visibility_attribute, [
 203         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 204         libffi_cv_hidden_visibility_attribute=no
 205         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 206             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 207                 libffi_cv_hidden_visibility_attribute=yes
 208             fi
 209         fi
 210         rm -f conftest.*
 211     ])
 212 if test $libffi_cv_hidden_visibility_attribute = yes; then
 213     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 214               [Define if __attribute__((visibility("hidden"))) is supported.])
 215 fi
 216
 217 AH_BOTTOM([
 218 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 219 #ifdef LIBFFI_ASM
 220 #define FFI_HIDDEN(name) .hidden name
 221 #else
 222 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 223 #endif
 224 #else
 225 #ifdef LIBFFI_ASM
 226 #define FFI_HIDDEN(name)
 227 #else
 228 #define FFI_HIDDEN
 229 #endif
 230 #endif
 231 ])
 232
 233 AC_SUBST(TARGET)
 234 AC_SUBST(TARGETDIR)
 235
 236 AC_SUBST(SHELL)
 237
 238 AC_ARG_ENABLE(debug,
 239 [  --enable-debug          debugging mode],
 240   if test "$enable_debug" = "yes"; then
 241     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 242   fi)
 243
 244 AC_ARG_ENABLE(structs,
 245 [  --disable-structs       omit code for struct support],
 246   if test "$enable_structs" = "no"; then
 247     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 248   fi)
 249
 250 AC_ARG_ENABLE(raw-api,
 251 [  --disable-raw-api       make the raw api unavailable],
 252   if test "$enable_raw_api" = "no"; then
 253     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 254   fi)
 255
 256 AC_ARG_ENABLE(purify-safety,
 257 [  --enable-purify-safety  purify-safe mode],
 258   if test "$enable_purify_safety" = "yes"; then
 259     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 260   fi)
 261
 262 if test -n "$with_cross_host" &&
 263    test x"$with_cross_host" != x"no"; then
 264   toolexecdir='$(exec_prefix)/$(target_alias)'
 265   toolexeclibdir='$(toolexecdir)/lib'
 266 else
 267   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 268   toolexeclibdir='$(libdir)'
 269 fi
 270 multi_os_directory=`$CC -print-multi-os-directory`
 271 case $multi_os_directory in
 272   .) ;; # Avoid trailing /.
 273   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 274 esac
 275 AC_SUBST(toolexecdir)
 276 AC_SUBST(toolexeclibdir)
 277
 278 if test "${multilib}" = "yes"; then
 279   multilib_arg="--enable-multilib"
 280 else
 281   multilib_arg=
 282 fi
 283
 284 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 285 AC_CONFIG_COMMANDS(src, [
 286 test -d src || mkdir src
 287 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 288 ], [TARGETDIR="$TARGETDIR"])
 289
 290 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 291
 292 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 293
 294 AC_OUTPUT