gcc/ada/sem_warn.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ W A R N                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1999-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains the routines used to deal with issuing warnings
  27 --  about uses of uninitialized variables and unused with's. It also has
  28 --  some unrelated routines related to the generation of warnings.
  29
  30 with Alloc; use Alloc;
  31 with Table;
  32 with Types; use Types;
  33
  34 package Sem_Warn is
  35
  36    ------------------------
  37    -- Warnings Off Table --
  38    ------------------------
  39
  40    type Warnings_Off_Entry is record
  41       N : Node_Id;
  42       --  A pragma Warnings (Off, ent [,Reason]) node
  43
  44       E : Entity_Id;
  45       --  The entity involved
  46
  47       R : String_Id;
  48       --  Warning reason if present, or null if not (not currently used)
  49    end record;
  50
  51    --  An entry is made in the following table for any valid Pragma Warnings
  52    --  (Off, entity) encountered while Opt.Warn_On_Warnings_Off is True. It
  53    --  is used to generate warnings on any of these pragmas that turn out not
  54    --  to be needed, or that could be replaced by Unmodified/Unreferenced.
  55
  56    package Warnings_Off_Pragmas is new Table.Table (
  57      Table_Component_Type => Warnings_Off_Entry,
  58      Table_Index_Type     => Int,
  59      Table_Low_Bound      => 0,
  60      Table_Initial        => Alloc.Warnings_Off_Pragmas_Initial,
  61      Table_Increment      => Alloc.Warnings_Off_Pragmas_Increment,
  62      Table_Name           => "Name_Warnings_Off_Pragmas");
  63
  64    --------------------
  65    -- Initialization --
  66    --------------------
  67
  68    procedure Initialize;
  69    --  Initialize this package for new compilation
  70
  71    ------------------------------------------
  72    -- Routines to Handle Unused References --
  73    ------------------------------------------
  74
  75    procedure Check_References (E : Entity_Id; Anod : Node_Id := Empty);
  76    --  Called at the end of processing a declarative region. The entity E
  77    --  is the entity for the scope. All entities declared in the region,
  78    --  as indicated by First_Entity and the entity chain, are checked to
  79    --  see if they are variables for which warnings need to be posted for
  80    --  either no assignments, or a use before an assignment or no references
  81    --  at all. The Anod node is present for the case of an accept statement,
  82    --  and references the accept statement. This is used to place the warning
  83    --  messages in the right place.
  84
  85    procedure Check_Unset_Reference (N : Node_Id);
  86    --  N is the node for an expression which occurs in a reference position,
  87    --  e.g. as the right side of an assignment. This procedure checks to see
  88    --  if the node is a reference to a variable entity where the entity has
  89    --  Not_Assigned set. If so, the Unset_Reference field is set if it is not
  90    --  the first occurrence. No warning is posted, instead warnings will be
  91    --  posted later by Check_References. The reason we do things that
  92    --  way is that if there are no assignments anywhere, we prefer to flag
  93    --  the entity, rather than a reference to it. Note that for the purposes
  94    --  of this routine, a type conversion or qualified expression whose
  95    --  expression is an entity is also processed. The reason that we do not
  96    --  process these at the point of occurrence is that both these constructs
  97    --  can occur in non-reference positions (e.g. as out parameters).
  98
  99    procedure Check_Unused_Withs (Spec_Unit : Unit_Number_Type := No_Unit);
 100    --  This routine performs two kinds of checks. It checks that all with'ed
 101    --  units are referenced, and that at least one entity of each with'ed
 102    --  unit is referenced (the latter check catches units that are only
 103    --  referenced in a use or package renaming statement). Appropriate
 104    --  warning messages are generated if either of these situations is
 105    --  detected.
 106    --
 107    --  A special case arises when a package body or a subprogram body with
 108    --  a separate spec is being compiled. In this case, a with may appear
 109    --  on the spec, but be needed only by the body. This still generates
 110    --  a warning, but the text is different (the with is not redundant,
 111    --  it is misplaced).
 112    --
 113    --  This special case is implemented by making an initial call to this
 114    --  procedure with Spec_Unit set to the unit number of the separate spec.
 115    --  This call does not generate any warning messages, but instead may
 116    --  result in flags being set in the N_With_Clause node that record that
 117    --  there was no use in the spec.
 118    --
 119    --  The main call (made after all units have been analyzed, with Spec_Unit
 120    --  set to the default value of No_Unit) generates the required warnings
 121    --  using the flags set by the initial call where appropriate to specialize
 122    --  the text of the warning messages.
 123
 124    ---------------------
 125    -- Output Routines --
 126    ---------------------
 127
 128    procedure Output_Non_Modified_In_Out_Warnings;
 129    --  Warnings about IN OUT parameters that could be IN are collected till
 130    --  the end of the compilation process (see body of this routine for a
 131    --  discussion of why this is done). This procedure outputs the warnings.
 132    --  Note: this should be called before Output_Unreferenced_Messages, since
 133    --  if we have an IN OUT warning, that's the one we want to see.
 134
 135    procedure Output_Obsolescent_Entity_Warnings (N : Node_Id; E : Entity_Id);
 136    --  N is a reference to obsolescent entity E, for which appropriate warning
 137    --  messages are to be generated (caller has already checked that warnings
 138    --  are active and appropriate for this entity).
 139
 140    procedure Output_Unreferenced_Messages;
 141    --  Warnings about unreferenced entities are collected till the end of
 142    --  the compilation process (see Check_Unset_Reference for further
 143    --  details). This procedure outputs waiting warnings, if any.
 144
 145    procedure Output_Unused_Warnings_Off_Warnings;
 146    --  Warnings about pragma Warnings (Off, ent) statements that are unused,
 147    --  or could be replaced by Unmodified/Unreferenced pragmas, are collected
 148    --  till the end of the compilation process. This procedure outputs waiting
 149    --  warnings if any.
 150
 151    ----------------------------
 152    -- Other Warning Routines --
 153    ----------------------------
 154
 155    procedure Check_Code_Statement (N : Node_Id);
 156    --  Perform warning checks on a code statement node
 157
 158    procedure Check_Infinite_Loop_Warning (Loop_Statement : Node_Id);
 159    --  N is the node for a loop statement. This procedure checks if a warning
 160    --  for a possible infinite loop should be given for a suspicious WHILE or
 161    --  EXIT WHEN condition.
 162
 163    procedure Check_Low_Bound_Tested (Expr : Node_Id);
 164    --  Expr is the node for a comparison operation. This procedure checks if
 165    --  the comparison is a source comparison of P'First with some other value
 166    --  and if so, sets the Low_Bound_Tested flag on entity P to suppress
 167    --  warnings about improper low bound assumptions (we assume that if the
 168    --  code has a test that explicitly checks P'First, then it is not operating
 169    --  in blind assumption mode).
 170
 171    procedure Warn_On_Known_Condition (C : Node_Id);
 172    --  C is a node for a boolean expression resulting from a relational
 173    --  or membership operation. If the expression has a compile time known
 174    --  value, then a warning is output if all the following conditions hold:
 175    --
 176    --    1. Original expression comes from source. We don't want to generate
 177    --       warnings for internally generated conditionals.
 178    --
 179    --    2. As noted above, the expression is a relational or membership
 180    --       test, we don't want to generate warnings for boolean variables
 181    --       since this is typical of conditional compilation in Ada.
 182    --
 183    --    3. The expression appears in a statement, rather than a declaration.
 184    --       In practice, most occurrences in declarations are legitimate
 185    --       conditionalizations, but occurrences in statements are often
 186    --       errors for which the warning is useful.
 187    --
 188    --    4. The expression does not occur within an instantiation. A non-
 189    --       static expression in a generic may become constant because of
 190    --       the attributes of the actuals, and we do not want to warn on
 191    --       these legitimate constant foldings.
 192    --
 193    --  If all these conditions are met, the warning is issued noting that
 194    --  the result of the test is always false or always true as appropriate.
 195
 196    function Warn_On_Modified_As_Out_Parameter (E : Entity_Id) return Boolean;
 197    --  Returns True if we should activate warnings for entity E being modified
 198    --  as an out parameter. True if either Warn_On_Modified_Unread is set for
 199    --  an only OUT parameter, or if Warn_On_All_Unread_Out_Parameters is set.
 200
 201    procedure Warn_On_Overlapping_Actuals (Subp : Entity_Id; N : Node_Id);
 202    --  Called on a subprogram call. Checks whether an IN OUT actual that is
 203    --  not by-copy may overlap with another actual, thus leading to aliasing
 204    --  in the body of the called subprogram. This is indeed a warning in Ada
 205    --  versions prior to Ada 2012, but, unless Opt.Error_To_Warning is set by
 206    --  use of debug flag -gnatd.E, this is illegal and generates an error.
 207
 208    procedure Warn_On_Suspicious_Index (Name : Entity_Id; X : Node_Id);
 209    --  This is called after resolving an indexed component or a slice. Name
 210    --  is the entity for the name of the indexed array, and X is the subscript
 211    --  for the indexed component case, or one of the bounds in the slice case.
 212    --  If Name is an unconstrained parameter of a standard string type, and
 213    --  the index is of the form of a literal or Name'Length [- literal], then
 214    --  a warning is generated that the subscripting operation is possibly
 215    --  incorrectly assuming a lower bound of 1.
 216
 217    procedure Warn_On_Suspicious_Update (N : Node_Id);
 218    --  N is a semantically analyzed attribute reference Prefix'Update. Issue
 219    --  a warning if Warn_On_Suspicious_Contract is set, and N is the left-hand
 220    --  side or right-hand side of an equality or inequality of the form:
 221    --    Prefix = Prefix'Update(...)
 222    --  or
 223    --    Prefix'Update(...) = Prefix
 224
 225    procedure Warn_On_Unassigned_Out_Parameter
 226      (Return_Node : Node_Id;
 227       Scope_Id    : Entity_Id);
 228    --  Called when processing a return statement given by Return_Node. Scope_Id
 229    --  is the Entity_Id for the procedure in which the return statement lives.
 230    --  A check is made for the case of a procedure with out parameters that
 231    --  have not yet been assigned, and appropriate warnings are given.
 232
 233    procedure Warn_On_Useless_Assignment
 234      (Ent : Entity_Id;
 235       N   : Node_Id := Empty);
 236    --  Called to check if we have a case of a useless assignment to the given
 237    --  entity Ent, as indicated by a non-empty Last_Assignment field. This call
 238    --  should only be made if at least one of the flags Warn_On_Modified_Unread
 239    --  or Warn_On_All_Unread_Out_Parameters is True, and if Ent is in the
 240    --  extended main source unit. N is Empty for the end of block call
 241    --  (warning message says value unreferenced), or it is the node for
 242    --  an overwriting assignment (warning message points to this assignment).
 243
 244    procedure Warn_On_Useless_Assignments (E : Entity_Id);
 245    pragma Inline (Warn_On_Useless_Assignments);
 246    --  Called at the end of a block or subprogram. Scans the entities of the
 247    --  block or subprogram to see if there are any variables for which useless
 248    --  assignments were made (assignments whose values were never read).
 249
 250    ----------------------
 251    -- Utility Routines --
 252    ----------------------
 253
 254    function Has_Junk_Name (E : Entity_Id) return Boolean;
 255    --  Return True if the entity name contains any of the following substrings:
 256    --    discard
 257    --    dummy
 258    --    ignore
 259    --    junk
 260    --    unused
 261    --  Used to suppress warnings on names matching these patterns. The contents
 262    --  of Name_Buffer and Name_Len are destroyed by this call.
 263
 264 end Sem_Warn;