libffi/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(fficonfig.h.in)
   3 AM_CONFIG_HEADER(fficonfig.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl Default to --enable-multilib
  12 AC_ARG_ENABLE(multilib,
  13 [  --enable-multilib       build many library versions (default)],
  14 [case "${enableval}" in
  15   yes) multilib=yes ;;
  16   no)  multilib=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  18  esac], [multilib=yes])dnl
  19
  20 dnl We may get other options which we don't document:
  21 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  22
  23 if test "${srcdir}" = "."; then
  24   if test "${with_target_subdir}" != "."; then
  25     libffi_basedir="${with_multisrctop}../"
  26   else
  27     libffi_basedir="${with_multisrctop}"
  28   fi
  29 else
  30   libffi_basedir=
  31 fi
  32 AC_SUBST(libffi_basedir)
  33 AC_CONFIG_AUX_DIR(${libffi_basedir}..)
  34
  35 AC_CANONICAL_HOST
  36
  37 AM_PROG_LIBTOOL
  38
  39 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
  40
  41 AC_EXEEXT
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_CC
  45 AC_PROG_LIBTOOL
  46
  47 TARGETDIR="unknown"
  48 case "$host" in
  49 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
  50 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  53 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  54 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  55 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  56 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  57 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  58 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  61 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  62 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  63 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  64 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  65 mips64*-*);;
  66 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  67 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  68 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  69 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  70 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  71 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  72 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  73 arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
  74 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  75 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  76 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  77 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  78 esac
  79
  80 if test $TARGETDIR = unknown; then
  81   AC_ERROR("libffi has not been ported to $host.")
  82 fi
  83
  84 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
  85 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
  86 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  87 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  88 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  89 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  90 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  91 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  92 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  93 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  94 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  95 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  96 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
  97 AM_CONDITIONAL(S390, test x$TARGET = xS390)
  98 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
  99 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 100
 101 if test x$TARGET = xMIPS_LINUX; then
 102   TARGET=MIPS
 103 fi
 104
 105 AC_HEADER_STDC
 106 AC_CHECK_FUNCS(memcpy)
 107 AC_FUNC_ALLOCA
 108
 109 dnl AC_CHECK_SIZEOF(char)
 110 AC_COMPILE_CHECK_SIZEOF(short)
 111 AC_COMPILE_CHECK_SIZEOF(int)
 112 AC_COMPILE_CHECK_SIZEOF(long)
 113 AC_COMPILE_CHECK_SIZEOF(long long)
 114 AC_COMPILE_CHECK_SIZEOF(float)
 115 AC_COMPILE_CHECK_SIZEOF(double)
 116 AC_COMPILE_CHECK_SIZEOF(long double)
 117
 118 AC_COMPILE_CHECK_SIZEOF(void *)
 119 AC_C_BIGENDIAN_CROSS
 120
 121 if test x$TARGET = xSPARC; then
 122     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 123         libffi_cv_as_sparc_ua_pcrel, [
 124         save_CFLAGS="$CFLAGS"
 125         save_LDFLAGS="$LDFLAGS"
 126         CFLAGS="$CFLAGS -fpic"
 127         LDFLAGS="$LDFLAGS -shared"
 128         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 129                     [libffi_cv_as_sparc_ua_pcrel=yes],
 130                     [libffi_cv_as_sparc_ua_pcrel=no])
 131         CFLAGS="$save_CFLAGS"
 132         LDFLAGS="$save_LDFLAGS"])
 133     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 134         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 135                   [Define if your assembler and linker support unaligned PC relative relocs.])
 136     fi
 137
 138     AC_CACHE_CHECK([assembler .register pseudo-op support],
 139        libffi_cv_as_register_pseudo_op, [
 140        libffi_cv_as_register_pseudo_op=unknown
 141        # Check if we have .register
 142        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 143                        [libffi_cv_as_register_pseudo_op=yes],
 144                        [libffi_cv_as_register_pseudo_op=no])
 145     ])
 146     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 147        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 148                [Define if your assembler supports .register.])
 149     fi
 150 fi
 151
 152 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 153     libffi_cv_ro_eh_frame, [
 154         libffi_cv_ro_eh_frame=no
 155         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 156         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 157             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 158                 libffi_cv_ro_eh_frame=yes
 159             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 160                  | grep -v '#write' > /dev/null; then
 161                 libffi_cv_ro_eh_frame=yes
 162             fi
 163         fi
 164         rm -f conftest.*
 165     ])
 166 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 167     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 168               [Define if .eh_frame sections should be read-only.])
 169 fi
 170
 171 AC_SUBST(TARGET)
 172 AC_SUBST(TARGETDIR)
 173
 174 AC_SUBST(SHELL)
 175
 176 AC_ARG_ENABLE(debug,
 177 [  --enable-debug          debugging mode],
 178   if test "$enable_debug" = "yes"; then
 179     AC_DEFINE(FFI_DEBUG)
 180   fi)
 181
 182 AC_ARG_ENABLE(structs,
 183 [  --disable-structs       omit code for struct support],
 184   if test "$enable_structs" = "no"; then
 185     AC_DEFINE(FFI_NO_STRUCTS)
 186   fi)
 187
 188 AC_ARG_ENABLE(raw-api,
 189 [  --disable-raw-api       make the raw api unavailable],
 190   if test "$enable_raw_api" = "no"; then
 191     AC_DEFINE(FFI_NO_RAW_API)
 192   fi)
 193
 194 AC_ARG_ENABLE(purify-safety,
 195 [  --enable-purify-safety  purify-safe mode],
 196   if test "$enable_purify_safety" = "yes"; then
 197     AC_DEFINE(USING_PURIFY)
 198   fi)
 199
 200 if test -n "$with_cross_host" &&
 201    test x"$with_cross_host" != x"no"; then
 202   toolexecdir='$(exec_prefix)/$(target_alias)'
 203   toolexeclibdir='$(toolexecdir)/lib'
 204 else
 205   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 206   toolexeclibdir='$(libdir)'
 207 fi
 208 multi_os_directory=`$CC -print-multi-os-directory`
 209 case $multi_os_directory in
 210   .) ;; # Avoid trailing /.
 211   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 212 esac
 213 AC_SUBST(toolexecdir)
 214 AC_SUBST(toolexeclibdir)
 215
 216 if test "${multilib}" = "yes"; then
 217   multilib_arg="--enable-multilib"
 218 else
 219   multilib_arg=
 220 fi
 221
 222 AC_OUTPUT(include/Makefile include/ffi.h Makefile,
 223 [
 224 if test -n "$CONFIG_FILES"; then
 225    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 226    ac_file=Makefile . ${srcdir}/${libffi_basedir}../config-ml.in
 227 fi
 228 ],
 229 srcdir=${srcdir}
 230 host=${host}
 231 target=${target}
 232 with_multisubdir=${with_multisubdir}
 233 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 234 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 235 libffi_basedir=${libffi_basedir}
 236 CC="${CC}"
 237 DEFS="$DEFS"
 238 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 239 test ! -d include && mkdir include
 240 test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
 241 if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then
 242         echo fficonfig.h unchanged
 243 else
 244         echo Moving fficonfig.h to include/fficonfig.h
 245         cp fficonfig.h include/fficonfig.h
 246 fi
 247 )
 248
 249 # Make target subdirectories if required.
 250 test -d src || mkdir src
 251 test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}