gcc/ada/s-stalib.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --              S Y S T E M . S T A N D A R D _ L I B R A R Y               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2001 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package is included in all programs. It contains declarations that
  35 --  are required to be part of every Ada program. A special mechanism is
  36 --  required to ensure that these are loaded, since it may be the case in
  37 --  some programs that the only references to these required packages are
  38 --  from C code or from code generated directly by Gigi, an in both cases
  39 --  the binder is not aware of such references.
  40
  41 --  System.Standard_Library also includes data that must be present in every
  42 --  program, in particular the definitions of all the standard and also some
  43 --  subprograms that must be present in every program.
  44
  45 --  The binder unconditionally includes s-stalib.ali, which ensures that this
  46 --  package and the packages it references are included in all Ada programs,
  47 --  together with the included data.
  48
  49 pragma Polling (Off);
  50 --  We must turn polling off for this unit, because otherwise we get
  51 --  elaboration circularities with Ada.Exceptions if polling is on.
  52
  53 with System;
  54 with Unchecked_Conversion;
  55
  56 package System.Standard_Library is
  57
  58    pragma Suppress (All_Checks);
  59    --  Suppress explicitly all the checks to work around the Solaris linker
  60    --  bug when using gnatmake -f -a (but without -gnatp). This is not needed
  61    --  with Solaris 2.6, so eventually can be removed ???
  62
  63    type Big_String_Ptr is access all String (Positive);
  64    --  A non-fat pointer type for null terminated strings
  65
  66    function To_Ptr is
  67      new Unchecked_Conversion (System.Address, Big_String_Ptr);
  68
  69    ---------------------------------------------
  70    -- Type For Enumeration Image Index Tables --
  71    ---------------------------------------------
  72
  73    --  Note: these types are declared at the start of this unit, since
  74    --  they must appear before any enumeration types declared in this
  75    --  unit. Note that the spec of system is already elaborated at
  76    --  this point (since we are a child of system), which means that
  77    --  enumeration types in package System cannot use these types.
  78
  79    type Image_Index_Table_8 is
  80      array (Integer range <>) of Short_Short_Integer;
  81    type Image_Index_Table_16 is
  82      array (Integer range <>) of Short_Integer;
  83    type Image_Index_Table_32 is
  84      array (Integer range <>) of Integer;
  85    --  These types are used to generate the index vector used for enumeration
  86    --  type image tables. See spec of Exp_Imgv in the main GNAT sources for a
  87    --  full description of the data structures that are used here.
  88
  89    -------------------------------------
  90    -- Exception Declarations and Data --
  91    -------------------------------------
  92
  93    type Exception_Data;
  94    type Exception_Data_Ptr is access all Exception_Data;
  95    --  An equivalent of Exception_Id that is public
  96
  97    --  The following record defines the underlying representation of exceptions
  98
  99    --  WARNING! Any changes to this may need to be reflectd in the following
 100    --  locations in the compiler and runtime code:
 101
 102    --    1. The Internal_Exception routine in s-exctab.adb
 103    --    2. The processing in gigi that tests Not_Handled_By_Others
 104    --    3. Expand_N_Exception_Declaration in Exp_Ch11
 105    --    4. The construction of the exception type in Cstand
 106
 107    type Exception_Data is record
 108       Not_Handled_By_Others : Boolean;
 109       --  Normally set False, indicating that the exception is handled in the
 110       --  usual way by others (i.e. an others handler handles the exception).
 111       --  Set True to indicate that this exception is not caught by others
 112       --  handlers, but must be explicitly named in a handler. This latter
 113       --  setting is currently used by the Abort_Signal.
 114
 115       Lang : Character;
 116       --  A character indicating the language raising the exception.
 117       --  Set to "A" for exceptions defined by an Ada program.
 118       --  Set to "V" for imported VMS exceptions.
 119
 120       Name_Length : Natural;
 121       --  Length of fully expanded name of exception
 122
 123       Full_Name : Big_String_Ptr;
 124       --  Fully expanded name of exception, null terminated
 125
 126       HTable_Ptr : Exception_Data_Ptr;
 127       --  Hash table pointer used to link entries together in the hash table
 128       --  built (by Register_Exception in s-exctab.adb) for converting between
 129       --  identities and names.
 130
 131       Import_Code : Integer;
 132       --  Value for imported exceptions. Needed only for the handling of
 133       --  Import/Export_Exception for the VMS case, but present in all
 134       --  implementations (we might well extend this mechanism for other
 135       --  systems in the future).
 136
 137    end record;
 138
 139    --  Definitions for standard predefined exceptions defined in Standard,
 140
 141    --  Why are the Nul's necessary here, seems like they should not be
 142    --  required, since Gigi is supposed to add a Nul to each name ???
 143
 144    Constraint_Error_Name : constant String := "CONSTRAINT_ERROR" & ASCII.NUL;
 145    Program_Error_Name    : constant String := "PROGRAM_ERROR"    & ASCII.NUL;
 146    Storage_Error_Name    : constant String := "STORAGE_ERROR"    & ASCII.NUL;
 147    Tasking_Error_Name    : constant String := "TASKING_ERROR"    & ASCII.NUL;
 148    Abort_Signal_Name     : constant String := "_ABORT_SIGNAL"    & ASCII.NUL;
 149
 150    Numeric_Error_Name    : constant String := "NUMERIC_ERROR"    & ASCII.NUL;
 151    --  This is used only in the Ada 83 case, but it is not worth having a
 152    --  separate version of s-stalib.ads for use in Ada 83 mode.
 153
 154    Constraint_Error_Def : aliased Exception_Data :=
 155      (Not_Handled_By_Others => False,
 156       Lang                  => 'A',
 157       Name_Length           => Constraint_Error_Name'Length,
 158       Full_Name             => To_Ptr (Constraint_Error_Name'Address),
 159       HTable_Ptr            => null,
 160       Import_Code           => 0);
 161
 162    Numeric_Error_Def : aliased Exception_Data :=
 163      (Not_Handled_By_Others => False,
 164       Lang                  => 'A',
 165       Name_Length           => Numeric_Error_Name'Length,
 166       Full_Name             => To_Ptr (Numeric_Error_Name'Address),
 167       HTable_Ptr            => null,
 168       Import_Code           => 0);
 169
 170    Program_Error_Def : aliased Exception_Data :=
 171      (Not_Handled_By_Others => False,
 172       Lang                  => 'A',
 173       Name_Length           => Program_Error_Name'Length,
 174       Full_Name             => To_Ptr (Program_Error_Name'Address),
 175       HTable_Ptr            => null,
 176       Import_Code           => 0);
 177
 178    Storage_Error_Def : aliased Exception_Data :=
 179      (Not_Handled_By_Others => False,
 180       Lang                  => 'A',
 181       Name_Length           => Storage_Error_Name'Length,
 182       Full_Name             => To_Ptr (Storage_Error_Name'Address),
 183       HTable_Ptr            => null,
 184       Import_Code           => 0);
 185
 186    Tasking_Error_Def : aliased Exception_Data :=
 187      (Not_Handled_By_Others => False,
 188       Lang                  => 'A',
 189       Name_Length           => Tasking_Error_Name'Length,
 190       Full_Name             => To_Ptr (Tasking_Error_Name'Address),
 191       HTable_Ptr            => null,
 192       Import_Code           => 0);
 193
 194    Abort_Signal_Def : aliased Exception_Data :=
 195      (Not_Handled_By_Others => True,
 196       Lang                  => 'A',
 197       Name_Length           => Abort_Signal_Name'Length,
 198       Full_Name             => To_Ptr (Abort_Signal_Name'Address),
 199       HTable_Ptr            => null,
 200       Import_Code           => 0);
 201
 202    pragma Export (C, Constraint_Error_Def, "constraint_error");
 203    pragma Export (C, Numeric_Error_Def,    "numeric_error");
 204    pragma Export (C, Program_Error_Def,    "program_error");
 205    pragma Export (C, Storage_Error_Def,    "storage_error");
 206    pragma Export (C, Tasking_Error_Def,    "tasking_error");
 207    pragma Export (C, Abort_Signal_Def,     "_abort_signal");
 208
 209    Local_Partition_ID : Natural := 0;
 210    --  This variable contains the local Partition_ID that will be used when
 211    --  building exception occurrences. In distributed mode, it will be
 212    --  set by each partition to the correct value during the elaboration.
 213
 214    type Exception_Trace_Kind is
 215      (RM_Convention,
 216       --  No particular trace is requested, only unhandled exceptions
 217       --  in the environment task (following the RM) will be printed.
 218       --  This is the default behavior.
 219
 220       Every_Raise,
 221       --  Denotes every possible raise event, either explicit or due to
 222       --  a specific language rule, within the context of a task or not.
 223
 224       Unhandled_Raise
 225       --  Denotes the raise events corresponding to exceptions for which
 226       --  there is no user defined handler.
 227      );
 228    --  Provide a way to denote different kinds of automatic traces related
 229    --  to exceptions that can be requested.
 230
 231    Exception_Trace : Exception_Trace_Kind := RM_Convention;
 232    pragma Atomic (Exception_Trace);
 233    --  By default, follow the RM convention.
 234
 235    -----------------
 236    -- Subprograms --
 237    -----------------
 238
 239    procedure Abort_Undefer_Direct;
 240    pragma Inline (Abort_Undefer_Direct);
 241    --  A little procedure that just calls Abort_Undefer.all, for use in
 242    --  clean up procedures, which only permit a simple subprogram name.
 243
 244    procedure Adafinal;
 245    --  Performs the Ada Runtime finalization the first time it is invoked.
 246    --  All subsequent calls are ignored.
 247
 248 end System.Standard_Library;