gcc/ada/a-dirval-mingw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --             A D A . D I R E C T O R I E S . V A L I D I T Y              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                            (Windows Version)                             --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2007, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is the Windows version of this package
  36
  37 with Ada.Characters.Latin_1; use Ada.Characters.Latin_1;
  38
  39 package body Ada.Directories.Validity is
  40
  41    Invalid_Character : constant array (Character) of Boolean :=
  42                          (NUL .. US | '\'       => True,
  43                           '/' | ':' | '*' | '?' => True,
  44                           '"' | '<' | '>' | '|' => True,
  45                           DEL .. NBSP           => True,
  46                           others                => False);
  47
  48    ---------------------------------
  49    -- Is_Path_Name_Case_Sensitive --
  50    ---------------------------------
  51
  52    function Is_Path_Name_Case_Sensitive return Boolean is
  53    begin
  54       return False;
  55    end Is_Path_Name_Case_Sensitive;
  56
  57    ------------------------
  58    -- Is_Valid_Path_Name --
  59    ------------------------
  60
  61    function Is_Valid_Path_Name (Name : String) return Boolean is
  62       Start : Positive := Name'First;
  63       Last  : Natural;
  64
  65    begin
  66       --  A path name cannot be empty, cannot contain more than 256 characters,
  67       --  cannot contain invalid characters and each directory/file name need
  68       --  to be valid.
  69
  70       if Name'Length = 0 or else Name'Length > 256 then
  71          return False;
  72
  73       else
  74          --  A drive letter may be specified at the beginning
  75
  76          if Name'Length >= 2
  77            and then  Name (Start + 1) = ':'
  78            and then
  79             (Name (Start) in 'A' .. 'Z' or else
  80              Name (Start) in 'a' .. 'z')
  81          then
  82             Start := Start + 2;
  83
  84             --  A drive letter followed by a colon and followed by nothing or
  85             --  by a relative path is an ambiguous path name on Windows, so we
  86             --  don't accept it.
  87
  88             if Start > Name'Last
  89               or else (Name (Start) /= '/' and then Name (Start) /= '\')
  90             then
  91                return False;
  92             end if;
  93          end if;
  94
  95          loop
  96             --  Look for the start of the next directory or file name
  97
  98             while Start <= Name'Last and then
  99               (Name (Start) = '\' or Name (Start) = '/')
 100             loop
 101                Start := Start + 1;
 102             end loop;
 103
 104             --  If all directories/file names are OK, return True
 105
 106             exit when Start > Name'Last;
 107
 108             Last := Start;
 109
 110             --  Look for the end of the directory/file name
 111
 112             while Last < Name'Last loop
 113                exit when Name (Last + 1) = '\' or Name (Last + 1) = '/';
 114                Last := Last + 1;
 115             end loop;
 116
 117             --  Check if the directory/file name is valid
 118
 119             if not Is_Valid_Simple_Name (Name (Start .. Last)) then
 120                   return False;
 121             end if;
 122
 123             --  Move to the next name
 124
 125             Start := Last + 1;
 126          end loop;
 127       end if;
 128
 129       --  If Name follows the rules, it is valid
 130
 131       return True;
 132    end Is_Valid_Path_Name;
 133
 134    --------------------------
 135    -- Is_Valid_Simple_Name --
 136    --------------------------
 137
 138    function Is_Valid_Simple_Name (Name : String) return Boolean is
 139       Only_Spaces : Boolean;
 140
 141    begin
 142       --  A file name cannot be empty, cannot contain more than 256 characters,
 143       --  and cannot contain invalid characters.
 144
 145       if Name'Length = 0 or else Name'Length > 256 then
 146          return False;
 147
 148       --  Name length is OK
 149
 150       else
 151          Only_Spaces := True;
 152          for J in Name'Range loop
 153             if Invalid_Character (Name (J)) then
 154                return False;
 155             elsif Name (J) /= ' ' then
 156                Only_Spaces := False;
 157             end if;
 158          end loop;
 159
 160          --  If no invalid chars, and not all spaces, file name is valid
 161
 162          return not Only_Spaces;
 163       end if;
 164    end Is_Valid_Simple_Name;
 165
 166    -------------
 167    -- OpenVMS --
 168    -------------
 169
 170    function OpenVMS return Boolean is
 171    begin
 172       return False;
 173    end OpenVMS;
 174
 175    -------------
 176    -- Windows --
 177    -------------
 178
 179    function Windows return Boolean is
 180    begin
 181       return True;
 182    end Windows;
 183
 184 end Ada.Directories.Validity;