gcc/ada/fname-uf.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             F N A M E . U F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Alloc;
  28 with Debug;    use Debug;
  29 with Fmap;     use Fmap;
  30 with Krunch;
  31 with Namet;    use Namet;
  32 with Opt;      use Opt;
  33 with Osint;    use Osint;
  34 with Table;
  35 with Widechar; use Widechar;
  36
  37 with GNAT.HTable;
  38
  39 package body Fname.UF is
  40
  41    --------------------------------------------------------
  42    -- Declarations for Handling Source_File_Name pragmas --
  43    --------------------------------------------------------
  44
  45    type SFN_Entry is record
  46       U : Unit_Name_Type; -- Unit name
  47       F : File_Name_Type; -- Spec/Body file name
  48    end record;
  49    --  Record single Unit_Name type call to Set_File_Name
  50
  51    package SFN_Table is new Table.Table (
  52      Table_Component_Type => SFN_Entry,
  53      Table_Index_Type     => Int,
  54      Table_Low_Bound      => 0,
  55      Table_Initial        => Alloc.SFN_Table_Initial,
  56      Table_Increment      => Alloc.SFN_Table_Increment,
  57      Table_Name           => "SFN_Table");
  58    --  Table recording all Unit_Name calls to Set_File_Name
  59
  60    type SFN_Header_Num is range 0 .. 100;
  61
  62    function SFN_Hash (F : Unit_Name_Type) return SFN_Header_Num;
  63    --  Compute hash index for use by Simple_HTable
  64
  65    No_Entry : constant Int := -1;
  66    --  Signals no entry in following table
  67
  68    package SFN_HTable is new GNAT.HTable.Simple_HTable (
  69      Header_Num => SFN_Header_Num,
  70      Element    => Int,
  71      No_Element => No_Entry,
  72      Key        => Unit_Name_Type,
  73      Hash       => SFN_Hash,
  74      Equal      => "=");
  75    --  Hash table allowing rapid access to SFN_Table, the element value
  76    --  is an index into this table.
  77
  78    type SFN_Pattern_Entry is record
  79       Pat : String_Ptr;   -- File name pattern (with asterisk in it)
  80       Typ : Character;    -- 'S'/'B'/'U' for spec/body/subunit
  81       Dot : String_Ptr;   -- Dot_Separator string
  82       Cas : Casing_Type;  -- Upper/Lower/Mixed
  83    end record;
  84    --  Records single call to Set_File_Name_Patterm
  85
  86    package SFN_Patterns is new Table.Table (
  87      Table_Component_Type => SFN_Pattern_Entry,
  88      Table_Index_Type     => Int,
  89      Table_Low_Bound      => 1,
  90      Table_Initial        => 10,
  91      Table_Increment      => 100,
  92      Table_Name           => "SFN_Patterns");
  93    --  Table recording all calls to Set_File_Name_Pattern. Note that the
  94    --  first two entries are set to represent the standard GNAT rules
  95    --  for file naming.
  96
  97    -----------------------
  98    -- File_Name_Of_Body --
  99    -----------------------
 100
 101    function File_Name_Of_Body (Name : Name_Id) return File_Name_Type is
 102    begin
 103       Get_Name_String (Name);
 104       Name_Buffer (Name_Len + 1 .. Name_Len + 2) := "%b";
 105       Name_Len := Name_Len + 2;
 106       return Get_File_Name (Name_Enter, Subunit => False);
 107    end File_Name_Of_Body;
 108
 109    -----------------------
 110    -- File_Name_Of_Spec --
 111    -----------------------
 112
 113    function File_Name_Of_Spec (Name : Name_Id) return File_Name_Type is
 114    begin
 115       Get_Name_String (Name);
 116       Name_Buffer (Name_Len + 1 .. Name_Len + 2) := "%s";
 117       Name_Len := Name_Len + 2;
 118       return Get_File_Name (Name_Enter, Subunit => False);
 119    end File_Name_Of_Spec;
 120
 121    -------------------
 122    -- Get_File_Name --
 123    -------------------
 124
 125    function Get_File_Name
 126      (Uname   : Unit_Name_Type;
 127       Subunit : Boolean)
 128       return    File_Name_Type
 129    is
 130       Unit_Char : Character;
 131       --  Set to 's' or 'b' for spec or body or to 'u' for a subunit
 132
 133       Unit_Char_Search : Character;
 134       --  Same as Unit_Char, except that in the case of 'u' for a subunit,
 135       --  we set Unit_Char_Search to 'b' if we do not find a subunit match.
 136
 137       N : Int;
 138
 139       Pname : File_Name_Type := No_File;
 140       Fname : File_Name_Type := No_File;
 141       --  Path name and File name for mapping
 142
 143    begin
 144       --  Null or error name means that some previous error occurred
 145       --  This is an unrecoverable error, so signal it.
 146
 147       if Uname <= Error_Name then
 148          raise Unrecoverable_Error;
 149       end if;
 150
 151       --  Look in the map from unit names to file names
 152
 153       Fname := Mapped_File_Name (Uname);
 154
 155       --  If the unit name is already mapped, return the corresponding
 156       --  file name from the map.
 157
 158       if Fname /= No_File then
 159          return Fname;
 160       end if;
 161
 162       --  If there is a specific SFN pragma, return the corresponding file name
 163
 164       N := SFN_HTable.Get (Uname);
 165
 166       if N /= No_Entry then
 167          return SFN_Table.Table (N).F;
 168       end if;
 169
 170       --  Here for the case where the name was not found in the table
 171
 172       Get_Decoded_Name_String (Uname);
 173
 174       --  A special fudge, normally we don't have operator symbols present,
 175       --  since it is always an error to do so. However, if we do, at this
 176       --  stage it has a leading double quote.
 177
 178       --  What we do in this case is to go back to the undecoded name, which
 179       --  is of the form, for example:
 180
 181       --    Oand%s
 182
 183       --  and build a file name that looks like:
 184
 185       --    _and_.ads
 186
 187       --  which is bit peculiar, but we keep it that way. This means that
 188       --  we avoid bombs due to writing a bad file name, and w get expected
 189       --  error processing downstream, e.g. a compilation following gnatchop.
 190
 191       if Name_Buffer (1) = '"' then
 192          Get_Name_String (Uname);
 193          Name_Len := Name_Len + 1;
 194          Name_Buffer (Name_Len)     := Name_Buffer (Name_Len - 1);
 195          Name_Buffer (Name_Len - 1) := Name_Buffer (Name_Len - 2);
 196          Name_Buffer (Name_Len - 2) := '_';
 197          Name_Buffer (1)            := '_';
 198       end if;
 199
 200       --  Deal with spec or body suffix
 201
 202       Unit_Char := Name_Buffer (Name_Len);
 203       pragma Assert (Unit_Char = 'b' or else Unit_Char = 's');
 204       pragma Assert (Name_Len >= 3 and then Name_Buffer (Name_Len - 1) = '%');
 205       Name_Len := Name_Len - 2;
 206
 207       if Subunit then
 208          Unit_Char := 'u';
 209       end if;
 210
 211       --  Now we need to find the proper translation of the name
 212
 213       declare
 214          Uname : constant String (1 .. Name_Len) :=
 215                    Name_Buffer (1 .. Name_Len);
 216
 217          Pent : Nat;
 218          Plen : Natural;
 219          Fnam : File_Name_Type := No_File;
 220          J    : Natural;
 221          Dot  : String_Ptr;
 222          Dotl : Natural;
 223
 224          function C (N : Natural) return Character;
 225          --  Return N'th character of pattern
 226
 227          function C (N : Natural) return Character is
 228          begin
 229             return SFN_Patterns.Table (Pent).Pat (N);
 230          end C;
 231
 232       --  Start of search through pattern table
 233
 234       begin
 235          --  Search pattern table to find a matching entry. In the general
 236          --  case we do two complete searches. The first time through we
 237          --  stop only if a matching file is found, the second time through
 238          --  we accept the first match regardless. Note that there will
 239          --  always be a match the second time around, because of the
 240          --  default entries at the end of the table.
 241
 242          for No_File_Check in False .. True loop
 243             Unit_Char_Search := Unit_Char;
 244
 245          <<Repeat_Search>>
 246          --  The search is repeated with Unit_Char_Search set to b, if an
 247          --  initial search for the subunit case fails to find any match.
 248
 249             Pent := SFN_Patterns.First;
 250             while Pent <= SFN_Patterns.Last loop
 251                if SFN_Patterns.Table (Pent).Typ = Unit_Char_Search then
 252                   Name_Len := 0;
 253
 254                   --  Found a match, execute the pattern
 255
 256                   Name_Len := Uname'Length;
 257                   Name_Buffer (1 .. Name_Len) := Uname;
 258                   Set_Casing (SFN_Patterns.Table (Pent).Cas);
 259
 260                   --  If dot translation required do it
 261
 262                   Dot  := SFN_Patterns.Table (Pent).Dot;
 263                   Dotl := Dot.all'Length;
 264
 265                   if Dot.all /= "." then
 266                      J := 1;
 267
 268                      while J <= Name_Len loop
 269                         if Name_Buffer (J) = '.' then
 270
 271                            if Dotl = 1 then
 272                               Name_Buffer (J) := Dot (Dot'First);
 273
 274                            else
 275                               Name_Buffer (J + Dotl .. Name_Len + Dotl - 1) :=
 276                                 Name_Buffer (J + 1 .. Name_Len);
 277                               Name_Buffer (J .. J + Dotl - 1) := Dot.all;
 278                               Name_Len := Name_Len + Dotl - 1;
 279                            end if;
 280
 281                            J := J + Dotl;
 282
 283                         --  Skip past wide char sequences to avoid messing
 284                         --  with dot characters that are part of a sequence.
 285
 286                         elsif Name_Buffer (J) = ASCII.ESC
 287                           or else (Upper_Half_Encoding
 288                                     and then
 289                                       Name_Buffer (J) in Upper_Half_Character)
 290                         then
 291                            Skip_Wide (Name_Buffer, J);
 292                         else
 293                            J := J + 1;
 294                         end if;
 295                      end loop;
 296                   end if;
 297
 298                   --  Here move result to right if preinsertion before *
 299
 300                   Plen := SFN_Patterns.Table (Pent).Pat'Length;
 301                   for K in 1 .. Plen loop
 302                      if C (K) = '*' then
 303                         if K /= 1 then
 304                            Name_Buffer (1 + K - 1 .. Name_Len + K - 1) :=
 305                              Name_Buffer (1 .. Name_Len);
 306
 307                            for L in 1 .. K - 1 loop
 308                               Name_Buffer (L) := C (L);
 309                            end loop;
 310
 311                            Name_Len := Name_Len + K - 1;
 312                         end if;
 313
 314                         for L in K + 1 .. Plen loop
 315                            Name_Len := Name_Len + 1;
 316                            Name_Buffer (Name_Len) := C (L);
 317                         end loop;
 318
 319                         exit;
 320                      end if;
 321                   end loop;
 322
 323                   --  Execute possible crunch on constructed name. The krunch
 324                   --  operation excludes any extension that may be present.
 325
 326                   J := Name_Len;
 327                   while J > 1 loop
 328                      exit when Name_Buffer (J) = '.';
 329                      J := J - 1;
 330                   end loop;
 331
 332                   --  Case of extension present
 333
 334                   if J > 1 then
 335                      declare
 336                         Ext : constant String := Name_Buffer (J .. Name_Len);
 337
 338                      begin
 339                         --  Remove extension
 340
 341                         Name_Len := J - 1;
 342
 343                         --  Krunch what's left
 344
 345                         Krunch
 346                           (Name_Buffer,
 347                            Name_Len,
 348                            Integer (Maximum_File_Name_Length),
 349                            Debug_Flag_4);
 350
 351                         --  Replace extension
 352
 353                         Name_Buffer
 354                           (Name_Len + 1 .. Name_Len + Ext'Length) := Ext;
 355                         Name_Len := Name_Len + Ext'Length;
 356                      end;
 357
 358                   --  Case of no extension present, straight krunch on
 359                   --  the entire file name.
 360
 361                   else
 362                      Krunch
 363                        (Name_Buffer,
 364                         Name_Len,
 365                         Integer (Maximum_File_Name_Length),
 366                         Debug_Flag_4);
 367                   end if;
 368
 369                   Fnam := File_Name_Type (Name_Find);
 370
 371                   --  If we are in the second search of the table, we accept
 372                   --  the file name without checking, because we know that
 373                   --  the file does not exist.
 374
 375                   if No_File_Check then
 376                      return Fnam;
 377
 378                   --  Otherwise we check if the file exists
 379
 380                   else
 381                      Pname := Find_File (Fnam, Source);
 382
 383                      --  If it does exist, we add it to the mappings and
 384                      --  return the file name.
 385
 386                      if Pname /= No_File then
 387
 388                         --  Add to mapping, so that we don't do another
 389                         --  path search in Find_File for this file name
 390                         --  and, if we use a mapping file, we are ready
 391                         --  to update it at the end of this compilation
 392                         --  for the benefit of other compilation processes.
 393
 394                         Add_To_File_Map (Get_File_Name.Uname, Fnam, Pname);
 395                         return Fnam;
 396
 397                      --  If there are only two entries, they are those of
 398                      --  the default GNAT naming scheme. The file does
 399                      --  not exist, but there is no point doing the
 400                      --  second search, because we will end up with the
 401                      --  same file name. Just return the file name.
 402
 403                      elsif SFN_Patterns.Last = 2 then
 404                         return Fnam;
 405
 406                      --  The file does not exist, but there may be other
 407                      --  naming scheme. Keep on searching.
 408
 409                      else
 410                         Fnam := No_File;
 411                      end if;
 412                   end if;
 413                end if;
 414
 415                Pent := Pent + 1;
 416             end loop;
 417
 418             --  If search failed, and was for a subunit, repeat the search
 419             --  with Unit_Char_Search reset to 'b', since in the normal case
 420             --  we simply treat subunits as bodies.
 421
 422             if Fnam = No_File and then Unit_Char_Search = 'u' then
 423                Unit_Char_Search := 'b';
 424                goto Repeat_Search;
 425             end if;
 426
 427             --  Repeat entire search in No_File_Check mode if necessary
 428
 429          end loop;
 430
 431          --  Something is wrong if search fails completely, since the
 432          --  default entries should catch all possibilities at this stage.
 433
 434          raise Program_Error;
 435       end;
 436    end Get_File_Name;
 437
 438    ----------------
 439    -- Initialize --
 440    ----------------
 441
 442    procedure Initialize is
 443    begin
 444       SFN_Table.Init;
 445       SFN_Patterns.Init;
 446
 447       --  Add default entries to SFN_Patterns.Table to represent the
 448       --  standard default GNAT rules for file name translation.
 449
 450       SFN_Patterns.Append (New_Val =>
 451         (Pat => new String'("*.ads"),
 452          Typ => 's',
 453          Dot => new String'("-"),
 454          Cas => All_Lower_Case));
 455
 456       SFN_Patterns.Append (New_Val =>
 457         (Pat => new String'("*.adb"),
 458          Typ => 'b',
 459          Dot => new String'("-"),
 460          Cas => All_Lower_Case));
 461    end Initialize;
 462
 463    ----------
 464    -- Lock --
 465    ----------
 466
 467    procedure Lock is
 468    begin
 469       SFN_Table.Locked := True;
 470       SFN_Table.Release;
 471    end Lock;
 472
 473    -------------------
 474    -- Set_File_Name --
 475    -------------------
 476
 477    procedure Set_File_Name (U : Unit_Name_Type; F : File_Name_Type) is
 478    begin
 479       SFN_Table.Increment_Last;
 480       SFN_Table.Table (SFN_Table.Last) := (U, F);
 481       SFN_HTable.Set (U, SFN_Table.Last);
 482    end Set_File_Name;
 483
 484    ---------------------------
 485    -- Set_File_Name_Pattern --
 486    ---------------------------
 487
 488    procedure Set_File_Name_Pattern
 489      (Pat : String_Ptr;
 490       Typ : Character;
 491       Dot : String_Ptr;
 492       Cas : Casing_Type)
 493    is
 494       L : constant Nat := SFN_Patterns.Last;
 495    begin
 496       SFN_Patterns.Increment_Last;
 497
 498       --  Move up the last two entries (the default ones) and then
 499       --  put the new entry into the table just before them (we
 500       --  always have the default entries be the last ones).
 501
 502       SFN_Patterns.Table (L + 1) := SFN_Patterns.Table (L);
 503       SFN_Patterns.Table (L)     := SFN_Patterns.Table (L - 1);
 504       SFN_Patterns.Table (L - 1) := (Pat, Typ, Dot, Cas);
 505    end Set_File_Name_Pattern;
 506
 507    --------------
 508    -- SFN_Hash --
 509    --------------
 510
 511    function SFN_Hash (F : Unit_Name_Type) return SFN_Header_Num is
 512    begin
 513       return SFN_Header_Num (Int (F) rem SFN_Header_Num'Range_Length);
 514    end SFN_Hash;
 515
 516 begin
 517
 518    --  We call the initialization routine from the package body, so that
 519    --  Fname.Init only needs to be called explicitly to reinitialize.
 520
 521    Fname.UF.Initialize;
 522 end Fname.UF;