gcc/ada/exp_ch9.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ C H 9                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Expand routines for chapter 9 constructs
  27
  28 with Types; use Types;
  29
  30 package Exp_Ch9 is
  31
  32    type Subprogram_Protection_Mode is
  33      (Dispatching_Mode,
  34       Protected_Mode,
  35       Unprotected_Mode);
  36    --  This type is used to distinguish the different protection modes of a
  37    --  protected subprogram.
  38
  39    procedure Build_Activation_Chain_Entity (N : Node_Id);
  40    --  Given a declaration N of an object that is a task, or contains tasks
  41    --  (other than allocators to tasks) this routine ensures that an activation
  42    --  chain has been declared in the appropriate scope, building the required
  43    --  declaration for the chain variable if not. The name of this variable
  44    --  is always _Chain and it is accessed by name.
  45
  46    function Build_Call_With_Task (N : Node_Id; E : Entity_Id) return Node_Id;
  47    --  N is a node representing the name of a task or an access to a task.
  48    --  The value returned is a call to the function whose name is the entity
  49    --  E (typically a runtime routine entity obtained using RTE) with the
  50    --  Task_Id of the associated task as the parameter. The caller is
  51    --  responsible for analyzing and resolving the resulting tree.
  52
  53    procedure Build_Class_Wide_Master (Typ : Entity_Id);
  54    --  Given an access-to-limited class-wide type or an access-to-limited
  55    --  interface, ensure that the designated type has a _master and generate
  56    --  a renaming of the said master to service the access type.
  57
  58    procedure Build_Entry_Names
  59      (Obj_Ref : Node_Id;
  60       Obj_Typ : Entity_Id;
  61       Stmts   : List_Id);
  62    --  Given a concurrent object, create static string names for all entries
  63    --  and entry families. Associate each name with the Protection_Entries or
  64    --  ATCB field of the object. Obj_Ref is a reference to the concurrent
  65    --  object. Obj_Typ is the type of the object. Stmts is the list where all
  66    --  generated code is attached.
  67
  68    procedure Build_Master_Entity (Obj_Or_Typ : Entity_Id);
  69    --  Given the name of an object or a type which is either a task, contains
  70    --  tasks or designates tasks, create a _master in the appropriate scope
  71    --  which captures the value of Current_Master. Mark the nearest enclosing
  72    --  body or block as being a task master.
  73
  74    procedure Build_Master_Renaming
  75      (Ptr_Typ : Entity_Id;
  76       Ins_Nod : Node_Id := Empty);
  77    --  Given an access type Ptr_Typ whose designated type is either a task or
  78    --  contains tasks, create a renaming of the form:
  79    --
  80    --     <Ptr_Typ>M : Master_Id renames _Master;
  81    --
  82    --  where _master denotes the task master of the enclosing context. Ins_Nod
  83    --  is used to provide a specific insertion node for the renaming.
  84
  85    function Build_Private_Protected_Declaration (N : Node_Id) return Entity_Id;
  86    --  A subprogram body without a previous spec that appears in a protected
  87    --  body must be expanded separately to create a subprogram declaration
  88    --  for it, in order to resolve internal calls to it from other protected
  89    --  operations. It would seem that no locking version of the operation is
  90    --  needed, but in fact, in Ada 2005 the subprogram may be used in a call-
  91    --  back, and therefore a protected version of the operation must be
  92    --  generated as well.
  93
  94    function Build_Protected_Sub_Specification
  95      (N        : Node_Id;
  96       Prot_Typ : Entity_Id;
  97       Mode     : Subprogram_Protection_Mode) return Node_Id;
  98    --  Build the specification for protected subprogram. This is called when
  99    --  expanding a protected type, and also when expanding the declaration for
 100    --  an Access_To_Protected_Subprogram type. In the latter case, Prot_Typ is
 101    --  empty, and the first parameter of the signature of the protected op is
 102    --  of type System.Address.
 103
 104    procedure Build_Protected_Subprogram_Call
 105      (N        : Node_Id;
 106       Name     : Node_Id;
 107       Rec      : Node_Id;
 108       External : Boolean := True);
 109    --  The node N is a subprogram or entry call to a protected subprogram. This
 110    --  procedure rewrites this call with the appropriate expansion. Name is the
 111    --  subprogram, and Rec is the record corresponding to the protected object.
 112    --  External is False if the call is to another protected subprogram within
 113    --  the same object.
 114
 115    procedure Build_Task_Activation_Call (N : Node_Id);
 116    --  This procedure is called for constructs that can be task activators,
 117    --  i.e. task bodies, subprogram bodies, package bodies and blocks. If the
 118    --  construct is a task activator (as indicated by the non-empty setting of
 119    --  Activation_Chain_Entity, either in the construct, or, in the case of a
 120    --  package body, in its associated package spec), then a call to
 121    --  Activate_Tasks with this entity as the single parameter is inserted at
 122    --  the start of the statements of the activator.
 123
 124    procedure Build_Task_Allocate_Block
 125      (Actions : List_Id;
 126       N       : Node_Id;
 127       Args    : List_Id);
 128    --  This routine is used in the case of allocators where the designated type
 129    --  is a task or contains tasks. In this case, the normal initialize call
 130    --  is replaced by:
 131    --
 132    --    blockname : label;
 133    --    blockname : declare
 134    --       _Chain  : Activation_Chain;
 135    --
 136    --       procedure _Expunge is
 137    --       begin
 138    --         Expunge_Unactivated_Tasks (_Chain);
 139    --       end;
 140    --
 141    --    begin
 142    --       Init (Args);
 143    --       Activate_Tasks (_Chain);
 144    --    at end
 145    --       _Expunge;
 146    --    end;
 147    --
 148    --  to get the task or tasks created and initialized. The expunge call
 149    --  ensures that any tasks that get created but not activated due to an
 150    --  exception are properly expunged (it has no effect in the normal case).
 151    --  The argument N is the allocator, and Args is the list of arguments for
 152    --  the initialization call, constructed by the caller, which uses the
 153    --  Master_Id of the access type as the _Master parameter, and _Chain
 154    --  (defined above) as the _Chain parameter.
 155
 156    procedure Build_Task_Allocate_Block_With_Init_Stmts
 157      (Actions    : List_Id;
 158       N          : Node_Id;
 159       Init_Stmts : List_Id);
 160    --  Ada 2005 (AI-287): Similar to previous routine, but used to expand
 161    --  allocated aggregates with default initialized components. Init_Stmts
 162    --  contains the list of statements required to initialize the allocated
 163    --  aggregate. It replaces the call to Init (Args) done by
 164    --  Build_Task_Allocate_Block.
 165
 166    function Build_Wrapper_Spec
 167      (Subp_Id : Entity_Id;
 168       Obj_Typ : Entity_Id;
 169       Formals : List_Id) return Node_Id;
 170    --  Ada 2005 (AI-345): Build the specification of a primitive operation
 171    --  associated with a protected or task type. This is required to implement
 172    --  dispatching calls through interfaces. Subp_Id is the primitive to be
 173    --  wrapped, Obj_Typ is the type of the newly added formal parameter to
 174    --  handle object notation, Formals are the original entry formals that
 175    --  will be explicitly replicated.
 176
 177    function Concurrent_Ref (N : Node_Id) return Node_Id;
 178    --  Given the name of a concurrent object (task or protected object), or
 179    --  the name of an access to a concurrent object, this function returns an
 180    --  expression referencing the associated Task_Id or Protection object,
 181    --  respectively. Note that a special case is when the name is a reference
 182    --  to a task type name. This can only happen within a task body, and the
 183    --  meaning is to get the Task_Id for the currently executing task.
 184
 185    function Convert_Concurrent
 186      (N   : Node_Id;
 187       Typ : Entity_Id) return Node_Id;
 188    --  N is an expression of type Typ. If the type is not a concurrent type
 189    --  then it is returned unchanged. If it is a task or protected reference,
 190    --  Convert_Concurrent creates an unchecked conversion node from this
 191    --  expression to the corresponding concurrent record type value. We need
 192    --  this in any situation where the concurrent type is used, because the
 193    --  actual concurrent object is an object of the corresponding concurrent
 194    --  type, and manipulations on the concurrent object actually manipulate the
 195    --  corresponding object of the record type.
 196
 197    function Entry_Index_Expression
 198      (Sloc  : Source_Ptr;
 199       Ent   : Entity_Id;
 200       Index : Node_Id;
 201       Ttyp  : Entity_Id)
 202       return  Node_Id;
 203    --  Returns an expression to compute a task entry index given the name of
 204    --  the entry or entry family. For the case of a task entry family, the
 205    --  Index parameter contains the expression for the subscript. Ttyp is the
 206    --  task type.
 207
 208    procedure Establish_Task_Master (N : Node_Id);
 209    --  Given a subprogram body, or a block statement, or a task body, this
 210    --  procedure makes the necessary transformations required of a task master
 211    --  (add Enter_Master call at start, and establish a cleanup routine to make
 212    --  sure Complete_Master is called on exit).
 213
 214    procedure Expand_Access_Protected_Subprogram_Type (N : Node_Id);
 215    --  Build Equivalent_Type for an Access_To_Protected_Subprogram.
 216    --  Equivalent_Type is a record type with two components: a pointer to the
 217    --  protected object, and a pointer to the operation itself.
 218
 219    procedure Expand_Accept_Declarations (N : Node_Id; Ent : Entity_Id);
 220    --  Expand declarations required for accept statement. See bodies of both
 221    --  Expand_Accept_Declarations and Expand_N_Accept_Statement for full
 222    --  details of the nature and use of these declarations, which are inserted
 223    --  immediately before the accept node N. The second argument is the entity
 224    --  for the corresponding entry.
 225
 226    procedure Expand_Entry_Barrier (N : Node_Id; Ent : Entity_Id);
 227    --  Expand the entry barrier into a function. This is called directly
 228    --  from Analyze_Entry_Body so that the discriminals and privals of the
 229    --  barrier can be attached to the function declaration list, and a new
 230    --  set prepared for the entry body procedure, before the entry body
 231    --  statement sequence can be expanded. The resulting function is analyzed
 232    --  now, within the context of the protected object, to resolve calls to
 233    --  other protected functions.
 234
 235    procedure Expand_N_Abort_Statement            (N : Node_Id);
 236    procedure Expand_N_Accept_Statement           (N : Node_Id);
 237    procedure Expand_N_Asynchronous_Select        (N : Node_Id);
 238    procedure Expand_N_Conditional_Entry_Call     (N : Node_Id);
 239    procedure Expand_N_Delay_Relative_Statement   (N : Node_Id);
 240    procedure Expand_N_Delay_Until_Statement      (N : Node_Id);
 241    procedure Expand_N_Entry_Body                 (N : Node_Id);
 242    procedure Expand_N_Entry_Call_Statement       (N : Node_Id);
 243    procedure Expand_N_Entry_Declaration          (N : Node_Id);
 244    procedure Expand_N_Protected_Body             (N : Node_Id);
 245
 246    procedure Expand_N_Protected_Type_Declaration (N : Node_Id);
 247    --  Expands protected type declarations. This results, among other things,
 248    --  in the declaration of a record type for the representation of protected
 249    --  objects and (if there are entries) in an entry service procedure. The
 250    --  Protection value used by the GNARL to control the object will always be
 251    --  the first field of the record, and the entry service procedure spec (if
 252    --  it exists) will always immediately follow the record declaration. This
 253    --  allows these two nodes to be found from the type, without benefit of
 254    --  further attributes, using Corresponding_Record.
 255
 256    procedure Expand_N_Requeue_Statement          (N : Node_Id);
 257    procedure Expand_N_Selective_Accept           (N : Node_Id);
 258    procedure Expand_N_Single_Task_Declaration    (N : Node_Id);
 259    procedure Expand_N_Task_Body                  (N : Node_Id);
 260    procedure Expand_N_Task_Type_Declaration      (N : Node_Id);
 261    procedure Expand_N_Timed_Entry_Call           (N : Node_Id);
 262
 263    procedure Expand_Protected_Body_Declarations
 264      (N       : Node_Id;
 265       Spec_Id : Entity_Id);
 266    --  Expand declarations required for a protected body. See bodies of both
 267    --  Expand_Protected_Body_Declarations and Expand_N_Protected_Body for full
 268    --  details of the nature and use of these declarations. The second argument
 269    --  is the entity for the corresponding protected type declaration.
 270
 271    function External_Subprogram (E : Entity_Id) return Entity_Id;
 272    --  return the external version of a protected operation, which locks
 273    --  the object before invoking the internal protected subprogram body.
 274
 275    function Find_Master_Scope (E : Entity_Id) return Entity_Id;
 276    --  When a type includes tasks, a master entity is created in the scope, to
 277    --  be used by the runtime during activation. In general the master is the
 278    --  immediate scope in which the type is declared, but in Ada 2005, in the
 279    --  presence of synchronized classwide interfaces, the immediate scope of
 280    --  an anonymous access type may be a transient scope, which has no run-time
 281    --  presence. In this case, the scope of the master is the innermost scope
 282    --  that comes from source.
 283
 284    function First_Protected_Operation (D : List_Id) return Node_Id;
 285    --  Given the declarations list for a protected body, find the
 286    --  first protected operation body.
 287
 288    procedure Install_Private_Data_Declarations
 289      (Loc      : Source_Ptr;
 290       Spec_Id  : Entity_Id;
 291       Conc_Typ : Entity_Id;
 292       Body_Nod : Node_Id;
 293       Decls    : List_Id;
 294       Barrier  : Boolean := False;
 295       Family   : Boolean := False);
 296    --  This routines generates several types, objects and object renamings used
 297    --  in the handling of discriminants and private components of protected and
 298    --  task types. It also generates the entry index for entry families. Formal
 299    --  Spec_Id denotes an entry, entry family or a subprogram, Conc_Typ is the
 300    --  concurrent type where Spec_Id resides, Body_Nod is the corresponding
 301    --  body of Spec_Id, Decls are the declarations of the subprogram or entry.
 302    --  Flag Barrier denotes whether the context is an entry barrier function.
 303    --  Flag Family is used in conjunction with Barrier to denote a barrier for
 304    --  an entry family.
 305    --
 306    --  The generated types, entities and renamings are:
 307    --
 308    --  * If flag Barrier is set or Spec_Id denotes a protected entry or an
 309    --    entry family, generate:
 310    --
 311    --      type prot_typVP is access prot_typV;
 312    --      _object : prot_typVP := prot_typV (_O);
 313    --
 314    --    where prot_typV is the corresponding record of a protected type and
 315    --    _O is a formal parameter representing the concurrent object of either
 316    --    the barrier function or the entry (family).
 317    --
 318    --  * If Conc_Typ is a protected type, create a renaming for the Protection
 319    --    field _object:
 320    --
 321    --      conc_typR : protection_typ renames _object._object;
 322    --
 323    --  * If Conc_Typ has discriminants, create renamings of the form:
 324    --
 325    --      discr_nameD : discr_typ renames _object.discr_name;
 326    --        or
 327    --      discr_nameD : discr_typ renames _task.discr_name;
 328    --
 329    --  * If Conc_Typ denotes a protected type and has private components,
 330    --    generate renamings of the form:
 331    --
 332    --      comp_name : comp_typ renames _object.comp_name;
 333    --
 334    --  * Finally, is flag Barrier and Family are set or Spec_Id denotes an
 335    --    entry family, generate the entry index constant:
 336    --
 337    --      subtype Jnn is <Type of Index> range Low .. High;
 338    --      J : constant Jnn :=
 339    --            Jnn'Val (_E - <Index expression> + Jnn'Pos (Jnn'First));
 340    --
 341    --  All the above declarations are inserted in the order shown to the front
 342    --  of Decls.
 343
 344    function Make_Task_Create_Call (Task_Rec : Entity_Id) return Node_Id;
 345    --  Given the entity of the record type created for a task type, build
 346    --  the call to Create_Task
 347
 348    function Make_Initialize_Protection
 349      (Protect_Rec : Entity_Id) return List_Id;
 350    --  Given the entity of the record type created for a protected type, build
 351    --  a list of statements needed for proper initialization of the object.
 352
 353    function Next_Protected_Operation (N : Node_Id) return Node_Id;
 354    --  Given a protected operation node (a subprogram or entry body), find the
 355    --  following node in the declarations list.
 356
 357    procedure Set_Discriminals (Dec : Node_Id);
 358    --  Replace discriminals in a protected type for use by the next protected
 359    --  operation on the type. Each operation needs a new set of discriminals,
 360    --  since it needs a unique renaming of the discriminant fields in the
 361    --  record used to implement the protected type.
 362
 363 end Exp_Ch9;