gcc/ada/s-osinte-aix.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                  S p e c                                 --
   8 --                                                                          --
   9 --             Copyright (C) 1991-1994, Florida State University            --
  10 --          Copyright (C) 1995-2015, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  18 --                                                                          --
  19 -- As a special exception under Section 7 of GPL version 3, you are granted --
  20 -- additional permissions described in the GCC Runtime Library Exception,   --
  21 -- version 3.1, as published by the Free Software Foundation.               --
  22 --                                                                          --
  23 -- You should have received a copy of the GNU General Public License and    --
  24 -- a copy of the GCC Runtime Library Exception along with this program;     --
  25 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  26 -- <http://www.gnu.org/licenses/>.                                          --
  27 --                                                                          --
  28 -- GNARL was developed by the GNARL team at Florida State University.       --
  29 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 --  This is a AIX (Native THREADS) version of this package
  34
  35 --  This package encapsulates all direct interfaces to OS services that are
  36 --  needed by the tasking run-time (libgnarl).
  37
  38 --  PLEASE DO NOT add any with-clauses to this package or remove the pragma
  39 --  Preelaborate. This package is designed to be a bottom-level (leaf) package.
  40
  41 with Ada.Unchecked_Conversion;
  42
  43 with Interfaces.C;
  44 with Interfaces.C.Extensions;
  45
  46 package System.OS_Interface is
  47    pragma Preelaborate;
  48
  49    pragma Linker_Options ("-pthread");
  50    --  This implies -lpthreads + other things depending on the GCC
  51    --  configuration, such as the selection of a proper libgcc variant
  52    --  for table-based exception handling when it is available.
  53
  54    pragma Linker_Options ("-lc_r");
  55
  56    subtype int            is Interfaces.C.int;
  57    subtype short          is Interfaces.C.short;
  58    subtype long           is Interfaces.C.long;
  59    subtype long_long      is Interfaces.C.Extensions.long_long;
  60    subtype unsigned       is Interfaces.C.unsigned;
  61    subtype unsigned_short is Interfaces.C.unsigned_short;
  62    subtype unsigned_long  is Interfaces.C.unsigned_long;
  63    subtype unsigned_char  is Interfaces.C.unsigned_char;
  64    subtype plain_char     is Interfaces.C.plain_char;
  65    subtype size_t         is Interfaces.C.size_t;
  66
  67    -----------
  68    -- Errno --
  69    -----------
  70
  71    function errno return int;
  72    pragma Import (C, errno, "__get_errno");
  73
  74    EAGAIN    : constant := 11;
  75    EINTR     : constant := 4;
  76    EINVAL    : constant := 22;
  77    ENOMEM    : constant := 12;
  78    ETIMEDOUT : constant := 78;
  79
  80    -------------
  81    -- Signals --
  82    -------------
  83
  84    Max_Interrupt : constant := 63;
  85    type Signal is new int range 0 .. Max_Interrupt;
  86    for Signal'Size use int'Size;
  87
  88    SIGHUP      : constant := 1; --  hangup
  89    SIGINT      : constant := 2; --  interrupt (rubout)
  90    SIGQUIT     : constant := 3; --  quit (ASCD FS)
  91    SIGILL      : constant := 4; --  illegal instruction (not reset)
  92    SIGTRAP     : constant := 5; --  trace trap (not reset)
  93    SIGIOT      : constant := 6; --  IOT instruction
  94    SIGABRT     : constant := 6; --  used by abort, replace SIGIOT in the future
  95    SIGEMT      : constant := 7; --  EMT instruction
  96    SIGFPE      : constant := 8; --  floating point exception
  97    SIGKILL     : constant := 9; --  kill (cannot be caught or ignored)
  98    SIGBUS      : constant := 10; --  bus error
  99    SIGSEGV     : constant := 11; --  segmentation violation
 100    SIGSYS      : constant := 12; --  bad argument to system call
 101    SIGPIPE     : constant := 13; --  write on a pipe with no one to read it
 102    SIGALRM     : constant := 14; --  alarm clock
 103    SIGTERM     : constant := 15; --  software termination signal from kill
 104    SIGUSR1     : constant := 30; --  user defined signal 1
 105    SIGUSR2     : constant := 31; --  user defined signal 2
 106    SIGCLD      : constant := 20; --  alias for SIGCHLD
 107    SIGCHLD     : constant := 20; --  child status change
 108    SIGPWR      : constant := 29; --  power-fail restart
 109    SIGWINCH    : constant := 28; --  window size change
 110    SIGURG      : constant := 16; --  urgent condition on IO channel
 111    SIGPOLL     : constant := 23; --  pollable event occurred
 112    SIGIO       : constant := 23; --  I/O possible (Solaris SIGPOLL alias)
 113    SIGSTOP     : constant := 17; --  stop (cannot be caught or ignored)
 114    SIGTSTP     : constant := 18; --  user stop requested from tty
 115    SIGCONT     : constant := 19; --  stopped process has been continued
 116    SIGTTIN     : constant := 21; --  background tty read attempted
 117    SIGTTOU     : constant := 22; --  background tty write attempted
 118    SIGVTALRM   : constant := 34; --  virtual timer expired
 119    SIGPROF     : constant := 32; --  profiling timer expired
 120    SIGXCPU     : constant := 24; --  CPU time limit exceeded
 121    SIGXFSZ     : constant := 25; --  filesize limit exceeded
 122    SIGWAITING  : constant := 39; --  m:n scheduling
 123
 124    --  The following signals are AIX specific
 125
 126    SIGMSG      : constant := 27; -- input data is in the ring buffer
 127    SIGDANGER   : constant := 33; -- system crash imminent
 128    SIGMIGRATE  : constant := 35; -- migrate process
 129    SIGPRE      : constant := 36; -- programming exception
 130    SIGVIRT     : constant := 37; -- AIX virtual time alarm
 131    SIGALRM1    : constant := 38; -- m:n condition variables
 132    SIGCPUFAIL  : constant := 59; -- Predictive De-configuration of Processors
 133    SIGKAP      : constant := 60; -- keep alive poll from native keyboard
 134    SIGGRANT    : constant := SIGKAP; -- monitor mode granted
 135    SIGRETRACT  : constant := 61; -- monitor mode should be relinquished
 136    SIGSOUND    : constant := 62; -- sound control has completed
 137    SIGSAK      : constant := 63; -- secure attention key
 138
 139    SIGADAABORT : constant := SIGEMT;
 140    --  Note: on other targets, we usually use SIGABRT, but on AIX, it appears
 141    --  that SIGABRT can't be used in sigwait(), so we use SIGEMT.
 142    --  SIGEMT is "Emulator Trap Instruction" from the PDP-11, and does not
 143    --  have a standardized usage.
 144
 145    type Signal_Set is array (Natural range <>) of Signal;
 146
 147    Unmasked : constant Signal_Set :=
 148                 (SIGTRAP, SIGTTIN, SIGTTOU, SIGTSTP, SIGPROF);
 149    Reserved : constant Signal_Set :=
 150                 (SIGABRT, SIGKILL, SIGSTOP, SIGALRM1, SIGWAITING, SIGCPUFAIL);
 151
 152    type sigset_t is private;
 153
 154    function sigaddset (set : access sigset_t; sig : Signal) return int;
 155    pragma Import (C, sigaddset, "sigaddset");
 156
 157    function sigdelset (set : access sigset_t; sig : Signal) return int;
 158    pragma Import (C, sigdelset, "sigdelset");
 159
 160    function sigfillset (set : access sigset_t) return int;
 161    pragma Import (C, sigfillset, "sigfillset");
 162
 163    function sigismember (set : access sigset_t; sig : Signal) return int;
 164    pragma Import (C, sigismember, "sigismember");
 165
 166    function sigemptyset (set : access sigset_t) return int;
 167    pragma Import (C, sigemptyset, "sigemptyset");
 168
 169    type struct_sigaction is record
 170       sa_handler : System.Address;
 171       sa_mask    : sigset_t;
 172       sa_flags   : int;
 173    end record;
 174    pragma Convention (C, struct_sigaction);
 175    type struct_sigaction_ptr is access all struct_sigaction;
 176
 177    SA_SIGINFO : constant := 16#0100#;
 178    SA_ONSTACK : constant := 16#0001#;
 179
 180    SIG_BLOCK   : constant := 0;
 181    SIG_UNBLOCK : constant := 1;
 182    SIG_SETMASK : constant := 2;
 183
 184    SIG_DFL : constant := 0;
 185    SIG_IGN : constant := 1;
 186
 187    function sigaction
 188      (sig  : Signal;
 189       act  : struct_sigaction_ptr;
 190       oact : struct_sigaction_ptr) return int;
 191    pragma Import (C, sigaction, "sigaction");
 192
 193    ----------
 194    -- Time --
 195    ----------
 196
 197    Time_Slice_Supported : constant Boolean := True;
 198    --  Indicates whether time slicing is supported
 199
 200    type timespec is private;
 201
 202    type clockid_t is new long_long;
 203
 204    function clock_gettime
 205      (clock_id : clockid_t;
 206       tp       : access timespec) return int;
 207    pragma Import (C, clock_gettime, "clock_gettime");
 208
 209    function clock_getres
 210      (clock_id : clockid_t;
 211       res      : access timespec) return int;
 212    pragma Import (C, clock_getres, "clock_getres");
 213
 214    function To_Duration (TS : timespec) return Duration;
 215    pragma Inline (To_Duration);
 216
 217    function To_Timespec (D : Duration) return timespec;
 218    pragma Inline (To_Timespec);
 219
 220    type struct_timezone is record
 221       tz_minuteswest : int;
 222       tz_dsttime     : int;
 223    end record;
 224    pragma Convention (C, struct_timezone);
 225    type struct_timezone_ptr is access all struct_timezone;
 226
 227    -------------------------
 228    -- Priority Scheduling --
 229    -------------------------
 230
 231    SCHED_FIFO  : constant := 1;
 232    SCHED_RR    : constant := 2;
 233    SCHED_OTHER : constant := 0;
 234
 235    function To_Target_Priority
 236      (Prio : System.Any_Priority) return Interfaces.C.int;
 237    --  Maps System.Any_Priority to a POSIX priority
 238
 239    -------------
 240    -- Process --
 241    -------------
 242
 243    type pid_t is private;
 244
 245    function kill (pid : pid_t; sig : Signal) return int;
 246    pragma Import (C, kill, "kill");
 247
 248    function getpid return pid_t;
 249    pragma Import (C, getpid, "getpid");
 250
 251    ---------
 252    -- LWP --
 253    ---------
 254
 255    function lwp_self return System.Address;
 256    pragma Import (C, lwp_self, "thread_self");
 257
 258    -------------
 259    -- Threads --
 260    -------------
 261
 262    type Thread_Body is access
 263      function (arg : System.Address) return System.Address;
 264    pragma Convention (C, Thread_Body);
 265
 266    function Thread_Body_Access is new
 267      Ada.Unchecked_Conversion (System.Address, Thread_Body);
 268
 269    type pthread_t           is private;
 270    subtype Thread_Id        is pthread_t;
 271
 272    type pthread_mutex_t     is limited private;
 273    type pthread_cond_t      is limited private;
 274    type pthread_attr_t      is limited private;
 275    type pthread_mutexattr_t is limited private;
 276    type pthread_condattr_t  is limited private;
 277    type pthread_key_t       is private;
 278
 279    PTHREAD_CREATE_DETACHED : constant := 1;
 280
 281    PTHREAD_SCOPE_PROCESS : constant := 1;
 282    PTHREAD_SCOPE_SYSTEM  : constant := 0;
 283
 284    --  Read/Write lock not supported on AIX. To add support both types
 285    --  pthread_rwlock_t and pthread_rwlockattr_t must properly be defined
 286    --  with the associated routines pthread_rwlock_[init/destroy] and
 287    --  pthread_rwlock_[rdlock/wrlock/unlock].
 288
 289    subtype pthread_rwlock_t     is pthread_mutex_t;
 290    subtype pthread_rwlockattr_t is pthread_mutexattr_t;
 291
 292    -----------
 293    -- Stack --
 294    -----------
 295
 296    type stack_t is record
 297       ss_sp    : System.Address;
 298       ss_size  : size_t;
 299       ss_flags : int;
 300    end record;
 301    pragma Convention (C, stack_t);
 302
 303    function sigaltstack
 304      (ss  : not null access stack_t;
 305       oss : access stack_t) return int;
 306    pragma Import (C, sigaltstack, "sigaltstack");
 307
 308    Alternate_Stack : aliased System.Address;
 309    --  This is a dummy definition, never used (Alternate_Stack_Size is null)
 310
 311    Alternate_Stack_Size : constant := 0;
 312    --  No alternate signal stack is used on this platform
 313
 314    Stack_Base_Available : constant Boolean := False;
 315    --  Indicates whether the stack base is available on this target
 316
 317    function Get_Stack_Base (thread : pthread_t) return Address;
 318    pragma Inline (Get_Stack_Base);
 319    --  Returns the stack base of the specified thread. Only call this function
 320    --  when Stack_Base_Available is True.
 321
 322    function Get_Page_Size return int;
 323    pragma Import (C, Get_Page_Size, "getpagesize");
 324    --  Returns the size of a page
 325
 326    PROT_NONE  : constant := 0;
 327    PROT_READ  : constant := 1;
 328    PROT_WRITE : constant := 2;
 329    PROT_EXEC  : constant := 4;
 330    PROT_ALL   : constant := PROT_READ + PROT_WRITE + PROT_EXEC;
 331    PROT_ON    : constant := PROT_READ;
 332    PROT_OFF   : constant := PROT_ALL;
 333
 334    function mprotect (addr : Address; len : size_t; prot : int) return int;
 335    pragma Import (C, mprotect);
 336
 337    ---------------------------------------
 338    -- Nonstandard Thread Initialization --
 339    ---------------------------------------
 340
 341    --  Though not documented, pthread_init *must* be called before any other
 342    --  pthread call.
 343
 344    procedure pthread_init;
 345    pragma Import (C, pthread_init, "pthread_init");
 346
 347    -------------------------
 348    -- POSIX.1c  Section 3 --
 349    -------------------------
 350
 351    function sigwait
 352      (set : access sigset_t;
 353       sig : access Signal) return int;
 354    pragma Import (C, sigwait, "sigwait");
 355
 356    function pthread_kill
 357      (thread : pthread_t;
 358       sig    : Signal) return int;
 359    pragma Import (C, pthread_kill, "pthread_kill");
 360
 361    function pthread_sigmask
 362      (how  : int;
 363       set  : access sigset_t;
 364       oset : access sigset_t) return int;
 365    pragma Import (C, pthread_sigmask, "sigthreadmask");
 366
 367    --------------------------
 368    -- POSIX.1c  Section 11 --
 369    --------------------------
 370
 371    function pthread_mutexattr_init
 372      (attr : access pthread_mutexattr_t) return int;
 373    pragma Import (C, pthread_mutexattr_init, "pthread_mutexattr_init");
 374
 375    function pthread_mutexattr_destroy
 376      (attr : access pthread_mutexattr_t) return int;
 377    pragma Import (C, pthread_mutexattr_destroy, "pthread_mutexattr_destroy");
 378
 379    function pthread_mutex_init
 380      (mutex : access pthread_mutex_t;
 381       attr  : access pthread_mutexattr_t) return int;
 382    pragma Import (C, pthread_mutex_init, "pthread_mutex_init");
 383
 384    function pthread_mutex_destroy (mutex : access pthread_mutex_t) return int;
 385    pragma Import (C, pthread_mutex_destroy, "pthread_mutex_destroy");
 386
 387    function pthread_mutex_lock (mutex : access pthread_mutex_t) return int;
 388    pragma Import (C, pthread_mutex_lock, "pthread_mutex_lock");
 389
 390    function pthread_mutex_unlock (mutex : access pthread_mutex_t) return int;
 391    pragma Import (C, pthread_mutex_unlock, "pthread_mutex_unlock");
 392
 393    function pthread_condattr_init
 394      (attr : access pthread_condattr_t) return int;
 395    pragma Import (C, pthread_condattr_init, "pthread_condattr_init");
 396
 397    function pthread_condattr_destroy
 398      (attr : access pthread_condattr_t) return int;
 399    pragma Import (C, pthread_condattr_destroy, "pthread_condattr_destroy");
 400
 401    function pthread_cond_init
 402      (cond : access pthread_cond_t;
 403       attr : access pthread_condattr_t) return int;
 404    pragma Import (C, pthread_cond_init, "pthread_cond_init");
 405
 406    function pthread_cond_destroy (cond : access pthread_cond_t) return int;
 407    pragma Import (C, pthread_cond_destroy, "pthread_cond_destroy");
 408
 409    function pthread_cond_signal (cond : access pthread_cond_t) return int;
 410    pragma Import (C, pthread_cond_signal, "pthread_cond_signal");
 411
 412    function pthread_cond_wait
 413      (cond  : access pthread_cond_t;
 414       mutex : access pthread_mutex_t) return int;
 415    pragma Import (C, pthread_cond_wait, "pthread_cond_wait");
 416
 417    function pthread_cond_timedwait
 418      (cond    : access pthread_cond_t;
 419       mutex   : access pthread_mutex_t;
 420       abstime : access timespec) return int;
 421    pragma Import (C, pthread_cond_timedwait, "pthread_cond_timedwait");
 422
 423    Relative_Timed_Wait : constant Boolean := False;
 424    --  pthread_cond_timedwait requires an absolute delay time
 425
 426    --------------------------
 427    -- POSIX.1c  Section 13 --
 428    --------------------------
 429
 430    PTHREAD_PRIO_PROTECT : constant := 2;
 431
 432    function PTHREAD_PRIO_INHERIT return int;
 433    --  Return value of C macro PTHREAD_PRIO_INHERIT. This function is needed
 434    --  since the value is different between AIX versions.
 435
 436    function pthread_mutexattr_setprotocol
 437      (attr     : access pthread_mutexattr_t;
 438       protocol : int) return int;
 439    pragma Import (C, pthread_mutexattr_setprotocol);
 440
 441    function pthread_mutexattr_setprioceiling
 442      (attr        : access pthread_mutexattr_t;
 443       prioceiling : int) return int;
 444    pragma Import (C, pthread_mutexattr_setprioceiling);
 445
 446    type Array_5_Int is array (0 .. 5) of int;
 447    type struct_sched_param is record
 448       sched_priority : int;
 449       sched_policy   : int;
 450       sched_reserved : Array_5_Int;
 451    end record;
 452
 453    function pthread_setschedparam
 454      (thread : pthread_t;
 455       policy : int;
 456       param  : access struct_sched_param) return int;
 457    pragma Import (C, pthread_setschedparam, "pthread_setschedparam");
 458
 459    function pthread_attr_setscope
 460      (attr            : access pthread_attr_t;
 461       contentionscope : int) return int;
 462    pragma Import (C, pthread_attr_setscope, "pthread_attr_setscope");
 463
 464    function pthread_attr_setinheritsched
 465      (attr            : access pthread_attr_t;
 466       inheritsched : int) return int;
 467    pragma Import (C, pthread_attr_setinheritsched);
 468
 469    function pthread_attr_setschedpolicy
 470      (attr   : access pthread_attr_t;
 471       policy : int) return int;
 472    pragma Import (C, pthread_attr_setschedpolicy);
 473
 474    function pthread_attr_setschedparam
 475      (attr        : access pthread_attr_t;
 476       sched_param : int) return int;
 477    pragma Import (C, pthread_attr_setschedparam);
 478
 479    function sched_yield return int;
 480    --  AIX have a nonstandard sched_yield
 481
 482    --------------------------
 483    -- P1003.1c  Section 16 --
 484    --------------------------
 485
 486    function pthread_attr_init (attributes : access pthread_attr_t) return int;
 487    pragma Import (C, pthread_attr_init, "pthread_attr_init");
 488
 489    function pthread_attr_destroy
 490      (attributes : access pthread_attr_t) return int;
 491    pragma Import (C, pthread_attr_destroy, "pthread_attr_destroy");
 492
 493    function pthread_attr_setdetachstate
 494      (attr        : access pthread_attr_t;
 495       detachstate : int) return int;
 496    pragma Import (C, pthread_attr_setdetachstate);
 497
 498    function pthread_attr_setstacksize
 499      (attr      : access pthread_attr_t;
 500       stacksize : size_t) return int;
 501    pragma Import (C, pthread_attr_setstacksize);
 502
 503    function pthread_create
 504      (thread        : access pthread_t;
 505       attributes    : access pthread_attr_t;
 506       start_routine : Thread_Body;
 507       arg           : System.Address)
 508      return int;
 509    pragma Import (C, pthread_create, "pthread_create");
 510
 511    procedure pthread_exit (status : System.Address);
 512    pragma Import (C, pthread_exit, "pthread_exit");
 513
 514    function pthread_self return pthread_t;
 515    pragma Import (C, pthread_self, "pthread_self");
 516
 517    --------------------------
 518    -- POSIX.1c  Section 17 --
 519    --------------------------
 520
 521    function pthread_setspecific
 522      (key   : pthread_key_t;
 523       value : System.Address) return int;
 524    pragma Import (C, pthread_setspecific, "pthread_setspecific");
 525
 526    function pthread_getspecific (key : pthread_key_t) return System.Address;
 527    pragma Import (C, pthread_getspecific, "pthread_getspecific");
 528
 529    type destructor_pointer is access procedure (arg : System.Address);
 530    pragma Convention (C, destructor_pointer);
 531
 532    function pthread_key_create
 533      (key        : access pthread_key_t;
 534       destructor : destructor_pointer) return int;
 535    pragma Import (C, pthread_key_create, "pthread_key_create");
 536
 537 private
 538    type sigset_t is record
 539       losigs : unsigned_long;
 540       hisigs : unsigned_long;
 541    end record;
 542    pragma Convention (C_Pass_By_Copy, sigset_t);
 543
 544    type pid_t is new int;
 545
 546    type time_t is new long;
 547
 548    type timespec is record
 549       tv_sec  : time_t;
 550       tv_nsec : long;
 551    end record;
 552    pragma Convention (C, timespec);
 553
 554    type pthread_attr_t is new System.Address;
 555    pragma Convention (C, pthread_attr_t);
 556    --  typedef struct __pt_attr        *pthread_attr_t;
 557
 558    type pthread_condattr_t is new System.Address;
 559    pragma Convention (C, pthread_condattr_t);
 560    --  typedef struct __pt_attr        *pthread_condattr_t;
 561
 562    type pthread_mutexattr_t is new System.Address;
 563    pragma Convention (C, pthread_mutexattr_t);
 564    --  typedef struct __pt_attr        *pthread_mutexattr_t;
 565
 566    type pthread_t is new System.Address;
 567    pragma Convention (C, pthread_t);
 568    --  typedef void    *pthread_t;
 569
 570    type ptq_queue;
 571    type ptq_queue_ptr is access all ptq_queue;
 572
 573    type ptq_queue is record
 574       ptq_next : ptq_queue_ptr;
 575       ptq_prev : ptq_queue_ptr;
 576    end record;
 577
 578    type Array_3_Int is array (0 .. 3) of int;
 579    type pthread_mutex_t is record
 580         link        : ptq_queue;
 581         ptmtx_lock  : int;
 582         ptmtx_flags : long;
 583         protocol    : int;
 584         prioceiling : int;
 585         ptmtx_owner : pthread_t;
 586         mtx_id      : int;
 587         attr        : pthread_attr_t;
 588         mtx_kind    : int;
 589         lock_cpt    : int;
 590         reserved    : Array_3_Int;
 591    end record;
 592    pragma Convention (C, pthread_mutex_t);
 593    type pthread_mutex_t_ptr is access pthread_mutex_t;
 594
 595    type pthread_cond_t is record
 596       link         : ptq_queue;
 597       ptcv_lock    : int;
 598       ptcv_flags   : long;
 599       ptcv_waiters : ptq_queue;
 600       cv_id        : int;
 601       attr         : pthread_attr_t;
 602       mutex        : pthread_mutex_t_ptr;
 603       cptwait      : int;
 604       reserved     : int;
 605    end record;
 606    pragma Convention (C, pthread_cond_t);
 607
 608    type pthread_key_t is new unsigned;
 609
 610 end System.OS_Interface;