libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 # Only use libltdl for non-newlib builds.
 146 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 147    AC_LTDL_SHLIBPATH
 148 fi
 149
 150 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 151
 152 # See if the user has requested runtime debugging.
 153 LIBGCJDEBUG="disable"
 154 AC_SUBST(LIBGCJDEBUG)
 155 AC_ARG_ENABLE(libgcj-debug,
 156   AS_HELP_STRING([--enable-libgcj-debug],
 157                  [enable runtime debugging code]),
 158   [if test "$enable_libgcj_debug" = yes; then
 159     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 160     LIBGCJDEBUG="enable"
 161   fi])
 162
 163 # Determine which AWT peer libraries to build
 164 AC_ARG_ENABLE(java-awt,
 165   AS_HELP_STRING([--enable-java-awt],
 166                  [list of AWT peer implementations to be built]))
 167
 168 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 169 use_xlib_awt=""
 170 use_gtk_awt=""
 171 use_qt_awt=""
 172 # The default toolkit to use is the first one specified.
 173 TOOLKIT=
 174 AC_SUBST(TOOLKIT)
 175
 176 for peer in $peerlibs ; do
 177   case $peer in
 178     xlib)
 179       if test "$no_x" = yes; then
 180         echo "*** xlib peers requested but no X library available" 1>&2
 181         exit 1
 182       else
 183         use_xlib_awt="yes"
 184         if test -z "$TOOLKIT"; then
 185            TOOLKIT=gnu.awt.xlib.XToolkit
 186         fi
 187       fi
 188       ;;
 189     gtk)
 190       if test "$no_x" = yes; then
 191          echo "*** gtk peers requested but no X library available" 1>&2
 192          exit 1
 193       else
 194          use_gtk_awt=yes
 195          if test -z "$TOOLKIT"; then
 196             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 197          fi
 198       fi
 199       ;;
 200     qt)
 201       if test "$no_x" = yes; then
 202          # Perhaps we should admit the possibility of embedded Qt.
 203          echo "*** Qt peers requested but no X library available" 1>&2
 204          exit 1
 205       else
 206          use_qt_awt=yes
 207          if test -z "$TOOLKIT"; then
 208             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 209          fi
 210       fi
 211       ;;
 212     no)
 213       use_xlib_awt=
 214       use_gtk_awt=
 215       use_qt_awt=
 216       break
 217       ;;
 218     *)
 219       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 220       exit 1
 221   esac
 222 done
 223
 224 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 225 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 226 AM_CONDITIONAL(QT_AWT, test "$use_qt_awt" = yes)
 227
 228 # Create standard.omit based on decisions we just made.
 229 cp $srcdir/standard.omit.in standard.omit
 230 if test "$use_xlib_awt" != yes; then
 231    echo gnu/awt/xlib >> standard.omit
 232    echo gnu/gcj/xlib >> standard.omit
 233 fi
 234 if test "$use_gtk_awt" != yes; then
 235    echo gnu/java/awt/peer/gtk >> standard.omit
 236 fi
 237 if test "$use_qt_awt" != yes; then
 238    echo gnu/java/awt/peer/qt >> standard.omit
 239 fi
 240
 241 if test -z "${with_multisubdir}"; then
 242    builddotdot=.
 243 else
 244    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 245 fi
 246
 247 NATIVE=yes
 248
 249 # Which gcj do we use?
 250 which_gcj=default
 251 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 252 if test -n "${with_cross_host}"; then
 253   # We are being configured with a cross compiler. We can't
 254   # use ac_exeext, because that is for the target platform.
 255   NATIVE=no
 256   cross_host_exeext=
 257   case "${with_cross_host}" in
 258      *mingw* | *cygwin*)
 259          cross_host_exeext=.exe
 260      ;;
 261   esac
 262   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 263      if test x"$build_noncanonical" = x"$with_cross_host"; then
 264         # Ordinary cross (host!=target and host=build)
 265         which_gcj=built
 266      else
 267         # Canadian cross (host!=target and host!=build)
 268         which_gcj=cross
 269      fi
 270   else
 271      which_gcj=cross
 272   fi
 273 else
 274   # We are being configured with a native or crossed-native compiler
 275   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 276      if test x"$build" = x"$host"; then
 277         # True native build (host=target and host=build)
 278         which_gcj=built
 279      else
 280         # Crossed-native build (host=target and host!=build)
 281         which_gcj=cross
 282      fi
 283   else
 284      which_gcj=path
 285   fi
 286 fi
 287 case "${which_gcj}" in
 288    built)
 289       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 290       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 291       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
 292    ;;
 293    cross)
 294       if test "x${with_newlib}" = "xyes"; then
 295          # FIXME (comment): Why is this needed?
 296          GCC_UNWIND_INCLUDE=
 297          GCJ="${target_noncanonical}-gcj"
 298       else
 299          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 300       fi
 301       ZIP='$(target_noncanonical)-fastjar'
 302       GCJH='$(target_noncanonical)-gcjh'
 303    ;;
 304    path)
 305       GCJ="gcj -B`${PWDCMD-pwd}`/"
 306       ## In this case, gcj is found outside the build tree.  However, zip is
 307       ## found in the build tree.
 308       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
 309       GCJH=gcjh
 310    ;;
 311 esac
 312
 313 AC_SUBST(GCJH)
 314 AC_SUBST(ZIP)
 315
 316 # Create it, so that compile/link tests don't fail
 317 test -f libgcj.spec || touch libgcj.spec
 318
 319
 320
 321 # Set up to configure Classpath.
 322 # FIXME: no supported way to pass args in autoconf.
 323 ac_configure_args="$ac_configure_args --disable-load-library"
 324 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 325 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 326 dir1=`cd $srcdir && pwd`
 327 dir2=`pwd`
 328 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 329 ac_configure_args="$ac_configure_args --disable-core-jni"
 330 dnl FIXME?
 331 ac_configure_args="$ac_configure_args --disable-examples"
 332 ac_configure_args="$ac_configure_args --with-glibj=build"
 333 if test "$use_gtk_awt" != yes; then
 334   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 335 fi
 336 if test "$use_qt_awt" != yes; then
 337   ac_configure_args="$ac_configure_args --disable-qt-peer"
 338 else
 339   # We need this as qt is disabled by default in classpath.
 340   ac_configure_args="$ac_configure_args --enable-qt-peer"
 341 fi
 342 dnl --with-gcj=$GCJ
 343 dnl --with-javah=$GCJH
 344 dnl gjdoc?
 345 dnl gtk-cairo -- just export here...
 346 dnl --enable-regen-headers?
 347
 348 # Only use libltdl for non-newlib builds.
 349 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 350    AC_LIBLTDL_CONVENIENCE
 351    AC_LIBTOOL_DLOPEN
 352    DIRLTDL=libltdl
 353    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 354    # Sigh.  Libtool's macro doesn't do the right thing.
 355    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 356    # FIXME: this is a hack.
 357    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 358    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 359 fi
 360 AC_SUBST(INCLTDL)
 361 AC_SUBST(LIBLTDL)
 362 AC_SUBST(DIRLTDL)
 363 AC_PROG_LIBTOOL
 364 AM_PROG_GCJ
 365 AM_PROG_CC_C_O
 366
 367 AC_CONFIG_SUBDIRS(classpath libltdl)
 368
 369 # The -no-testsuite modules omit the test subdir.
 370 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 371
 372 # Should the runtime set system properties by examining the
 373 # environment variable GCJ_PROPERTIES?
 374 AC_ARG_ENABLE(getenv-properties,
 375   AS_HELP_STRING([--disable-getenv-properties],
 376                  [don't set system properties from GCJ_PROPERTIES]))
 377
 378 # Whether GCJ_PROPERTIES is used depends on the target.
 379 if test -z "$enable_getenv_properties"; then
 380    enable_getenv_properties=${enable_getenv_properties_default-yes}
 381 fi
 382 if test "$enable_getenv_properties" = no; then
 383    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 384      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 385 fi
 386
 387 # Whether we should use arguments to main()
 388 if test -z "$enable_main_args"; then
 389    enable_main_args=${enable_main_args_default-yes}
 390 fi
 391 if test "$enable_main_args" = no; then
 392    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 393 fi
 394
 395
 396 # Should we use hashtable-based synchronization?
 397 # Currently works only for Linux X86/ia64
 398 # Typically faster and more space-efficient
 399 AC_ARG_ENABLE(hash-synchronization,
 400   AS_HELP_STRING([--enable-hash-synchronization],
 401                  [use global hash table for monitor locks]))
 402
 403 if test -z "$enable_hash_synchronization"; then
 404    enable_hash_synchronization=$enable_hash_synchronization_default
 405 fi
 406
 407 AC_ARG_WITH(java-home,
 408   AS_HELP_STRING([--with-java-home=DIRECTORY],
 409                  [value of java.home system property]),
 410                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 411 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 412 AC_SUBST(JAVA_HOME)
 413
 414 # What is the native OS API for MinGW?
 415 AC_ARG_WITH(win32-nlsapi,
 416   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 417                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 418 [case "${withval}" in
 419   ansi) with_win32_nlsapi=ansi ;;
 420   unicows) with_win32_nlsapi=unicows ;;
 421   unicode) with_win32_nlsapi=unicode ;;
 422   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 423 esac],[with_win32_nlsapi=ansi])
 424
 425 case "${with_win32_nlsapi}" in
 426   unicows | unicode)
 427     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 428       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 429     ;;
 430 esac
 431
 432 # configure.host sets slow_pthread_self if the synchronization code should
 433 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 434 if test "${slow_pthread_self}" = "yes"; then
 435   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 436     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 437 fi
 438
 439 # Check for gc debugging.  This option is handled both here and in the GC.
 440 AC_ARG_ENABLE(gc-debug,
 441    AS_HELP_STRING([--enable-gc-debug],
 442                   [include full support for pointer backtracing etc.]),
 443 [ if test "$enable_gc_debug" = "yes"; then
 444     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 445               [Define if we want to use debug calls into the garbage collector.])
 446   fi])
 447
 448 # See if the user has the interpreter included.
 449 AC_ARG_ENABLE(interpreter,
 450   AS_HELP_STRING([--enable-interpreter],
 451                  [enable interpreter]),
 452   [if test "$enable_interpreter" = yes; then
 453     # This can also be set in configure.host.
 454     libgcj_interpreter=yes
 455   elif test "$enable_interpreter" = no; then
 456     libgcj_interpreter=no
 457   fi])
 458
 459 if test "$libgcj_interpreter" = yes; then
 460    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 461 fi
 462 INTERPRETER="$libgcj_interpreter"
 463 AC_SUBST(INTERPRETER)
 464
 465 AC_MSG_CHECKING([for exception model to use])
 466 AC_LANG_PUSH(C++)
 467 AC_ARG_ENABLE(sjlj-exceptions,
 468   AS_HELP_STRING([--enable-sjlj-exceptions],
 469                  [force use of builtin_setjmp for exceptions]),
 470 [:],
 471 [dnl Botheration.  Now we've got to detect the exception model.
 472 dnl Link tests against libgcc.a are problematic since -- at least
 473 dnl as of this writing -- we've not been given proper -L bits for
 474 dnl single-tree newlib and libgloss.
 475 dnl
 476 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 477 dnl conftest files before we got a change to grep them first.
 478 cat > conftest.$ac_ext << EOF
 479 [#]line __oline__ "configure"
 480 struct S { ~S(); };
 481 void bar();
 482 void foo()
 483 {
 484   S s;
 485   bar();
 486 }
 487 EOF
 488 old_CXXFLAGS="$CXXFLAGS"
 489 CXXFLAGS=-S
 490 if AC_TRY_EVAL(ac_compile); then
 491   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 492     enable_sjlj_exceptions=yes
 493   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 494     enable_sjlj_exceptions=no
 495   fi
 496 fi
 497 CXXFLAGS="$old_CXXFLAGS"
 498 rm -f conftest*])
 499 if test x$enable_sjlj_exceptions = xyes; then
 500   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 501         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 502   ac_exception_model_name=sjlj
 503 elif test x$enable_sjlj_exceptions = xno; then
 504   ac_exception_model_name="call frame"
 505 else
 506   AC_MSG_ERROR([unable to detect exception model])
 507 fi
 508 AC_LANG_POP(C++)
 509 AC_MSG_RESULT($ac_exception_model_name)
 510
 511 # If we are non using SJLJ exceptions, and this host does not have support
 512 # for unwinding from a signal handler, enable checked dereferences and divides.
 513 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 514   CHECKREFSPEC=-fcheck-references
 515   DIVIDESPEC=-fuse-divide-subroutine
 516   EXCEPTIONSPEC=
 517 fi
 518
 519 # See if the user wants to disable java.net.  This is the mildly
 520 # ugly way that we admit that target-side configuration sucks.
 521 AC_ARG_ENABLE(java-net,
 522   AS_HELP_STRING([--disable-java-net],
 523                  [disable java.net]))
 524
 525 # Whether java.net is built by default can depend on the target.
 526 if test -z "$enable_java_net"; then
 527    enable_java_net=${enable_java_net_default-yes}
 528 fi
 529 if test "$enable_java_net" = no; then
 530    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 531 fi
 532
 533 # See if the user wants to configure without libffi.  Some
 534 # architectures don't support it, and default values are set in
 535 # configure.host.
 536 AC_ARG_WITH(libffi,
 537   AS_HELP_STRING([--without-libffi],
 538                  [don't use libffi]),
 539   [:],
 540   [with_libffi=${with_libffi_default-yes}])
 541
 542 LIBFFI=
 543 LIBFFIINCS=
 544 if test "$with_libffi" != no; then
 545    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 546    LIBFFI=../libffi/libffi_convenience.la
 547    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 548 fi
 549 AC_SUBST(LIBFFI)
 550 AC_SUBST(LIBFFIINCS)
 551
 552 # See if the user wants to disable JVMPI support.
 553 AC_ARG_ENABLE(jvmpi,
 554   AS_HELP_STRING([--disable-jvmpi],
 555                  [disable JVMPI support]))
 556
 557 if test "$enable_jvmpi" != no; then
 558     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 559 fi
 560
 561 # If the target is an eCos system, use the appropriate eCos
 562 # I/O routines.
 563 # FIXME: this should not be a local option but a global target
 564 # system; at present there is no eCos target.
 565 TARGET_ECOS=${PROCESS-"no"}
 566 AC_ARG_WITH(ecos,
 567 [  --with-ecos             enable runtime eCos target support],
 568 TARGET_ECOS="$with_ecos"
 569 )
 570
 571 PLATFORM_INNER_NAT_HDRS=
 572 case "$TARGET_ECOS" in
 573    no) case "$host" in
 574       *mingw*)
 575             PLATFORM=Win32
 576             PLATFORMNET=Win32
 577             PLATFORMH=win32.h
 578         CHECK_FOR_BROKEN_MINGW_LD
 579       ;;
 580       *)
 581             PLATFORM=Posix
 582             PLATFORMNET=Posix
 583             PLATFORMH=posix.h
 584             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 585       ;;
 586       esac
 587       ;;
 588    *)
 589       PLATFORM=Ecos
 590       PLATFORMNET=NoNet
 591       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 592       PLATFORMH=posix.h
 593       ;;
 594 esac
 595 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 596 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 597
 598 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 599                                       [Define if you have int32_t and uint32_t.]))
 600 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 601                                         [Define if you have int32_t and uint32_t.]))
 602 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 603                                           [Define if you have u_int32_t]))
 604 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 605                                            [Define if you have u_int32_t]))
 606
 607 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 608 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 609
 610 case "$host" in
 611   *-darwin*) DARWIN_CRT=true ;;
 612   *) DARWIN_CRT=false ;;
 613 esac
 614 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 615
 616 # These may not be defined in a non-ANS conformant embedded system.
 617 # FIXME: Should these case a runtime exception in that case?
 618 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 619                                   [Define is you have 'mktime' in <time.h>]))
 620 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 621                                   [Define is you have 'localtime' in <time.h>]))
 622
 623 # Create the subdirectory for natFile.cc, or the attempt
 624 # to create the link will fail.
 625 test -d java || mkdir java
 626 test -d java/io || mkdir java/io
 627 test -d gnu || mkdir gnu
 628 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 629
 630 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 631 test -d java/lang || mkdir java/lang
 632 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 633 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 634
 635 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 636 test -d java/net || mkdir java/net
 637 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 638 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 639
 640 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 641 test -d gnu/java || mkdir gnu/java
 642 test -d gnu/java/net || mkdir gnu/java/net
 643 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 644 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 645
 646 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 647 test -d gnu/java/nio || mkdir gnu/java/nio
 648 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 649 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 650 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 651 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 652
 653 case "${host}" in
 654     *mingw*)
 655       SYSTEMSPEC="-lgdi32 -lws2_32"
 656       if test "${with_win32_nlsapi}" = "unicows"; then
 657         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 658       fi
 659     ;;
 660     *)
 661       SYSTEMSPEC=
 662     ;;
 663 esac
 664 AC_SUBST(SYSTEMSPEC)
 665
 666 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 667 AC_SUBST(LIBGCJTESTSPEC)
 668
 669 AC_ARG_WITH(system-zlib,
 670   AS_HELP_STRING([--with-system-zlib],
 671                  [use installed libz]))
 672 ZLIBSPEC=
 673 AC_SUBST(ZLIBSPEC)
 674 ZLIBTESTSPEC=
 675 AC_SUBST(ZLIBTESTSPEC)
 676
 677 AC_PATH_XTRA
 678
 679 # determine whether to enable the cairo GTK Graphics2D backend
 680 AC_ARG_ENABLE(gtk-cairo,
 681   AS_HELP_STRING([--enable-gtk-cairo],
 682                  [build the cairo Graphics2D implementation on GTK]))
 683 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 684 if test "x${enable_gtk_cairo}" = xyes
 685 then
 686         PKG_CHECK_MODULES(CAIRO, cairo)
 687         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 688 fi
 689 AC_SUBST(CAIRO_LIBS)
 690 AC_SUBST(CAIRO_CFLAGS)
 691 AC_SUBST(PANGOFT2_LIBS)
 692 AC_SUBST(PANGOFT2_CFLAGS)
 693
 694 # FIXME: this should be _libs on some hosts.
 695 libsubdir=.libs
 696
 697 # extra LD Flags which are required for targets
 698 case "${host}" in
 699 *-*-darwin[[0-7]].*)
 700     # For now we have to disable it on darwin[8-9] because it slows down
 701     # the linking phase. A possible bug in ld?
 702     # on Darwin -single_module speeds up loading of the dynamic libraries.
 703     extra_ldflags_libjava=-Wl,-single_module
 704     ;;
 705 esac
 706 AC_SUBST(extra_ldflags_libjava)
 707
 708 # Allow the GC to be disabled.  Can be useful when debugging.
 709 AC_MSG_CHECKING([for garbage collector to use])
 710 AC_ARG_ENABLE(java-gc,
 711   AS_HELP_STRING([--enable-java-gc=TYPE],
 712                  [choose garbage collector (default is boehm)]),
 713   [GC=$enableval],
 714   [GC=boehm])
 715 GCLIBS=
 716 GCINCS=
 717 GCDEPS=
 718 GCSPEC=
 719 JC1GCSPEC=
 720 GCTESTSPEC=
 721 case "$GC" in
 722  boehm)
 723     AC_MSG_RESULT(boehm)
 724     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 725     JC1GCSPEC='-fuse-boehm-gc'
 726     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 727     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 728     GCOBJS=boehm.lo
 729     GCHDR=boehm-gc.h
 730     # The POSIX thread support needs to know this.
 731     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 732     ;;
 733  no)
 734     AC_MSG_RESULT(none)
 735     GCHDR=no-gc.h
 736     ;;
 737  *)
 738     AC_MSG_ERROR([unrecognized collector "$GC"])
 739     ;;
 740 esac
 741 AC_SUBST(GCLIBS)
 742 AC_SUBST(GCINCS)
 743 AC_SUBST(GCDEPS)
 744 AC_SUBST(GCSPEC)
 745 AC_SUBST(JC1GCSPEC)
 746 AC_SUBST(GCTESTSPEC)
 747 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 748 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 749 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 750
 751
 752 AC_MSG_CHECKING([for thread model used by GCC])
 753 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 754 AC_MSG_RESULT([$THREADS])
 755
 756 case "$THREADS" in
 757  no | none | single)
 758     THREADS=none
 759     ;;
 760  posix | posix95 | pthreads)
 761     THREADS=posix
 762     case "$host" in
 763      *-*-linux*)
 764         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 765         ;;
 766     esac
 767     ;;
 768  win32)
 769     ;;
 770  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 771     AC_MSG_ERROR(thread package $THREADS not yet supported)
 772     ;;
 773  *)
 774     AC_MSG_ERROR($THREADS is an unknown thread package)
 775     ;;
 776 esac
 777
 778 THREADCXXFLAGS=
 779 THREADLDFLAGS=
 780 THREADLIBS=
 781 THREADINCS=
 782 THREADDEPS=
 783 THREADH=
 784 THREADSPEC=
 785 case "$THREADS" in
 786  posix)
 787     case "$host" in
 788      *-*-cygwin*)
 789         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 790         ;;
 791      *-*-freebsd[[1234]]*)
 792         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 793         # merely adds pthread_* functions) but it does have a -pthread switch
 794         # which is required at link-time to select -lc_r *instead* of -lc.
 795         THREADLDFLAGS=-pthread
 796         # Don't set THREADSPEC here as might be expected since -pthread is
 797         # not processed when found within a spec file, it must come from
 798         # the command line.  For now, the user must provide the -pthread
 799         # switch to link code compiled with gcj.  In future, consider adding
 800         # support for weak references to pthread_* functions ala gthr.h API.
 801         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 802         ;;
 803      *-*-freebsd*)
 804         # FreeBSD 5 implements a model much closer to other modern UNIX
 805         # which support threads.  However, it still does not support
 806         # -lpthread.
 807         THREADLDFLAGS=-pthread
 808         THREADSPEC=-lc_r
 809         ;;
 810      alpha*-dec-osf*)
 811         THREADCXXFLAGS=-pthread
 812         # boehm-gc needs some functions from librt, so link that too.
 813         THREADLIBS='-lpthread -lrt'
 814         THREADSPEC='-lpthread -lrt'
 815         ;;
 816      *)
 817         THREADLIBS=-lpthread
 818         THREADSPEC=-lpthread
 819         ;;
 820     esac
 821     THREADH=posix-threads.h
 822     # MIT pthreads doesn't seem to have the mutexattr functions.
 823     # But for now we don't check for it.  We just assume you aren't
 824     # using MIT pthreads.
 825     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 826
 827     # If we're using the Boehm GC, then we happen to know that it
 828     # defines _REENTRANT, so we don't bother.  Eww.
 829     if test "$GC" != boehm; then
 830        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 831     fi
 832     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 833     ;;
 834
 835  win32)
 836     THREADH=win32-threads.h
 837     ;;
 838
 839  none)
 840     THREADH=no-threads.h
 841     ;;
 842 esac
 843 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 844 AC_SUBST(THREADLIBS)
 845 AC_SUBST(THREADINCS)
 846 AC_SUBST(THREADDEPS)
 847 AC_SUBST(THREADSPEC)
 848 AC_SUBST(THREADLDFLAGS)
 849 AC_SUBST(THREADCXXFLAGS)
 850 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 851 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 852 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 853
 854 if test -d sysdep; then true; else mkdir sysdep; fi
 855 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 856 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 857 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 858
 859 HASH_SYNC_SPEC=
 860 # Hash synchronization is only useful with posix threads right now.
 861 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 862    HASH_SYNC_SPEC=-fhash-synchronization
 863    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 864 fi
 865 AC_SUBST(HASH_SYNC_SPEC)
 866
 867 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 868
 869 # We're in the tree with gcc, and need to include some of its headers.
 870 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 871
 872 if test "x${with_newlib}" = "xyes"; then
 873    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 874    # may not work correctly, because the compiler may not be able to
 875    # link executables.
 876
 877    # We assume newlib.  This lets us hard-code the functions we know
 878    # we'll have.
 879    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 880    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 881    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 882    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 883    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 884    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 885    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 886    # This is only for POSIX threads.
 887    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 888    # We also assume we are using gcc, which provides alloca.
 889    AC_DEFINE(HAVE_ALLOCA)
 890
 891    # Assume we do not have getuid and friends.
 892    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 893    PLATFORMNET=NoNet
 894 else
 895    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 896                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 897                    access stat mkdir rename rmdir unlink realpath utime chmod \
 898                    nl_langinfo setlocale \
 899                    inet_pton uname inet_ntoa \
 900                    fork execvp pipe sigaction ftruncate])
 901    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 902    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 903    AC_CHECK_LIB(dl, dladdr, [
 904        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])
 905
 906    if test x"$build" = x"$host"; then
 907      AC_CHECK_FILES(/proc/self/exe, [
 908        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 909    else
 910      case $host in
 911      *-linux*)
 912        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 913        ;;
 914      esac
 915    fi
 916
 917    AM_ICONV
 918    AM_LC_MESSAGES
 919    AC_STRUCT_TIMEZONE
 920
 921    AC_CHECK_FUNCS(gethostbyname_r, [
 922      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 923        [Define if you have the 'gethostbyname_r' function.])
 924      # There are two different kinds of gethostbyname_r.
 925      # We look for the one that returns `int'.
 926      # Hopefully this check is robust enough.
 927      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 928        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 929
 930      case " $GCINCS " in
 931      *" -D_REENTRANT "*) ;;
 932      *)
 933         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 934         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 935         [libjava_cv_gethostbyname_r_needs_reentrant],
 936         [ AC_LANG_PUSH(C++)
 937           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 938             [[gethostbyname_r("", 0, 0);]])],
 939             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 940                 CPPFLAGS_SAVE="$CPPFLAGS"
 941                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 942                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 943                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 944                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 945                 CPPFLAGS="$CPPFLAGS_SAVE"
 946           ])
 947           AC_LANG_POP(C++)
 948         ])
 949         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 950           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 951         fi
 952      ;;
 953      esac
 954
 955      AC_CACHE_CHECK([for struct hostent_data],
 956         [libjava_cv_struct_hostent_data], [dnl
 957         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 958 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 959 # define _REENTRANT 1
 960 #endif
 961 #include <netdb.h>]], [[struct hostent_data data;]])],
 962           [libjava_cv_struct_hostent_data=yes],
 963           [libjava_cv_struct_hostent_data=no])])
 964      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 965        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 966          [Define if struct hostent_data is defined in netdb.h])
 967      fi
 968    ])
 969
 970    # FIXME: libjava source code expects to find a prototype for
 971    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 972    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 973    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 974    # linkage check is enough, yet C++ code requires proper prototypes.)
 975    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 976    AC_CHECK_FUNCS(gethostbyaddr_r, [
 977      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 978        [Define if you have the 'gethostbyaddr_r' function.])
 979      # There are two different kinds of gethostbyaddr_r.
 980      # We look for the one that returns `int'.
 981      # Hopefully this check is robust enough.
 982      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 983        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 984          [Define if gethostbyaddr_r returns 'int'.])])])])
 985
 986    AC_CHECK_FUNCS(gethostname, [
 987      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 988        [Define if you have the 'gethostname' function.])
 989      AC_EGREP_HEADER(gethostname, unistd.h, [
 990        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 991          [Define if gethostname is declared in <unistd.h>.])])])
 992
 993    AC_CHECK_FUNCS(usleep, [
 994      AC_EGREP_HEADER(usleep, unistd.h, [
 995        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 996           [Define if usleep is declared in <unistd.h>.])])])
 997
 998    # Look for these functions in the thread library, but only bother
 999    # if using POSIX threads.
1000    if test "$THREADS" = posix; then
1001       save_LIBS="$LIBS"
1002       LIBS="$LIBS $THREADLIBS"
1003       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1004       # E.g., Solaris.
1005       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1006
1007       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1008       # Solaris 7 the name librt is preferred.
1009       AC_CHECK_FUNCS(sched_yield, , [
1010         AC_CHECK_LIB(rt, sched_yield, [
1011           AC_DEFINE(HAVE_SCHED_YIELD)
1012           THREADLIBS="$THREADLIBS -lrt"
1013           THREADSPEC="$THREADSPEC -lrt"], [
1014           AC_CHECK_LIB(posix4, sched_yield, [
1015             AC_DEFINE(HAVE_SCHED_YIELD)
1016             THREADLIBS="$THREADLIBS -lposix4"
1017             THREADSPEC="$THREADSPEC -lposix4"])])])
1018       LIBS="$save_LIBS"
1019
1020       # We can save a little space at runtime if the mutex has m_count
1021       # or __m_count.  This is a nice hack for Linux.
1022       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1023           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1024         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1025              [Define if pthread_mutex_t has m_count member.]), [
1026         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1027             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1028           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1029             [Define if pthread_mutex_t has __m_count member.]))])
1030    fi
1031
1032    # We require a way to get the time.
1033    time_found=no
1034    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1035    if test "$time_found" = no; then
1036       AC_MSG_ERROR([no function found to get the time])
1037    fi
1038
1039    AC_CHECK_FUNCS(memmove)
1040
1041    # We require memcpy.
1042    memcpy_found=no
1043    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1044    if test "$memcpy_found" = no; then
1045       AC_MSG_ERROR([memcpy is required])
1046    fi
1047
1048    AC_CHECK_LIB(dl, dlopen, [
1049        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
1050
1051    # Some library-finding code we stole from Tcl.
1052    #--------------------------------------------------------------------
1053    #    Check for the existence of the -lsocket and -lnsl libraries.
1054    #    The order here is important, so that they end up in the right
1055    #    order in the command line generated by make.  Here are some
1056    #    special considerations:
1057    #    1. Use "connect" and "accept" to check for -lsocket, and
1058    #       "gethostbyname" to check for -lnsl.
1059    #    2. Use each function name only once:  can't redo a check because
1060    #       autoconf caches the results of the last check and won't redo it.
1061    #    3. Use -lnsl and -lsocket only if they supply procedures that
1062    #       aren't already present in the normal libraries.  This is because
1063    #       IRIX 5.2 has libraries, but they aren't needed and they're
1064    #       bogus:  they goof up name resolution if used.
1065    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1066    #       To get around this problem, check for both libraries together
1067    #       if -lsocket doesn't work by itself.
1068    #--------------------------------------------------------------------
1069
1070    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1071     [gcj_cv_lib_sockets=
1072      gcj_checkBoth=0
1073      unset ac_cv_func_connect
1074      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1075      if test "$gcj_checkSocket" = 1; then
1076          unset ac_cv_func_connect
1077          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1078                       gcj_checkBoth=1)
1079      fi
1080      if test "$gcj_checkBoth" = 1; then
1081          gcj_oldLibs=$LIBS
1082          LIBS="$LIBS -lsocket -lnsl"
1083          unset ac_cv_func_accept
1084          AC_CHECK_FUNC(accept,
1085                        [gcj_checkNsl=0
1086                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1087          unset ac_cv_func_accept
1088          LIBS=$gcj_oldLibs
1089      fi
1090      unset ac_cv_func_gethostbyname
1091      gcj_oldLibs=$LIBS
1092      LIBS="$LIBS $gcj_cv_lib_sockets"
1093      AC_CHECK_FUNC(gethostbyname, ,
1094                    [AC_CHECK_LIB(nsl, main,
1095                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1096      unset ac_cv_func_gethostbyname
1097      LIBS=$gcj_oldLIBS
1098    ])
1099    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1100
1101    if test "$with_system_zlib" = yes; then
1102       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1103    fi
1104
1105    # Test for Gtk stuff, if asked for.
1106    if test "$use_gtk_awt" = yes; then
1107       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1108       AC_SUBST(GTK_CFLAGS)
1109       AC_SUBST(GTK_LIBS)
1110
1111       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1112       AC_SUBST(GLIB_CFLAGS)
1113       AC_SUBST(GLIB_LIBS)
1114
1115       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1116       AC_SUBST(LIBART_CFLAGS)
1117       AC_SUBST(LIBART_LIBS)
1118
1119       # We require the XTest Extension to support java.awt.Robot.
1120       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1121                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1122                    [${X_LIBS}])
1123    fi
1124
1125    # On Solaris, and maybe other architectures, the Boehm collector
1126    # requires -ldl.
1127    if test "$GC" = boehm; then
1128       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1129    fi
1130 fi
1131
1132 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1133 case $build in
1134     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1135     *)         CLASSPATH_SEPARATOR=':' ;;
1136 esac
1137 AC_SUBST(CLASSPATH_SEPARATOR)
1138
1139 # We must search the source tree for java.lang, since we still don't
1140 # have libgcj.jar nor java/lang/*.class
1141 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1142 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1143
1144 # Since some classes depend on this one, we need its source available
1145 # before we can do any GCJ compilation test :-(
1146 if test ! -f gnu/classpath/Configuration.java; then
1147   test -d gnu || mkdir gnu
1148   test -d gnu/classpath || mkdir gnu/classpath
1149   # Note that it is not crucial that all the values here be correct.
1150   sed -e "s,@prefix@,$prefix," \
1151       -e "s,@VERSION@,$VERSION," \
1152       -e "s,@LIBDEBUG@,false," \
1153       -e "s,@INIT_LOAD_LIBRARY@,false," \
1154       -e "s,@@,$LIBGCJDEBUG," \
1155       -e "s,@default_toolkit@,$TOOLKIT," \
1156       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1157       -e "s,@GTK_CAIRO_ENABLED@,false," \
1158         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1159         > gnu/classpath/Configuration.java
1160   # We do not want to redirect the output of the grep below to /dev/null,
1161   # but we add /dev/null to the input list so that grep will print the
1162   # filename of Configuration.java in case it finds any matches.
1163   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1164     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1165   fi
1166 fi
1167
1168 LT_AC_PROG_GCJ
1169
1170 # Now remove it.
1171 rm -f gnu/classpath/Configuration.java
1172
1173 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1174
1175 AC_CHECK_SIZEOF(void *)
1176
1177 AC_C_BIGENDIAN
1178
1179 ZLIBS=
1180 SYS_ZLIBS=
1181 ZINCS=
1182
1183 if test -z "$ZLIBSPEC"; then
1184    # Use zlib from the GCC tree.
1185    ZINCS='-I$(top_srcdir)/../zlib'
1186    ZLIBS=../zlib/libzgcj_convenience.la
1187 else
1188    # System's zlib.
1189    SYS_ZLIBS="$ZLIBSPEC"
1190 fi
1191 AC_SUBST(ZLIBS)
1192 AC_SUBST(SYS_ZLIBS)
1193 AC_SUBST(ZINCS)
1194 AC_SUBST(DIVIDESPEC)
1195 AC_SUBST(CHECKREFSPEC)
1196 AC_SUBST(EXCEPTIONSPEC)
1197 AC_SUBST(BACKTRACESPEC)
1198 AC_SUBST(IEEESPEC)
1199
1200 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1201 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1202 AC_SUBST(GCC_UNWIND_INCLUDE)
1203
1204 # Process the option "--enable-version-specific-runtime-libs"
1205 # Calculate toolexeclibdir
1206 case ${version_specific_libs} in
1207   yes)
1208     # Need the gcc compiler version to know where to install libraries
1209     # and header files if --enable-version-specific-runtime-libs option
1210     # is selected.
1211     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1212     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1213     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1214     toolexeclibdir=$toolexecmainlibdir
1215     ;;
1216   no)
1217     if test -n "$with_cross_host" &&
1218        test x"$with_cross_host" != x"no"; then
1219       # Install a library built with a cross compiler in tooldir, not libdir.
1220       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1221       toolexecmainlibdir='$(toolexecdir)/lib'
1222     else
1223       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1224       toolexecmainlibdir='$(libdir)'
1225     fi
1226     multi_os_directory=`$CC -print-multi-os-directory`
1227     case $multi_os_directory in
1228       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1229       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1230     esac
1231     ;;
1232 esac
1233 AC_SUBST(toolexecdir)
1234 AC_SUBST(toolexecmainlibdir)
1235 AC_SUBST(toolexeclibdir)
1236
1237 # Determine where the standard .db file is found.
1238 multi_os_directory=`$CC -print-multi-os-directory`
1239 case $multi_os_directory in
1240   .) dbexecdir='$(libdir)/gcj-$(gcc_version)' ;; # Avoid /.
1241   *) dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)' ;;
1242 esac
1243 AC_SUBST(dbexecdir)
1244
1245 # Determine gcj version number.
1246 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1247 GCJVERSION=$gcjversion
1248 AC_SUBST(GCJVERSION)
1249 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1250
1251 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1252 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1253
1254 TL_AC_GXX_INCLUDE_DIR
1255
1256 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1257 # On that system, sys/ioctl.h will not include sys/filio.h unless
1258 # BSD_COMP is defined; just including sys/filio.h is simpler.
1259 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1260 # for now.  If you change this, you also must update natFile.cc.
1261 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1262                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1263                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1264                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1265                   dirent.h])
1266 AC_CHECK_HEADERS(inttypes.h, [
1267     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1268     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1269 ])
1270 AC_HEADER_SYS_WAIT
1271
1272 AC_CHECK_TYPE([ssize_t], [int])
1273
1274 AC_MSG_CHECKING([for in_addr_t])
1275 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1276 #if STDC_HEADERS
1277 #include <stdlib.h>
1278 #include <stddef.h>
1279 #endif
1280 #if HAVE_NETINET_IN_H
1281 #include <netinet/in.h>
1282 #endif]], [[in_addr_t foo;]])],
1283   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1284      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1285    AC_MSG_RESULT(yes)],
1286   [AC_MSG_RESULT(no)])
1287
1288 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1289 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1290   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1291      [Define if struct ip_mreq is defined in netinet/in.h.])
1292    AC_MSG_RESULT(yes)],
1293   [AC_MSG_RESULT(no)])
1294
1295 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1296 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1297   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1298      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1299    AC_MSG_RESULT(yes)],
1300   [AC_MSG_RESULT(no)])
1301
1302 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1303 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1304   [AC_DEFINE(HAVE_INET6, 1,
1305      [Define if inet6 structures are defined in netinet/in.h.])
1306    AC_MSG_RESULT(yes)],
1307   [AC_MSG_RESULT(no)])
1308
1309 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1310 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1311 #include <sys/types.h>
1312 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1313   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1314    AC_MSG_RESULT(yes)],
1315   [AC_MSG_RESULT(no)])
1316
1317 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1318 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1319   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1320    AC_MSG_RESULT(yes)],
1321   [AC_MSG_RESULT(no)
1322    AC_MSG_CHECKING([for global timezone variable])
1323    dnl FIXME: we don't want a link check here because that won't work
1324    dnl when cross-compiling.  So instead we make an assumption that
1325    dnl the header file will mention timezone if it exists.
1326    dnl Don't find the win32 function timezone
1327    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1328      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1329       AC_MSG_RESULT(yes)],
1330      [AC_MSG_RESULT(no)
1331        AC_MSG_CHECKING([for global _timezone variable])
1332        dnl FIXME: As above, don't want link check
1333        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1334          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1335             [Define if your platform has the global _timezone variable.])
1336           AC_MSG_RESULT(yes)],
1337           [AC_MSG_RESULT(no)])])])
1338
1339 AC_FUNC_ALLOCA
1340 AC_FUNC_MMAP
1341
1342 AC_CHECK_PROGS(PERL, perl, false)
1343
1344 SYSDEP_SOURCES=
1345 SIGNAL_HANDLER_AUX=
1346
1347 case "${host}" in
1348  i?86-*-linux*)
1349     SIGNAL_HANDLER=include/i386-signal.h
1350     ;;
1351  sparc*-sun-solaris*)
1352     SIGNAL_HANDLER=include/sparc-signal.h
1353     ;;
1354 # ia64-*)
1355 #    SYSDEP_SOURCES=sysdep/ia64.c
1356 #    test -d sysdep || mkdir sysdep
1357 #    ;;
1358  hppa*-*-linux*)
1359     SIGNAL_HANDLER=include/pa-signal.h
1360     ;;
1361  ia64-*-linux*)
1362     SIGNAL_HANDLER=include/dwarf2-signal.h
1363     ;;
1364  powerpc*-*-linux*)
1365     SIGNAL_HANDLER=include/powerpc-signal.h
1366     ;;
1367  alpha*-*-linux*)
1368     SIGNAL_HANDLER=include/dwarf2-signal.h
1369     ;;
1370  s390*-*-linux*)
1371     SIGNAL_HANDLER=include/s390-signal.h
1372     ;;
1373  x86_64*-*-linux*)
1374     SIGNAL_HANDLER=include/x86_64-signal.h
1375     SIGNAL_HANDLER_AUX=include/i386-signal.h
1376     ;;
1377  sparc*-*-linux*)
1378     SIGNAL_HANDLER=include/dwarf2-signal.h
1379     ;;
1380  sh*-*-linux*)
1381     SIGNAL_HANDLER=include/sh-signal.h
1382     ;;
1383  *mingw*)
1384     SIGNAL_HANDLER=include/win32-signal.h
1385     ;;
1386  mips*-*-linux*)
1387     SIGNAL_HANDLER=include/mips-signal.h
1388     ;;
1389  *-*-darwin*)
1390     SIGNAL_HANDLER=include/darwin-signal.h
1391     ;;
1392  *)
1393     SIGNAL_HANDLER=include/default-signal.h
1394     ;;
1395 esac
1396
1397 # If we're using sjlj exceptions, forget what we just learned.
1398 if test "$enable_sjlj_exceptions" = yes; then
1399    SIGNAL_HANDLER=include/default-signal.h
1400    SIGNAL_HANDLER_AUX=
1401 fi
1402
1403 AC_SUBST(SYSDEP_SOURCES)
1404
1405 if test -z "$SIGNAL_HANDLER_AUX"; then
1406   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1407 fi
1408
1409 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1410                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1411
1412 if test "${multilib}" = "yes"; then
1413   multilib_arg="--enable-multilib"
1414 else
1415   multilib_arg=
1416 fi
1417
1418 # See if we support thread-local storage.
1419 GCC_CHECK_TLS
1420
1421
1422 here=`${PWDCMD-pwd}`
1423 AC_SUBST(here)
1424
1425 # We get this from the environment.
1426 AC_SUBST(GCJFLAGS)
1427
1428 AC_CONFIG_FILES([
1429 Makefile
1430 libgcj.pc
1431 libgcj.spec
1432 libgcj-test.spec
1433 gcj/Makefile
1434 include/Makefile
1435 testsuite/Makefile
1436 ])
1437
1438 AC_CONFIG_COMMANDS([default],
1439 [# Only add multilib support code if we just rebuilt top-level Makefile.
1440 case " $CONFIG_FILES " in
1441  *" Makefile "*)
1442    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1443    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1444    ;;
1445 esac
1446 for ac_multi_file in $CONFIG_FILES; do
1447   case $ac_multi_file in
1448   */Makefile)
1449     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1450   esac
1451 done
1452 ],
1453 srcdir=${srcdir}
1454 host=${host}
1455 target=${target}
1456 with_multisubdir=${with_multisubdir}
1457 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1458 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1459 libgcj_basedir=${libgcj_basedir}
1460 CC="${CC}"
1461 CXX="${CXX}"
1462 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1463 )
1464
1465 AC_OUTPUT