gcc/ada/sem_mech.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ M E C H                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1996-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;   use Atree;
  27 with Einfo;   use Einfo;
  28 with Errout;  use Errout;
  29 with Namet;   use Namet;
  30 with Sem;     use Sem;
  31 with Sem_Aux; use Sem_Aux;
  32 with Sinfo;   use Sinfo;
  33 with Snames;  use Snames;
  34
  35 package body Sem_Mech is
  36
  37    -------------------------
  38    -- Set_Mechanism_Value --
  39    -------------------------
  40
  41    procedure Set_Mechanism_Value (Ent : Entity_Id; Mech_Name : Node_Id) is
  42
  43       procedure Bad_Mechanism;
  44       --  Signal bad mechanism name
  45
  46       -------------------
  47       -- Bad_Mechanism --
  48       -------------------
  49
  50       procedure Bad_Mechanism is
  51       begin
  52          Error_Msg_N ("unrecognized mechanism name", Mech_Name);
  53       end Bad_Mechanism;
  54
  55    --  Start of processing for Set_Mechanism_Value
  56
  57    begin
  58       if Mechanism (Ent) /= Default_Mechanism then
  59          Error_Msg_NE
  60            ("mechanism for & has already been set", Mech_Name, Ent);
  61       end if;
  62
  63       --  MECHANISM_NAME ::= value | reference
  64
  65       if Nkind (Mech_Name) = N_Identifier then
  66          if Chars (Mech_Name) = Name_Value then
  67             Set_Mechanism_With_Checks (Ent, By_Copy, Mech_Name);
  68
  69          elsif Chars (Mech_Name) = Name_Reference then
  70             Set_Mechanism_With_Checks (Ent, By_Reference, Mech_Name);
  71
  72          elsif Chars (Mech_Name) = Name_Copy then
  73             Error_Msg_N ("bad mechanism name, Value assumed", Mech_Name);
  74             Set_Mechanism (Ent, By_Copy);
  75
  76          else
  77             Bad_Mechanism;
  78          end if;
  79
  80       else
  81          Bad_Mechanism;
  82       end if;
  83    end Set_Mechanism_Value;
  84
  85    -------------------------------
  86    -- Set_Mechanism_With_Checks --
  87    -------------------------------
  88
  89    procedure Set_Mechanism_With_Checks
  90      (Ent  : Entity_Id;
  91       Mech : Mechanism_Type;
  92       Enod : Node_Id)
  93    is
  94       pragma Unreferenced (Enod);
  95
  96    begin
  97       --  Right now we don't do any checks, should we do more ???
  98
  99       Set_Mechanism (Ent, Mech);
 100    end Set_Mechanism_With_Checks;
 101
 102    --------------------
 103    -- Set_Mechanisms --
 104    --------------------
 105
 106    procedure Set_Mechanisms (E : Entity_Id) is
 107       Formal : Entity_Id;
 108       Typ    : Entity_Id;
 109
 110    begin
 111       --  Skip this processing if inside a generic template. Not only is
 112       --  it unnecessary (since neither extra formals nor mechanisms are
 113       --  relevant for the template itself), but at least at the moment,
 114       --  procedures get frozen early inside a template so attempting to
 115       --  look at the formal types does not work too well if they are
 116       --  private types that have not been frozen yet.
 117
 118       if Inside_A_Generic then
 119          return;
 120       end if;
 121
 122       --  Loop through formals
 123
 124       Formal := First_Formal (E);
 125       while Present (Formal) loop
 126
 127          if Mechanism (Formal) = Default_Mechanism then
 128             Typ := Underlying_Type (Etype (Formal));
 129
 130             --  If there is no underlying type, then skip this processing and
 131             --  leave the convention set to Default_Mechanism. It seems odd
 132             --  that there should ever be such cases but there are (see
 133             --  comments for filed regression tests 1418-001 and 1912-009) ???
 134
 135             if No (Typ) then
 136                goto Skip_Formal;
 137             end if;
 138
 139             case Convention (E) is
 140
 141                ---------
 142                -- Ada --
 143                ---------
 144
 145                --  Note: all RM defined conventions are treated the same from
 146                --  the point of view of parameter passing mechanism. Convention
 147                --  Ghost has the same dynamic semantics as convention Ada.
 148
 149                when Convention_Ada       |
 150                     Convention_Intrinsic |
 151                     Convention_Entry     |
 152                     Convention_Ghost     |
 153                     Convention_Protected |
 154                     Convention_Stubbed   =>
 155
 156                   --  By reference types are passed by reference (RM 6.2(4))
 157
 158                   if Is_By_Reference_Type (Typ) then
 159                      Set_Mechanism (Formal, By_Reference);
 160
 161                   --  By copy types are passed by copy (RM 6.2(3))
 162
 163                   elsif Is_By_Copy_Type (Typ) then
 164                      Set_Mechanism (Formal, By_Copy);
 165
 166                   --  All other types we leave the Default_Mechanism set, so
 167                   --  that the backend can choose the appropriate method.
 168
 169                   else
 170                      null;
 171                   end if;
 172
 173                --  Special Ada conventions specifying passing mechanism
 174
 175                when Convention_Ada_Pass_By_Copy =>
 176                   Set_Mechanism (Formal, By_Copy);
 177
 178                when Convention_Ada_Pass_By_Reference =>
 179                   Set_Mechanism (Formal, By_Reference);
 180
 181                -------
 182                -- C --
 183                -------
 184
 185                --  Note: Assembler, C++, Java, Stdcall also use C conventions
 186
 187                when Convention_Assembler |
 188                     Convention_C         |
 189                     Convention_CIL       |
 190                     Convention_CPP       |
 191                     Convention_Java      |
 192                     Convention_Stdcall   =>
 193
 194                   --  The following values are passed by copy
 195
 196                   --    IN Scalar parameters (RM B.3(66))
 197                   --    IN parameters of access types (RM B.3(67))
 198                   --    Access parameters (RM B.3(68))
 199                   --    Access to subprogram types (RM B.3(71))
 200
 201                   --  Note: in the case of access parameters, it is the pointer
 202                   --  that is passed by value. In GNAT access parameters are
 203                   --  treated as IN parameters of an anonymous access type, so
 204                   --  this falls out free.
 205
 206                   --  The bottom line is that all IN elementary types are
 207                   --  passed by copy in GNAT.
 208
 209                   if Is_Elementary_Type (Typ) then
 210                      if Ekind (Formal) = E_In_Parameter then
 211                         Set_Mechanism (Formal, By_Copy);
 212
 213                      --  OUT and IN OUT parameters of elementary types are
 214                      --  passed by reference (RM B.3(68)). Note that we are
 215                      --  not following the advice to pass the address of a
 216                      --  copy to preserve by copy semantics.
 217
 218                      else
 219                         Set_Mechanism (Formal, By_Reference);
 220                      end if;
 221
 222                   --  Records are normally passed by reference (RM B.3(69)).
 223                   --  However, this can be overridden by the use of the
 224                   --  C_Pass_By_Copy pragma or C_Pass_By_Copy convention.
 225
 226                   elsif Is_Record_Type (Typ) then
 227
 228                      --  If the record is not convention C, then we always
 229                      --  pass by reference, C_Pass_By_Copy does not apply.
 230
 231                      if Convention (Typ) /= Convention_C then
 232                         Set_Mechanism (Formal, By_Reference);
 233
 234                      --  OUT and IN OUT parameters of record types are passed
 235                      --  by reference regardless of pragmas (RM B.3 (69/2)).
 236
 237                      elsif Ekind_In (Formal, E_Out_Parameter,
 238                                              E_In_Out_Parameter)
 239                      then
 240                         Set_Mechanism (Formal, By_Reference);
 241
 242                      --  IN parameters of record types are passed by copy only
 243                      --  when the related type has convention C_Pass_By_Copy
 244                      --  (RM B.3 (68.1/2)).
 245
 246                      elsif Ekind (Formal) = E_In_Parameter
 247                        and then C_Pass_By_Copy (Typ)
 248                      then
 249                         Set_Mechanism (Formal, By_Copy);
 250
 251                      --  Otherwise, for a C convention record, we set the
 252                      --  convention in accordance with a possible use of
 253                      --  the C_Pass_By_Copy pragma. Note that the value of
 254                      --  Default_C_Record_Mechanism in the absence of such
 255                      --  a pragma is By_Reference.
 256
 257                      else
 258                         Set_Mechanism (Formal, Default_C_Record_Mechanism);
 259                      end if;
 260
 261                   --  Array types are passed by reference (B.3 (71))
 262
 263                   elsif Is_Array_Type (Typ) then
 264                      Set_Mechanism (Formal, By_Reference);
 265
 266                   --  For all other types, use Default_Mechanism mechanism
 267
 268                   else
 269                      null;
 270                   end if;
 271
 272                -----------
 273                -- COBOL --
 274                -----------
 275
 276                when Convention_COBOL =>
 277
 278                   --  Access parameters (which in GNAT look like IN parameters
 279                   --  of an access type) are passed by copy (RM B.4(96)) as
 280                   --  are all other IN parameters of scalar type (RM B.4(97)).
 281
 282                   --  For now we pass these parameters by reference as well.
 283                   --  The RM specifies the intent BY_CONTENT, but gigi does
 284                   --  not currently transform By_Copy properly. If we pass by
 285                   --  reference, it will be imperative to introduce copies ???
 286
 287                   if Is_Elementary_Type (Typ)
 288                     and then Ekind (Formal) = E_In_Parameter
 289                   then
 290                      Set_Mechanism (Formal, By_Reference);
 291
 292                   --  All other parameters (i.e. all non-scalar types, and
 293                   --  all OUT or IN OUT parameters) are passed by reference.
 294                   --  Note that at the moment we are not bothering to make
 295                   --  copies of scalar types as recommended in the RM.
 296
 297                   else
 298                      Set_Mechanism (Formal, By_Reference);
 299                   end if;
 300
 301                -------------
 302                -- Fortran --
 303                -------------
 304
 305                when Convention_Fortran =>
 306
 307                   --  Access types are passed by default (presumably this
 308                   --  will mean they are passed by copy)
 309
 310                   if Is_Access_Type (Typ) then
 311                      null;
 312
 313                   --  For now, we pass all other parameters by reference.
 314                   --  It is not clear that this is right in the long run,
 315                   --  but it seems to correspond to what gnu f77 wants.
 316
 317                   else
 318                      Set_Mechanism (Formal, By_Reference);
 319                   end if;
 320             end case;
 321          end if;
 322
 323          <<Skip_Formal>> -- remove this when problem above is fixed ???
 324
 325          Next_Formal (Formal);
 326       end loop;
 327
 328       --  Note: there is nothing we need to do for the return type here.
 329       --  We deal with returning by reference in the Ada sense, by use of
 330       --  the flag By_Ref, rather than by messing with mechanisms.
 331
 332       --  A mechanism of Reference for the return means that an extra
 333       --  parameter must be provided for the return value (that is the
 334       --  DEC meaning of the pragma), and is unrelated to the Ada notion
 335       --  of return by reference.
 336
 337       --  Note: there was originally code here to set the mechanism to
 338       --  By_Reference for types that are "by reference" in the Ada sense,
 339       --  but, in accordance with the discussion above, this is wrong, and
 340       --  the code was removed.
 341
 342    end Set_Mechanisms;
 343
 344 end Sem_Mech;