gcc/ada/exp_ch13.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ C H 1 3                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Ch3;  use Exp_Ch3;
  30 with Exp_Ch6;  use Exp_Ch6;
  31 with Exp_Imgv; use Exp_Imgv;
  32 with Exp_Tss;  use Exp_Tss;
  33 with Exp_Util; use Exp_Util;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Opt;      use Opt;
  38 with Restrict; use Restrict;
  39 with Rident;   use Rident;
  40 with Rtsfind;  use Rtsfind;
  41 with Sem;      use Sem;
  42 with Sem_Aux;  use Sem_Aux;
  43 with Sem_Ch7;  use Sem_Ch7;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Eval; use Sem_Eval;
  46 with Sem_Util; use Sem_Util;
  47 with Sinfo;    use Sinfo;
  48 with Snames;   use Snames;
  49 with Targparm; use Targparm;
  50 with Tbuild;   use Tbuild;
  51 with Uintp;    use Uintp;
  52 with Validsw;  use Validsw;
  53
  54 package body Exp_Ch13 is
  55
  56    ------------------------------------------
  57    -- Expand_N_Attribute_Definition_Clause --
  58    ------------------------------------------
  59
  60    --  Expansion action depends on attribute involved
  61
  62    procedure Expand_N_Attribute_Definition_Clause (N : Node_Id) is
  63       Loc : constant Source_Ptr := Sloc (N);
  64       Exp : constant Node_Id    := Expression (N);
  65       Ent : Entity_Id;
  66       V   : Node_Id;
  67
  68    begin
  69       Ent := Entity (Name (N));
  70
  71       if Is_Type (Ent) then
  72          Ent := Underlying_Type (Ent);
  73       end if;
  74
  75       case Get_Attribute_Id (Chars (N)) is
  76
  77          -------------
  78          -- Address --
  79          -------------
  80
  81          when Attribute_Address =>
  82
  83             --  If there is an initialization which did not come from the
  84             --  source program, then it is an artifact of our expansion, and we
  85             --  suppress it. The case we are most concerned about here is the
  86             --  initialization of a packed array to all false, which seems
  87             --  inappropriate for variable to which an address clause is
  88             --  applied. The expression may itself have been rewritten if the
  89             --  type is packed array, so we need to examine whether the
  90             --  original node is in the source. An exception though is the case
  91             --  of an access variable which is default initialized to null, and
  92             --  such initialization is retained.
  93
  94             --  Furthermore, if the initialization is the equivalent aggregate
  95             --  of the type initialization procedure, it replaces an implicit
  96             --  call to the init proc, and must be respected. Note that for
  97             --  packed types we do not build equivalent aggregates.
  98
  99             --  Also, if Init_Or_Norm_Scalars applies, then we need to retain
 100             --  any default initialization for objects of scalar types and
 101             --  types with scalar components. Normally a composite type will
 102             --  have an init_proc in the presence of Init_Or_Norm_Scalars,
 103             --  so when that flag is set we have just have to do a test for
 104             --  scalar and string types (the predefined string types such as
 105             --  String and Wide_String don't have an init_proc).
 106
 107             declare
 108                Decl : constant Node_Id := Declaration_Node (Ent);
 109                Typ  : constant Entity_Id := Etype (Ent);
 110
 111             begin
 112                if Nkind (Decl) = N_Object_Declaration
 113                   and then Present (Expression (Decl))
 114                   and then Nkind (Expression (Decl)) /= N_Null
 115                   and then
 116                    not Comes_From_Source (Original_Node (Expression (Decl)))
 117                then
 118                   if Present (Base_Init_Proc (Typ))
 119                     and then
 120                       Present (Static_Initialization (Base_Init_Proc (Typ)))
 121                   then
 122                      null;
 123
 124                   elsif Init_Or_Norm_Scalars
 125                     and then
 126                       (Is_Scalar_Type (Typ) or else Is_String_Type (Typ))
 127                   then
 128                      null;
 129
 130                   else
 131                      Set_Expression (Decl, Empty);
 132                   end if;
 133
 134                --  An object declaration to which an address clause applies
 135                --  has a delayed freeze, but the address expression itself
 136                --  must be elaborated at the point it appears. If the object
 137                --  is controlled, additional checks apply elsewhere.
 138
 139                elsif Nkind (Decl) = N_Object_Declaration
 140                  and then not Needs_Constant_Address (Decl, Typ)
 141                then
 142                   Remove_Side_Effects (Exp);
 143                end if;
 144             end;
 145
 146          ---------------
 147          -- Alignment --
 148          ---------------
 149
 150          when Attribute_Alignment =>
 151
 152             --  As required by Gigi, we guarantee that the operand is an
 153             --  integer literal (this simplifies things in Gigi).
 154
 155             if Nkind (Exp) /= N_Integer_Literal then
 156                Rewrite
 157                  (Exp, Make_Integer_Literal (Loc, Expr_Value (Exp)));
 158             end if;
 159
 160          ------------------
 161          -- Storage_Size --
 162          ------------------
 163
 164          when Attribute_Storage_Size =>
 165
 166             --  If the type is a task type, then assign the value of the
 167             --  storage size to the Size variable associated with the task.
 168             --  Insert the assignment right after the declaration of the Size
 169             --  variable.
 170
 171             --  Generate:
 172
 173             --  task_typeZ := expression
 174
 175             if Ekind (Ent) = E_Task_Type then
 176                declare
 177                   Assign : Node_Id;
 178
 179                begin
 180                   Assign :=
 181                     Make_Assignment_Statement (Loc,
 182                       Name =>
 183                         New_Reference_To (Storage_Size_Variable (Ent), Loc),
 184                       Expression =>
 185                         Convert_To (RTE (RE_Size_Type), Expression (N)));
 186
 187                   --  If the clause is not generated by an aspect, insert
 188                   --  the assignment here.  Freezing rules ensure that this
 189                   --  is safe, or clause will have been rejected already.
 190
 191                   if Is_List_Member (N) then
 192                      Insert_After (N, Assign);
 193
 194                   --  Otherwise, insert assignment after task declaration.
 195
 196                   else
 197                      Insert_After
 198                        (Parent (Storage_Size_Variable (Entity (N))), Assign);
 199                   end if;
 200
 201                   Analyze (Assign);
 202                end;
 203
 204             --  For Storage_Size for an access type, create a variable to hold
 205             --  the value of the specified size with name typeV and expand an
 206             --  assignment statement to initialize this value.
 207
 208             elsif Is_Access_Type (Ent) then
 209
 210                --  We don't need the variable for a storage size of zero
 211
 212                if not No_Pool_Assigned (Ent) then
 213                   V :=
 214                     Make_Defining_Identifier (Loc,
 215                       Chars => New_External_Name (Chars (Ent), 'V'));
 216
 217                   --  Insert the declaration of the object
 218
 219                   Insert_Action (N,
 220                     Make_Object_Declaration (Loc,
 221                       Defining_Identifier => V,
 222                       Object_Definition  =>
 223                         New_Reference_To (RTE (RE_Storage_Offset), Loc),
 224                       Expression =>
 225                         Convert_To (RTE (RE_Storage_Offset), Expression (N))));
 226
 227                   Set_Storage_Size_Variable (Ent, Entity_Id (V));
 228                end if;
 229             end if;
 230
 231          --  Other attributes require no expansion
 232
 233          when others =>
 234             null;
 235
 236       end case;
 237    end Expand_N_Attribute_Definition_Clause;
 238
 239    -----------------------------
 240    -- Expand_N_Free_Statement --
 241    -----------------------------
 242
 243    procedure Expand_N_Free_Statement (N : Node_Id) is
 244       Expr : constant Node_Id := Expression (N);
 245       Typ  : Entity_Id;
 246
 247    begin
 248       --  Certain run-time configurations and targets do not provide support
 249       --  for controlled types.
 250
 251       if Restriction_Active (No_Finalization) then
 252          return;
 253
 254       --  Do not create a specialized Deallocate since .NET/JVM compilers do
 255       --  not support pools and address arithmetic.
 256
 257       elsif VM_Target /= No_VM then
 258          return;
 259       end if;
 260
 261       --  Use the base type to perform the check for finalization master
 262
 263       Typ := Etype (Expr);
 264
 265       if Ekind (Typ) = E_Access_Subtype then
 266          Typ := Etype (Typ);
 267       end if;
 268
 269       --  Handle private access types
 270
 271       if Is_Private_Type (Typ)
 272         and then Present (Full_View (Typ))
 273       then
 274          Typ := Full_View (Typ);
 275       end if;
 276
 277       --  Do not create a custom Deallocate when freeing an object with
 278       --  suppressed finalization. In such cases the object is never attached
 279       --  to a master, so it does not need to be detached. Use a regular free
 280       --  statement instead.
 281
 282       if No (Finalization_Master (Typ)) then
 283          return;
 284       end if;
 285
 286       --  Use a temporary to store the result of a complex expression. Perform
 287       --  the following transformation:
 288       --
 289       --     Free (Complex_Expression);
 290       --
 291       --     Temp : constant Type_Of_Expression := Complex_Expression;
 292       --     Free (Temp);
 293
 294       if Nkind (Expr) /= N_Identifier then
 295          declare
 296             Expr_Typ : constant Entity_Id  := Etype (Expr);
 297             Loc      : constant Source_Ptr := Sloc (N);
 298             New_Expr : Node_Id;
 299             Temp_Id  : Entity_Id;
 300
 301          begin
 302             Temp_Id := Make_Temporary (Loc, 'T');
 303             Insert_Action (N,
 304               Make_Object_Declaration (Loc,
 305                 Defining_Identifier => Temp_Id,
 306                 Object_Definition =>
 307                   New_Reference_To (Expr_Typ, Loc),
 308                 Expression =>
 309                   Relocate_Node (Expr)));
 310
 311             New_Expr := New_Reference_To (Temp_Id, Loc);
 312             Set_Etype (New_Expr, Expr_Typ);
 313
 314             Set_Expression (N, New_Expr);
 315          end;
 316       end if;
 317
 318       --  Create a custom Deallocate for a controlled object. This routine
 319       --  ensures that the hidden list header will be deallocated along with
 320       --  the actual object.
 321
 322       Build_Allocate_Deallocate_Proc (N, Is_Allocate => False);
 323    end Expand_N_Free_Statement;
 324
 325    ----------------------------
 326    -- Expand_N_Freeze_Entity --
 327    ----------------------------
 328
 329    procedure Expand_N_Freeze_Entity (N : Node_Id) is
 330       E              : constant Entity_Id := Entity (N);
 331       E_Scope        : Entity_Id;
 332       In_Other_Scope : Boolean;
 333       In_Outer_Scope : Boolean;
 334       Decl           : Node_Id;
 335       Delete         : Boolean := False;
 336
 337    begin
 338       --  If there are delayed aspect specifications, we insert them just
 339       --  before the freeze node. They are already analyzed so we don't need
 340       --  to reanalyze them (they were analyzed before the type was frozen),
 341       --  but we want them in the tree for the back end, and so that the
 342       --  listing from sprint is clearer on where these occur logically.
 343
 344       if Has_Delayed_Aspects (E) then
 345          declare
 346             Aitem : Node_Id;
 347             Ritem : Node_Id;
 348
 349          begin
 350             --  Look for aspect specs for this entity
 351
 352             Ritem := First_Rep_Item (E);
 353             while Present (Ritem) loop
 354                if Nkind (Ritem) = N_Aspect_Specification
 355                  and then Entity (Ritem) = E
 356                then
 357                   Aitem := Aspect_Rep_Item (Ritem);
 358
 359                   --  Skip this for aspects (e.g. Current_Value) for which
 360                   --  there is no corresponding pragma or attribute.
 361
 362                   if Present (Aitem) then
 363                      pragma Assert (Is_Delayed_Aspect (Aitem));
 364                      Insert_Before (N, Aitem);
 365                   end if;
 366                end if;
 367
 368                Next_Rep_Item (Ritem);
 369             end loop;
 370          end;
 371       end if;
 372
 373       --  Processing for objects with address clauses
 374
 375       if Is_Object (E) and then Present (Address_Clause (E)) then
 376          Apply_Address_Clause_Check (E, N);
 377          return;
 378
 379       --  Only other items requiring any front end action are types and
 380       --  subprograms.
 381
 382       elsif not Is_Type (E) and then not Is_Subprogram (E) then
 383          return;
 384       end if;
 385
 386       --  Here E is a type or a subprogram
 387
 388       E_Scope := Scope (E);
 389
 390       --  This is an error protection against previous errors
 391
 392       if No (E_Scope) then
 393          Check_Error_Detected;
 394          return;
 395       end if;
 396
 397       --  Remember that we are processing a freezing entity and its freezing
 398       --  nodes. This flag (non-zero = set) is used to avoid the need of
 399       --  climbing through the tree while processing the freezing actions (ie.
 400       --  to avoid generating spurious warnings or to avoid killing constant
 401       --  indications while processing the code associated with freezing
 402       --  actions). We use a counter to deal with nesting.
 403
 404       Inside_Freezing_Actions := Inside_Freezing_Actions + 1;
 405
 406       --  If we are freezing entities defined in protected types, they belong
 407       --  in the enclosing scope, given that the original type has been
 408       --  expanded away. The same is true for entities in task types, in
 409       --  particular the parameter records of entries (Entities in bodies are
 410       --  all frozen within the body). If we are in the task body, this is a
 411       --  proper scope. If we are within a subprogram body, the proper scope
 412       --  is the corresponding spec. This may happen for itypes generated in
 413       --  the bodies of protected operations.
 414
 415       if Ekind (E_Scope) = E_Protected_Type
 416         or else (Ekind (E_Scope) = E_Task_Type
 417                   and then not Has_Completion (E_Scope))
 418       then
 419          E_Scope := Scope (E_Scope);
 420
 421       elsif Ekind (E_Scope) = E_Subprogram_Body then
 422          E_Scope := Corresponding_Spec (Unit_Declaration_Node (E_Scope));
 423       end if;
 424
 425       --  If the scope of the entity is in open scopes, it is the current one
 426       --  or an enclosing one, including a loop, a block, or a subprogram.
 427
 428       if In_Open_Scopes (E_Scope) then
 429          In_Other_Scope := False;
 430          In_Outer_Scope := E_Scope /= Current_Scope;
 431
 432       --  Otherwise it is a local package or a different compilation unit
 433
 434       else
 435          In_Other_Scope := True;
 436          In_Outer_Scope := False;
 437       end if;
 438
 439       --  If the entity being frozen is defined in a scope that is not
 440       --  currently on the scope stack, we must establish the proper
 441       --  visibility before freezing the entity and related subprograms.
 442
 443       if In_Other_Scope then
 444          Push_Scope (E_Scope);
 445
 446          --  Finalizers are little odd in terms of freezing. The spec of the
 447          --  procedure appears in the declarations while the body appears in
 448          --  the statement part of a single construct. Since the finalizer must
 449          --  be called by the At_End handler of the construct, the spec is
 450          --  manually frozen right after its declaration. The only side effect
 451          --  of this action appears in contexts where the construct is not in
 452          --  its final resting place. These contexts are:
 453
 454          --    * Entry bodies - The declarations and statements are moved to
 455          --      the procedure equivalen of the entry.
 456          --    * Protected subprograms - The declarations and statements are
 457          --      moved to the non-protected version of the subprogram.
 458          --    * Task bodies - The declarations and statements are moved to the
 459          --      task body procedure.
 460
 461          --  Visible declarations do not need to be installed in these three
 462          --  cases since it does not make semantic sense to do so. All entities
 463          --  referenced by a finalizer are visible and already resolved, plus
 464          --  the enclosing scope may not have visible declarations at all.
 465
 466          if Ekind (E) = E_Procedure
 467            and then Is_Finalizer (E)
 468            and then
 469              (Is_Entry (E_Scope)
 470                 or else (Is_Subprogram (E_Scope)
 471                            and then Is_Protected_Type (Scope (E_Scope)))
 472                 or else Is_Task_Type (E_Scope))
 473          then
 474             null;
 475          else
 476             Install_Visible_Declarations (E_Scope);
 477          end if;
 478
 479          if Is_Package_Or_Generic_Package (E_Scope) or else
 480             Is_Protected_Type (E_Scope)             or else
 481             Is_Task_Type (E_Scope)
 482          then
 483             Install_Private_Declarations (E_Scope);
 484          end if;
 485
 486       --  If the entity is in an outer scope, then that scope needs to
 487       --  temporarily become the current scope so that operations created
 488       --  during type freezing will be declared in the right scope and
 489       --  can properly override any corresponding inherited operations.
 490
 491       elsif In_Outer_Scope then
 492          Push_Scope (E_Scope);
 493       end if;
 494
 495       --  If type, freeze the type
 496
 497       if Is_Type (E) then
 498          Delete := Freeze_Type (N);
 499
 500          --  And for enumeration type, build the enumeration tables
 501
 502          if Is_Enumeration_Type (E) then
 503             Build_Enumeration_Image_Tables (E, N);
 504          end if;
 505
 506       --  If subprogram, freeze the subprogram
 507
 508       elsif Is_Subprogram (E) then
 509          Freeze_Subprogram (N);
 510
 511          --  Ada 2005 (AI-251): Remove the freezing node associated with the
 512          --  entities internally used by the frontend to register primitives
 513          --  covering abstract interfaces. The call to Freeze_Subprogram has
 514          --  already expanded the code that fills the corresponding entry in
 515          --  its secondary dispatch table and therefore the code generator
 516          --  has nothing else to do with this freezing node.
 517
 518          Delete := Present (Interface_Alias (E));
 519       end if;
 520
 521       --  Analyze actions generated by freezing. The init_proc contains source
 522       --  expressions that may raise Constraint_Error, and the assignment
 523       --  procedure for complex types needs checks on individual component
 524       --  assignments, but all other freezing actions should be compiled with
 525       --  all checks off.
 526
 527       if Present (Actions (N)) then
 528          Decl := First (Actions (N));
 529          while Present (Decl) loop
 530             if Nkind (Decl) = N_Subprogram_Body
 531               and then (Is_Init_Proc (Defining_Entity (Decl))
 532                           or else
 533                             Chars (Defining_Entity (Decl)) = Name_uAssign)
 534             then
 535                Analyze (Decl);
 536
 537             --  A subprogram body created for a renaming_as_body completes
 538             --  a previous declaration, which may be in a different scope.
 539             --  Establish the proper scope before analysis.
 540
 541             elsif Nkind (Decl) = N_Subprogram_Body
 542               and then Present (Corresponding_Spec (Decl))
 543               and then Scope (Corresponding_Spec (Decl)) /= Current_Scope
 544             then
 545                Push_Scope (Scope (Corresponding_Spec (Decl)));
 546                Analyze (Decl, Suppress => All_Checks);
 547                Pop_Scope;
 548
 549             --  We treat generated equality specially, if validity checks are
 550             --  enabled, in order to detect components default-initialized
 551             --  with invalid values.
 552
 553             elsif Nkind (Decl) = N_Subprogram_Body
 554               and then Chars (Defining_Entity (Decl)) = Name_Op_Eq
 555               and then Validity_Checks_On
 556               and then Initialize_Scalars
 557             then
 558                declare
 559                   Save_Force : constant Boolean := Force_Validity_Checks;
 560                begin
 561                   Force_Validity_Checks := True;
 562                   Analyze (Decl);
 563                   Force_Validity_Checks := Save_Force;
 564                end;
 565
 566             --  All other freezing actions
 567
 568             else
 569                Analyze (Decl, Suppress => All_Checks);
 570             end if;
 571
 572             Next (Decl);
 573          end loop;
 574       end if;
 575
 576       --  If we are to delete this N_Freeze_Entity, do so by rewriting so that
 577       --  a loop on all nodes being inserted will work propertly.
 578
 579       if Delete then
 580          Rewrite (N, Make_Null_Statement (Sloc (N)));
 581       end if;
 582
 583       --  Pop scope if we installed one for the analysis
 584
 585       if In_Other_Scope then
 586          if Ekind (Current_Scope) = E_Package then
 587             End_Package_Scope (E_Scope);
 588          else
 589             End_Scope;
 590          end if;
 591
 592       elsif In_Outer_Scope then
 593          Pop_Scope;
 594       end if;
 595
 596       --  Restore previous value of the nesting-level counter that records
 597       --  whether we are inside a (possibly nested) call to this procedure.
 598
 599       Inside_Freezing_Actions := Inside_Freezing_Actions - 1;
 600    end Expand_N_Freeze_Entity;
 601
 602    -------------------------------------------
 603    -- Expand_N_Record_Representation_Clause --
 604    -------------------------------------------
 605
 606    --  The only expansion required is for the case of a mod clause present,
 607    --  which is removed, and translated into an alignment representation
 608    --  clause inserted immediately after the record rep clause with any
 609    --  initial pragmas inserted at the start of the component clause list.
 610
 611    procedure Expand_N_Record_Representation_Clause (N : Node_Id) is
 612       Loc     : constant Source_Ptr := Sloc (N);
 613       Rectype : constant Entity_Id  := Entity (Identifier (N));
 614       Mod_Val : Uint;
 615       Citems  : List_Id;
 616       Repitem : Node_Id;
 617       AtM_Nod : Node_Id;
 618
 619    begin
 620       if Present (Mod_Clause (N)) and then not Ignore_Rep_Clauses then
 621          Mod_Val := Expr_Value (Expression (Mod_Clause (N)));
 622          Citems  := Pragmas_Before (Mod_Clause (N));
 623
 624          if Present (Citems) then
 625             Append_List_To (Citems, Component_Clauses (N));
 626             Set_Component_Clauses (N, Citems);
 627          end if;
 628
 629          AtM_Nod :=
 630            Make_Attribute_Definition_Clause (Loc,
 631              Name       => New_Reference_To (Base_Type (Rectype), Loc),
 632              Chars      => Name_Alignment,
 633              Expression => Make_Integer_Literal (Loc, Mod_Val));
 634
 635          Set_From_At_Mod (AtM_Nod);
 636          Insert_After (N, AtM_Nod);
 637          Set_Mod_Clause (N, Empty);
 638       end if;
 639
 640       --  If the record representation clause has no components, then
 641       --  completely remove it.  Note that we also have to remove
 642       --  ourself from the Rep Item list.
 643
 644       if Is_Empty_List (Component_Clauses (N)) then
 645          if First_Rep_Item (Rectype) = N then
 646             Set_First_Rep_Item (Rectype, Next_Rep_Item (N));
 647          else
 648             Repitem := First_Rep_Item (Rectype);
 649             while Present (Next_Rep_Item (Repitem)) loop
 650                if Next_Rep_Item (Repitem) = N then
 651                   Set_Next_Rep_Item (Repitem, Next_Rep_Item (N));
 652                   exit;
 653                end if;
 654
 655                Next_Rep_Item (Repitem);
 656             end loop;
 657          end if;
 658
 659          Rewrite (N,
 660            Make_Null_Statement (Loc));
 661       end if;
 662    end Expand_N_Record_Representation_Clause;
 663
 664 end Exp_Ch13;