gcc/ada/a-dirval-vms.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --             A D A . D I R E C T O R I E S . V A L I D I T Y              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                              (VMS Version)                               --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2006 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is the OpenVMS version of this package
  36
  37 package body Ada.Directories.Validity is
  38
  39    Max_Number_Of_Characters : constant := 39;
  40    Max_Path_Length          : constant := 1_024;
  41
  42    Invalid_Character : constant array (Character) of Boolean :=
  43                          ('a' .. 'z' => False,
  44                           'A' .. 'Z' => False,
  45                           '0' .. '9' => False,
  46                           '_' | '$' | '-' | '.' => False,
  47                           others => True);
  48
  49    ---------------------------------
  50    -- Is_Path_Name_Case_Sensitive --
  51    ---------------------------------
  52
  53    function Is_Path_Name_Case_Sensitive return Boolean is
  54    begin
  55       return False;
  56    end Is_Path_Name_Case_Sensitive;
  57
  58    ------------------------
  59    -- Is_Valid_Path_Name --
  60    ------------------------
  61
  62    function Is_Valid_Path_Name (Name : String) return Boolean is
  63       First     : Positive := Name'First;
  64       Last      : Positive;
  65       Dot_Found : Boolean := False;
  66
  67    begin
  68       --  A valid path (directory) name cannot be empty, and cannot contain
  69       --  more than 1024 characters. Directories can be ".", ".." or be simple
  70       --  name without extensions.
  71
  72       if Name'Length = 0 or else Name'Length > Max_Path_Length then
  73          return False;
  74
  75       else
  76          loop
  77             --  Look for the start of the next directory or file name
  78
  79             while First <= Name'Last and then Name (First) = '/' loop
  80                First := First + 1;
  81             end loop;
  82
  83             --  If all directories/file names are OK, return True
  84
  85             exit when First > Name'Last;
  86
  87             Last := First;
  88             Dot_Found := False;
  89
  90             --  Look for the end of the directory/file name
  91
  92             while Last < Name'Last loop
  93                exit when Name (Last + 1) = '/';
  94                Last := Last + 1;
  95
  96                if Name (Last) = '.' then
  97                   Dot_Found := True;
  98                end if;
  99             end loop;
 100
 101             --  If name include a dot, it can only be ".", ".." or a the last
 102             --  file name.
 103
 104             if Dot_Found then
 105                if Name (First .. Last) /= "." and then
 106                   Name (First .. Last) /= ".."
 107                then
 108                   return Last = Name'Last
 109                     and then Is_Valid_Simple_Name (Name (First .. Last));
 110
 111                end if;
 112
 113             --  Check if the directory/file name is valid
 114
 115             elsif not Is_Valid_Simple_Name (Name (First .. Last)) then
 116                   return False;
 117             end if;
 118
 119             --  Move to the next name
 120
 121             First := Last + 1;
 122          end loop;
 123       end if;
 124
 125       --  If Name follows the rules, then it is valid
 126
 127       return True;
 128    end Is_Valid_Path_Name;
 129
 130    --------------------------
 131    -- Is_Valid_Simple_Name --
 132    --------------------------
 133
 134    function Is_Valid_Simple_Name (Name : String) return Boolean is
 135       In_Extension         : Boolean := False;
 136       Number_Of_Characters : Natural := 0;
 137
 138    begin
 139       --  A file name cannot be empty, and cannot have more than 39 characters
 140       --  before or after a single '.'.
 141
 142       if Name'Length = 0 then
 143          return False;
 144
 145       else
 146          --  Check each character for validity
 147
 148          for J in Name'Range loop
 149             if Invalid_Character (Name (J)) then
 150                return False;
 151
 152             elsif Name (J) = '.' then
 153
 154                --  Name cannot contain several dots
 155
 156                if In_Extension then
 157                   return False;
 158
 159                else
 160                   --  Reset the number of characters to count the characters
 161                   --  of the extension.
 162
 163                   In_Extension := True;
 164                   Number_Of_Characters := 0;
 165                end if;
 166
 167             else
 168                --  Check that the number of character is not too large
 169
 170                Number_Of_Characters := Number_Of_Characters + 1;
 171
 172                if Number_Of_Characters > Max_Number_Of_Characters then
 173                   return False;
 174                end if;
 175             end if;
 176          end loop;
 177       end if;
 178
 179       --  If the rules are followed, then it is valid
 180
 181       return True;
 182    end Is_Valid_Simple_Name;
 183
 184    -------------
 185    -- OpenVMS --
 186    -------------
 187
 188    function OpenVMS return Boolean is
 189    begin
 190       return True;
 191    end OpenVMS;
 192
 193 end Ada.Directories.Validity;