gcc/ada/g-dirope.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --            G N A T . D I R E C T O R Y _ O P E R A T I O N S             --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 1998-2010, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Directory operations
  35
  36 --  This package provides routines for manipulating directories. A directory
  37 --  can be treated as a file, using open and close routines, and a scanning
  38 --  routine is provided for iterating through the entries in a directory.
  39
  40 --  See also child package GNAT.Directory_Operations.Iteration
  41
  42 --  Note: support on OpenVMS is limited to the support of Unix-style
  43 --  directory names (OpenVMS native directory format is not supported).
  44 --  Read individual entries for more specific notes on OpenVMS support.
  45
  46 with System;
  47 with Ada.Strings.Maps;
  48
  49 package GNAT.Directory_Operations is
  50
  51    subtype Dir_Name_Str is String;
  52    --  A subtype used in this package to represent string values that are
  53    --  directory names. A directory name is a prefix for files that appear
  54    --  with in the directory. This means that for UNIX systems, the string
  55    --  includes a final '/', and for DOS-like systems, it includes a final
  56    --  '\' character. It can also include drive letters if the operating
  57    --  system provides for this. The final '/' or '\' in a Dir_Name_Str is
  58    --  optional when passed as a procedure or function in parameter.
  59    --  On OpenVMS, only Unix style path names are supported, not VMS style,
  60    --  but the directory and file names are not case sensitive.
  61
  62    type Dir_Type is limited private;
  63    --  A value used to reference a directory. Conceptually this value includes
  64    --  the identity of the directory, and a sequential position within it.
  65
  66    Null_Dir : constant Dir_Type;
  67    --  Represent the value for an uninitialized or closed directory
  68
  69    Directory_Error : exception;
  70    --  Exception raised if the directory cannot be opened, read, closed,
  71    --  created or if it is not possible to change the current execution
  72    --  environment directory.
  73
  74    Dir_Separator : constant Character;
  75    --  Running system default directory separator
  76
  77    --------------------------------
  78    -- Basic Directory operations --
  79    --------------------------------
  80
  81    procedure Change_Dir (Dir_Name : Dir_Name_Str);
  82    --  Changes the working directory of the current execution environment
  83    --  to the directory named by Dir_Name. Raises Directory_Error if Dir_Name
  84    --  does not exist.
  85
  86    procedure Make_Dir (Dir_Name : Dir_Name_Str);
  87    --  Create a new directory named Dir_Name. Raises Directory_Error if
  88    --  Dir_Name cannot be created.
  89
  90    procedure Remove_Dir
  91      (Dir_Name  : Dir_Name_Str;
  92       Recursive : Boolean := False);
  93    --  Remove the directory named Dir_Name. If Recursive is set to True, then
  94    --  Remove_Dir removes all the subdirectories and files that are in
  95    --  Dir_Name. Raises Directory_Error if Dir_Name cannot be removed.
  96
  97    function Get_Current_Dir return Dir_Name_Str;
  98    --  Returns the current working directory for the execution environment
  99
 100    procedure Get_Current_Dir (Dir : out Dir_Name_Str; Last : out Natural);
 101    --  Returns the current working directory for the execution environment
 102    --  The name is returned in Dir_Name. Last is the index in Dir_Name such
 103    --  that Dir_Name (Last) is the last character written. If Dir_Name is
 104    --  too small for the directory name, the name will be truncated before
 105    --  being copied to Dir_Name.
 106
 107    -------------------------
 108    -- Pathname Operations --
 109    -------------------------
 110
 111    subtype Path_Name is String;
 112    --  All routines using Path_Name handle both styles (UNIX and DOS) of
 113    --  directory separators (either slash or back slash).
 114
 115    function Dir_Name (Path : Path_Name) return Dir_Name_Str;
 116    --  Returns directory name for Path. This is similar to the UNIX dirname
 117    --  command. Everything after the last directory separator is removed. If
 118    --  there is no directory separator the current working directory is
 119    --  returned. Note that the contents of Path is case-sensitive on
 120    --  systems that have case-sensitive file names (like Unix), and
 121    --  non-case-sensitive on systems where the file system is also non-
 122    --  case-sensitive (such as Windows, and OpenVMS).
 123
 124    function Base_Name
 125      (Path   : Path_Name;
 126       Suffix : String := "") return String;
 127    --  Any directory prefix is removed. A directory prefix is defined as
 128    --  text up to and including the last directory separator character in
 129    --  the input string. In addition if Path ends with the string given for
 130    --  Suffix, then it is also removed. Note that Suffix here can be an
 131    --  arbitrary string (it is not required to be a file extension). This
 132    --  is equivalent to the UNIX basename command. The following rule is
 133    --  always true:
 134    --
 135    --    'Path' and 'Dir_Name (Path) & Dir_Separator & Base_Name (Path)'
 136    --    represent the same file.
 137    --
 138    --  The comparison of Suffix is case-insensitive on systems such as Windows
 139    --  and VMS where the file search is case-insensitive (e.g. on such systems,
 140    --  Base_Name ("/Users/AdaCore/BB12.patch", ".Patch") returns "BB12").
 141    --
 142    --  Note that the index bounds of the result match the corresponding indexes
 143    --  in the Path string (you cannot assume that the lower bound of the
 144    --  returned string is one).
 145
 146    function File_Extension (Path : Path_Name) return String;
 147    --  Return the file extension. This is defined as the string after the
 148    --  last dot, including the dot itself. For example, if the file name
 149    --  is "file1.xyz.adq", then the returned value would be ".adq". If no
 150    --  dot is present in the file name, or the last character of the file
 151    --  name is a dot, then the null string is returned.
 152
 153    function File_Name (Path : Path_Name) return String;
 154    --  Returns the file name and the file extension if present. It removes all
 155    --  path information. This is equivalent to Base_Name with default Extension
 156    --  value.
 157
 158    type Path_Style is (UNIX, DOS, System_Default);
 159    function Format_Pathname
 160      (Path  : Path_Name;
 161       Style : Path_Style := System_Default) return Path_Name;
 162    --  Removes all double directory separator and converts all '\' to '/' if
 163    --  Style is UNIX and converts all '/' to '\' if Style is set to DOS. This
 164    --  function will help to provide a consistent naming scheme running for
 165    --  different environments. If style is set to System_Default the routine
 166    --  will use the default directory separator on the running environment.
 167    --
 168    --  The Style argument indicates the syntax to be used for path names:
 169    --
 170    --    UNIX
 171    --      Use '/' as the directory separator. The default on Unix systems
 172    --      and on OpenVMS.
 173    --
 174    --    DOS
 175    --      Use '\' as the directory separator. The default on Windows.
 176    --
 177    --    System_Default
 178    --      Use the default style for the current system
 179
 180    type Environment_Style is (UNIX, DOS, Both, System_Default);
 181    function Expand_Path
 182      (Path : Path_Name;
 183       Mode : Environment_Style := System_Default) return Path_Name;
 184    --  Returns Path with environment variables (or logical names on OpenVMS)
 185    --  replaced by the current environment variable value. For example,
 186    --  $HOME/mydir will be replaced by /home/joe/mydir if $HOME environment
 187    --  variable is set to /home/joe and Mode is UNIX. If an environment
 188    --  variable does not exists the variable will be replaced by the empty
 189    --  string. Two dollar or percent signs are replaced by a single
 190    --  dollar/percent sign. Note that a variable must start with a letter.
 191    --
 192    --  The Mode argument indicates the recognized syntax for environment
 193    --  variables as follows:
 194    --
 195    --    UNIX
 196    --      Environment variables and OpenVMS logical names use $ as prefix and
 197    --      can use curly brackets as in ${HOME}/mydir. If there is no closing
 198    --      curly bracket for an opening one then no translation is done, so for
 199    --      example ${VAR/toto is returned as ${VAR/toto. The use of {} brackets
 200    --      is required if the environment variable name contains other than
 201    --      alphanumeric characters.
 202    --
 203    --    DOS
 204    --      Environment variables uses % as prefix and suffix (e.g. %HOME%/dir).
 205    --      The name DOS refer to "DOS-like" environment. This includes all
 206    --      Windows systems.
 207    --
 208    --    Both
 209    --      Recognize both forms described above.
 210    --
 211    --    System_Default
 212    --      Uses either UNIX on Unix and OpenVMS systems, or DOS on Windows,
 213    --      depending on the running environment. What about other OS's???
 214
 215    ---------------
 216    -- Iterators --
 217    ---------------
 218
 219    procedure Open (Dir : out Dir_Type; Dir_Name : Dir_Name_Str);
 220    --  Opens the directory named by Dir_Name and returns a Dir_Type value
 221    --  that refers to this directory, and is positioned at the first entry.
 222    --  Raises Directory_Error if Dir_Name cannot be accessed. In that case
 223    --  Dir will be set to Null_Dir.
 224
 225    procedure Close (Dir : in out Dir_Type);
 226    --  Closes the directory stream referred to by Dir. After calling Close
 227    --  Is_Open will return False. Dir will be set to Null_Dir.
 228    --  Raises Directory_Error if Dir has not be opened (Dir = Null_Dir).
 229
 230    function Is_Open (Dir : Dir_Type) return Boolean;
 231    --  Returns True if Dir is open, or False otherwise
 232
 233    procedure Read
 234      (Dir  : Dir_Type;
 235       Str  : out String;
 236       Last : out Natural);
 237    --  Reads the next entry from the directory and sets Str to the name
 238    --  of that entry. Last is the index in Str such that Str (Last) is the
 239    --  last character written. Last is 0 when there are no more files in the
 240    --  directory. If Str is too small for the file name, the file name will
 241    --  be truncated before being copied to Str. The list of files returned
 242    --  includes directories in systems providing a hierarchical directory
 243    --  structure, including . (the current directory) and .. (the parent
 244    --  directory) in systems providing these entries. The directory is
 245    --  returned in target-OS form. Raises Directory_Error if Dir has not
 246    --  be opened (Dir = Null_Dir).
 247
 248    function Read_Is_Thread_Safe return Boolean;
 249    --  Indicates if procedure Read is thread safe. On systems where the
 250    --  target system supports this functionality, Read is thread safe,
 251    --  and this function returns True (e.g. this will be the case on any
 252    --  UNIX or UNIX-like system providing a correct implementation of the
 253    --  function readdir_r). If the system cannot provide a thread safe
 254    --  implementation of Read, then this function returns False.
 255
 256 private
 257
 258    type Dir_Type_Value is new System.Address;
 259    --  Low-level address directory structure as returned by opendir in C
 260    --
 261    --  Note that we used to define this type in the body of this package,
 262    --  but this was causing troubles in the context of .NET code generation
 263    --  (because Taft amendment types are not fully implemented and cause
 264    --  undefined references to the class), so we moved the type declaration
 265    --  to the spec's private part, which is no problem in any case here.
 266
 267    type Dir_Type is access Dir_Type_Value;
 268
 269    Null_Dir : constant Dir_Type := null;
 270
 271    pragma Import (C, Dir_Separator, "__gnat_dir_separator");
 272
 273    Dir_Seps : constant Ada.Strings.Maps.Character_Set :=
 274                 Ada.Strings.Maps.To_Set ("/\");
 275    --  UNIX and DOS style directory separators
 276
 277 end GNAT.Directory_Operations;