libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 # We may wish to install the target headers somewhere.
 132 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 133 dnl install-libiberty is disabled by default
 134
 135 AC_ARG_ENABLE(install-libiberty,
 136 [  --enable-install-libiberty       Install headers and library for end users],
 137 enable_install_libiberty=$enableval,
 138 enable_install_libiberty=no)dnl
 139
 140 # Option parsed, now set things appropriately.
 141 case x"$enable_install_libiberty" in
 142   xyes|x)
 143     target_header_dir=libiberty
 144     ;;
 145   xno)
 146     target_header_dir=
 147     ;;
 148   *)
 149     # This could be sanity-checked in various ways...
 150     target_header_dir="${enable_install_libiberty}"
 151     ;;
 152 esac
 153 AC_MSG_RESULT($enable_install_libiberty)
 154 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 155
 156 GCC_NO_EXECUTABLES
 157 AC_PROG_CC
 158 AC_SYS_LARGEFILE
 159 AC_PROG_CPP_WERROR
 160
 161 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 162                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 163 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 164
 165 AC_PROG_CC_C_O
 166 # autoconf is lame and doesn't give us any substitution variable for this.
 167 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 168   NO_MINUS_C_MINUS_O=yes
 169 else
 170   OUTPUT_OPTION='-o $@'
 171 fi
 172 AC_SUBST(NO_MINUS_C_MINUS_O)
 173 AC_SUBST(OUTPUT_OPTION)
 174
 175 AC_C_CONST
 176 AC_C_INLINE
 177 AC_C_BIGENDIAN
 178
 179 dnl When we start using libtool:
 180 dnl Default to a non shared library.  This may be overridden by the
 181 dnl configure option --enable-shared.
 182 dnl AM_DISABLE_SHARED
 183
 184 dnl When we start using libtool:
 185 dnl AM_PROG_LIBTOOL
 186
 187 dnl When we start using automake:
 188 dnl AM_CONFIG_HEADER(config.h:config.in)
 189 AC_CONFIG_HEADER(config.h:config.in)
 190
 191 dnl When we start using automake:
 192 dnl AM_MAINTAINER_MODE
 193 dnl AC_EXEEXT
 194
 195 dnl When we start using automake:
 196 dnl AM_PROG_INSTALL
 197 AC_PROG_INSTALL
 198
 199 # Don't build the shared library for build.
 200 if [[ -n "${with_build_subdir}" ]]; then
 201   enable_shared=no
 202 fi
 203
 204 frag=
 205 case "${host}" in
 206   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 207                         frag=mh-aix ;;
 208   *-*-cxux7*)           frag=mh-cxux7 ;;
 209   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 210   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 211   i370-*-opened*)       frag=mh-openedition ;;
 212   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 213 esac
 214
 215 if [[ -n "${frag}" ]]; then
 216   frag=${libiberty_topdir}/libiberty/config/$frag
 217 fi
 218
 219 GCC_PICFLAG
 220
 221 # If they didn't specify --enable-shared, don't generate shared libs.
 222 case "${enable_shared}" in
 223   yes) shared=yes ;;
 224   no) shared=no ;;
 225   "") shared=no ;;
 226   *) shared=yes ;;
 227 esac
 228 if [[ "${shared}" != "yes" ]]; then
 229   PICFLAG=
 230 fi
 231 AC_SUBST(PICFLAG)
 232
 233 echo "# Warning: this fragment is automatically generated" > temp-frag
 234
 235 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 236   echo "Appending ${frag} to xhost-mkfrag"
 237   echo "# Following fragment copied from ${frag}" >> temp-frag
 238   cat ${frag} >> temp-frag
 239 fi
 240
 241 # record if we want to build shared libs.
 242 if [[ "${shared}" = "yes" ]]; then
 243   echo enable_shared = yes >> temp-frag
 244 else
 245   echo enable_shared = no >> temp-frag
 246 fi
 247
 248 frag=xhost-mkfrag
 249 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 250
 251 host_makefile_frag=${frag}
 252 AC_SUBST_FILE(host_makefile_frag)
 253
 254 # It's OK to check for header files.  Although the compiler may not be
 255 # able to link anything, it had better be able to at least compile
 256 # something.
 257 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 258 AC_HEADER_SYS_WAIT
 259 AC_HEADER_TIME
 260
 261 libiberty_AC_DECLARE_ERRNO
 262
 263 # Determine the size of an int for struct fibnode.
 264 AC_CHECK_SIZEOF([int])
 265
 266 # Look for a 64-bit type.
 267 AC_MSG_CHECKING([for a 64-bit type])
 268 AC_CACHE_VAL(liberty_cv_uint64,
 269 [AC_TRY_COMPILE(
 270 [#ifdef HAVE_STDINT_H
 271 #include <stdint.h>
 272 #endif],
 273 [extern uint64_t foo;],
 274 liberty_cv_uint64=uint64_t,
 275 [AC_TRY_COMPILE(
 276 [#ifdef HAVE_LIMITS_H
 277 #include <limits.h>
 278 #endif
 279 #ifndef CHAR_BIT
 280 #define CHAR_BIT 8
 281 #endif],
 282 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 283 liberty_cv_uint64="unsigned long",
 284 [AC_TRY_COMPILE(
 285 [#ifdef HAVE_LIMITS_H
 286 #include <limits.h>
 287 #endif
 288 #ifndef CHAR_BIT
 289 #define CHAR_BIT 8
 290 #endif],
 291 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 292 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 293 AC_MSG_RESULT($liberty_cv_uint64)
 294 if test "$liberty_cv_uint64" != none; then
 295   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 296                      [Define to an unsigned 64-bit type available in the compiler.])
 297 fi
 298
 299 AC_TYPE_INTPTR_T
 300 AC_TYPE_UINTPTR_T
 301 AC_TYPE_SSIZE_T
 302
 303 # Given the above check, we always have uintptr_t or a fallback
 304 # definition.  So define HAVE_UINTPTR_T in case any imported code
 305 # relies on it.
 306 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 307
 308 AC_TYPE_PID_T
 309
 310 # This is the list of functions which libiberty will provide if they
 311 # are not available on the host.
 312
 313 funcs="asprintf"
 314 funcs="$funcs atexit"
 315 funcs="$funcs basename"
 316 funcs="$funcs bcmp"
 317 funcs="$funcs bcopy"
 318 funcs="$funcs bsearch"
 319 funcs="$funcs bzero"
 320 funcs="$funcs calloc"
 321 funcs="$funcs clock"
 322 funcs="$funcs ffs"
 323 funcs="$funcs getcwd"
 324 funcs="$funcs getpagesize"
 325 funcs="$funcs gettimeofday"
 326 funcs="$funcs index"
 327 funcs="$funcs insque"
 328 funcs="$funcs memchr"
 329 funcs="$funcs memcmp"
 330 funcs="$funcs memcpy"
 331 funcs="$funcs memmem"
 332 funcs="$funcs memmove"
 333 funcs="$funcs mempcpy"
 334 funcs="$funcs memset"
 335 funcs="$funcs mkstemps"
 336 funcs="$funcs putenv"
 337 funcs="$funcs random"
 338 funcs="$funcs rename"
 339 funcs="$funcs rindex"
 340 funcs="$funcs setenv"
 341 funcs="$funcs snprintf"
 342 funcs="$funcs sigsetmask"
 343 funcs="$funcs stpcpy"
 344 funcs="$funcs stpncpy"
 345 funcs="$funcs strcasecmp"
 346 funcs="$funcs strchr"
 347 funcs="$funcs strdup"
 348 funcs="$funcs strncasecmp"
 349 funcs="$funcs strndup"
 350 funcs="$funcs strnlen"
 351 funcs="$funcs strrchr"
 352 funcs="$funcs strstr"
 353 funcs="$funcs strtod"
 354 funcs="$funcs strtol"
 355 funcs="$funcs strtoul"
 356 funcs="$funcs strverscmp"
 357 funcs="$funcs tmpnam"
 358 funcs="$funcs vasprintf"
 359 funcs="$funcs vfprintf"
 360 funcs="$funcs vprintf"
 361 funcs="$funcs vsnprintf"
 362 funcs="$funcs vsprintf"
 363 funcs="$funcs waitpid"
 364 funcs="$funcs setproctitle"
 365
 366 # Also in the old function.def file: alloca, vfork, getopt.
 367
 368 vars="sys_errlist sys_nerr sys_siglist"
 369
 370 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 371  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 372  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 373  sysmp table times wait3 wait4"
 374
 375 # These are neither executed nor required, but they help keep
 376 # autoheader happy without adding a bunch of text to acconfig.h.
 377 if test "x" = "y"; then
 378   AC_CHECK_FUNCS(asprintf atexit \
 379     basename bcmp bcopy bsearch bzero \
 380     calloc canonicalize_file_name clock \
 381     dup3 \
 382     ffs __fsetlocking \
 383     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 384     index insque \
 385     memchr memcmp memcpy memmem memmove memset mkstemps \
 386     on_exit \
 387     psignal pstat_getdynamic pstat_getstatic putenv \
 388     random realpath rename rindex \
 389     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 390      stpcpy stpncpy strcasecmp strchr strdup \
 391      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 392      strtol strtoul strverscmp sysconf sysctl sysmp \
 393     table times tmpnam \
 394     vasprintf vfprintf vprintf vsprintf \
 395     wait3 wait4 waitpid)
 396   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 397   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 398   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 399   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 400 fi
 401
 402 # For each of these functions, if the host does not provide the
 403 # function we want to put FN.o in LIBOBJS, and if the host does
 404 # provide the function, we want to define HAVE_FN in config.h.
 405
 406 setobjs=
 407 CHECK=
 408 target_header_dir=
 409 if test -n "${with_target_subdir}"; then
 410
 411   # We are being configured as a target library.  AC_REPLACE_FUNCS
 412   # may not work correctly, because the compiler may not be able to
 413   # link executables.  Note that we may still be being configured
 414   # native.
 415
 416   # If we are being configured for newlib, we know which functions
 417   # newlib provide and which ones we will be expected to provide.
 418
 419   if test "x${with_newlib}" = "xyes"; then
 420     AC_LIBOBJ([asprintf])
 421     AC_LIBOBJ([basename])
 422     AC_LIBOBJ([insque])
 423     AC_LIBOBJ([random])
 424     AC_LIBOBJ([strdup])
 425     AC_LIBOBJ([vasprintf])
 426
 427     for f in $funcs; do
 428       case "$f" in
 429         asprintf | basename | insque | random | strdup | vasprintf)
 430           ;;
 431         *)
 432           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 433           AC_DEFINE_UNQUOTED($n)
 434           ;;
 435       esac
 436     done
 437
 438     # newlib doesnt provide any of the variables in $vars, so we
 439     # dont have to check them here.
 440
 441     # Of the functions in $checkfuncs, newlib only has strerror.
 442     AC_DEFINE(HAVE_STRERROR)
 443
 444     setobjs=yes
 445
 446   fi
 447
 448   # If we are being configured for Mingw, we know which functions
 449   # Mingw provides and which ones we will be expected to provide.
 450
 451   case "${host}" in
 452   *-*-mingw*)
 453     AC_LIBOBJ([asprintf])
 454     AC_LIBOBJ([basename])
 455     AC_LIBOBJ([bcmp])
 456     AC_LIBOBJ([bcopy])
 457     AC_LIBOBJ([bzero])
 458     AC_LIBOBJ([clock])
 459     AC_LIBOBJ([ffs])
 460     AC_LIBOBJ([getpagesize])
 461     AC_LIBOBJ([index])
 462     AC_LIBOBJ([insque])
 463     AC_LIBOBJ([mempcpy])
 464     AC_LIBOBJ([mkstemps])
 465     AC_LIBOBJ([random])
 466     AC_LIBOBJ([rindex])
 467     AC_LIBOBJ([sigsetmask])
 468     AC_LIBOBJ([stpcpy])
 469     AC_LIBOBJ([stpncpy])
 470     AC_LIBOBJ([strndup])
 471     AC_LIBOBJ([strnlen])
 472     AC_LIBOBJ([strverscmp])
 473     AC_LIBOBJ([vasprintf])
 474     AC_LIBOBJ([waitpid])
 475
 476     for f in $funcs; do
 477       case "$f" in
 478         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 479           ;;
 480         *)
 481           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 482           AC_DEFINE_UNQUOTED($n)
 483           ;;
 484       esac
 485     done
 486
 487     # Mingw doesnt provide any of the variables in $vars, so we
 488     # dont have to check them here.
 489
 490     # Of the functions in $checkfuncs, Mingw only has strerror.
 491     AC_DEFINE(HAVE_STRERROR)
 492
 493     setobjs=yes
 494     ;;
 495
 496   *-*-msdosdjgpp)
 497     AC_LIBOBJ([vasprintf])
 498     AC_LIBOBJ([vsnprintf])
 499     AC_LIBOBJ([snprintf])
 500     AC_LIBOBJ([asprintf])
 501
 502     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 503              getcwd getpagesize getrusage gettimeofday \
 504              index insque memchr memcmp memcpy memmove memset psignal \
 505              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 506              strchr strdup strerror strncasecmp strrchr strstr strtod \
 507              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 508              vsprintf waitpid
 509     do
 510       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 511       AC_DEFINE_UNQUOTED($n)
 512     done
 513
 514
 515     setobjs=yes
 516     ;;
 517
 518   esac
 519
 520 else
 521
 522    # Not a target library, so we set things up to run the test suite.
 523    CHECK=really-check
 524
 525 fi
 526
 527 AC_SUBST(CHECK)
 528 AC_SUBST(target_header_dir)
 529
 530 case "${host}" in
 531   *-*-cygwin* | *-*-mingw*)
 532     AC_DEFINE(HAVE_SYS_ERRLIST)
 533     AC_DEFINE(HAVE_SYS_NERR)
 534     ;;
 535 esac
 536
 537 if test -z "${setobjs}"; then
 538   case "${host}" in
 539
 540   *-*-vxworks*)
 541     # Handle VxWorks configuration specially, since on VxWorks the
 542     # libraries are actually on the target board, not in the file
 543     # system.
 544     AC_LIBOBJ([basename])
 545     AC_LIBOBJ([getpagesize])
 546     AC_LIBOBJ([insque])
 547     AC_LIBOBJ([random])
 548     AC_LIBOBJ([strcasecmp])
 549     AC_LIBOBJ([strncasecmp])
 550     AC_LIBOBJ([strdup])
 551     AC_LIBOBJ([vfork])
 552     AC_LIBOBJ([waitpid])
 553     AC_LIBOBJ([vasprintf])
 554     for f in $funcs; do
 555       case "$f" in
 556         basename | getpagesize | insque | random | strcasecmp)
 557           ;;
 558         strncasecmp | strdup | vfork | waitpid | vasprintf)
 559           ;;
 560         *)
 561           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 562           AC_DEFINE_UNQUOTED($n)
 563           ;;
 564       esac
 565     done
 566
 567     # VxWorks doesn't provide any of the variables in $vars, so we
 568     # don't have to check them here.
 569
 570     # Of the functions in $checkfuncs, VxWorks only has strerror.
 571     AC_DEFINE(HAVE_STRERROR)
 572
 573     setobjs=yes
 574     ;;
 575
 576   esac
 577 fi
 578
 579 if test -z "${setobjs}"; then
 580
 581   case "${host}" in
 582
 583   *-*-mingw32*)
 584     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 585     # macros, so the test below won't find them.
 586     libiberty_cv_var_sys_nerr=yes
 587     libiberty_cv_var_sys_errlist=yes
 588     ;;
 589
 590   *-*-msdosdjgpp*)
 591     # vfork and fork are stubs.
 592     ac_cv_func_vfork_works=no
 593     ;;
 594
 595   *-*-uwin*)
 596     # Under some versions of uwin, vfork is notoriously buggy and the test
 597     # can hang configure; on other versions, vfork exists just as a stub.
 598     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 599     ac_cv_func_vfork_works=no
 600     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 601     # macros (actually, these are imported from a DLL, but the end effect
 602     # is the same), so the test below won't find them.
 603     libiberty_cv_var_sys_nerr=yes
 604     libiberty_cv_var_sys_errlist=yes
 605     ;;
 606
 607   *-*-*vms*)
 608     # Under VMS, vfork works very different than on Unix. The standard test
 609     # won't work, and it isn't easily adaptable. It makes more sense to
 610     # just force it.
 611     ac_cv_func_vfork_works=yes
 612     ;;
 613
 614   esac
 615
 616   # We haven't set the list of objects yet.  Use the standard autoconf
 617   # tests.  This will only work if the compiler works.
 618   AC_ISC_POSIX
 619   AC_REPLACE_FUNCS($funcs)
 620   libiberty_AC_FUNC_C_ALLOCA
 621   AC_FUNC_FORK
 622   if test $ac_cv_func_vfork_works = no; then
 623     AC_LIBOBJ([vfork])
 624   fi
 625   # We only need _doprnt if we might use it to implement v*printf.
 626   if test $ac_cv_func_vprintf != yes \
 627      || test $ac_cv_func_vfprintf != yes \
 628      || test $ac_cv_func_vsprintf != yes; then
 629     AC_REPLACE_FUNCS(_doprnt)
 630   else
 631     AC_CHECK_FUNCS(_doprnt)
 632   fi
 633
 634   for v in $vars; do
 635     AC_MSG_CHECKING([for $v])
 636     AC_CACHE_VAL(libiberty_cv_var_$v,
 637       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 638                       [eval "libiberty_cv_var_$v=yes"],
 639                       [eval "libiberty_cv_var_$v=no"])])
 640     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 641       AC_MSG_RESULT(yes)
 642       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 643       AC_DEFINE_UNQUOTED($n)
 644     else
 645       AC_MSG_RESULT(no)
 646     fi
 647   done
 648
 649   # special check for _system_configuration because AIX <4.3.2 do not
 650   # contain the `physmem' member.
 651   AC_MSG_CHECKING([for external symbol _system_configuration])
 652   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 653                         [[double x = _system_configuration.physmem;]])],
 654     [AC_MSG_RESULT([yes])
 655     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 656               [Define if you have the _system_configuration variable.])],
 657     [AC_MSG_RESULT([no])])
 658
 659   AC_CHECK_FUNCS($checkfuncs)
 660   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 661   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 662   AC_CHECK_DECLS([strverscmp])
 663   libiberty_NEED_DECLARATION(canonicalize_file_name)
 664 fi
 665
 666 # Figure out which version of pexecute to use.
 667 case "${host}" in
 668      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 669      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 670      *-*-msdos*)                pexecute=pex-msdos  ;;
 671      *)                         pexecute=pex-unix   ;;
 672 esac
 673 AC_SUBST(pexecute)
 674
 675 libiberty_AC_FUNC_STRNCMP
 676
 677 # Install a library built with a cross compiler in $(tooldir) rather
 678 # than $(libdir).
 679 if test -z "${with_cross_host}"; then
 680   INSTALL_DEST=libdir
 681 else
 682   INSTALL_DEST=tooldir
 683 fi
 684 AC_SUBST(INSTALL_DEST)
 685
 686 m4_pattern_allow(LIBOBJS)
 687 L=""
 688 for l in x $LIBOBJS; do
 689   case $l in
 690     x) ;;
 691     *) L="$L ./$l" ;;
 692   esac
 693 done
 694 LIBOBJS="$L"
 695
 696 dnl Required by html and install-html
 697 AC_SUBST(datarootdir)
 698 AC_SUBST(docdir)
 699 AC_SUBST(htmldir)
 700
 701 # We need multilib support, but only if configuring for the target.
 702 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 703 AC_CONFIG_COMMANDS([default],
 704   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 705 if test -n "$CONFIG_FILES"; then
 706   if test -n "${with_target_subdir}"; then
 707     # FIXME: We shouldn't need to set ac_file
 708     ac_file=Makefile
 709     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 710     . ${libiberty_topdir}/config-ml.in
 711   fi
 712 fi]],
 713 [[srcdir=${srcdir}
 714 host=${host}
 715 target=${target}
 716 with_target_subdir=${with_target_subdir}
 717 with_multisubdir=${with_multisubdir}
 718 ac_configure_args="--enable-multilib ${ac_configure_args}"
 719 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 720 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 721 libiberty_topdir=${libiberty_topdir}
 722 ]])
 723 AC_OUTPUT