gcc/ada/a-cfhama.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --    A D A . C O N T A I N E R S . F O R M A L _ H A S H E D _ M A P S     --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This spec is derived from package Ada.Containers.Bounded_Hashed_Maps in the
  33 --  Ada 2012 RM. The modifications are meant to facilitate formal proofs by
  34 --  making it easier to express properties, and by making the specification of
  35 --  this unit compatible with SPARK 2014. Note that the API of this unit may be
  36 --  subject to incompatible changes as SPARK 2014 evolves.
  37
  38 --  The modifications are:
  39
  40 --    A parameter for the container is added to every function reading the
  41 --    contents of a container: Key, Element, Next, Query_Element, Has_Element,
  42 --    Iterate, Equivalent_Keys. This change is motivated by the need to have
  43 --    cursors which are valid on different containers (typically a container C
  44 --    and its previous version C'Old) for expressing properties, which is not
  45 --    possible if cursors encapsulate an access to the underlying container.
  46
  47 --    There are four new functions:
  48
  49 --      function Strict_Equal (Left, Right : Map) return Boolean;
  50 --      function Overlap (Left, Right : Map) return Boolean;
  51 --      function Left  (Container : Map; Position : Cursor) return Map;
  52 --      function Right (Container : Map; Position : Cursor) return Map;
  53
  54 --    See detailed specifications for these subprograms
  55
  56 private with Ada.Containers.Hash_Tables;
  57
  58 generic
  59    type Key_Type is private;
  60    type Element_Type is private;
  61
  62    with function Hash (Key : Key_Type) return Hash_Type;
  63    with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  64    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  65
  66 package Ada.Containers.Formal_Hashed_Maps is
  67    pragma Pure;
  68
  69    type Map (Capacity : Count_Type; Modulus : Hash_Type) is private;
  70    pragma Preelaborable_Initialization (Map);
  71
  72    type Cursor is private;
  73    pragma Preelaborable_Initialization (Cursor);
  74
  75    Empty_Map : constant Map;
  76
  77    No_Element : constant Cursor;
  78
  79    function "=" (Left, Right : Map) return Boolean;
  80
  81    function Capacity (Container : Map) return Count_Type;
  82
  83    procedure Reserve_Capacity
  84      (Container : in out Map;
  85       Capacity  : Count_Type)
  86    with
  87      Pre => Capacity <= Container.Capacity;
  88
  89    function Length (Container : Map) return Count_Type;
  90
  91    function Is_Empty (Container : Map) return Boolean;
  92
  93    procedure Clear (Container : in out Map);
  94
  95    procedure Assign (Target : in out Map; Source : Map) with
  96      Pre => Target.Capacity >= Length (Source);
  97
  98    function Copy
  99      (Source   : Map;
 100       Capacity : Count_Type := 0) return Map
 101    with
 102      Pre => Capacity >= Source.Capacity;
 103    --  Copy returns a container stricty equal to Source. It must have
 104    --  the same cursors associated with each element. Therefore:
 105    --  - capacity=0 means use container.capacity as capacity of target
 106    --  - the modulus cannot be changed.
 107
 108    function Key (Container : Map; Position : Cursor) return Key_Type with
 109      Pre => Has_Element (Container, Position);
 110
 111    function Element
 112      (Container : Map;
 113       Position  : Cursor) return Element_Type
 114    with
 115      Pre => Has_Element (Container, Position);
 116
 117    procedure Replace_Element
 118      (Container : in out Map;
 119       Position  : Cursor;
 120       New_Item  : Element_Type)
 121    with
 122      Pre => Has_Element (Container, Position);
 123
 124    procedure Move (Target : in out Map; Source : in out Map) with
 125      Pre => Target.Capacity >= Length (Source);
 126
 127    procedure Insert
 128      (Container : in out Map;
 129       Key       : Key_Type;
 130       New_Item  : Element_Type;
 131       Position  : out Cursor;
 132       Inserted  : out Boolean)
 133    with
 134      Pre => Length (Container) < Container.Capacity;
 135
 136    procedure Insert
 137      (Container : in out Map;
 138       Key       : Key_Type;
 139       New_Item  : Element_Type)
 140    with
 141      Pre => Length (Container) < Container.Capacity
 142               and then (not Contains (Container, Key));
 143
 144    procedure Include
 145      (Container : in out Map;
 146       Key       : Key_Type;
 147       New_Item  : Element_Type)
 148    with
 149      Pre => Length (Container) < Container.Capacity;
 150
 151    procedure Replace
 152      (Container : in out Map;
 153       Key       : Key_Type;
 154       New_Item  : Element_Type)
 155    with
 156      Pre => Contains (Container, Key);
 157
 158    procedure Exclude (Container : in out Map; Key : Key_Type);
 159
 160    procedure Delete (Container : in out Map; Key : Key_Type) with
 161      Pre => Contains (Container, Key);
 162
 163    procedure Delete (Container : in out Map; Position : in out Cursor) with
 164      Pre => Has_Element (Container, Position);
 165
 166    function First (Container : Map) return Cursor;
 167
 168    function Next (Container : Map; Position : Cursor) return Cursor with
 169      Pre => Has_Element (Container, Position) or else Position = No_Element;
 170
 171    procedure Next (Container : Map; Position : in out Cursor) with
 172      Pre => Has_Element (Container, Position) or else Position = No_Element;
 173
 174    function Find (Container : Map; Key : Key_Type) return Cursor;
 175
 176    function Contains (Container : Map; Key : Key_Type) return Boolean;
 177
 178    function Element (Container : Map; Key : Key_Type) return Element_Type with
 179      Pre => Contains (Container, Key);
 180
 181    function Has_Element (Container : Map; Position : Cursor) return Boolean;
 182
 183    function Equivalent_Keys
 184      (Left   : Map;
 185       CLeft  : Cursor;
 186       Right  : Map;
 187       CRight : Cursor) return Boolean;
 188
 189    function Equivalent_Keys
 190      (Left  : Map;
 191       CLeft : Cursor;
 192       Right : Key_Type) return Boolean;
 193
 194    function Equivalent_Keys
 195      (Left   : Key_Type;
 196       Right  : Map;
 197       CRight : Cursor) return Boolean;
 198
 199    function Default_Modulus (Capacity : Count_Type) return Hash_Type;
 200
 201    function Strict_Equal (Left, Right : Map) return Boolean;
 202    --  Strict_Equal returns True if the containers are physically equal, i.e.
 203    --  they are structurally equal (function "=" returns True) and that they
 204    --  have the same set of cursors.
 205
 206    function Left  (Container : Map; Position : Cursor) return Map with
 207      Pre => Has_Element (Container, Position) or else Position = No_Element;
 208    function Right (Container : Map; Position : Cursor) return Map with
 209      Pre => Has_Element (Container, Position) or else Position = No_Element;
 210    --  Left returns a container containing all elements preceding Position
 211    --  (excluded) in Container. Right returns a container containing all
 212    --  elements following Position (included) in Container. These two new
 213    --  functions can be used to express invariant properties in loops which
 214    --  iterate over containers. Left returns the part of the container already
 215    --  scanned and Right the part not scanned yet.
 216
 217    function Overlap (Left, Right : Map) return Boolean;
 218    --  Overlap returns True if the containers have common keys
 219
 220 private
 221    pragma Inline (Length);
 222    pragma Inline (Is_Empty);
 223    pragma Inline (Clear);
 224    pragma Inline (Key);
 225    pragma Inline (Element);
 226    pragma Inline (Contains);
 227    pragma Inline (Capacity);
 228    pragma Inline (Has_Element);
 229    pragma Inline (Equivalent_Keys);
 230    pragma Inline (Next);
 231
 232    type Node_Type is record
 233       Key         : Key_Type;
 234       Element     : Element_Type;
 235       Next        : Count_Type;
 236       Has_Element : Boolean := False;
 237    end record;
 238
 239    package HT_Types is new
 240      Ada.Containers.Hash_Tables.Generic_Bounded_Hash_Table_Types
 241        (Node_Type);
 242
 243    type Map (Capacity : Count_Type; Modulus : Hash_Type) is
 244       new HT_Types.Hash_Table_Type (Capacity, Modulus) with null record;
 245
 246    use HT_Types;
 247
 248    type Cursor is record
 249       Node : Count_Type;
 250    end record;
 251
 252    Empty_Map : constant Map := (Capacity => 0, Modulus => 0, others => <>);
 253
 254    No_Element : constant Cursor := (Node => 0);
 255
 256 end Ada.Containers.Formal_Hashed_Maps;